CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  32   file(GLOB_RECURSE
  33     tablegenned_files_on_include_dir
  34     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  35   file(GLOB_RECURSE
  36     tablegenned_files_on_lib_dir
  37     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  38   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  39     message(FATAL_ERROR "Apparently there is a previous in-source build,
  40 probably as the result of running `configure' and `make' on
  41 ${LLVM_MAIN_SRC_DIR}.
  42 This may cause problems. The suspicious files are:
  43 ${tablegenned_files_on_lib_dir}
  44 ${tablegenned_files_on_include_dir}
  45 Please clean the source directory.")
  46   endif()
  47 endif()
  48
  49 set(LLVM_ALL_TARGETS
  50   Alpha
  51   ARM
  52   CBackend
  53   CellSPU
  54   CppBackend
  55   Mips
  56   MSIL
  57   MSP430
  58   PIC16
  59   PowerPC
  60   Sparc
  61   SystemZ
  62   X86
  63   XCore
  64   )
  65
  66 if( MSVC )
  67   set(LLVM_TARGETS_TO_BUILD X86
  68     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  69 else( MSVC )
  70   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  71     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  72 endif( MSVC )
  73
  74 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  75
  76 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  77   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  78 else()
  79   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  80 endif()
  81
  82 if( LLVM_ENABLE_ASSERTIONS )
  83   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  84   if( NOT MSVC )
  85     add_definitions( -D_DEBUG )
  86   endif()
  87   # On Release builds cmake automatically defines NDEBUG, so we
  88   # explicitly undefine it:
  89   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  90     add_definitions( -UNDEBUG )
  91   endif()
  92 else()
  93   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  94     add_definitions( -DNDEBUG )
  95   endif()
  96 endif()
  97
  98 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  99   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 100 endif()
 101
 102 set(LLVM_ENUM_TARGETS "")
 103 foreach(c ${LLVM_TARGETS_TO_BUILD})
 104   list(FIND LLVM_ALL_TARGETS ${c} idx)
 105   if( idx LESS 0 )
 106     message(FATAL_ERROR "The target `${c}' does not exists.
 107     It should be one of\n${LLVM_ALL_TARGETS}")
 108   else()
 109     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 110   endif()
 111 endforeach(c)
 112
 113 # Produce llvm/Config/Targets.def
 114 configure_file(
 115   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 116   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 117   )
 118
 119 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 120
 121 # Add path for custom modules
 122 set(CMAKE_MODULE_PATH
 123   ${CMAKE_MODULE_PATH}
 124   "${LLVM_MAIN_SRC_DIR}/cmake"
 125   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 126   )
 127
 128 include(AddLLVMDefinitions)
 129
 130 if(WIN32)
 131   if(CYGWIN)
 132     set(LLVM_ON_WIN32 0)
 133     set(LLVM_ON_UNIX 1)
 134   else(CYGWIN)
 135     set(LLVM_ON_WIN32 1)
 136     set(LLVM_ON_UNIX 0)
 137   endif(CYGWIN)
 138   set(LTDL_SHLIB_EXT ".dll")
 139   set(EXEEXT ".exe")
 140   # Maximum path length is 160 for non-unicode paths
 141   set(MAXPATHLEN 160)
 142 else(WIN32)
 143   if(UNIX)
 144     set(LLVM_ON_WIN32 0)
 145     set(LLVM_ON_UNIX 1)
 146     set(LTDL_SHLIB_EXT ".so")
 147     set(EXEEXT "")
 148     # FIXME: Maximum path length is currently set to 'safe' fixed value
 149     set(MAXPATHLEN 2024)
 150   else(UNIX)
 151     MESSAGE(SEND_ERROR "Unable to determine platform")
 152   endif(UNIX)
 153 endif(WIN32)
 154
 155 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 156   set(HAVE_LLVM_CONFIG 1)
 157 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 158
 159 include(config-ix)
 160
 161 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 162
 163 set(ENABLE_PIC 0)
 164 if( LLVM_ENABLE_PIC )
 165   if( SUPPORTS_FPIC_FLAG )
 166     message(STATUS "Building with -fPIC")
 167     add_llvm_definitions(-fPIC)
 168     set(ENABLE_PIC 1)
 169  else( SUPPORTS_FPIC_FLAG )
 170     message(STATUS "Warning: -fPIC not supported.")
 171   endif()
 172 endif()
 173
 174 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 175 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 176 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 177
 178 # set(CMAKE_VERBOSE_MAKEFILE true)
 179
 180 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 181 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 182
 183 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 184   # TODO: support other platforms and toolchains.
 185   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 186   if( LLVM_BUILD_32_BITS )
 187     message(STATUS "Building 32 bits executables and libraries.")
 188     add_llvm_definitions( -m32 )
 189     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 190     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 191     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 192   endif( LLVM_BUILD_32_BITS )
 193 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 194
 195 if( MSVC )
 196   # List of valid CRTs for MSVC
 197   set(MSVC_CRT
 198     MD
 199     MDd)
 200
 201   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 202   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 203   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 204   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 205   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 206   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 207
 208   # Suppress 'new behavior: elements of array 'array' will be default initialized'
 209   add_llvm_definitions( -wd4351 )
 210
 211   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 212     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 213     if (idx LESS 0)
 214       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 215     endif (idx LESS 0)
 216     add_llvm_definitions("/${LLVM_USE_CRT}")
 217     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 218   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 219 endif( MSVC )
 220
 221 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 222
 223 include(AddLLVM)
 224 include(TableGen)
 225
 226 add_subdirectory(lib/Support)
 227 add_subdirectory(lib/System)
 228
 229 # Everything else depends on Support and System:
 230 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 231
 232 set(LLVM_TABLEGEN "tblgen" CACHE
 233   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 234 # Effective tblgen executable to be used:
 235 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 236
 237 add_subdirectory(utils/TableGen)
 238
 239 if( CMAKE_CROSSCOMPILING )
 240   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 241   include( CrossCompileLLVM )
 242 endif( CMAKE_CROSSCOMPILING )
 243
 244 add_subdirectory(include/llvm)
 245
 246 add_subdirectory(lib/VMCore)
 247 add_subdirectory(lib/CodeGen)
 248 add_subdirectory(lib/CodeGen/SelectionDAG)
 249 add_subdirectory(lib/CodeGen/AsmPrinter)
 250 add_subdirectory(lib/Bitcode/Reader)
 251 add_subdirectory(lib/Bitcode/Writer)
 252 add_subdirectory(lib/Transforms/Utils)
 253 add_subdirectory(lib/Transforms/Instrumentation)
 254 add_subdirectory(lib/Transforms/Scalar)
 255 add_subdirectory(lib/Transforms/IPO)
 256 add_subdirectory(lib/Transforms/Hello)
 257 add_subdirectory(lib/Linker)
 258 add_subdirectory(lib/Analysis)
 259 add_subdirectory(lib/Analysis/IPA)
 260 add_subdirectory(lib/MC)
 261
 262 add_subdirectory(utils/FileCheck)
 263
 264  set(LLVM_ENUM_ASM_PRINTERS "")
 265  set(LLVM_ENUM_ASM_PARSERS "")
 266  foreach(t ${LLVM_TARGETS_TO_BUILD})
 267   message(STATUS "Targeting ${t}")
 268   add_subdirectory(lib/Target/${t})
 269   add_subdirectory(lib/Target/${t}/TargetInfo)
 270   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 271    add_subdirectory(lib/Target/${t}/AsmPrinter)
 272     set(LLVM_ENUM_ASM_PRINTERS
 273         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 274  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 275   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmParser/CMakeLists.txt )
 276    add_subdirectory(lib/Target/${t}/AsmParser)
 277     set(LLVM_ENUM_ASM_PARSERS
 278         "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 279  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmParser/CMakeLists.txt )
 280 endforeach(t)
 281
 282 # Produce llvm/Config/AsmPrinters.def
 283 configure_file(
 284   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 285   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 286   )
 287
 288 # Produce llvm/Config/AsmParsers.def
 289 configure_file(
 290   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 291   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 292   )
 293
 294 add_subdirectory(lib/ExecutionEngine)
 295 add_subdirectory(lib/ExecutionEngine/Interpreter)
 296 add_subdirectory(lib/ExecutionEngine/JIT)
 297 add_subdirectory(lib/Target)
 298 add_subdirectory(lib/AsmParser)
 299 add_subdirectory(lib/Debugger)
 300 add_subdirectory(lib/Archive)
 301
 302 add_subdirectory(projects)
 303 add_subdirectory(tools)
 304
 305 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 306 if (LLVM_EXAMPLES)
 307   add_subdirectory(examples)
 308 endif ()
 309
 310 install(DIRECTORY include
 311   DESTINATION .
 312   PATTERN ".svn" EXCLUDE
 313   PATTERN "*.cmake" EXCLUDE
 314   PATTERN "*.in" EXCLUDE
 315   )
 316
 317 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 318   DESTINATION .
 319   )
 320
 321 # TODO: make and install documentation.