tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file is distributed under the University of Illinois Open Source
   7 # License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21
  22 #---- begin autoconf values ----
  23 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  24 my $VERSION             = q{@PACKAGE_VERSION@};
  25 my $PREFIX              = q{@LLVM_PREFIX@};
  26 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  27 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  28 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  29 my $LLVM_ON_WIN32       = q{@LLVM_ON_WIN32@};
  30 my $LLVM_ON_UNIX        = q{@LLVM_ON_UNIX@};
  31 my $LLVMGCCDIR          = q{@LLVMGCCDIR@};
  32 my $LLVMGCC             = q{@LLVMGCC@};
  33 my $LLVMGXX             = q{@LLVMGXX@};
  34 my $LLVMGCC_VERSION     = q{@LLVMGCC_VERSION@};
  35 my $LLVMGCC_MAJVERS     = q{@LLVMGCC_MAJVERS@};
  36 my $ENDIAN              = q{@ENDIAN@};
  37 my $SHLIBEXT            = q{@SHLIBEXT@};
  38 my $EXEEXT              = q{@EXEEXT@};
  39 my $OS                  = q{@OS@};
  40 my $ARCH                = lc(q{@ARCH@});
  41 my $TARGET_TRIPLE       = q{@target@};
  42 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  43 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  44 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  45 #---- end autoconf values ----
  46
  47 # Must pretend x86_64 architecture is really x86, otherwise the native backend
  48 # won't get linked in.
  49 $ARCH = "x86" if $ARCH eq "x86_64";
  50
  51 #---- begin Makefile values ----
  52 my $CPPFLAGS            = q{@LLVM_CPPFLAGS@};
  53 my $CFLAGS              = q{@LLVM_CFLAGS@};
  54 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  55 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  56 my $SYSTEM_LIBS         = q{@LIBS@};
  57 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  58 #---- end Makefile values ----
  59
  60 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  61 # been installed, or is running from the build directory, which changes the
  62 # locations of some files.
  63
  64 # Convert the current executable name into its directory (e.g. ".").
  65 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  66
  67 # Find the unix pwd program: we don't want to use the bash builtin, as it does
  68 # not look through symlinks etc.
  69 my $PWD = `which pwd`;
  70 chomp($PWD);
  71 $PWD = "pwd" if (!-e $PWD);
  72
  73 # Turn the directory into an absolute directory on the file system, also pop up
  74 # from "bin" into the build or prefix dir.
  75 my $ABS_RUN_DIR = `cd $RUN_DIR/..; $PWD`;
  76 chomp($ABS_RUN_DIR);
  77
  78 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  79 my $ABS_OBJ_ROOT = "$LLVM_OBJ_ROOT/$LLVM_BUILDMODE";
  80 $ABS_OBJ_ROOT = `cd $ABS_OBJ_ROOT; $PWD` if (-d $ABS_OBJ_ROOT);
  81 chomp($ABS_OBJ_ROOT);
  82
  83 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  84 my $INCLUDEOPTION = "-I$INCLUDEDIR";
  85 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  86 my $BINDIR     = "$ABS_RUN_DIR/bin";
  87 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  88   # If we are running out of the build directory, the include dir is in the
  89   # srcdir.
  90   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  91   # We need include files from both the srcdir and objdir.
  92   $INCLUDEOPTION = "-I$INCLUDEDIR -I$LLVM_OBJ_ROOT/include"
  93 } else {
  94   # If installed, ignore the prefix the tree was configured with, use the
  95   # current prefix.
  96   $PREFIX = $ABS_RUN_DIR;
  97 }
  98
  99 sub usage;
 100 sub fix_library_names (@);
 101 sub fix_library_files (@);
 102 sub expand_dependencies (@);
 103 sub name_map_entries;
 104
 105 # Parse our command-line arguments.
 106 usage if @ARGV == 0;
 107 my @components;
 108 my $has_opt = 0;
 109 my $want_libs = 0;
 110 my $want_libnames = 0;
 111 my $want_libfiles = 0;
 112 my $want_components = 0;
 113 foreach my $arg (@ARGV) {
 114     if ($arg =~ /^-/) {
 115         if ($arg eq "--version") {
 116             $has_opt = 1; print "$VERSION\n";
 117         } elsif ($arg eq "--prefix") {
 118             $has_opt = 1; print "$PREFIX\n";
 119         } elsif ($arg eq "--bindir") {
 120             $has_opt = 1; print "$BINDIR\n";
 121         } elsif ($arg eq "--includedir") {
 122             $has_opt = 1; print "$INCLUDEDIR\n";
 123         } elsif ($arg eq "--libdir") {
 124             $has_opt = 1; print "$LIBDIR\n";
 125         } elsif ($arg eq "--cppflags") {
 126             $has_opt = 1; print "$INCLUDEOPTION $CPPFLAGS\n";
 127         } elsif ($arg eq "--cflags") {
 128             $has_opt = 1; print "$INCLUDEOPTION $CFLAGS\n";
 129         } elsif ($arg eq "--cxxflags") {
 130             $has_opt = 1; print "$INCLUDEOPTION $CXXFLAGS\n";
 131         } elsif ($arg eq "--ldflags") {
 132             $has_opt = 1; print "-L$LIBDIR $LDFLAGS $SYSTEM_LIBS\n";
 133         } elsif ($arg eq "--libs") {
 134             $has_opt = 1; $want_libs = 1;
 135         } elsif ($arg eq "--libnames") {
 136             $has_opt = 1; $want_libnames = 1;
 137         } elsif ($arg eq "--libfiles") {
 138             $has_opt = 1; $want_libfiles = 1;
 139         } elsif ($arg eq "--components") {
 140             $has_opt = 1; print join(' ', name_map_entries), "\n";
 141         } elsif ($arg eq "--targets-built") {
 142             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 143         } elsif ($arg eq "--host-target") {
 144             $has_opt = 1; print "$TARGET_TRIPLE\n";
 145         } elsif ($arg eq "--build-mode") {
 146             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 147         } elsif ($arg eq "--obj-root") {
 148             $has_opt = 1; print `cd $LLVM_OBJ_ROOT/; $PWD`;
 149         } elsif ($arg eq "--src-root") {
 150             $has_opt = 1; print `cd $LLVM_SRC_ROOT/; $PWD`;
 151         } else {
 152             usage();
 153         }
 154     } else {
 155         push @components, $arg;
 156     }
 157 }
 158
 159 # If no options were specified, fail.
 160 usage unless $has_opt;
 161
 162 # If no components were specified, default to 'all'.
 163 if (@components == 0) {
 164     push @components, 'all';
 165 }
 166
 167 # Force component names to lower case.
 168 @components = map lc, @components;
 169
 170 # Handle any arguments which require building our dependency graph.
 171 if ($want_libs || $want_libnames || $want_libfiles) {
 172     my @libs = expand_dependencies(@components);
 173     print join(' ', fix_library_names(@libs)), "\n" if ($want_libs);
 174     print join(' ',  @libs), "\n" if ($want_libnames);
 175     print join(' ', fix_library_files(@libs)), "\n" if ($want_libfiles);
 176 }
 177
 178 exit 0;
 179
 180 #==========================================================================
 181 #  Support Routines
 182 #==========================================================================
 183
 184 sub usage {
 185     print STDERR <<__EOD__;
 186 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 187
 188 Get various configuration information needed to compile programs which use
 189 LLVM.  Typically called from 'configure' scripts.  Examples:
 190   llvm-config --cxxflags
 191   llvm-config --ldflags
 192   llvm-config --libs engine bcreader scalaropts
 193
 194 Options:
 195   --version          Print LLVM version.
 196   --prefix           Print the installation prefix.
 197   --src-root         Print the source root LLVM was built from.
 198   --obj-root         Print the object root used to build LLVM.
 199   --bindir           Directory containing LLVM executables.
 200   --includedir       Directory containing LLVM headers.
 201   --libdir           Directory containing LLVM libraries.
 202   --cppflags         C preprocessor flags for files that include LLVM headers.
 203   --cflags           C compiler flags for files that include LLVM headers.
 204   --cxxflags         C++ compiler flags for files that include LLVM headers.
 205   --ldflags          Print Linker flags.
 206   --libs             Libraries needed to link against LLVM components.
 207   --libnames         Bare library names for in-tree builds.
 208   --libfiles         Fully qualified library filenames for makefile depends.
 209   --components       List of all possible components.
 210   --targets-built    List of all targets currently built.
 211   --host-target      Target triple used to configure LLVM.
 212   --build-mode       Print build mode of LLVM tree (e.g. Debug or Release).
 213 Typical components:
 214   all                All LLVM libraries (default).
 215   backend            Either a native backend or the C backend.
 216   engine             Either a native JIT or a bytecode interpreter.
 217 __EOD__
 218     exit(1);
 219 }
 220
 221 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 222 # files which can't be found using -L.
 223 sub fix_library_names (@) {
 224     my @libs = @_;
 225     my @result;
 226     foreach my $lib (@libs) {
 227         # Transform the bare library name appropriately.
 228         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 229         if (defined $basename) {
 230             push @result, "-l$basename";
 231         } else {
 232             push @result, "$LIBDIR/$lib";
 233         }
 234     }
 235     return @result;
 236 }
 237
 238 # Turn the list of libraries into a list of files.
 239 sub fix_library_files(@) {
 240     my @libs = @_;
 241     my @result;
 242     foreach my $lib (@libs) {
 243         # Transform the bare library name into a filename.
 244         push @result, "$LIBDIR/$lib";
 245     }
 246     return @result;
 247 }
 248
 249 #==========================================================================
 250 #  Library Dependency Analysis
 251 #==========================================================================
 252 #  Given a few human-readable library names, find all their dependencies
 253 #  and sort them into an order which the linker will like.  If we packed
 254 #  our libraries into fewer archives, we could make the linker do much
 255 #  of this work for us.
 256 #
 257 #  Libraries have two different types of names in this code: Human-friendly
 258 #  "component" names entered on the command-line, and the raw file names
 259 #  we use internally (and ultimately pass to the linker).
 260 #
 261 #  To understand this code, you'll need a working knowledge of Perl 5,
 262 #  and possibly some quality time with 'man perlref'.
 263
 264 sub load_dependencies;
 265 sub build_name_map;
 266 sub have_native_backend;
 267 sub find_best_engine;
 268 sub expand_names (@);
 269 sub find_all_required_sets (@);
 270 sub find_all_required_sets_helper ($$@);
 271
 272 # Each "set" contains one or more libraries which must be included as a
 273 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 274 # reference pointing to a list of internal library names.
 275 my @SETS;
 276
 277 # Various mapping tables.
 278 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 279 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 280 my %NAME_MAP;       # Maps human-entered names to internal names.
 281
 282 # Have our dependencies been loaded yet?
 283 my $DEPENDENCIES_LOADED = 0;
 284
 285 # Given a list of human-friendly component names, translate them into a
 286 # complete set of linker arguments.
 287 sub expand_dependencies (@) {
 288     my @libs = @_;
 289     load_dependencies;
 290     my @required_sets = find_all_required_sets(expand_names(@libs));
 291     my @sorted_sets = topologically_sort_sets(@required_sets);
 292
 293     # Expand the library sets into libraries.
 294     my @result;
 295     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 296     return @result;
 297 }
 298
 299 # Load in the raw dependency data stored at the end of this file.
 300 sub load_dependencies {
 301     return if $DEPENDENCIES_LOADED;
 302     $DEPENDENCIES_LOADED = 1;
 303     while (<DATA>) {
 304         # Parse our line.
 305         my ($libs, $deps) = /^\s*([^:]+):\s*(.*)\s*$/;
 306         die "Malformed dependency data" unless defined $deps;
 307         my @libs = split(' ', $libs);
 308         my @deps = split(' ', $deps);
 309
 310         # Record our dependency data.
 311         my $set = \@libs;
 312         push @SETS, $set;
 313         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 314         $SET_DEPS{$set} = \@deps;
 315     }
 316     build_name_map;
 317 }
 318
 319 # Build a map converting human-friendly component names into internal
 320 # library names.
 321 sub build_name_map {
 322     # Add entries for all the actual libraries.
 323     foreach my $set (@SETS) {
 324         foreach my $lib (sort @$set) {
 325             my $short_name = $lib;
 326             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 327             $short_name =~ tr/A-Z/a-z/;
 328             $NAME_MAP{$short_name} = [$lib];
 329         }
 330     }
 331
 332     # Add target-specific entries
 333     foreach my $target (@TARGETS_BUILT) {
 334         # FIXME: Temporary, until we don't switch all targets
 335         if (defined $NAME_MAP{$target.'asmprinter'}) {
 336             $NAME_MAP{$target} = [$target.'info',
 337                                   $target.'asmprinter',
 338                                   $target.'codegen']
 339         } else {
 340             $NAME_MAP{$target} = [$target.'info',
 341                                   $NAME_MAP{$target}[0]]
 342         }
 343
 344         if (defined $NAME_MAP{$target.'asmparser'}) {
 345             push @{$NAME_MAP{$target}},$target.'asmparser'
 346         }
 347     }
 348
 349     # Add virtual entries.
 350     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 351     $NAME_MAP{'nativecodegen'} = have_native_backend() ? [$ARCH.'codegen'] : [];
 352     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 353     $NAME_MAP{'engine'}  = find_best_engine;
 354     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 355 }
 356
 357 # Return true if we have a native backend to use.
 358 sub have_native_backend {
 359     my %BUILT;
 360     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 361     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 362 }
 363
 364 # Find a working subclass of ExecutionEngine for this platform.
 365 sub find_best_engine {
 366     if (have_native_backend && $TARGET_HAS_JIT) {
 367         return ['jit', 'native'];
 368     } else {
 369         return ['interpreter'];
 370     }
 371 }
 372
 373 # Get all the human-friendly component names.
 374 sub name_map_entries {
 375     load_dependencies;
 376     return sort keys %NAME_MAP;
 377 }
 378
 379 # Map human-readable names to internal library names.
 380 sub expand_names (@) {
 381     my @names = @_;
 382     my @result;
 383     foreach my $name (@names) {
 384         if (defined $LIB_TO_SET_MAP{$name}) {
 385             # We've hit bottom: An actual library name.
 386             push @result, $name;
 387         } elsif (defined $NAME_MAP{$name}) {
 388             # We've found a short name to expand.
 389             push @result, expand_names(@{$NAME_MAP{$name}});
 390         } else {
 391             print STDERR "llvm-config: unknown component name: $name\n";
 392             exit(1);
 393         }
 394     }
 395     return @result;
 396 }
 397
 398 # Given a list of internal library names, return all sets of libraries which
 399 # will need to be included by the linker (in no particular order).
 400 sub find_all_required_sets (@) {
 401     my @libs = @_;
 402     my %sets_added;
 403     my @result;
 404     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 405     return @result;
 406 }
 407
 408 # Recursive closures are pretty broken in Perl, so we're going to separate
 409 # this function from find_all_required_sets and pass in the state we need
 410 # manually, as references.  Yes, this is fairly unpleasant.
 411 sub find_all_required_sets_helper ($$@) {
 412     my ($sets_added, $result, @libs) = @_;
 413     foreach my $lib (@libs) {
 414         my $set = $LIB_TO_SET_MAP{$lib};
 415         next if defined $$sets_added{$set};
 416         $$sets_added{$set} = 1;
 417         push @$result, $set;
 418         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 419     }
 420 }
 421
 422 # Print a list of sets, with a label.  Used for debugging.
 423 sub print_sets ($@) {
 424     my ($label, @sets) = @_;
 425     my @output;
 426     foreach my $set (@sets) { push @output, join(',', @$set); }
 427     print "$label: ", join(';', @output), "\n";
 428 }
 429
 430 # Returns true if $lib is a key in $added.
 431 sub has_lib_been_added ($$) {
 432     my ($added, $lib) = @_;
 433     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 434 }
 435
 436 # Returns true if all the dependencies of $set appear in $added.
 437 sub have_all_deps_been_added ($$) {
 438     my ($added, $set) = @_;
 439     #print_sets("  Checking", $set);
 440     #print_sets("     Wants", $SET_DEPS{$set});
 441     foreach my $lib (@{$SET_DEPS{$set}}) {
 442         return 0 unless has_lib_been_added($added, $lib);
 443     }
 444     return 1;
 445 }
 446
 447 # Given a list of sets, topologically sort them using dependencies.
 448 sub topologically_sort_sets (@) {
 449     my @sets = @_;
 450     my %added;
 451     my @result;
 452     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 453         #print_sets("So far", reverse(@result));
 454         #print_sets("Remaining", @sets);
 455         for (my $i = 0; $i < @sets; ++$i) {
 456             my $set = $sets[$i];
 457             if (have_all_deps_been_added(\%added, $set)) {
 458                 push @result, $set;
 459                 $added{$set} = 1;
 460                 #print "Removing $i.\n";
 461                 splice(@sets, $i, 1);
 462                 next SCAN; # Restart our scan.
 463             }
 464         }
 465         die "Can't find a library with no dependencies";
 466     }
 467     return reverse(@result);
 468 }
 469
 470 # Our library dependency data will be added after the '__END__' token, and will
 471 # be read through the magic <DATA> filehandle.
 472 __END__