cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(alloca.h HAVE_ALLOCA_H)
   5 check_include_file(argz.h HAVE_ARGZ_H)
   6 check_include_file(assert.h HAVE_ASSERT_H)
   7 check_include_file(dirent.h HAVE_DIRENT_H)
   8 check_include_file(dl.h HAVE_DL_H)
   9 check_include_file(dld.h HAVE_DLD_H)
  10 check_include_file(dlfcn.h HAVE_DLFCN_H)
  11 check_include_file(errno.h HAVE_ERRNO_H)
  12 check_include_file(execinfo.h HAVE_EXECINFO_H)
  13 check_include_file(fcntl.h HAVE_FCNTL_H)
  14 check_include_file(inttypes.h HAVE_INTTYPES_H)
  15 check_include_file(limits.h HAVE_LIMITS_H)
  16 check_include_file(link.h HAVE_LINK_H)
  17 check_include_file(malloc.h HAVE_MALLOC_H)
  18 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  19 check_include_file(memory.h HAVE_MEMORY_H)
  20 check_include_file(ndir.h HAVE_NDIR_H)
  21 check_include_file(pthread.h HAVE_PTHREAD_H)
  22 check_include_file(setjmp.h HAVE_SETJMP_H)
  23 check_include_file(signal.h HAVE_SIGNAL_H)
  24 check_include_file(stdint.h HAVE_STDINT_H)
  25 check_include_file(stdio.h HAVE_STDIO_H)
  26 check_include_file(stdlib.h HAVE_STDLIB_H)
  27 check_include_file(string.h HAVE_STRING_H)
  28 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  29 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  30 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  31 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  32 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  33 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  34 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  35 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  36 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  37 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  38 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  39 check_include_file(termios.h HAVE_TERMIOS_H)
  40 check_include_file(unistd.h HAVE_UNISTD_H)
  41 check_include_file(utime.h HAVE_UTIME_H)
  42 check_include_file(windows.h HAVE_WINDOWS_H)
  43
  44 # library checks
  45 include(CheckLibraryExists)
  46 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  47 check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  48 check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  49 check_library_exists(dl dlopen "" HAVE_LIBDL)
  50
  51 # function checks
  52 include(CheckSymbolExists)
  53 include(CheckFunctionExists)
  54 check_symbol_exists(alloca alloca.h HAVE_ALLOCA)
  55 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  56 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  57 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  58 check_function_exists(isatty HAVE_ISATTY)
  59 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  60 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  61 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  62 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  63 check_symbol_exists(ceilf math.h HAVE_CEILF)
  64 check_symbol_exists(floorf math.h HAVE_FLOORF)
  65 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  66 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  67                     HAVE_MALLOC_ZONE_STATISTICS)
  68 check_symbol_exists(mkdtemp unistd.h HAVE_MKDTEMP)
  69 check_symbol_exists(mkstemp unistd.h HAVE_MKSTEMP)
  70 check_symbol_exists(mktemp unistd.h HAVE_MKTEMP)
  71 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  72 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  73 check_symbol_exists(strerror string.h HAVE_STRERROR)
  74 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
  75 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
  76
  77 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  78 if( LLVM_USING_GLIBC )
  79   add_llvm_definitions( -D_GNU_SOURCE )
  80 endif()
  81
  82 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
  83 include(CheckAtomic)
  84
  85 include(CheckCXXCompilerFlag)
  86 check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  87
  88 include(GetTargetTriple)
  89 get_target_triple(LLVM_HOSTTRIPLE)
  90 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  91
  92 # Determine the native architecture.
  93 # FIXME: this will have to change for cross-compiling.
  94 string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
  95 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
  96   set(LLVM_NATIVE_ARCH X86)
  97 elseif (LLVM_NATIVE_ARCH STREQUAL amd64)
  98   set(LLVM_NATIVE_ARCH X86)
  99 elseif (LLVM_NATIVE_ARCH STREQUAL x86_64)
 100   set(LLVM_NATIVE_ARCH X86)
 101 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 102   set(LLVM_NATIVE_ARCH Sparc)
 103 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 104   set(LLVM_NATIVE_ARCH PowerPC)
 105 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 106   set(LLVM_NATIVE_ARCH Alpha)
 107 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 108   set(LLVM_NATIVE_ARCH ARM)
 109 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 110   set(LLVM_NATIVE_ARCH Mips)
 111 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 112   set(LLVM_NATIVE_ARCH "PIC16")
 113 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 114   set(LLVM_NATIVE_ARCH XCore)
 115 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 116   set(LLVM_NATIVE_ARCH MSP430)
 117 else ()
 118   message(STATUS
 119     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 120   set(LLVM_NATIVE_ARCH)
 121 endif ()
 122
 123 if (LLVM_NATIVE_ARCH)
 124   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 125   if (NATIVE_ARCH_IDX EQUAL -1)
 126     message(STATUS
 127       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 128     set(LLVM_NATIVE_ARCH)
 129   else ()
 130     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 131   endif ()
 132 endif()
 133
 134 if( MINGW )
 135   set(HAVE_LIBIMAGEHLP 1)
 136   set(HAVE_LIBPSAPI 1)
 137   # TODO: Check existence of libraries.
 138   #   include(CheckLibraryExists)
 139   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 140 endif( MINGW )
 141
 142 if( MSVC )
 143   set(error_t int)
 144   set(mode_t "unsigned short")
 145   set(LTDL_SHLIBPATH_VAR "PATH")
 146   set(LTDL_SYSSEARCHPATH "")
 147   set(LTDL_DLOPEN_DEPLIBS 1)
 148   set(SHLIBEXT ".lib")
 149   set(LTDL_OBJDIR "_libs")
 150   set(HAVE_STRTOLL 1)
 151   set(strtoll "_strtoi64")
 152   set(strtoull "_strtoui64")
 153   set(stricmp "_stricmp")
 154   set(strdup "_strdup")
 155 else( MSVC )
 156   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 157   set(LTDL_SYSSEARCHPATH "") # TODO
 158   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 159 endif( MSVC )
 160
 161 # FIXME: Signal handler return type, currently hardcoded to 'void'
 162 set(RETSIGTYPE void)
 163
 164 if( LLVM_ENABLE_THREADS )
 165   if( HAVE_PTHREAD_H OR WIN32 )
 166     set(ENABLE_THREADS 1)
 167   endif()
 168 endif()
 169
 170 if( ENABLE_THREADS )
 171   message(STATUS "Threads enabled.")
 172 else( ENABLE_THREADS )
 173   message(STATUS "Threads disabled.")
 174 endif()
 175
 176 configure_file(
 177   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 178   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 179   )
 180
 181 configure_file(
 182   ${LLVM_MAIN_INCLUDE_DIR}/llvm/ADT/iterator.cmake
 183   ${LLVM_BINARY_DIR}/include/llvm/ADT/iterator.h
 184   )
 185
 186 configure_file(
 187   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 188   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 189   )
 190