lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet2    : SDTypeProfile<2, 0, [SDTCisVT<0, f80>,
  21                                            SDTCisVT<1, f80>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def SDTX86CwdStore  : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  33
  34 def X86fld          : SDNode<"X86ISD::FLD", SDTX86Fld,
  35                              [SDNPHasChain, SDNPMayLoad]>;
  36 def X86fst          : SDNode<"X86ISD::FST", SDTX86Fst,
  37                              [SDNPHasChain, SDNPInFlag, SDNPMayStore]>;
  38 def X86fild         : SDNode<"X86ISD::FILD", SDTX86Fild,
  39                              [SDNPHasChain, SDNPMayLoad]>;
  40 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG", SDTX86Fild,
  41                              [SDNPHasChain, SDNPOutFlag, SDNPMayLoad]>;
  42 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  43                              [SDNPHasChain, SDNPMayStore]>;
  44 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  45                              [SDNPHasChain, SDNPMayStore]>;
  46 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  47                              [SDNPHasChain, SDNPMayStore]>;
  48 def X86fp_cwd_get16 : SDNode<"X86ISD::FNSTCW16m",          SDTX86CwdStore,
  49                              [SDNPHasChain, SDNPMayStore, SDNPSideEffect]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "##FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "##FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "##FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "##FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "##FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "##FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i16mem:$dst, RFP80:$src),
  99                               "##FP80_TO_INT16_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 101   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 102                               (outs), (ins i32mem:$dst, RFP80:$src),
 103                               "##FP80_TO_INT32_IN_MEM PSEUDO!",
 104                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 105   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 106                               (outs), (ins i64mem:$dst, RFP80:$src),
 107                               "##FP80_TO_INT64_IN_MEM PSEUDO!",
 108                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 109 }
 110
 111 let isTerminator = 1 in
 112   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 113     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "##FP_REG_KILL", []>;
 114
 115 // All FP Stack operations are represented with four instructions here.  The
 116 // first three instructions, generated by the instruction selector, use "RFP32"
 117 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 118 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 119 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 120 // copied to each other without losing information.  These instructions are all
 121 // pseudo instructions and use the "_Fp" suffix.
 122 // In some cases there are additional variants with a mixture of different
 123 // register sizes.
 124 // The second instruction is defined with FPI, which is the actual instruction
 125 // emitted by the assembler.  These use "RST" registers, although frequently
 126 // the actual register(s) used are implicit.  These are always 80 bits.
 127 // The FP stackifier pass converts one to the other after register allocation
 128 // occurs.
 129 //
 130 // Note that the FpI instruction should have instruction selection info (e.g.
 131 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 132 // encoding and asm printing info).
 133
 134 // Pseudo Instructions for FP stack return values.
 135 def FpGET_ST0_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 136 def FpGET_ST0_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 137 def FpGET_ST0_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 138
 139 // FpGET_ST1* should only be issued *after* an FpGET_ST0* has been issued when
 140 // there are two values live out on the stack from a call or inlineasm.  This
 141 // magic is handled by the stackifier.  It is not valid to emit FpGET_ST1* and
 142 // then FpGET_ST0*.  In addition, it is invalid for any FP-using operations to
 143 // occur between them.
 144 def FpGET_ST1_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 145 def FpGET_ST1_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 146 def FpGET_ST1_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 147
 148 let Defs = [ST0] in {
 149 def FpSET_ST0_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(0) = FPR
 150 def FpSET_ST0_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(0) = FPR
 151 def FpSET_ST0_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(0) = FPR
 152 }
 153
 154 let Defs = [ST1] in {
 155 def FpSET_ST1_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(1) = FPR
 156 def FpSET_ST1_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(1) = FPR
 157 def FpSET_ST1_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(1) = FPR
 158 }
 159
 160 // FpIf32, FpIf64 - Floating Point Psuedo Instruction template.
 161 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 162 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 163 // f80 instructions cannot use SSE and use neither of these.
 164 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 165   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 166 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 167   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 168
 169 // Register copies.  Just copies, the shortening ones do not truncate.
 170 let neverHasSideEffects = 1 in {
 171   def MOV_Fp3232 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 172   def MOV_Fp3264 : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 173   def MOV_Fp6432 : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 174   def MOV_Fp6464 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 175   def MOV_Fp8032 : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 176   def MOV_Fp3280 : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 177   def MOV_Fp8064 : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 178   def MOV_Fp6480 : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 179   def MOV_Fp8080 : FpI_  <(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 180 }
 181
 182 // Factoring for arithmetic.
 183 multiclass FPBinary_rr<SDNode OpNode> {
 184 // Register op register -> register
 185 // These are separated out because they have no reversed form.
 186 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 187                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 188 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 189                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 190 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 191                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 192 }
 193 // The FopST0 series are not included here because of the irregularities
 194 // in where the 'r' goes in assembly output.
 195 // These instructions cannot address 80-bit memory.
 196 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 197 // ST(0) = ST(0) + [mem]
 198 def _Fp32m  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 199                   [(set RFP32:$dst,
 200                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 201 def _Fp64m  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 202                   [(set RFP64:$dst,
 203                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 204 def _Fp64m32: FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 205                   [(set RFP64:$dst,
 206                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 207 def _Fp80m32: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 208                   [(set RFP80:$dst,
 209                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 210 def _Fp80m64: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 211                   [(set RFP80:$dst,
 212                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 213 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 214                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))> { let mayLoad = 1; }
 215 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 216                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))> { let mayLoad = 1; }
 217 // ST(0) = ST(0) + [memint]
 218 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2), OneArgFPRW,
 219                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 220                                        (X86fild addr:$src2, i16)))]>;
 221 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2), OneArgFPRW,
 222                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 223                                        (X86fild addr:$src2, i32)))]>;
 224 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2), OneArgFPRW,
 225                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 226                                        (X86fild addr:$src2, i16)))]>;
 227 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2), OneArgFPRW,
 228                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 229                                        (X86fild addr:$src2, i32)))]>;
 230 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2), OneArgFPRW,
 231                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 232                                        (X86fild addr:$src2, i16)))]>;
 233 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2), OneArgFPRW,
 234                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 235                                        (X86fild addr:$src2, i32)))]>;
 236 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 237                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))> { let mayLoad = 1; }
 238 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 239                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))> { let mayLoad = 1; }
 240 }
 241
 242 defm ADD : FPBinary_rr<fadd>;
 243 defm SUB : FPBinary_rr<fsub>;
 244 defm MUL : FPBinary_rr<fmul>;
 245 defm DIV : FPBinary_rr<fdiv>;
 246 defm ADD : FPBinary<fadd, MRM0m, "add">;
 247 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 248 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 249 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 250 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 251 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 252
 253 class FPST0rInst<bits<8> o, string asm>
 254   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 255 class FPrST0Inst<bits<8> o, string asm>
 256   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 257 class FPrST0PInst<bits<8> o, string asm>
 258   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 259
 260 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 261 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 262 // we have to put some 'r's in and take them out of weird places.
 263 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 264 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 265 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 266 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 267 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 268 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 269 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 270 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 271 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 272 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 273 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 274 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 275 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 276 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 277 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 278 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 279 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 280 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 281
 282 // Unary operations.
 283 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 284 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 285                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 286 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 287                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 288 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 289                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 290 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 291 }
 292
 293 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 294 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 295 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 296 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 297 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 298
 299 let neverHasSideEffects = 1 in {
 300 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP, []>;
 301 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP, []>;
 302 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP, []>;
 303 }
 304 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 305
 306 // Versions of FP instructions that take a single memory operand.  Added for the
 307 //   disassembler; remove as they are included with patterns elsewhere.
 308 def FCOM32m  : FPI<0xD8, MRM2m, (outs), (ins f32mem:$src), "fcom\t$src">;
 309 def FCOMP32m : FPI<0xD8, MRM3m, (outs), (ins f32mem:$src), "fcomp\t$src">;
 310
 311 def FLDENVm  : FPI<0xD9, MRM4m, (outs), (ins f32mem:$src), "fldenv\t$src">;
 312 def FSTENVm  : FPI<0xD9, MRM6m, (outs f32mem:$dst), (ins), "fstenv\t$dst">;
 313
 314 def FICOM32m : FPI<0xDA, MRM2m, (outs), (ins i32mem:$src), "ficom{l}\t$src">;
 315 def FICOMP32m: FPI<0xDA, MRM3m, (outs), (ins i32mem:$src), "ficomp{l}\t$src">;
 316
 317 def FCOM64m  : FPI<0xDC, MRM2m, (outs), (ins f64mem:$src), "fcom\t$src">;
 318 def FCOMP64m : FPI<0xDC, MRM3m, (outs), (ins f64mem:$src), "fcomp\t$src">;
 319
 320 def FISTTP32m: FPI<0xDD, MRM1m, (outs i32mem:$dst), (ins), "fisttp{l}\t$dst">;
 321 def FRSTORm  : FPI<0xDD, MRM4m, (outs f32mem:$dst), (ins), "frstor\t$dst">;
 322 def FSAVEm   : FPI<0xDD, MRM6m, (outs f32mem:$dst), (ins), "fsave\t$dst">;
 323 def FSTSWm   : FPI<0xDD, MRM7m, (outs f32mem:$dst), (ins), "fstsw\t$dst">;
 324
 325 def FICOM16m : FPI<0xDE, MRM2m, (outs), (ins i16mem:$src), "ficom{w}\t$src">;
 326 def FICOMP16m: FPI<0xDE, MRM3m, (outs), (ins i16mem:$src), "ficomp{w}\t$src">;
 327
 328 def FBLDm    : FPI<0xDF, MRM4m, (outs), (ins f32mem:$src), "fbld\t$src">;
 329 def FBSTPm   : FPI<0xDF, MRM6m, (outs f32mem:$dst), (ins), "fbstp\t$dst">;
 330
 331 // Floating point cmovs.
 332 multiclass FPCMov<PatLeaf cc> {
 333   def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 334                        CondMovFP,
 335                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 336                                         cc, EFLAGS))]>;
 337   def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 338                        CondMovFP,
 339                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 340                                         cc, EFLAGS))]>;
 341   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 342                      CondMovFP,
 343                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 344                                         cc, EFLAGS))]>;
 345 }
 346 let Uses = [EFLAGS], isTwoAddress = 1 in {
 347 defm CMOVB  : FPCMov<X86_COND_B>;
 348 defm CMOVBE : FPCMov<X86_COND_BE>;
 349 defm CMOVE  : FPCMov<X86_COND_E>;
 350 defm CMOVP  : FPCMov<X86_COND_P>;
 351 defm CMOVNB : FPCMov<X86_COND_AE>;
 352 defm CMOVNBE: FPCMov<X86_COND_A>;
 353 defm CMOVNE : FPCMov<X86_COND_NE>;
 354 defm CMOVNP : FPCMov<X86_COND_NP>;
 355 }
 356
 357 // These are not factored because there's no clean way to pass DA/DB.
 358 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 359                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 360 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 361                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 362 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 363                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 364 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 365                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 366 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 367                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 368 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 369                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 370 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 371                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 372 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 373                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 374
 375 // Floating point loads & stores.
 376 let canFoldAsLoad = 1 in {
 377 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 378                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 379 let isReMaterializable = 1, mayHaveSideEffects = 1 in
 380   def LD_Fp64m : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 381                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 382 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 383                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 384 }
 385 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 386                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 387 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 388                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 389 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 390                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 391 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 392                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 393 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 394                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 395 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 396                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 397 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 398                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 399 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 400                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 401 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 402                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 403 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 404                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 405 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 406                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 407 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 408                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 409
 410 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 411                   [(store RFP32:$src, addr:$op)]>;
 412 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 413                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 414 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 415                   [(store RFP64:$src, addr:$op)]>;
 416 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 417                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 418 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 419                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 420 // FST does not support 80-bit memory target; FSTP must be used.
 421
 422 let mayStore = 1, neverHasSideEffects = 1 in {
 423 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 424 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 425 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 426 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 427 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 428 }
 429 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 430                     [(store RFP80:$src, addr:$op)]>;
 431 let mayStore = 1, neverHasSideEffects = 1 in {
 432 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 433 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 434 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 435 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 436 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 437 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 438 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 439 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 440 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 441 }
 442
 443 let mayLoad = 1 in {
 444 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 445 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 446 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 447 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 448 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 449 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 450 }
 451 let mayStore = 1 in {
 452 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 453 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 454 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 455 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 456 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 457 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 458 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 459 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 460 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 461 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 462 }
 463
 464 // FISTTP requires SSE3 even though it's a FPStack op.
 465 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 466                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 467                     Requires<[HasSSE3]>;
 468 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 469                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 470                     Requires<[HasSSE3]>;
 471 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 472                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 473                     Requires<[HasSSE3]>;
 474 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 475                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 476                     Requires<[HasSSE3]>;
 477 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 478                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 479                     Requires<[HasSSE3]>;
 480 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 481                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 482                     Requires<[HasSSE3]>;
 483 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 484                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 485                     Requires<[HasSSE3]>;
 486 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 487                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 488                     Requires<[HasSSE3]>;
 489 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 490                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 491                     Requires<[HasSSE3]>;
 492
 493 let mayStore = 1 in {
 494 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 495 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 496 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst), "fisttp{ll}\t$dst">;
 497 }
 498
 499 // FP Stack manipulation instructions.
 500 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 501 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 502 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 503 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 504
 505 // Floating point constant loads.
 506 let isReMaterializable = 1 in {
 507 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 508                 [(set RFP32:$dst, fpimm0)]>;
 509 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 510                 [(set RFP32:$dst, fpimm1)]>;
 511 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 512                 [(set RFP64:$dst, fpimm0)]>;
 513 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 514                 [(set RFP64:$dst, fpimm1)]>;
 515 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 516                 [(set RFP80:$dst, fpimm0)]>;
 517 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 518                 [(set RFP80:$dst, fpimm1)]>;
 519 }
 520
 521 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 522 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 523
 524
 525 // Floating point compares.
 526 let Defs = [EFLAGS] in {
 527 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 528                         []>;  // FPSW = cmp ST(0) with ST(i)
 529 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 530                         []>;  // FPSW = cmp ST(0) with ST(i)
 531 def UCOM_Fpr80 : FpI_  <(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 532                         []>;  // FPSW = cmp ST(0) with ST(i)
 533
 534 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 535                   [(X86cmp RFP32:$lhs, RFP32:$rhs),
 536                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 537 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 538                   [(X86cmp RFP64:$lhs, RFP64:$rhs),
 539                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 540 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 541                   [(X86cmp RFP80:$lhs, RFP80:$rhs),
 542                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 543 }
 544
 545 let Defs = [EFLAGS], Uses = [ST0] in {
 546 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 547                     (outs), (ins RST:$reg),
 548                     "fucom\t$reg">, DD;
 549 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 550                     (outs), (ins RST:$reg),
 551                     "fucomp\t$reg">, DD;
 552 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 553                     (outs), (ins),
 554                     "fucompp">, DA;
 555
 556 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 557                     (outs), (ins RST:$reg),
 558                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 559 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 560                     (outs), (ins RST:$reg),
 561                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 562 }
 563
 564 // Floating point flag ops.
 565 let Defs = [AX] in
 566 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 567                   (outs), (ins), "fnstsw", []>, DF;
 568
 569 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 570                   (outs), (ins i16mem:$dst), "fnstcw\t$dst",
 571                   [(X86fp_cwd_get16 addr:$dst)]>;
 572
 573 let mayLoad = 1 in
 574 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 575                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 576
 577 //===----------------------------------------------------------------------===//
 578 // Non-Instruction Patterns
 579 //===----------------------------------------------------------------------===//
 580
 581 // Required for RET of f32 / f64 / f80 values.
 582 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 583 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 584 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 585
 586 // Required for CALL which return f32 / f64 / f80 values.
 587 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 588 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op, RFP64:$src)>;
 589 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 590 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op, RFP80:$src)>;
 591 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op, RFP80:$src)>;
 592 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op, RFP80:$src)>;
 593
 594 // Floating point constant -0.0 and -1.0
 595 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 596 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 597 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 598 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 599 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 600 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 601
 602 // Used to conv. i64 to f64 since there isn't a SSE version.
 603 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 604
 605 // FP extensions map onto simple pseudo-value conversions if they are to/from
 606 // the FP stack.
 607 def : Pat<(f64 (fextend RFP32:$src)), (MOV_Fp3264 RFP32:$src)>,
 608           Requires<[FPStackf32]>;
 609 def : Pat<(f80 (fextend RFP32:$src)), (MOV_Fp3280 RFP32:$src)>,
 610            Requires<[FPStackf32]>;
 611 def : Pat<(f80 (fextend RFP64:$src)), (MOV_Fp6480 RFP64:$src)>,
 612            Requires<[FPStackf64]>;
 613
 614 // FP truncations map onto simple pseudo-value conversions if they are to/from
 615 // the FP stack.  We have validated that only value-preserving truncations make
 616 // it through isel.
 617 def : Pat<(f32 (fround RFP64:$src)), (MOV_Fp6432 RFP64:$src)>,
 618           Requires<[FPStackf32]>;
 619 def : Pat<(f32 (fround RFP80:$src)), (MOV_Fp8032 RFP80:$src)>,
 620            Requires<[FPStackf32]>;
 621 def : Pat<(f64 (fround RFP80:$src)), (MOV_Fp8064 RFP80:$src)>,
 622            Requires<[FPStackf64]>;