lib/Target/X86/X86InstrMMX.td

   1 //====- X86InstrMMX.td - Describe the X86 Instruction Set --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 MMX instruction set, defining the instructions,
  11 // and properties of the instructions which are needed for code generation,
  12 // machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // MMX Pattern Fragments
  18 //===----------------------------------------------------------------------===//
  19
  20 def load_mmx : PatFrag<(ops node:$ptr), (v1i64 (load node:$ptr))>;
  21
  22 def bc_v8i8  : PatFrag<(ops node:$in), (v8i8  (bitconvert node:$in))>;
  23 def bc_v4i16 : PatFrag<(ops node:$in), (v4i16 (bitconvert node:$in))>;
  24 def bc_v2i32 : PatFrag<(ops node:$in), (v2i32 (bitconvert node:$in))>;
  25 def bc_v1i64 : PatFrag<(ops node:$in), (v1i64 (bitconvert node:$in))>;
  26
  27 //===----------------------------------------------------------------------===//
  28 // MMX Masks
  29 //===----------------------------------------------------------------------===//
  30
  31 // MMX_SHUFFLE_get_shuf_imm xform function: convert vector_shuffle mask to
  32 // PSHUFW imm.
  33 def MMX_SHUFFLE_get_shuf_imm : SDNodeXForm<vector_shuffle, [{
  34   return getI8Imm(X86::getShuffleSHUFImmediate(N));
  35 }]>;
  36
  37 // Patterns for: vector_shuffle v1, v2, <2, 6, 3, 7, ...>
  38 def mmx_unpckh : PatFrag<(ops node:$lhs, node:$rhs),
  39                          (vector_shuffle node:$lhs, node:$rhs), [{
  40   return X86::isUNPCKHMask(cast<ShuffleVectorSDNode>(N));
  41 }]>;
  42
  43 // Patterns for: vector_shuffle v1, v2, <0, 4, 2, 5, ...>
  44 def mmx_unpckl : PatFrag<(ops node:$lhs, node:$rhs),
  45                          (vector_shuffle node:$lhs, node:$rhs), [{
  46   return X86::isUNPCKLMask(cast<ShuffleVectorSDNode>(N));
  47 }]>;
  48
  49 // Patterns for: vector_shuffle v1, <undef>, <0, 0, 1, 1, ...>
  50 def mmx_unpckh_undef : PatFrag<(ops node:$lhs, node:$rhs),
  51                                (vector_shuffle node:$lhs, node:$rhs), [{
  52   return X86::isUNPCKH_v_undef_Mask(cast<ShuffleVectorSDNode>(N));
  53 }]>;
  54
  55 // Patterns for: vector_shuffle v1, <undef>, <2, 2, 3, 3, ...>
  56 def mmx_unpckl_undef : PatFrag<(ops node:$lhs, node:$rhs),
  57                                (vector_shuffle node:$lhs, node:$rhs), [{
  58   return X86::isUNPCKL_v_undef_Mask(cast<ShuffleVectorSDNode>(N));
  59 }]>;
  60
  61 def mmx_pshufw : PatFrag<(ops node:$lhs, node:$rhs),
  62                          (vector_shuffle node:$lhs, node:$rhs), [{
  63   return X86::isPSHUFDMask(cast<ShuffleVectorSDNode>(N));
  64 }], MMX_SHUFFLE_get_shuf_imm>;
  65
  66 //===----------------------------------------------------------------------===//
  67 // MMX Multiclasses
  68 //===----------------------------------------------------------------------===//
  69
  70 let Constraints = "$src1 = $dst" in {
  71   // MMXI_binop_rm - Simple MMX binary operator.
  72   multiclass MMXI_binop_rm<bits<8> opc, string OpcodeStr, SDNode OpNode,
  73                            ValueType OpVT, bit Commutable = 0> {
  74     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
  75                                   (ins VR64:$src1, VR64:$src2),
  76                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  77                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1, VR64:$src2)))]> {
  78       let isCommutable = Commutable;
  79     }
  80     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
  81                                   (ins VR64:$src1, i64mem:$src2),
  82                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  83                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1,
  84                                          (bitconvert
  85                                           (load_mmx addr:$src2)))))]>;
  86   }
  87
  88   multiclass MMXI_binop_rm_int<bits<8> opc, string OpcodeStr, Intrinsic IntId,
  89                                bit Commutable = 0> {
  90     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
  91                                   (ins VR64:$src1, VR64:$src2),
  92                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  93                  [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]> {
  94       let isCommutable = Commutable;
  95     }
  96     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
  97                                   (ins VR64:$src1, i64mem:$src2),
  98                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  99                  [(set VR64:$dst, (IntId VR64:$src1,
 100                                    (bitconvert (load_mmx addr:$src2))))]>;
 101   }
 102
 103   // MMXI_binop_rm_v1i64 - Simple MMX binary operator whose type is v1i64.
 104   //
 105   // FIXME: we could eliminate this and use MMXI_binop_rm instead if tblgen knew
 106   // to collapse (bitconvert VT to VT) into its operand.
 107   //
 108   multiclass MMXI_binop_rm_v1i64<bits<8> opc, string OpcodeStr, SDNode OpNode,
 109                                  bit Commutable = 0> {
 110     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 111                                   (ins VR64:$src1, VR64:$src2),
 112                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 113                   [(set VR64:$dst, (v1i64 (OpNode VR64:$src1, VR64:$src2)))]> {
 114       let isCommutable = Commutable;
 115     }
 116     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 117                                   (ins VR64:$src1, i64mem:$src2),
 118                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 119                   [(set VR64:$dst,
 120                     (OpNode VR64:$src1,(load_mmx addr:$src2)))]>;
 121   }
 122
 123   multiclass MMXI_binop_rmi_int<bits<8> opc, bits<8> opc2, Format ImmForm,
 124                                 string OpcodeStr, Intrinsic IntId,
 125                                 Intrinsic IntId2> {
 126     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 127                                   (ins VR64:$src1, VR64:$src2),
 128                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 129                   [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]>;
 130     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 131                                   (ins VR64:$src1, i64mem:$src2),
 132                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 133                   [(set VR64:$dst, (IntId VR64:$src1,
 134                                     (bitconvert (load_mmx addr:$src2))))]>;
 135     def ri : MMXIi8<opc2, ImmForm, (outs VR64:$dst),
 136                                    (ins VR64:$src1, i32i8imm:$src2),
 137                     !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 138            [(set VR64:$dst, (IntId2 VR64:$src1, (i32 imm:$src2)))]>;
 139   }
 140 }
 141
 142 //===----------------------------------------------------------------------===//
 143 // MMX EMMS & FEMMS Instructions
 144 //===----------------------------------------------------------------------===//
 145
 146 def MMX_EMMS  : MMXI<0x77, RawFrm, (outs), (ins), "emms",
 147                                                   [(int_x86_mmx_emms)]>;
 148 def MMX_FEMMS : MMXI<0x0E, RawFrm, (outs), (ins), "femms",
 149                                                   [(int_x86_mmx_femms)]>;
 150
 151 //===----------------------------------------------------------------------===//
 152 // MMX Scalar Instructions
 153 //===----------------------------------------------------------------------===//
 154
 155 // Data Transfer Instructions
 156 def MMX_MOVD64rr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 157                         "movd\t{$src, $dst|$dst, $src}",
 158                         [(set VR64:$dst,
 159                           (v2i32 (scalar_to_vector GR32:$src)))]>;
 160 let canFoldAsLoad = 1, isReMaterializable = 1 in
 161 def MMX_MOVD64rm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 162                         "movd\t{$src, $dst|$dst, $src}",
 163               [(set VR64:$dst,
 164                 (v2i32 (scalar_to_vector (loadi32 addr:$src))))]>;
 165 let mayStore = 1 in
 166 def MMX_MOVD64mr : MMXI<0x7E, MRMDestMem, (outs), (ins i32mem:$dst, VR64:$src),
 167                         "movd\t{$src, $dst|$dst, $src}", []>;
 168
 169 let neverHasSideEffects = 1 in
 170 def MMX_MOVD64to64rr : MMXRI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 171                              "movd\t{$src, $dst|$dst, $src}",
 172                              []>;
 173
 174 let neverHasSideEffects = 1 in
 175 // These are 64 bit moves, but since the OS X assembler doesn't
 176 // recognize a register-register movq, we write them as
 177 // movd.
 178 def MMX_MOVD64from64rr : MMXRI<0x7E, MRMDestReg,
 179                                (outs GR64:$dst), (ins VR64:$src),
 180                                "movd\t{$src, $dst|$dst, $src}", []>;
 181 def MMX_MOVD64rrv164 : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 182                             "movd\t{$src, $dst|$dst, $src}",
 183                             [(set VR64:$dst,
 184                               (v1i64 (scalar_to_vector GR64:$src)))]>;
 185
 186 let neverHasSideEffects = 1 in
 187 def MMX_MOVQ64rr : MMXI<0x6F, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src),
 188                         "movq\t{$src, $dst|$dst, $src}", []>;
 189 let canFoldAsLoad = 1, isReMaterializable = 1, mayHaveSideEffects = 1 in
 190 def MMX_MOVQ64rm : MMXI<0x6F, MRMSrcMem, (outs VR64:$dst), (ins i64mem:$src),
 191                         "movq\t{$src, $dst|$dst, $src}",
 192                         [(set VR64:$dst, (load_mmx addr:$src))]>;
 193 def MMX_MOVQ64mr : MMXI<0x7F, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 194                         "movq\t{$src, $dst|$dst, $src}",
 195                         [(store (v1i64 VR64:$src), addr:$dst)]>;
 196
 197 def MMX_MOVDQ2Qrr : SDIi8<0xD6, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 198                           "movdq2q\t{$src, $dst|$dst, $src}",
 199                           [(set VR64:$dst,
 200                             (v1i64 (bitconvert
 201                             (i64 (vector_extract (v2i64 VR128:$src),
 202                                   (iPTR 0))))))]>;
 203
 204 def MMX_MOVQ2DQrr : SSDIi8<0xD6, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 205                            "movq2dq\t{$src, $dst|$dst, $src}",
 206           [(set VR128:$dst,
 207             (movl immAllZerosV,
 208                   (v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src))))))]>;
 209
 210 let neverHasSideEffects = 1 in
 211 def MMX_MOVQ2FR64rr: SSDIi8<0xD6, MRMSrcReg, (outs FR64:$dst), (ins VR64:$src),
 212                            "movq2dq\t{$src, $dst|$dst, $src}", []>;
 213
 214 def MMX_MOVNTQmr  : MMXI<0xE7, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 215                          "movntq\t{$src, $dst|$dst, $src}",
 216                          [(int_x86_mmx_movnt_dq addr:$dst, VR64:$src)]>;
 217
 218 let AddedComplexity = 15 in
 219 // movd to MMX register zero-extends
 220 def MMX_MOVZDI2PDIrr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 221                              "movd\t{$src, $dst|$dst, $src}",
 222               [(set VR64:$dst,
 223                     (v2i32 (X86vzmovl (v2i32 (scalar_to_vector GR32:$src)))))]>;
 224 let AddedComplexity = 20 in
 225 def MMX_MOVZDI2PDIrm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst),
 226                                              (ins i32mem:$src),
 227                              "movd\t{$src, $dst|$dst, $src}",
 228           [(set VR64:$dst,
 229                 (v2i32 (X86vzmovl (v2i32
 230                                    (scalar_to_vector (loadi32 addr:$src))))))]>;
 231
 232 // Arithmetic Instructions
 233
 234 // -- Addition
 235 defm MMX_PADDB : MMXI_binop_rm<0xFC, "paddb", add, v8i8,  1>;
 236 defm MMX_PADDW : MMXI_binop_rm<0xFD, "paddw", add, v4i16, 1>;
 237 defm MMX_PADDD : MMXI_binop_rm<0xFE, "paddd", add, v2i32, 1>;
 238 defm MMX_PADDQ : MMXI_binop_rm<0xD4, "paddq", add, v1i64, 1>;
 239
 240 defm MMX_PADDSB  : MMXI_binop_rm_int<0xEC, "paddsb" , int_x86_mmx_padds_b, 1>;
 241 defm MMX_PADDSW  : MMXI_binop_rm_int<0xED, "paddsw" , int_x86_mmx_padds_w, 1>;
 242
 243 defm MMX_PADDUSB : MMXI_binop_rm_int<0xDC, "paddusb", int_x86_mmx_paddus_b, 1>;
 244 defm MMX_PADDUSW : MMXI_binop_rm_int<0xDD, "paddusw", int_x86_mmx_paddus_w, 1>;
 245
 246 // -- Subtraction
 247 defm MMX_PSUBB : MMXI_binop_rm<0xF8, "psubb", sub, v8i8>;
 248 defm MMX_PSUBW : MMXI_binop_rm<0xF9, "psubw", sub, v4i16>;
 249 defm MMX_PSUBD : MMXI_binop_rm<0xFA, "psubd", sub, v2i32>;
 250 defm MMX_PSUBQ : MMXI_binop_rm<0xFB, "psubq", sub, v1i64>;
 251
 252 defm MMX_PSUBSB  : MMXI_binop_rm_int<0xE8, "psubsb" , int_x86_mmx_psubs_b>;
 253 defm MMX_PSUBSW  : MMXI_binop_rm_int<0xE9, "psubsw" , int_x86_mmx_psubs_w>;
 254
 255 defm MMX_PSUBUSB : MMXI_binop_rm_int<0xD8, "psubusb", int_x86_mmx_psubus_b>;
 256 defm MMX_PSUBUSW : MMXI_binop_rm_int<0xD9, "psubusw", int_x86_mmx_psubus_w>;
 257
 258 // -- Multiplication
 259 defm MMX_PMULLW  : MMXI_binop_rm<0xD5, "pmullw", mul, v4i16, 1>;
 260
 261 defm MMX_PMULHW  : MMXI_binop_rm_int<0xE5, "pmulhw",  int_x86_mmx_pmulh_w,  1>;
 262 defm MMX_PMULHUW : MMXI_binop_rm_int<0xE4, "pmulhuw", int_x86_mmx_pmulhu_w, 1>;
 263 defm MMX_PMULUDQ : MMXI_binop_rm_int<0xF4, "pmuludq", int_x86_mmx_pmulu_dq, 1>;
 264
 265 // -- Miscellanea
 266 defm MMX_PMADDWD : MMXI_binop_rm_int<0xF5, "pmaddwd", int_x86_mmx_pmadd_wd, 1>;
 267
 268 defm MMX_PAVGB   : MMXI_binop_rm_int<0xE0, "pavgb", int_x86_mmx_pavg_b, 1>;
 269 defm MMX_PAVGW   : MMXI_binop_rm_int<0xE3, "pavgw", int_x86_mmx_pavg_w, 1>;
 270
 271 defm MMX_PMINUB  : MMXI_binop_rm_int<0xDA, "pminub", int_x86_mmx_pminu_b, 1>;
 272 defm MMX_PMINSW  : MMXI_binop_rm_int<0xEA, "pminsw", int_x86_mmx_pmins_w, 1>;
 273
 274 defm MMX_PMAXUB  : MMXI_binop_rm_int<0xDE, "pmaxub", int_x86_mmx_pmaxu_b, 1>;
 275 defm MMX_PMAXSW  : MMXI_binop_rm_int<0xEE, "pmaxsw", int_x86_mmx_pmaxs_w, 1>;
 276
 277 defm MMX_PSADBW  : MMXI_binop_rm_int<0xF6, "psadbw", int_x86_mmx_psad_bw, 1>;
 278
 279 // Logical Instructions
 280 defm MMX_PAND : MMXI_binop_rm_v1i64<0xDB, "pand", and, 1>;
 281 defm MMX_POR  : MMXI_binop_rm_v1i64<0xEB, "por" , or,  1>;
 282 defm MMX_PXOR : MMXI_binop_rm_v1i64<0xEF, "pxor", xor, 1>;
 283
 284 let Constraints = "$src1 = $dst" in {
 285   def MMX_PANDNrr : MMXI<0xDF, MRMSrcReg,
 286                          (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 287                          "pandn\t{$src2, $dst|$dst, $src2}",
 288                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 289                                                   VR64:$src2)))]>;
 290   def MMX_PANDNrm : MMXI<0xDF, MRMSrcMem,
 291                          (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 292                          "pandn\t{$src2, $dst|$dst, $src2}",
 293                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 294                                                   (load addr:$src2))))]>;
 295 }
 296
 297 // Shift Instructions
 298 defm MMX_PSRLW : MMXI_binop_rmi_int<0xD1, 0x71, MRM2r, "psrlw",
 299                                     int_x86_mmx_psrl_w, int_x86_mmx_psrli_w>;
 300 defm MMX_PSRLD : MMXI_binop_rmi_int<0xD2, 0x72, MRM2r, "psrld",
 301                                     int_x86_mmx_psrl_d, int_x86_mmx_psrli_d>;
 302 defm MMX_PSRLQ : MMXI_binop_rmi_int<0xD3, 0x73, MRM2r, "psrlq",
 303                                     int_x86_mmx_psrl_q, int_x86_mmx_psrli_q>;
 304
 305 defm MMX_PSLLW : MMXI_binop_rmi_int<0xF1, 0x71, MRM6r, "psllw",
 306                                     int_x86_mmx_psll_w, int_x86_mmx_pslli_w>;
 307 defm MMX_PSLLD : MMXI_binop_rmi_int<0xF2, 0x72, MRM6r, "pslld",
 308                                     int_x86_mmx_psll_d, int_x86_mmx_pslli_d>;
 309 defm MMX_PSLLQ : MMXI_binop_rmi_int<0xF3, 0x73, MRM6r, "psllq",
 310                                     int_x86_mmx_psll_q, int_x86_mmx_pslli_q>;
 311
 312 defm MMX_PSRAW : MMXI_binop_rmi_int<0xE1, 0x71, MRM4r, "psraw",
 313                                     int_x86_mmx_psra_w, int_x86_mmx_psrai_w>;
 314 defm MMX_PSRAD : MMXI_binop_rmi_int<0xE2, 0x72, MRM4r, "psrad",
 315                                     int_x86_mmx_psra_d, int_x86_mmx_psrai_d>;
 316
 317 // Shift up / down and insert zero's.
 318 def : Pat<(v1i64 (X86vshl     VR64:$src, (i8 imm:$amt))),
 319           (v1i64 (MMX_PSLLQri VR64:$src, imm:$amt))>;
 320 def : Pat<(v1i64 (X86vshr     VR64:$src, (i8 imm:$amt))),
 321           (v1i64 (MMX_PSRLQri VR64:$src, imm:$amt))>;
 322
 323 // Comparison Instructions
 324 defm MMX_PCMPEQB : MMXI_binop_rm_int<0x74, "pcmpeqb", int_x86_mmx_pcmpeq_b>;
 325 defm MMX_PCMPEQW : MMXI_binop_rm_int<0x75, "pcmpeqw", int_x86_mmx_pcmpeq_w>;
 326 defm MMX_PCMPEQD : MMXI_binop_rm_int<0x76, "pcmpeqd", int_x86_mmx_pcmpeq_d>;
 327
 328 defm MMX_PCMPGTB : MMXI_binop_rm_int<0x64, "pcmpgtb", int_x86_mmx_pcmpgt_b>;
 329 defm MMX_PCMPGTW : MMXI_binop_rm_int<0x65, "pcmpgtw", int_x86_mmx_pcmpgt_w>;
 330 defm MMX_PCMPGTD : MMXI_binop_rm_int<0x66, "pcmpgtd", int_x86_mmx_pcmpgt_d>;
 331
 332 // Conversion Instructions
 333
 334 // -- Unpack Instructions
 335 let Constraints = "$src1 = $dst" in {
 336   // Unpack High Packed Data Instructions
 337   def MMX_PUNPCKHBWrr : MMXI<0x68, MRMSrcReg,
 338                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 339                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 340                              [(set VR64:$dst,
 341                                (v8i8 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 342   def MMX_PUNPCKHBWrm : MMXI<0x68, MRMSrcMem,
 343                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 344                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 345                              [(set VR64:$dst,
 346                                (v8i8 (mmx_unpckh VR64:$src1,
 347                                       (bc_v8i8 (load_mmx addr:$src2)))))]>;
 348
 349   def MMX_PUNPCKHWDrr : MMXI<0x69, MRMSrcReg,
 350                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 351                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 352                              [(set VR64:$dst,
 353                                (v4i16 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 354   def MMX_PUNPCKHWDrm : MMXI<0x69, MRMSrcMem,
 355                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 356                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 357                              [(set VR64:$dst,
 358                                (v4i16 (mmx_unpckh VR64:$src1,
 359                                        (bc_v4i16 (load_mmx addr:$src2)))))]>;
 360
 361   def MMX_PUNPCKHDQrr : MMXI<0x6A, MRMSrcReg,
 362                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 363                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 364                              [(set VR64:$dst,
 365                                (v2i32 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 366   def MMX_PUNPCKHDQrm : MMXI<0x6A, MRMSrcMem,
 367                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 368                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 369                              [(set VR64:$dst,
 370                                (v2i32 (mmx_unpckh VR64:$src1,
 371                                        (bc_v2i32 (load_mmx addr:$src2)))))]>;
 372
 373   // Unpack Low Packed Data Instructions
 374   def MMX_PUNPCKLBWrr : MMXI<0x60, MRMSrcReg,
 375                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 376                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 377                              [(set VR64:$dst,
 378                                (v8i8 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 379   def MMX_PUNPCKLBWrm : MMXI<0x60, MRMSrcMem,
 380                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 381                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 382                              [(set VR64:$dst,
 383                                (v8i8 (mmx_unpckl VR64:$src1,
 384                                       (bc_v8i8 (load_mmx addr:$src2)))))]>;
 385
 386   def MMX_PUNPCKLWDrr : MMXI<0x61, MRMSrcReg,
 387                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 388                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 389                              [(set VR64:$dst,
 390                                (v4i16 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 391   def MMX_PUNPCKLWDrm : MMXI<0x61, MRMSrcMem,
 392                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 393                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 394                              [(set VR64:$dst,
 395                                (v4i16 (mmx_unpckl VR64:$src1,
 396                                        (bc_v4i16 (load_mmx addr:$src2)))))]>;
 397
 398   def MMX_PUNPCKLDQrr : MMXI<0x62, MRMSrcReg,
 399                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 400                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 401                              [(set VR64:$dst,
 402                                (v2i32 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 403   def MMX_PUNPCKLDQrm : MMXI<0x62, MRMSrcMem,
 404                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 405                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 406                              [(set VR64:$dst,
 407                                (v2i32 (mmx_unpckl VR64:$src1,
 408                                        (bc_v2i32 (load_mmx addr:$src2)))))]>;
 409 }
 410
 411 // -- Pack Instructions
 412 defm MMX_PACKSSWB : MMXI_binop_rm_int<0x63, "packsswb", int_x86_mmx_packsswb>;
 413 defm MMX_PACKSSDW : MMXI_binop_rm_int<0x6B, "packssdw", int_x86_mmx_packssdw>;
 414 defm MMX_PACKUSWB : MMXI_binop_rm_int<0x67, "packuswb", int_x86_mmx_packuswb>;
 415
 416 // -- Shuffle Instructions
 417 def MMX_PSHUFWri : MMXIi8<0x70, MRMSrcReg,
 418                           (outs VR64:$dst), (ins VR64:$src1, i8imm:$src2),
 419                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 420                           [(set VR64:$dst,
 421                             (v4i16 (mmx_pshufw:$src2 VR64:$src1, (undef))))]>;
 422 def MMX_PSHUFWmi : MMXIi8<0x70, MRMSrcMem,
 423                           (outs VR64:$dst), (ins i64mem:$src1, i8imm:$src2),
 424                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 425                           [(set VR64:$dst,
 426                             (mmx_pshufw:$src2 (bc_v4i16 (load_mmx addr:$src1)),
 427                                               (undef)))]>;
 428
 429 // -- Conversion Instructions
 430 let neverHasSideEffects = 1 in {
 431 def MMX_CVTPD2PIrr  : MMX2I<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 432                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 433 let mayLoad = 1 in
 434 def MMX_CVTPD2PIrm  : MMX2I<0x2D, MRMSrcMem, (outs VR64:$dst),
 435                                              (ins f128mem:$src),
 436                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 437
 438 def MMX_CVTPI2PDrr  : MMX2I<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 439                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 440 let mayLoad = 1 in
 441 def MMX_CVTPI2PDrm  : MMX2I<0x2A, MRMSrcMem, (outs VR128:$dst),
 442                                              (ins i64mem:$src),
 443                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 444
 445 def MMX_CVTPI2PSrr  : MMXI<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 446                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 447 let mayLoad = 1 in
 448 def MMX_CVTPI2PSrm  : MMXI<0x2A, MRMSrcMem, (outs VR128:$dst),
 449                                             (ins i64mem:$src),
 450                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 451
 452 def MMX_CVTPS2PIrr  : MMXI<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 453                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 454 let mayLoad = 1 in
 455 def MMX_CVTPS2PIrm  : MMXI<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 456                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 457
 458 def MMX_CVTTPD2PIrr : MMX2I<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 459                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 460 let mayLoad = 1 in
 461 def MMX_CVTTPD2PIrm : MMX2I<0x2C, MRMSrcMem, (outs VR64:$dst),
 462                                              (ins f128mem:$src),
 463                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 464
 465 def MMX_CVTTPS2PIrr : MMXI<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 466                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 467 let mayLoad = 1 in
 468 def MMX_CVTTPS2PIrm : MMXI<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 469                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 470 } // end neverHasSideEffects
 471
 472
 473 // Extract / Insert
 474 def MMX_X86pextrw : SDNode<"X86ISD::PEXTRW", SDTypeProfile<1, 2, []>, []>;
 475 def MMX_X86pinsrw : SDNode<"X86ISD::PINSRW", SDTypeProfile<1, 3, []>, []>;
 476
 477 def MMX_PEXTRWri  : MMXIi8<0xC5, MRMSrcReg,
 478                            (outs GR32:$dst), (ins VR64:$src1, i16i8imm:$src2),
 479                            "pextrw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 480                            [(set GR32:$dst, (MMX_X86pextrw (v4i16 VR64:$src1),
 481                                              (iPTR imm:$src2)))]>;
 482 let Constraints = "$src1 = $dst" in {
 483   def MMX_PINSRWrri : MMXIi8<0xC4, MRMSrcReg,
 484                       (outs VR64:$dst), (ins VR64:$src1, GR32:$src2,
 485                                              i16i8imm:$src3),
 486                       "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 487                       [(set VR64:$dst, (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 488                                                GR32:$src2,(iPTR imm:$src3))))]>;
 489   def MMX_PINSRWrmi : MMXIi8<0xC4, MRMSrcMem,
 490                      (outs VR64:$dst), (ins VR64:$src1, i16mem:$src2,
 491                                             i16i8imm:$src3),
 492                      "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 493                      [(set VR64:$dst,
 494                        (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 495                                (i32 (anyext (loadi16 addr:$src2))),
 496                                (iPTR imm:$src3))))]>;
 497 }
 498
 499 // Mask creation
 500 def MMX_PMOVMSKBrr : MMXI<0xD7, MRMSrcReg, (outs GR32:$dst), (ins VR64:$src),
 501                           "pmovmskb\t{$src, $dst|$dst, $src}",
 502                           [(set GR32:$dst, (int_x86_mmx_pmovmskb VR64:$src))]>;
 503
 504 // Misc.
 505 let Uses = [EDI] in
 506 def MMX_MASKMOVQ : MMXI<0xF7, MRMSrcReg, (outs), (ins VR64:$src, VR64:$mask),
 507                         "maskmovq\t{$mask, $src|$src, $mask}",
 508                         [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, EDI)]>;
 509 let Uses = [RDI] in
 510 def MMX_MASKMOVQ64: MMXI64<0xF7, MRMSrcReg, (outs), (ins VR64:$src, VR64:$mask),
 511                            "maskmovq\t{$mask, $src|$src, $mask}",
 512                            [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, RDI)]>;
 513
 514 //===----------------------------------------------------------------------===//
 515 // Alias Instructions
 516 //===----------------------------------------------------------------------===//
 517
 518 // Alias instructions that map zero vector to pxor.
 519 let isReMaterializable = 1, isCodeGenOnly = 1 in {
 520   def MMX_V_SET0       : MMXI<0xEF, MRMInitReg, (outs VR64:$dst), (ins),
 521                               "pxor\t$dst, $dst",
 522                               [(set VR64:$dst, (v2i32 immAllZerosV))]>;
 523   def MMX_V_SETALLONES : MMXI<0x76, MRMInitReg, (outs VR64:$dst), (ins),
 524                               "pcmpeqd\t$dst, $dst",
 525                               [(set VR64:$dst, (v2i32 immAllOnesV))]>;
 526 }
 527
 528 let Predicates = [HasMMX] in {
 529   def : Pat<(v1i64 immAllZerosV), (MMX_V_SET0)>;
 530   def : Pat<(v4i16 immAllZerosV), (MMX_V_SET0)>;
 531   def : Pat<(v8i8  immAllZerosV), (MMX_V_SET0)>;
 532 }
 533
 534 //===----------------------------------------------------------------------===//
 535 // Non-Instruction Patterns
 536 //===----------------------------------------------------------------------===//
 537
 538 // Store 64-bit integer vector values.
 539 def : Pat<(store (v8i8  VR64:$src), addr:$dst),
 540           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 541 def : Pat<(store (v4i16 VR64:$src), addr:$dst),
 542           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 543 def : Pat<(store (v2i32 VR64:$src), addr:$dst),
 544           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 545 def : Pat<(store (v2f32 VR64:$src), addr:$dst),
 546           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 547 def : Pat<(store (v1i64 VR64:$src), addr:$dst),
 548           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 549
 550 // Bit convert.
 551 def : Pat<(v8i8  (bitconvert (v1i64 VR64:$src))), (v8i8  VR64:$src)>;
 552 def : Pat<(v8i8  (bitconvert (v2i32 VR64:$src))), (v8i8  VR64:$src)>;
 553 def : Pat<(v8i8  (bitconvert (v2f32 VR64:$src))), (v8i8  VR64:$src)>;
 554 def : Pat<(v8i8  (bitconvert (v4i16 VR64:$src))), (v8i8  VR64:$src)>;
 555 def : Pat<(v4i16 (bitconvert (v1i64 VR64:$src))), (v4i16 VR64:$src)>;
 556 def : Pat<(v4i16 (bitconvert (v2i32 VR64:$src))), (v4i16 VR64:$src)>;
 557 def : Pat<(v4i16 (bitconvert (v2f32 VR64:$src))), (v4i16 VR64:$src)>;
 558 def : Pat<(v4i16 (bitconvert (v8i8  VR64:$src))), (v4i16 VR64:$src)>;
 559 def : Pat<(v2i32 (bitconvert (v1i64 VR64:$src))), (v2i32 VR64:$src)>;
 560 def : Pat<(v2i32 (bitconvert (v2f32 VR64:$src))), (v2i32 VR64:$src)>;
 561 def : Pat<(v2i32 (bitconvert (v4i16 VR64:$src))), (v2i32 VR64:$src)>;
 562 def : Pat<(v2i32 (bitconvert (v8i8  VR64:$src))), (v2i32 VR64:$src)>;
 563 def : Pat<(v2f32 (bitconvert (v1i64 VR64:$src))), (v2f32 VR64:$src)>;
 564 def : Pat<(v2f32 (bitconvert (v2i32 VR64:$src))), (v2f32 VR64:$src)>;
 565 def : Pat<(v2f32 (bitconvert (v4i16 VR64:$src))), (v2f32 VR64:$src)>;
 566 def : Pat<(v2f32 (bitconvert (v8i8  VR64:$src))), (v2f32 VR64:$src)>;
 567 def : Pat<(v1i64 (bitconvert (v2i32 VR64:$src))), (v1i64 VR64:$src)>;
 568 def : Pat<(v1i64 (bitconvert (v2f32 VR64:$src))), (v1i64 VR64:$src)>;
 569 def : Pat<(v1i64 (bitconvert (v4i16 VR64:$src))), (v1i64 VR64:$src)>;
 570 def : Pat<(v1i64 (bitconvert (v8i8  VR64:$src))), (v1i64 VR64:$src)>;
 571
 572 // 64-bit bit convert.
 573 def : Pat<(v1i64 (bitconvert (i64 GR64:$src))),
 574           (MMX_MOVD64to64rr GR64:$src)>;
 575 def : Pat<(v2i32 (bitconvert (i64 GR64:$src))),
 576           (MMX_MOVD64to64rr GR64:$src)>;
 577 def : Pat<(v2f32 (bitconvert (i64 GR64:$src))),
 578           (MMX_MOVD64to64rr GR64:$src)>;
 579 def : Pat<(v4i16 (bitconvert (i64 GR64:$src))),
 580           (MMX_MOVD64to64rr GR64:$src)>;
 581 def : Pat<(v8i8  (bitconvert (i64 GR64:$src))),
 582           (MMX_MOVD64to64rr GR64:$src)>;
 583 def : Pat<(i64 (bitconvert (v1i64 VR64:$src))),
 584           (MMX_MOVD64from64rr VR64:$src)>;
 585 def : Pat<(i64 (bitconvert (v2i32 VR64:$src))),
 586           (MMX_MOVD64from64rr VR64:$src)>;
 587 def : Pat<(i64 (bitconvert (v2f32 VR64:$src))),
 588           (MMX_MOVD64from64rr VR64:$src)>;
 589 def : Pat<(i64 (bitconvert (v4i16 VR64:$src))),
 590           (MMX_MOVD64from64rr VR64:$src)>;
 591 def : Pat<(i64  (bitconvert (v8i8 VR64:$src))),
 592           (MMX_MOVD64from64rr VR64:$src)>;
 593 def : Pat<(f64 (bitconvert (v1i64 VR64:$src))),
 594           (MMX_MOVQ2FR64rr VR64:$src)>;
 595 def : Pat<(f64 (bitconvert (v2i32 VR64:$src))),
 596           (MMX_MOVQ2FR64rr VR64:$src)>;
 597 def : Pat<(f64 (bitconvert (v4i16 VR64:$src))),
 598           (MMX_MOVQ2FR64rr VR64:$src)>;
 599 def : Pat<(f64 (bitconvert (v8i8 VR64:$src))),
 600           (MMX_MOVQ2FR64rr VR64:$src)>;
 601
 602 let AddedComplexity = 20 in {
 603   def : Pat<(v2i32 (X86vzmovl (bc_v2i32 (load_mmx addr:$src)))),
 604             (MMX_MOVZDI2PDIrm addr:$src)>;
 605 }
 606
 607 // Clear top half.
 608 let AddedComplexity = 15 in {
 609   def : Pat<(v2i32 (X86vzmovl VR64:$src)),
 610             (MMX_PUNPCKLDQrr VR64:$src, (MMX_V_SET0))>;
 611 }
 612
 613 // Patterns to perform canonical versions of vector shuffling.
 614 let AddedComplexity = 10 in {
 615   def : Pat<(v8i8  (mmx_unpckl_undef VR64:$src, (undef))),
 616             (MMX_PUNPCKLBWrr VR64:$src, VR64:$src)>;
 617   def : Pat<(v4i16 (mmx_unpckl_undef VR64:$src, (undef))),
 618             (MMX_PUNPCKLWDrr VR64:$src, VR64:$src)>;
 619   def : Pat<(v2i32 (mmx_unpckl_undef VR64:$src, (undef))),
 620             (MMX_PUNPCKLDQrr VR64:$src, VR64:$src)>;
 621 }
 622
 623 let AddedComplexity = 10 in {
 624   def : Pat<(v8i8  (mmx_unpckh_undef VR64:$src, (undef))),
 625             (MMX_PUNPCKHBWrr VR64:$src, VR64:$src)>;
 626   def : Pat<(v4i16 (mmx_unpckh_undef VR64:$src, (undef))),
 627             (MMX_PUNPCKHWDrr VR64:$src, VR64:$src)>;
 628   def : Pat<(v2i32 (mmx_unpckh_undef VR64:$src, (undef))),
 629             (MMX_PUNPCKHDQrr VR64:$src, VR64:$src)>;
 630 }
 631
 632 // Patterns to perform vector shuffling with a zeroed out vector.
 633 let AddedComplexity = 20 in {
 634   def : Pat<(bc_v2i32 (mmx_unpckl immAllZerosV,
 635                        (v2i32 (scalar_to_vector (load_mmx addr:$src))))),
 636             (MMX_PUNPCKLDQrm VR64:$src, VR64:$src)>;
 637 }
 638
 639 // Some special case PANDN patterns.
 640 // FIXME: Get rid of these.
 641 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 642                   VR64:$src2)),
 643           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 644 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 645                   VR64:$src2)),
 646           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 647 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 648                   VR64:$src2)),
 649           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 650
 651 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 652                   (load addr:$src2))),
 653           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 654 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 655                   (load addr:$src2))),
 656           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 657 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 658                   (load addr:$src2))),
 659           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 660
 661 // Move MMX to lower 64-bit of XMM
 662 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v8i8 VR64:$src))))),
 663           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 664 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v4i16 VR64:$src))))),
 665           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 666 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v2i32 VR64:$src))))),
 667           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 668 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v1i64 VR64:$src))))),
 669           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 670
 671 // Move lower 64-bit of XMM to MMX.
 672 def : Pat<(v2i32 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 673                                                   (iPTR 0))))),
 674           (v2i32 (MMX_MOVDQ2Qrr VR128:$src))>;
 675 def : Pat<(v4i16 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 676                                                   (iPTR 0))))),
 677           (v4i16 (MMX_MOVDQ2Qrr VR128:$src))>;
 678 def : Pat<(v8i8 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 679                                                   (iPTR 0))))),
 680           (v8i8 (MMX_MOVDQ2Qrr VR128:$src))>;
 681
 682 // Patterns for vector comparisons
 683 def : Pat<(v8i8 (X86pcmpeqb VR64:$src1, VR64:$src2)),
 684           (MMX_PCMPEQBrr VR64:$src1, VR64:$src2)>;
 685 def : Pat<(v8i8 (X86pcmpeqb VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 686           (MMX_PCMPEQBrm VR64:$src1, addr:$src2)>;
 687 def : Pat<(v4i16 (X86pcmpeqw VR64:$src1, VR64:$src2)),
 688           (MMX_PCMPEQWrr VR64:$src1, VR64:$src2)>;
 689 def : Pat<(v4i16 (X86pcmpeqw VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 690           (MMX_PCMPEQWrm VR64:$src1, addr:$src2)>;
 691 def : Pat<(v2i32 (X86pcmpeqd VR64:$src1, VR64:$src2)),
 692           (MMX_PCMPEQDrr VR64:$src1, VR64:$src2)>;
 693 def : Pat<(v2i32 (X86pcmpeqd VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 694           (MMX_PCMPEQDrm VR64:$src1, addr:$src2)>;
 695
 696 def : Pat<(v8i8 (X86pcmpgtb VR64:$src1, VR64:$src2)),
 697           (MMX_PCMPGTBrr VR64:$src1, VR64:$src2)>;
 698 def : Pat<(v8i8 (X86pcmpgtb VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 699           (MMX_PCMPGTBrm VR64:$src1, addr:$src2)>;
 700 def : Pat<(v4i16 (X86pcmpgtw VR64:$src1, VR64:$src2)),
 701           (MMX_PCMPGTWrr VR64:$src1, VR64:$src2)>;
 702 def : Pat<(v4i16 (X86pcmpgtw VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 703           (MMX_PCMPGTWrm VR64:$src1, addr:$src2)>;
 704 def : Pat<(v2i32 (X86pcmpgtd VR64:$src1, VR64:$src2)),
 705           (MMX_PCMPGTDrr VR64:$src1, VR64:$src2)>;
 706 def : Pat<(v2i32 (X86pcmpgtd VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 707           (MMX_PCMPGTDrm VR64:$src1, addr:$src2)>;
 708
 709 // CMOV* - Used to implement the SELECT DAG operation.  Expanded by the
 710 // scheduler into a branch sequence.
 711 // These are expanded by the scheduler.
 712 let Uses = [EFLAGS], usesCustomDAGSchedInserter = 1 in {
 713   def CMOV_V1I64 : I<0, Pseudo,
 714                     (outs VR64:$dst), (ins VR64:$t, VR64:$f, i8imm:$cond),
 715                     "#CMOV_V1I64 PSEUDO!",
 716                     [(set VR64:$dst,
 717                       (v1i64 (X86cmov VR64:$t, VR64:$f, imm:$cond,
 718                                           EFLAGS)))]>;
 719 }