autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 225   mips-*)                 llvm_cv_target_arch="Mips" ;;
 226   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 227   xcore-*)                llvm_cv_target_arch="XCore" ;;
 228   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 229   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 230   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 231   *)                      llvm_cv_target_arch="Unknown" ;;
 232 esac])
 233
 234 if test "$llvm_cv_target_arch" = "Unknown" ; then
 235   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 236 fi
 237
 238 # Determine the LLVM native architecture for the target
 239 case "$llvm_cv_target_arch" in
 240     x86)     LLVM_NATIVE_ARCH="X86" ;;
 241     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 242     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 243 esac
 244
 245 dnl Define a substitution, ARCH, for the target architecture
 246 AC_SUBST(ARCH,$llvm_cv_target_arch)
 247
 248 dnl Check for the endianness of the target
 249 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 250
 251 dnl Check for build platform executable suffix if we're crosscompiling
 252 if test "$cross_compiling" = yes; then
 253   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 254   AC_BUILD_EXEEXT
 255   ac_build_prefix=${build_alias}-
 256   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 257   if test -z "$BUILD_CXX"; then
 258      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 259      if test -z "$BUILD_CXX"; then
 260        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 261      fi
 262   fi
 263 else
 264   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 265 fi
 266
 267 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 268 dnl that this build is being done from a checkout. This sets up several
 269 dnl defaults for the command line switches. When we build with a CVS directory,
 270 dnl we get a debug with assertions turned on. Without, we assume a source
 271 dnl release and we get an optimized build without assertions.
 272 dnl See --enable-optimized and --enable-assertions below
 273 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 274   cvsbuild="yes"
 275   optimize="no"
 276   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 277 else
 278   cvsbuild="no"
 279   optimize="yes"
 280 fi
 281
 282 dnl===-----------------------------------------------------------------------===
 283 dnl===
 284 dnl=== SECTION 3: Command line arguments for the configure script.
 285 dnl===
 286 dnl===-----------------------------------------------------------------------===
 287
 288 dnl --enable-optimized : check whether they want to do an optimized build:
 289 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 290  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 291 if test ${enableval} = "no" ; then
 292   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 293 else
 294   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 295 fi
 296
 297 dnl --enable-profiling : check whether they want to do a profile build:
 298 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 299  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 300 if test ${enableval} = "no" ; then
 301   AC_SUBST(ENABLE_PROFILING,[[]])
 302 else
 303   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 304 fi
 305
 306 dnl --enable-assertions : check whether they want to turn on assertions or not:
 307 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 308   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 309 if test ${enableval} = "yes" ; then
 310   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 311 else
 312   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 313 fi
 314
 315 dnl LLVM_COMPACT_SENTINELS : can be used to shrink ilist's end iterators and disable certain checks on them:
 316 if test ${ENABLE_OPTIMIZED},${DISABLE_ASSERTIONS} = "ENABLE_OPTIMIZED=1,DISABLE_ASSERTIONS=1" ; then
 317   AC_SUBST(LLVM_COMPACT_SENTINELS,[1])
 318 else
 319   AC_SUBST(LLVM_COMPACT_SENTINELS,[0])
 320 fi
 321
 322 AC_DEFINE_UNQUOTED([LLVM_COMPACT_SENTINELS],$LLVM_COMPACT_SENTINELS,
 323                    [Define to 1 for ilist sentinel compaction])
 324
 325
 326 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 327 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 328   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 329 if test ${enableval} = "yes" ; then
 330   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 331   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 332 else
 333   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 334   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 335 fi
 336
 337 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 338 AC_ARG_ENABLE(debug-runtime,
 339    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 340 if test ${enableval} = "no" ; then
 341   AC_SUBST(DEBUG_RUNTIME,[[]])
 342 else
 343   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 344 fi
 345
 346 dnl --enable-jit: check whether they want to enable the jit
 347 AC_ARG_ENABLE(jit,
 348   AS_HELP_STRING(--enable-jit,
 349                  [Enable Just In Time Compiling (default is YES)]),,
 350   enableval=default)
 351 if test ${enableval} = "no"
 352 then
 353   AC_SUBST(JIT,[[]])
 354 else
 355   case "$llvm_cv_target_arch" in
 356     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 357     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 358     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 359     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 360     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 361     ARM)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 362     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 363     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 364     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 365     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 366     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 367     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 368     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 369   esac
 370 fi
 371
 372 dnl Allow enablement of doxygen generated documentation
 373 AC_ARG_ENABLE(doxygen,
 374               AS_HELP_STRING([--enable-doxygen],
 375                              [Build doxygen documentation (default is NO)]),,
 376                              enableval=default)
 377 case "$enableval" in
 378   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 379   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 380   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 381   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 382 esac
 383
 384 dnl Allow disablement of threads
 385 AC_ARG_ENABLE(threads,
 386               AS_HELP_STRING([--enable-threads],
 387                              [Use threads if available (default is YES)]),,
 388                              enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 391   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 392   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 394 esac
 395 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 396
 397 dnl Allow building without position independent code
 398 AC_ARG_ENABLE(pic,
 399   AS_HELP_STRING([--enable-pic],
 400                  [Build LLVM with Position Independent Code (default is YES)]),,
 401                  enableval=default)
 402 case "$enableval" in
 403   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 404   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 405   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 406   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 407 esac
 408 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 409                    [Define if position independent code is enabled])
 410
 411 dnl Allow specific targets to be specified for building (or not)
 412 TARGETS_TO_BUILD=""
 413 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 414     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 415     enableval=all)
 416 case "$enableval" in
 417   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 418   host-only)
 419     case "$llvm_cv_target_arch" in
 420       x86)         TARGETS_TO_BUILD="X86" ;;
 421       x86_64)      TARGETS_TO_BUILD="X86" ;;
 422       Sparc)       TARGETS_TO_BUILD="Sparc" ;;
 423       PowerPC)     TARGETS_TO_BUILD="PowerPC" ;;
 424       Alpha)       TARGETS_TO_BUILD="Alpha" ;;
 425       ARM)         TARGETS_TO_BUILD="ARM" ;;
 426       Mips)        TARGETS_TO_BUILD="Mips" ;;
 427       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 428       PIC16)       TARGETS_TO_BUILD="PIC16" ;;
 429       XCore)       TARGETS_TO_BUILD="XCore" ;;
 430       MSP430)      TARGETS_TO_BUILD="MSP430" ;;
 431       SystemZ)     TARGETS_TO_BUILD="SystemZ" ;;
 432       Blackfin)    TARGETS_TO_BUILD="Blackfin" ;;
 433       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 434     esac
 435     ;;
 436   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 437       case "$a_target" in
 438         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 439         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 440         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 441         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 442         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 443         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 444         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 445         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 446         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 447         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 448         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 449         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 450         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 451         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 452         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 453         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 454         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 455       esac
 456   done
 457   ;;
 458 esac
 459 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 460
 461 # Determine whether we are building LLVM support for the native architecture.
 462 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 463 for a_target in $TARGETS_TO_BUILD; do
 464   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 465     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 466     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 467       [LLVM architecture name for the native architecture, if available])
 468   fi
 469 done
 470
 471 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 472 # Targets.def, AsmPrinters.def, and AsmParsers.def.
 473 LLVM_ENUM_TARGETS=""
 474 LLVM_ENUM_ASM_PRINTERS=""
 475 LLVM_ENUM_ASM_PARSERS=""
 476 for target_to_build in $TARGETS_TO_BUILD; do
 477   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 478   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 479     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 480   fi
 481   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 482     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 483   fi
 484 done
 485 AC_SUBST(LLVM_ENUM_TARGETS)
 486 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 487 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 488
 489 dnl Prevent the CBackend from using printf("%a") for floating point so older
 490 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 491 dnl can still compile the CBE's output
 492 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 493   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 494   enableval=default)
 495 case "$enableval" in
 496   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 497   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 498   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 499   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 500 esac
 501 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 502                    [Define if CBE is enabled for printf %a output])
 503
 504 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 505 AC_ARG_WITH(llvmgccdir,
 506   AS_HELP_STRING([--with-llvmgccdir],
 507     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 508     withval=default)
 509 case "$withval" in
 510   default) WITH_LLVMGCCDIR=default ;;
 511   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 512   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 513 esac
 514
 515 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 516 AC_ARG_WITH(llvmgcc,
 517   AS_HELP_STRING([--with-llvmgcc],
 518     [Specify location of llvm-gcc driver (default searches PATH)]),
 519     LLVMGCC=$with_llvmgcc
 520       WITH_LLVMGCCDIR="",)
 521
 522 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 523 AC_ARG_WITH(llvmgxx,
 524   AS_HELP_STRING([--with-llvmgxx],
 525     [Specify location of llvm-g++ driver (default searches PATH)]),
 526     LLVMGXX=$with_llvmgxx
 527     WITH_LLVMGCCDIR="",)
 528
 529 if test -n "$LLVMGCC"; then
 530    LLVMGCCCOMMAND="$LLVMGCC"
 531 fi
 532
 533 if test -n "$LLVMGXX"; then
 534    LLVMGXXCOMMAND="$LLVMGXX"
 535 fi
 536
 537 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 538    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 539 fi
 540
 541 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 542    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 543 fi
 544
 545 dnl Specify extra build options
 546 AC_ARG_WITH(extra-options,
 547   AS_HELP_STRING([--with-extra-options],
 548                  [Specify additional options to compile LLVM with]),,
 549                  withval=default)
 550 case "$withval" in
 551   default) EXTRA_OPTIONS= ;;
 552   *) EXTRA_OPTIONS=$withval ;;
 553 esac
 554 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 555
 556 dnl Allow specific bindings to be specified for building (or not)
 557 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 558     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 559     enableval=default)
 560 BINDINGS_TO_BUILD=""
 561 case "$enableval" in
 562   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 563   all ) BINDINGS_TO_BUILD="ocaml" ;;
 564   none | no) BINDINGS_TO_BUILD="" ;;
 565   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 566       case "$a_binding" in
 567         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 568         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 569       esac
 570   done
 571   ;;
 572 esac
 573
 574 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 575 dnl script for bindings/ocaml/configure, except that its auto value depends on
 576 dnl OCAMLC, which is found here to support tests.
 577 AC_ARG_WITH([ocaml-libdir],
 578   [AS_HELP_STRING([--with-ocaml-libdir],
 579     [Specify install location for ocaml bindings (default is stdlib)])],
 580   [],
 581   [withval=auto])
 582 case "$withval" in
 583   auto) with_ocaml_libdir="$withval" ;;
 584   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 585   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 586 esac
 587
 588 dnl Allow linking of LLVM with GPLv3 binutils code.
 589 AC_ARG_WITH(binutils-include,
 590   AS_HELP_STRING([--with-binutils-include],
 591     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 592   withval=default)
 593 case "$withval" in
 594   default) WITH_BINUTILS_INCDIR=default ;;
 595   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 596   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 597 esac
 598 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 599   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 600   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 601      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 602      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 603   fi
 604 fi
 605
 606 dnl --enable-libffi : check whether the user wants to turn off libffi:
 607 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 608   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 609   enableval=yes)
 610 case "$enableval" in
 611   yes) llvm_cv_enable_libffi="yes" ;;
 612   no)  llvm_cv_enable_libffi="no"  ;;
 613   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 614 esac
 615
 616 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 617 if test "$llvm_cv_os_type" = "Win32" ; then
 618    llvmc_dynamic="yes"
 619 else
 620    llvmc_dynamic="no"
 621 fi
 622
 623 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 624 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 625 --enable-llvmc-dynamic,
 626 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 627 enableval=$llvmc_dynamic)
 628 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 629    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 630 else
 631    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 632 fi
 633
 634 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 635 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 636 --enable-llvmc-dynamic-plugins,
 637 [Enable dynamic LLVMC plugins (default is YES)]),,
 638 enableval=yes)
 639 if test ${enableval} = "yes" ; then
 640    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 641 else
 642    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 643 fi
 644
 645 dnl===-----------------------------------------------------------------------===
 646 dnl===
 647 dnl=== SECTION 4: Check for programs we need and that they are the right version
 648 dnl===
 649 dnl===-----------------------------------------------------------------------===
 650
 651 dnl Check for compilation tools
 652 AC_PROG_CPP
 653 AC_PROG_CC(gcc)
 654 AC_PROG_CXX(g++)
 655
 656 AC_PROG_NM
 657 AC_SUBST(NM)
 658
 659 dnl Check for the tools that the makefiles require
 660 AC_CHECK_GNU_MAKE
 661 AC_PROG_LN_S
 662 AC_PATH_PROG(CMP, [cmp], [cmp])
 663 AC_PATH_PROG(CP, [cp], [cp])
 664 AC_PATH_PROG(DATE, [date], [date])
 665 AC_PATH_PROG(FIND, [find], [find])
 666 AC_PATH_PROG(GREP, [grep], [grep])
 667 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 668 AC_PATH_PROG(MV,   [mv],   [mv])
 669 AC_PROG_RANLIB
 670 AC_PATH_PROG(RM,   [rm],   [rm])
 671 AC_PATH_PROG(SED,  [sed],  [sed])
 672 AC_PATH_PROG(TAR,  [tar],  [gtar])
 673 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 674
 675 dnl Looking for misc. graph plotting software
 676 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 677 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 678   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 679   dnl If we're targeting for mingw we should emit windows paths, not msys
 680   if test "$llvm_cv_os_type" = "MingW" ; then
 681     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 682   fi
 683   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 684    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 685 fi
 686 AC_PATH_PROG(DOT, [dot], [echo dot])
 687 if test "$DOT" != "echo dot" ; then
 688   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 689   dnl If we're targeting for mingw we should emit windows paths, not msys
 690   if test "$llvm_cv_os_type" = "MingW" ; then
 691     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 692   fi
 693   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 694    [Define to path to dot program if found or 'echo dot' otherwise])
 695 fi
 696 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 697 if test "$FDP" != "echo fdp" ; then
 698   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 699   dnl If we're targeting for mingw we should emit windows paths, not msys
 700   if test "$llvm_cv_os_type" = "MingW" ; then
 701     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 702   fi
 703   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 704    [Define to path to fdp program if found or 'echo fdp' otherwise])
 705 fi
 706 AC_PATH_PROG(NEATO, [neato], [echo neato])
 707 if test "$NEATO" != "echo neato" ; then
 708   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 709   dnl If we're targeting for mingw we should emit windows paths, not msys
 710   if test "$llvm_cv_os_type" = "MingW" ; then
 711     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 712   fi
 713   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 714    [Define to path to neato program if found or 'echo neato' otherwise])
 715 fi
 716 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 717 if test "$TWOPI" != "echo twopi" ; then
 718   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 719   dnl If we're targeting for mingw we should emit windows paths, not msys
 720   if test "$llvm_cv_os_type" = "MingW" ; then
 721     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 722   fi
 723   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 724    [Define to path to twopi program if found or 'echo twopi' otherwise])
 725 fi
 726 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 727 if test "$CIRCO" != "echo circo" ; then
 728   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 729   dnl If we're targeting for mingw we should emit windows paths, not msys
 730   if test "$llvm_cv_os_type" = "MingW" ; then
 731     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 732   fi
 733   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 734    [Define to path to circo program if found or 'echo circo' otherwise])
 735 fi
 736 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 737 if test "$GV" != "echo gv" ; then
 738   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 739   dnl If we're targeting for mingw we should emit windows paths, not msys
 740   if test "$llvm_cv_os_type" = "MingW" ; then
 741     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 742   fi
 743   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 744    [Define to path to gv program if found or 'echo gv' otherwise])
 745 fi
 746 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 747 if test "$DOTTY" != "echo dotty" ; then
 748   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 749   dnl If we're targeting for mingw we should emit windows paths, not msys
 750   if test "$llvm_cv_os_type" = "MingW" ; then
 751     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 752   fi
 753   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 754    [Define to path to dotty program if found or 'echo dotty' otherwise])
 755 fi
 756
 757 dnl Look for a sufficiently recent version of Perl.
 758 LLVM_PROG_PERL([5.006])
 759 AC_SUBST(PERL)
 760 if test x"$PERL" = xnone; then
 761    AC_SUBST(HAVE_PERL,0)
 762    AC_MSG_ERROR([perl is required but was not found, please install it])
 763 else
 764    AC_SUBST(HAVE_PERL,1)
 765 fi
 766
 767 dnl Find the install program
 768 AC_PROG_INSTALL
 769
 770 dnl Checks for documentation and testing tools that we can do without. If these
 771 dnl are not found then they are set to "true" which always succeeds but does
 772 dnl nothing. This just lets the build output show that we could have done
 773 dnl something if the tool was available.
 774 AC_PATH_PROG(BZIP2, [bzip2])
 775 AC_PATH_PROG(DOXYGEN, [doxygen])
 776 AC_PATH_PROG(GROFF, [groff])
 777 AC_PATH_PROG(GZIP, [gzip])
 778 AC_PATH_PROG(POD2HTML, [pod2html])
 779 AC_PATH_PROG(POD2MAN, [pod2man])
 780 AC_PATH_PROG(RUNTEST, [runtest])
 781 DJ_AC_PATH_TCLSH
 782 AC_PATH_PROG(ZIP, [zip])
 783 AC_PATH_PROGS(OCAMLC, [ocamlc])
 784 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 785 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 786 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 787 AC_PATH_PROGS(GAS, [gas as])
 788
 789 dnl Determine whether the linker supports the -R option.
 790 AC_LINK_USE_R
 791
 792 dnl Determine whether the linker supports the -export-dynamic option.
 793 AC_LINK_EXPORT_DYNAMIC
 794
 795 dnl Check for libtool and the library that has dlopen function (which must come
 796 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 797 dnl libtool).
 798 AC_LIBTOOL_DLOPEN
 799 AC_LIB_LTDL
 800 AC_PROG_LIBTOOL
 801
 802 if test "$lt_cv_dlopen_self" = "yes" ; then
 803   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 804               [Define if dlopen(0) will open the symbols of the program])
 805 fi
 806
 807
 808 if test "$WITH_LLVMGCCDIR" = "default" ; then
 809   LLVMGCC="llvm-gcc${EXEEXT}"
 810   LLVMGXX="llvm-g++${EXEEXT}"
 811   LLVMGCCCOMMAND="$LLVMGCC"
 812   LLVMGXXCOMMAND="$LLVMGXX"
 813   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 814   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 815   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 816   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 817 else
 818   if test -z "$LLVMGCC"; then
 819     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 820     LLVMGCCCOMMAND="$LLVMGCC"
 821   fi
 822   if test -z "$LLVMGXX"; then
 823     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 824     LLVMGXXCOMMAND="$LLVMGXX"
 825   fi
 826
 827   AC_SUBST(LLVMGCC,$LLVMGCC)
 828   AC_SUBST(LLVMGXX,$LLVMGXX)
 829   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 830   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 831 fi
 832
 833
 834 AC_MSG_CHECKING([tool compatibility])
 835
 836 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 837 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 838 dnl to support those options.
 839 dnl "icc" emits gcc signatures
 840 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 841 ICC=no
 842 IXX=no
 843 case $CC in
 844   icc*|icpc*)
 845     ICC=yes
 846     IXX=yes
 847     ;;
 848    *)
 849     ;;
 850 esac
 851
 852 if test "$GCC" != "yes" && test "$ICC" != "yes"
 853 then
 854   AC_MSG_ERROR([gcc|icc required but not found])
 855 fi
 856
 857 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 858 if test "$GXX" != "yes" && test "$IXX" != "yes"
 859 then
 860   AC_MSG_ERROR([g++|icc required but not found])
 861 fi
 862
 863 dnl Verify that GCC is version 3.0 or higher
 864 if test "$GCC" = "yes"
 865 then
 866   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 867 #error Unsupported GCC version
 868 #endif
 869 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 870 fi
 871
 872 dnl Check for GNU Make.  We use its extensions, so don't build without it
 873 if test -z "$llvm_cv_gnu_make_command"
 874 then
 875   AC_MSG_ERROR([GNU Make required but not found])
 876 fi
 877
 878 dnl Tool compatibility is okay if we make it here.
 879 AC_MSG_RESULT([ok])
 880
 881 dnl===-----------------------------------------------------------------------===
 882 dnl===
 883 dnl=== SECTION 5: Check for libraries
 884 dnl===
 885 dnl===-----------------------------------------------------------------------===
 886
 887 AC_CHECK_LIB(m,sin)
 888 if test "$llvm_cv_os_type" = "MingW" ; then
 889   AC_CHECK_LIB(imagehlp, main)
 890   AC_CHECK_LIB(psapi, main)
 891 fi
 892
 893 dnl dlopen() is required for plugin support.
 894 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 895                [Define if dlopen() is available on this platform.]),
 896                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 897
 898 dnl libffi is optional; used to call external functions from the interpreter
 899 if test "$llvm_cv_enable_libffi" = "yes" ; then
 900   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 901                  [Define if libffi is available on this platform.]),
 902                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 903 fi
 904
 905 dnl mallinfo is optional; the code can compile (minus features) without it
 906 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 907                [Define if mallinfo() is available on this platform.]))
 908
 909 dnl pthread locking functions are optional - but llvm will not be thread-safe
 910 dnl without locks.
 911 if test "$ENABLE_THREADS" -eq 1 ; then
 912   AC_CHECK_LIB(pthread,pthread_mutex_init)
 913   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 914                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 915                            [Have pthread_mutex_lock]))
 916   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 917                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 918                  [Have pthread_rwlock_init]))
 919   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 920                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 921                  [Have pthread_getspecific]))
 922 fi
 923
 924 dnl Allow extra x86-disassembler library
 925 AC_ARG_WITH(udis86,
 926   AS_HELP_STRING([--with-udis86=<path>],
 927     [Use udis86 external x86 disassembler library]),
 928     [
 929       AC_SUBST(USE_UDIS86, [1])
 930       case "$withval" in
 931         /usr/lib|yes) ;;
 932         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 933       esac
 934       AC_CHECK_LIB(udis86, ud_init, [], [
 935         echo "Error! You need to have libudis86 around."
 936         exit -1
 937       ])
 938     ],
 939     AC_SUBST(USE_UDIS86, [0]))
 940 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 941                    [Define if use udis86 library])
 942
 943 dnl Allow OProfile support for JIT output.
 944 AC_ARG_WITH(oprofile,
 945   AS_HELP_STRING([--with-oprofile=<prefix>],
 946     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
 947     [
 948       AC_SUBST(USE_OPROFILE, [1])
 949       case "$withval" in
 950         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
 951         *) llvm_cv_oppath="${withval}/lib/oprofile"
 952            CPPFLAGS="-I${withval}/include";;
 953       esac
 954       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
 955       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
 956         echo "Error! You need to have libopagent around."
 957         exit -1
 958       ])
 959       AC_CHECK_HEADER([opagent.h], [], [
 960         echo "Error! You need to have opagent.h around."
 961         exit -1
 962       ])
 963     ],
 964     [
 965       llvm_cv_old_LIBS="$LIBS"
 966       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
 967       dnl If either the library or header aren't present, omit oprofile support.
 968       AC_SEARCH_LIBS(op_open_agent, opagent,
 969                      [AC_SUBST(USE_OPROFILE, [1])],
 970                      [LIBS="$llvm_cv_old_LIBS"
 971                       AC_SUBST(USE_OPROFILE, [0])])
 972       AC_CHECK_HEADER([opagent.h], [], [
 973         LIBS="$llvm_cv_old_LIBS"
 974         AC_SUBST(USE_OPROFILE, [0])
 975       ])
 976     ])
 977 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
 978                    [Define if we have the oprofile JIT-support library])
 979
 980 dnl===-----------------------------------------------------------------------===
 981 dnl===
 982 dnl=== SECTION 6: Check for header files
 983 dnl===
 984 dnl===-----------------------------------------------------------------------===
 985
 986 dnl First, use autoconf provided macros for specific headers that we need
 987 dnl We don't check for ancient stuff or things that are guaranteed to be there
 988 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 989 dnl Generally we're looking for POSIX headers.
 990 AC_HEADER_DIRENT
 991 AC_HEADER_MMAP_ANONYMOUS
 992 AC_HEADER_STAT
 993 AC_HEADER_STDC
 994 AC_HEADER_SYS_WAIT
 995 AC_HEADER_TIME
 996
 997 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 998 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 999 AC_CHECK_HEADERS([utime.h windows.h])
1000 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1001 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1002 if test "$ENABLE_THREADS" -eq 1 ; then
1003   AC_CHECK_HEADERS(pthread.h,
1004                    AC_SUBST(HAVE_PTHREAD, 1),
1005                    AC_SUBST(HAVE_PTHREAD, 0))
1006 else
1007   AC_SUBST(HAVE_PTHREAD, 0)
1008 fi
1009
1010 dnl Try to find ffi.h.
1011 if test "$llvm_cv_enable_libffi" = "yes" ; then
1012   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1013 fi
1014
1015 dnl===-----------------------------------------------------------------------===
1016 dnl===
1017 dnl=== SECTION 7: Check for types and structures
1018 dnl===
1019 dnl===-----------------------------------------------------------------------===
1020
1021 AC_HUGE_VAL_CHECK
1022 AC_TYPE_PID_T
1023 AC_TYPE_SIZE_T
1024 AC_TYPE_SIGNAL
1025 AC_STRUCT_TM
1026 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1027 AC_CHECK_TYPES([uint64_t],,
1028          AC_CHECK_TYPES([u_int64_t],,
1029          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1030
1031 dnl===-----------------------------------------------------------------------===
1032 dnl===
1033 dnl=== SECTION 8: Check for specific functions needed
1034 dnl===
1035 dnl===-----------------------------------------------------------------------===
1036
1037 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1038 AC_CHECK_FUNCS([powf fmodf strtof round ])
1039 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1040 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1041 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1042 AC_CHECK_FUNCS([strerror strerror_r strerror_s ])
1043 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1044 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1045 AC_C_PRINTF_A
1046 AC_FUNC_ALLOCA
1047 AC_FUNC_RAND48
1048
1049 dnl Check for variations in the Standard C++ library and STL. These macros are
1050 dnl provided by LLVM in the autoconf/m4 directory.
1051 AC_CXX_HAVE_STD_ITERATOR
1052 AC_CXX_HAVE_BI_ITERATOR
1053 AC_CXX_HAVE_FWD_ITERATOR
1054 AC_FUNC_ISNAN
1055 AC_FUNC_ISINF
1056
1057 dnl Check for mmap support.We also need to know if /dev/zero is required to
1058 dnl be opened for allocating RWX memory.
1059 dnl Make sure we aren't attempting to configure for an unknown system
1060 if test "$llvm_cv_platform_type" = "Unix" ; then
1061   AC_FUNC_MMAP
1062   AC_FUNC_MMAP_FILE
1063   AC_NEED_DEV_ZERO_FOR_MMAP
1064
1065   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1066   then
1067     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1068   fi
1069   if test "$ac_cv_func_mmap_file" = "no"
1070   then
1071     AC_MSG_WARN([mmap() of files required but not found])
1072   fi
1073 fi
1074
1075 dnl atomic builtins are required for threading support.
1076 AC_MSG_CHECKING(for GCC atomic builtins)
1077 AC_LINK_IFELSE(
1078   AC_LANG_SOURCE(
1079     [[int main() {
1080         volatile unsigned long val = 1;
1081         __sync_synchronize();
1082         __sync_val_compare_and_swap(&val, 1, 0);
1083         __sync_add_and_fetch(&val, 1);
1084         __sync_sub_and_fetch(&val, 1);
1085         return 0;
1086       }
1087     ]]),
1088   AC_MSG_RESULT(yes)
1089   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1090   AC_MSG_RESULT(no)
1091   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1092   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1093
1094
1095 dnl===-----------------------------------------------------------------------===
1096 dnl===
1097 dnl=== SECTION 9: Additional checks, variables, etc.
1098 dnl===
1099 dnl===-----------------------------------------------------------------------===
1100
1101 dnl Check, whether __dso_handle is present
1102 AC_CHECK_FUNCS([__dso_handle])
1103
1104 dnl See if the llvm-gcc executable can compile to LLVM assembly
1105 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1106 [llvm_cv_llvmgcc_sanity="no"
1107 if test -x "$LLVMGCC" ; then
1108   cp /dev/null conftest.c
1109   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1110       grep 'target datalayout =' > /dev/null 2>&1
1111   if test $? -eq 0 ; then
1112     llvm_cv_llvmgcc_sanity="yes"
1113   fi
1114   rm conftest.c
1115 fi])
1116
1117 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1118 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1119   AC_MSG_CHECKING([llvm-gcc component support])
1120   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1121   AC_SUBST(LLVMCC1,$llvmcc1path)
1122   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1123   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1124   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1125   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1126   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1127   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1128   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1129   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1130   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1131   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1132   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1133   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1134   AC_MSG_RESULT([ok])
1135 fi
1136
1137 dnl Propagate the shared library extension that the libltdl checks did to
1138 dnl the Makefiles so we can use it there too
1139 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1140
1141 # Translate the various configuration directories and other basic
1142 # information into substitutions that will end up in Makefile.config.in
1143 # that these configured values can be used by the makefiles
1144 if test "${prefix}" = "NONE" ; then
1145   prefix="/usr/local"
1146 fi
1147 eval LLVM_PREFIX="${prefix}";
1148 eval LLVM_BINDIR="${prefix}/bin";
1149 eval LLVM_LIBDIR="${prefix}/lib";
1150 eval LLVM_DATADIR="${prefix}/share/llvm";
1151 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1152 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1153 eval LLVM_INCLUDEDIR="${prefix}/include";
1154 eval LLVM_INFODIR="${prefix}/info";
1155 eval LLVM_MANDIR="${prefix}/man";
1156 LLVM_CONFIGTIME=`date`
1157 AC_SUBST(LLVM_PREFIX)
1158 AC_SUBST(LLVM_BINDIR)
1159 AC_SUBST(LLVM_LIBDIR)
1160 AC_SUBST(LLVM_DATADIR)
1161 AC_SUBST(LLVM_DOCSDIR)
1162 AC_SUBST(LLVM_ETCDIR)
1163 AC_SUBST(LLVM_INCLUDEDIR)
1164 AC_SUBST(LLVM_INFODIR)
1165 AC_SUBST(LLVM_MANDIR)
1166 AC_SUBST(LLVM_CONFIGTIME)
1167
1168 # Place the various directores into the config.h file as #defines so that we
1169 # can know about the installation paths within LLVM.
1170 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1171                    [Installation prefix directory])
1172 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1173                    [Installation directory for binary executables])
1174 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1175                    [Installation directory for libraries])
1176 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1177                    [Installation directory for data files])
1178 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1179                    [Installation directory for documentation])
1180 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1181                    [Installation directory for config files])
1182 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1183                    [Installation directory for include files])
1184 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1185                    [Installation directory for .info files])
1186 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1187                    [Installation directory for man pages])
1188 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1189                    [Time at which LLVM was configured])
1190 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1191                    [Host triple we were built on])
1192
1193 # Determine which bindings to build.
1194 if test "$BINDINGS_TO_BUILD" = auto ; then
1195   BINDINGS_TO_BUILD=""
1196   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1197     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1198   fi
1199 fi
1200 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1201
1202 # This isn't really configurey, but it avoids having to repeat the list in
1203 # other files.
1204 AC_SUBST(ALL_BINDINGS,ocaml)
1205
1206 # Do any work necessary to ensure that bindings have what they need.
1207 binding_prereqs_failed=0
1208 for a_binding in $BINDINGS_TO_BUILD ; do
1209   case "$a_binding" in
1210   ocaml)
1211     if test "x$OCAMLC" = x ; then
1212       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1213       binding_prereqs_failed=1
1214     fi
1215     if test "x$OCAMLDEP" = x ; then
1216       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1217       binding_prereqs_failed=1
1218     fi
1219     if test "x$OCAMLOPT" = x ; then
1220       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1221       dnl ocamlopt is optional!
1222     fi
1223     if test "x$with_ocaml_libdir" != xauto ; then
1224       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1225     else
1226       ocaml_stdlib="`"$OCAMLC" -where`"
1227       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1228       then
1229         # ocaml stdlib is beneath our prefix; use stdlib
1230         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1231       else
1232         # ocaml stdlib is outside our prefix; use libdir/ocaml
1233         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1234       fi
1235     fi
1236     ;;
1237   esac
1238 done
1239 if test "$binding_prereqs_failed" = 1 ; then
1240   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1241 fi
1242
1243 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1244 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1245
1246 dnl Determine linker rpath flag
1247 if test "$llvm_cv_link_use_r" = "yes" ; then
1248   RPATH="-Wl,-R"
1249 else
1250   RPATH="-Wl,-rpath"
1251 fi
1252 AC_SUBST(RPATH)
1253
1254 dnl Determine linker rdynamic flag
1255 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1256   RDYNAMIC="-Wl,-export-dynamic"
1257 else
1258   RDYNAMIC=""
1259 fi
1260 AC_SUBST(RDYNAMIC)
1261
1262 dnl===-----------------------------------------------------------------------===
1263 dnl===
1264 dnl=== SECTION 10: Specify the output files and generate it
1265 dnl===
1266 dnl===-----------------------------------------------------------------------===
1267
1268 dnl Configure header files
1269 dnl WARNING: dnl If you add or remove any of the following config headers, then
1270 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1271 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1272 dnl files can be updated automatically when their *.in sources change.
1273 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1274 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1275 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1276 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1277 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1278 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1279
1280 dnl Configure the makefile's configuration data
1281 AC_CONFIG_FILES([Makefile.config])
1282
1283 dnl Configure the RPM spec file for LLVM
1284 AC_CONFIG_FILES([llvm.spec])
1285
1286 dnl Configure doxygen's configuration file
1287 AC_CONFIG_FILES([docs/doxygen.cfg])
1288
1289 dnl Configure llvmc's Base plugin
1290 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1291
1292 dnl Do the first stage of configuration for llvm-config.in.
1293 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1294
1295 dnl Do special configuration of Makefiles
1296 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1297 AC_CONFIG_MAKEFILE(Makefile)
1298 AC_CONFIG_MAKEFILE(Makefile.common)
1299 AC_CONFIG_MAKEFILE(examples/Makefile)
1300 AC_CONFIG_MAKEFILE(lib/Makefile)
1301 AC_CONFIG_MAKEFILE(runtime/Makefile)
1302 AC_CONFIG_MAKEFILE(test/Makefile)
1303 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1304 AC_CONFIG_MAKEFILE(unittests/Makefile)
1305 AC_CONFIG_MAKEFILE(tools/Makefile)
1306 AC_CONFIG_MAKEFILE(utils/Makefile)
1307 AC_CONFIG_MAKEFILE(projects/Makefile)
1308 AC_CONFIG_MAKEFILE(bindings/Makefile)
1309 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1310
1311 dnl Finally, crank out the output
1312 AC_OUTPUT