test/lib/llvm.exp

   1 # This procedure executes one line of a test case's execution script.
   2 proc execOneLine { test PRS outcome lineno line } {
   3   set status 0
   4   set resultmsg ""
   5   set retval [ catch { eval exec -keepnewline -- $line } errmsg ]
   6   if { $retval != 0 } {
   7     set code [lindex $::errorCode 0]
   8     set lineno [expr $lineno + 1]
   9     if { $PRS != ""} {
  10       set PRS " for $PRS"
  11     }
  12     set errmsg " at line $lineno\nwhile running: $line\n$errmsg"
  13     switch "$code" {
  14       CHILDSTATUS {
  15         set status [lindex $::errorCode 2]
  16         if { $status != 0 } {
  17           set resultmsg "$test$PRS\nFailed with exit($status)$errmsg"
  18         }
  19       }
  20       CHILDKILLED {
  21         set signal [lindex $::errorCode 2]
  22         set resultmsg "$test$PRS\nFailed with signal($signal)$errmsg"
  23       }
  24       CHILDSUSP {
  25         set signal [lindex $::errorCode 2]
  26         set resultmsg "$test$PRS\nFailed with suspend($signal)$errmsg"
  27       }
  28       POSIX {
  29         set posixNum [lindex $::errorCode 1]
  30         set posixMsg [lindex $::errorCode 2]
  31         set resultmsg "$test$PRS\nFailed with posix($posixNum,$posixMsg)$errmsg"
  32       }
  33       NONE {
  34         # Any other error such as stderr output of a program, or syntax error in
  35         # the RUN line.
  36         set resultmsg "$test$PRS\nFailed with unknown error (or has stderr output)$errmsg"
  37       }
  38       default {
  39         set resultmsg "$test$PRS\nFailed with unknown error$errmsg"
  40       }
  41     }
  42   }
  43   return $resultmsg
  44 }
  45
  46 # This procedure performs variable substitutions on the RUN: lines of a test
  47 # cases.
  48 proc substitute { line test tmpFile } {
  49   global srcroot objroot srcdir objdir subdir target_triplet
  50   global llvmgcc llvmgxx llvmgcc_version llvmgccmajvers ocamlopt
  51   global gccpath gxxpath compile_c compile_cxx link shlibext llvmlibsdir
  52   global llvmdsymutil valgrind grep gas bugpoint_topts
  53   set path [file join $srcdir $subdir]
  54
  55   # Substitute all Tcl variables.
  56   set new_line [subst $line ]
  57
  58   #replace %% with _#MARKER#_ to make the replacement of %% more predictable
  59   regsub -all {%%} $new_line {_#MARKER#_} new_line
  60   #replace %llvmgcc_only with actual path to llvmgcc
  61   regsub -all {%llvmgcc_only} $new_line "$llvmgcc" new_line
  62   #replace %llvmgcc with actual path to llvmgcc
  63   regsub -all {%llvmgcc} $new_line "$llvmgcc -emit-llvm -w" new_line
  64   #replace %llvmgxx with actual path to llvmg++
  65   regsub -all {%llvmgxx} $new_line "$llvmgxx -emit-llvm -w" new_line
  66   #replace %compile_cxx with C++ compilation command
  67   regsub -all {%compile_cxx} $new_line "$compile_cxx" new_line
  68   #replace %compile_c with C compilation command
  69   regsub -all {%compile_c} $new_line "$compile_c" new_line
  70   #replace %link with C++ link command
  71   regsub -all {%link} $new_line "$link" new_line
  72   #replace %shlibext with shared library extension
  73   regsub -all {%shlibext} $new_line "$shlibext" new_line
  74   #replace %ocamlopt with ocaml compiler command
  75   regsub -all {%ocamlopt} $new_line "$ocamlopt" new_line
  76   #replace %llvmdsymutil with dsymutil command
  77   regsub -all {%llvmdsymutil} $new_line "$llvmdsymutil" new_line
  78   #replace %llvmlibsdir with configure library directory
  79   regsub -all {%llvmlibsdir} $new_line "$llvmlibsdir" new_line
  80   #replace %bugpoint_topts with actual bugpoint target options
  81   regsub -all {%bugpoint_topts} $new_line "$bugpoint_topts" new_line
  82   #replace %p with path to source,
  83   regsub -all {%p} $new_line [file join $srcdir $subdir] new_line
  84   #replace %s with filename
  85   regsub -all {%s} $new_line $test new_line
  86   #replace %t with temp filenames
  87   regsub -all {%t} $new_line $tmpFile new_line
  88   #replace _#MARKER#_ with %
  89   regsub -all {_#MARKER#_} $new_line % new_line
  90
  91   #replace grep with GNU grep
  92   regsub -all { grep } $new_line " $grep " new_line
  93   #replace as with GNU as
  94   regsub -all {\| as } $new_line "| $gas " new_line
  95
  96   #valgind related stuff
  97 # regsub -all {bugpoint } $new_line "$valgrind bugpoint " new_line
  98   regsub -all {llc } $new_line "$valgrind llc " new_line
  99   regsub -all {lli } $new_line "$valgrind lli " new_line
 100   regsub -all {llvm-ar } $new_line "$valgrind llvm-ar " new_line
 101   regsub -all {llvm-as } $new_line "$valgrind llvm-as " new_line
 102   regsub -all {llvm-bcanalyzer } $new_line "$valgrind llvm-bcanalyzer " new_line
 103   regsub -all {llvm-dis } $new_line "$valgrind llvm-dis " new_line
 104   regsub -all {llvm-extract } $new_line "$valgrind llvm-extract " new_line
 105   regsub -all {llvm-ld } $new_line "$valgrind llvm-ld " new_line
 106   regsub -all {llvm-link } $new_line "$valgrind llvm-link " new_line
 107   regsub -all {llvm-nm } $new_line "$valgrind llvm-nm " new_line
 108   regsub -all {llvm-prof } $new_line "$valgrind llvm-prof " new_line
 109   regsub -all {llvm-ranlib } $new_line "$valgrind llvm-ranlib " new_line
 110   regsub -all {([^a-zA-Z_-])opt } $new_line "\\1$valgrind opt " new_line
 111   regsub -all {^opt } $new_line "$valgrind opt " new_line
 112   regsub -all {tblgen } $new_line "$valgrind tblgen " new_line
 113   regsub -all "not $valgrind " $new_line "$valgrind not " new_line
 114
 115   return $new_line
 116 }
 117
 118 # This procedure runs the set of tests for the test_source_files array.
 119 proc RunLLVMTests { test_source_files } {
 120   global srcroot objroot srcdir objdir subdir target_triplet llvmgcc_version
 121   set timeout 60
 122
 123   set path [file join $objdir $subdir]
 124
 125   #Make Output Directory if it does not exist already
 126   if { [file exists path] } {
 127     cd $path
 128   } else {
 129     file mkdir $path
 130     cd $path
 131   }
 132
 133   file mkdir Output
 134   cd Output
 135
 136   foreach test $test_source_files {
 137     #Should figure out best way to set the timeout
 138     #set timeout 40
 139
 140     set filename [file tail $test]
 141     verbose "ABOUT TO RUN: $filename" 2
 142     set outcome PASS
 143     set tmpFile "$filename.tmp"
 144
 145     # Mark that it should not be XFAIL for this target.
 146     set targetPASS 0
 147
 148     #set hasRunline bool to check if testcase has a runline
 149     set numLines 0
 150
 151     # Open the test file and start reading lines
 152     set testFileId [ open $test r]
 153     set runline ""
 154     set PRNUMS ""
 155     foreach line [split [read $testFileId] \n] {
 156
 157       # if its the END. line then stop parsing (optimization for big files)
 158       if {[regexp {END.[[:space:]]*$} $line match endofscript]} {
 159         break
 160
 161       # if the line is continued, concatenate and continue the loop
 162       } elseif {[regexp {RUN: *(.+)(\\)$} $line match oneline suffix]} {
 163         set runline "$runline$oneline "
 164
 165       # if its a terminating RUN: line then do substitution on the whole line
 166       # and then save the line.
 167       } elseif {[regexp {RUN: *(.+)$} $line match oneline suffix]} {
 168         set runline "$runline$oneline"
 169         set runline [ substitute $runline $test $tmpFile ]
 170         set lines($numLines) $runline
 171         set numLines [expr $numLines + 1]
 172         set runline ""
 173
 174       # if its an PR line, save the problem report number
 175       } elseif {[regexp {PR([0-9]+)} $line match prnum]} {
 176         if {$PRNUMS == ""} {
 177           set PRNUMS "PR$prnum"
 178         } else {
 179           set PRNUMS "$PRNUMS,$prnum"
 180         }
 181       # if its an XFAIL line, see if we should be XFAILing or not.
 182       } elseif {[regexp {XFAIL:[ *](.+)} $line match targets]} {
 183         set targets
 184
 185         #split up target if more then 1 specified
 186         foreach target [split $targets ,] {
 187           if { $target == "*" } {
 188               if {$targetPASS != 1} {
 189                  set outcome XFAIL
 190               }
 191           } elseif { [regexp $target $target_triplet match] } {
 192               if {$targetPASS != 1} {
 193                  set outcome XFAIL
 194               }
 195           } elseif { [regexp {llvmgcc(([0-9]+)|([0-9]+[.][0-9]+))} $target match submatch submatch2]  } {
 196             if { [regexp ^($submatch)$|^(($submatch)(\.)) $llvmgcc_version match] } {
 197               if {$targetPASS != 1} {
 198                  set outcome XFAIL
 199               }
 200             }
 201           }
 202         }
 203       } elseif {[regexp {XTARGET:[ *](.+)} $line match targets]} {
 204         set targets
 205
 206         #split up target if more then 1 specified
 207         foreach target [split $targets ,] {
 208           if { [regexp {\*} $target match] } {
 209               set targetPASS 1
 210               set outcome PASS
 211           } elseif { [regexp $target $target_triplet match] } {
 212               set targetPASS 1
 213               set outcome PASS
 214           } elseif { [regexp {llvmgcc(([0-9]+)|([0-9]+[.][0-9]+))} $target match submatch submatch2]  } {
 215             if { [regexp ^($submatch)$|^(($submatch)(\.)) $llvmgcc_version match] } {
 216               set targetPASS 1
 217               set outcome PASS
 218             }
 219           }
 220         }
 221       }
 222     }
 223
 224     # Done reading the script
 225     close $testFileId
 226
 227
 228     if { $numLines == 0 } {
 229       fail "$test: \nDoes not have a RUN line\n"
 230     } else {
 231       set failed 0
 232       for { set i 0 } { $i < $numLines } { set i [ expr $i + 1 ] } {
 233         regsub ^.*RUN:(.*) $lines($i) \1 theLine
 234         set resultmsg [execOneLine $test $PRNUMS $outcome $i $theLine ]
 235         if { $resultmsg != "" } {
 236           if { $outcome == "XFAIL" } {
 237             xfail "$resultmsg"
 238           } else {
 239             fail "$resultmsg"
 240           }
 241           set failed 1
 242           break
 243         }
 244       }
 245       if { $failed } {
 246         continue
 247       } else {
 248         if { $PRNUMS != "" } {
 249           set PRNUMS " for $PRNUMS"
 250         }
 251         if { $outcome == "XFAIL" } {
 252           xpass "$test$PRNUMS"
 253         } else {
 254           pass "$test$PRNUMS"
 255         }
 256       }
 257     }
 258   }
 259 }
 260
 261 # This procedure provides an interface to check the LLVMGCC_LANGS makefile
 262 # variable to see if llvm-gcc supports compilation of a particular language.
 263 proc llvm_gcc_supports { lang } {
 264   global llvmgcc llvmgcc_langs
 265   # validate the language choices and determine the name of the compiler
 266   # component responsible for determining if the compiler has been built.
 267   switch "$lang" {
 268     ada     { set file gnat1 }
 269     c       { set file cc1 }
 270     c++     { set file cc1plus }
 271     objc    { set file cc1obj }
 272     obj-c++ { set file cc1objplus }
 273     fortran { set file f951 }
 274     default { return 0 }
 275   }
 276   foreach supported_lang [split "$llvmgcc_langs" ,] {
 277     if { "$lang" == "$supported_lang" } {
 278       # FIXME: Knowing it is configured is not enough. We should do two more
 279       # checks here. First, we need to run llvm-gcc -print-prog-name=$file to
 280       # get the path to the compiler. If we don't get a path, the language isn't
 281       # properly configured or built. If we do get a path, we should check to
 282       # make sure that it is executable and perhaps even try executing it.
 283       return 1;
 284     }
 285   }
 286   return 0;
 287 }
 288
 289 # This procedure provides an interface to check the TARGETS_TO_BUILD makefile
 290 # variable to see if a particular target has been configured to build. This
 291 # helps avoid running tests for targets that aren't available.
 292 proc llvm_supports_target { tgtName } {
 293   global TARGETS_TO_BUILD
 294   foreach target [split $TARGETS_TO_BUILD] {
 295     if { [regexp $tgtName $target match] } {
 296       return 1
 297     }
 298   }
 299   return 0
 300 }