CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  23 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  24 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  25 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  26 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  27 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  28
  29 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  30   file(GLOB_RECURSE
  31     tablegenned_files_on_include_dir
  32     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  33   file(GLOB_RECURSE
  34     tablegenned_files_on_lib_dir
  35     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  36   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  37     message(FATAL_ERROR "Apparently there is a previous in-source build,
  38 probably as the result of running `configure' and `make' on
  39 ${LLVM_MAIN_SRC_DIR}.
  40 This may cause problems. The suspicious files are:
  41 ${tablegenned_files_on_lib_dir}
  42 ${tablegenned_files_on_include_dir}
  43 Please clean the source directory.")
  44   endif()
  45 endif()
  46
  47 set(LLVM_ALL_TARGETS
  48   Alpha
  49   ARM
  50   Blackfin
  51   CBackend
  52   CellSPU
  53   CppBackend
  54   Mips
  55   MSIL
  56   MSP430
  57   PIC16
  58   PowerPC
  59   Sparc
  60   SystemZ
  61   X86
  62   XCore
  63   )
  64
  65 if( MSVC )
  66   set(LLVM_TARGETS_TO_BUILD X86
  67     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  68 else( MSVC )
  69   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  70     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  71 endif( MSVC )
  72
  73 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  74
  75 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  76   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  77 else()
  78   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  79 endif()
  80
  81 if( LLVM_ENABLE_ASSERTIONS )
  82   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  83   if( NOT MSVC )
  84     add_definitions( -D_DEBUG )
  85   endif()
  86   # On Release builds cmake automatically defines NDEBUG, so we
  87   # explicitly undefine it:
  88   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  89     add_definitions( -UNDEBUG )
  90   endif()
  91 else()
  92   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  93     add_definitions( -DNDEBUG )
  94   endif()
  95 endif()
  96
  97 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" AND NOT LLVM_ENABLE_ASSERTIONS )
  98   set( LLVM_COMPACT_SENTINELS 1 )
  99 else( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" AND NOT LLVM_ENABLE_ASSERTIONS )
 100   set( LLVM_COMPACT_SENTINELS 0 )
 101 endif( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" AND NOT LLVM_ENABLE_ASSERTIONS )
 102
 103 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 104   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 105 endif()
 106
 107 set(LLVM_ENUM_TARGETS "")
 108 foreach(c ${LLVM_TARGETS_TO_BUILD})
 109   list(FIND LLVM_ALL_TARGETS ${c} idx)
 110   if( idx LESS 0 )
 111     message(FATAL_ERROR "The target `${c}' does not exist.
 112     It should be one of\n${LLVM_ALL_TARGETS}")
 113   else()
 114     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 115   endif()
 116 endforeach(c)
 117
 118 # Produce llvm/Config/Targets.def
 119 configure_file(
 120   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 121   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 122   )
 123
 124 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 125
 126 # Add path for custom modules
 127 set(CMAKE_MODULE_PATH
 128   ${CMAKE_MODULE_PATH}
 129   "${LLVM_MAIN_SRC_DIR}/cmake"
 130   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 131   )
 132
 133 include(AddLLVMDefinitions)
 134
 135 if(WIN32)
 136   if(CYGWIN)
 137     set(LLVM_ON_WIN32 0)
 138     set(LLVM_ON_UNIX 1)
 139   else(CYGWIN)
 140     set(LLVM_ON_WIN32 1)
 141     set(LLVM_ON_UNIX 0)
 142   endif(CYGWIN)
 143   set(LTDL_SHLIB_EXT ".dll")
 144   set(EXEEXT ".exe")
 145   # Maximum path length is 160 for non-unicode paths
 146   set(MAXPATHLEN 160)
 147 else(WIN32)
 148   if(UNIX)
 149     set(LLVM_ON_WIN32 0)
 150     set(LLVM_ON_UNIX 1)
 151     set(LTDL_SHLIB_EXT ".so")
 152     set(EXEEXT "")
 153     # FIXME: Maximum path length is currently set to 'safe' fixed value
 154     set(MAXPATHLEN 2024)
 155   else(UNIX)
 156     MESSAGE(SEND_ERROR "Unable to determine platform")
 157   endif(UNIX)
 158 endif(WIN32)
 159
 160 include(config-ix)
 161
 162 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 163
 164 set(ENABLE_PIC 0)
 165 if( LLVM_ENABLE_PIC )
 166   if( SUPPORTS_FPIC_FLAG )
 167     message(STATUS "Building with -fPIC")
 168     add_llvm_definitions(-fPIC)
 169     set(ENABLE_PIC 1)
 170  else( SUPPORTS_FPIC_FLAG )
 171     message(STATUS "Warning: -fPIC not supported.")
 172   endif()
 173 endif()
 174
 175 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 176 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 177 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 178
 179 # set(CMAKE_VERBOSE_MAKEFILE true)
 180
 181 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 182 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 183
 184 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 185   # TODO: support other platforms and toolchains.
 186   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 187   if( LLVM_BUILD_32_BITS )
 188     message(STATUS "Building 32 bits executables and libraries.")
 189     add_llvm_definitions( -m32 )
 190     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 191     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 192     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 193   endif( LLVM_BUILD_32_BITS )
 194 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 195
 196 if( MSVC )
 197   # List of valid CRTs for MSVC
 198   set(MSVC_CRT
 199     MD
 200     MDd)
 201
 202   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 203   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 204   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 205   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 206   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 207   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 208
 209   # Suppress 'new behavior: elements of array 'array' will be default initialized'
 210   add_llvm_definitions( -wd4351 )
 211
 212   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 213     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 214     if (idx LESS 0)
 215       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 216     endif (idx LESS 0)
 217     add_llvm_definitions("/${LLVM_USE_CRT}")
 218     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 219   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 220 endif( MSVC )
 221
 222 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 223
 224 include(AddLLVM)
 225 include(TableGen)
 226
 227 add_subdirectory(lib/Support)
 228 add_subdirectory(lib/System)
 229
 230 # Everything else depends on Support and System:
 231 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 232
 233 set(LLVM_TABLEGEN "tblgen" CACHE
 234   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 235 # Effective tblgen executable to be used:
 236 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 237
 238 add_subdirectory(utils/TableGen)
 239
 240 if( CMAKE_CROSSCOMPILING )
 241   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 242   include( CrossCompileLLVM )
 243 endif( CMAKE_CROSSCOMPILING )
 244
 245 add_subdirectory(include/llvm)
 246
 247 add_subdirectory(lib/VMCore)
 248 add_subdirectory(lib/CodeGen)
 249 add_subdirectory(lib/CodeGen/SelectionDAG)
 250 add_subdirectory(lib/CodeGen/AsmPrinter)
 251 add_subdirectory(lib/Bitcode/Reader)
 252 add_subdirectory(lib/Bitcode/Writer)
 253 add_subdirectory(lib/Transforms/Utils)
 254 add_subdirectory(lib/Transforms/Instrumentation)
 255 add_subdirectory(lib/Transforms/Scalar)
 256 add_subdirectory(lib/Transforms/IPO)
 257 add_subdirectory(lib/Transforms/Hello)
 258 add_subdirectory(lib/Linker)
 259 add_subdirectory(lib/Analysis)
 260 add_subdirectory(lib/Analysis/IPA)
 261 add_subdirectory(lib/MC)
 262
 263 add_subdirectory(utils/FileCheck)
 264
 265 set(LLVM_ENUM_ASM_PRINTERS "")
 266 set(LLVM_ENUM_ASM_PARSERS "")
 267 foreach(t ${LLVM_TARGETS_TO_BUILD})
 268   message(STATUS "Targeting ${t}")
 269   set(CURRENT_LLVM_TARGET ${t})
 270   add_subdirectory(lib/Target/${t})
 271   add_subdirectory(lib/Target/${t}/TargetInfo)
 272   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 273     add_subdirectory(lib/Target/${t}/AsmPrinter)
 274     set(LLVM_ENUM_ASM_PRINTERS
 275       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 276   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 277   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmParser/CMakeLists.txt )
 278     add_subdirectory(lib/Target/${t}/AsmParser)
 279     set(LLVM_ENUM_ASM_PARSERS
 280       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 281   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmParser/CMakeLists.txt )
 282   set(CURRENT_LLVM_TARGET)
 283 endforeach(t)
 284
 285 # Produce llvm/Config/AsmPrinters.def
 286 configure_file(
 287   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 288   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 289   )
 290
 291 # Produce llvm/Config/AsmParsers.def
 292 configure_file(
 293   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 294   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 295   )
 296
 297 add_subdirectory(lib/ExecutionEngine)
 298 add_subdirectory(lib/ExecutionEngine/Interpreter)
 299 add_subdirectory(lib/ExecutionEngine/JIT)
 300 add_subdirectory(lib/Target)
 301 add_subdirectory(lib/AsmParser)
 302 add_subdirectory(lib/Debugger)
 303 add_subdirectory(lib/Archive)
 304
 305 add_subdirectory(projects)
 306 add_subdirectory(tools)
 307
 308 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 309 if (LLVM_EXAMPLES)
 310   add_subdirectory(examples)
 311 endif ()
 312
 313 install(DIRECTORY include
 314   DESTINATION .
 315   PATTERN ".svn" EXCLUDE
 316   PATTERN "*.cmake" EXCLUDE
 317   PATTERN "*.in" EXCLUDE
 318   PATTERN "*.tmp" EXCLUDE
 319   )
 320
 321 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 322   DESTINATION .
 323   )
 324
 325 # TODO: make and install documentation.