lib/Target/ARM/ARMInstrInfo.td

   1 //===- ARMInstrInfo.td - Target Description for ARM Target -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the ARM instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // ARM specific DAG Nodes.
  16 //
  17
  18 // Type profiles.
  19 def SDT_ARMCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  20 def SDT_ARMCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>, SDTCisVT<1, i32> ]>;
  21
  22 def SDT_ARMSaveCallPC : SDTypeProfile<0, 1, []>;
  23
  24 def SDT_ARMcall    : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
  25
  26 def SDT_ARMCMov    : SDTypeProfile<1, 3,
  27                                    [SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>,
  28                                     SDTCisVT<3, i32>]>;
  29
  30 def SDT_ARMBrcond  : SDTypeProfile<0, 2,
  31                                    [SDTCisVT<0, OtherVT>, SDTCisVT<1, i32>]>;
  32
  33 def SDT_ARMBrJT    : SDTypeProfile<0, 3,
  34                                   [SDTCisPtrTy<0>, SDTCisVT<1, i32>,
  35                                    SDTCisVT<2, i32>]>;
  36
  37 def SDT_ARMCmp     : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
  38
  39 def SDT_ARMPICAdd  : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  40                                           SDTCisPtrTy<1>, SDTCisVT<2, i32>]>;
  41
  42 def SDT_ARMThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  43
  44 // Node definitions.
  45 def ARMWrapper       : SDNode<"ARMISD::Wrapper",     SDTIntUnaryOp>;
  46 def ARMWrapperJT     : SDNode<"ARMISD::WrapperJT",   SDTIntBinOp>;
  47
  48 def ARMcallseq_start : SDNode<"ISD::CALLSEQ_START", SDT_ARMCallSeqStart,
  49                               [SDNPHasChain, SDNPOutFlag]>;
  50 def ARMcallseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_ARMCallSeqEnd,
  51                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  52
  53 def ARMcall          : SDNode<"ARMISD::CALL", SDT_ARMcall,
  54                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  55 def ARMcall_pred    : SDNode<"ARMISD::CALL_PRED", SDT_ARMcall,
  56                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  57 def ARMcall_nolink   : SDNode<"ARMISD::CALL_NOLINK", SDT_ARMcall,
  58                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  59
  60 def ARMretflag       : SDNode<"ARMISD::RET_FLAG", SDTNone,
  61                               [SDNPHasChain, SDNPOptInFlag]>;
  62
  63 def ARMcmov          : SDNode<"ARMISD::CMOV", SDT_ARMCMov,
  64                               [SDNPInFlag]>;
  65 def ARMcneg          : SDNode<"ARMISD::CNEG", SDT_ARMCMov,
  66                               [SDNPInFlag]>;
  67
  68 def ARMbrcond        : SDNode<"ARMISD::BRCOND", SDT_ARMBrcond,
  69                               [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  70
  71 def ARMbrjt          : SDNode<"ARMISD::BR_JT", SDT_ARMBrJT,
  72                               [SDNPHasChain]>;
  73
  74 def ARMcmp           : SDNode<"ARMISD::CMP", SDT_ARMCmp,
  75                               [SDNPOutFlag]>;
  76
  77 def ARMcmpNZ         : SDNode<"ARMISD::CMPNZ", SDT_ARMCmp,
  78                               [SDNPOutFlag]>;
  79
  80 def ARMpic_add       : SDNode<"ARMISD::PIC_ADD", SDT_ARMPICAdd>;
  81
  82 def ARMsrl_flag      : SDNode<"ARMISD::SRL_FLAG", SDTIntUnaryOp, [SDNPOutFlag]>;
  83 def ARMsra_flag      : SDNode<"ARMISD::SRA_FLAG", SDTIntUnaryOp, [SDNPOutFlag]>;
  84 def ARMrrx           : SDNode<"ARMISD::RRX"     , SDTIntUnaryOp, [SDNPInFlag ]>;
  85
  86 def ARMthread_pointer: SDNode<"ARMISD::THREAD_POINTER", SDT_ARMThreadPointer>;
  87
  88 //===----------------------------------------------------------------------===//
  89 // ARM Instruction Predicate Definitions.
  90 //
  91 def HasV5T  : Predicate<"Subtarget->hasV5TOps()">;
  92 def HasV5TE : Predicate<"Subtarget->hasV5TEOps()">;
  93 def HasV6   : Predicate<"Subtarget->hasV6Ops()">;
  94 def IsThumb : Predicate<"Subtarget->isThumb()">;
  95 def IsARM   : Predicate<"!Subtarget->isThumb()">;
  96
  97 //===----------------------------------------------------------------------===//
  98 // ARM Flag Definitions.
  99
 100 class RegConstraint<string C> {
 101   string Constraints = C;
 102 }
 103
 104 //===----------------------------------------------------------------------===//
 105 //  ARM specific transformation functions and pattern fragments.
 106 //
 107
 108 // so_imm_XFORM - Return a so_imm value packed into the format described for
 109 // so_imm def below.
 110 def so_imm_XFORM : SDNodeXForm<imm, [{
 111   return CurDAG->getTargetConstant(ARM_AM::getSOImmVal(N->getZExtValue()),
 112                                    MVT::i32);
 113 }]>;
 114
 115 // so_imm_neg_XFORM - Return a so_imm value packed into the format described for
 116 // so_imm_neg def below.
 117 def so_imm_neg_XFORM : SDNodeXForm<imm, [{
 118   return CurDAG->getTargetConstant(ARM_AM::getSOImmVal(-(int)N->getZExtValue()),
 119                                    MVT::i32);
 120 }]>;
 121
 122 // so_imm_not_XFORM - Return a so_imm value packed into the format described for
 123 // so_imm_not def below.
 124 def so_imm_not_XFORM : SDNodeXForm<imm, [{
 125   return CurDAG->getTargetConstant(ARM_AM::getSOImmVal(~(int)N->getZExtValue()),
 126                                    MVT::i32);
 127 }]>;
 128
 129 // rot_imm predicate - True if the 32-bit immediate is equal to 8, 16, or 24.
 130 def rot_imm : PatLeaf<(i32 imm), [{
 131   int32_t v = (int32_t)N->getZExtValue();
 132   return v == 8 || v == 16 || v == 24;
 133 }]>;
 134
 135 /// imm1_15 predicate - True if the 32-bit immediate is in the range [1,15].
 136 def imm1_15 : PatLeaf<(i32 imm), [{
 137   return (int32_t)N->getZExtValue() >= 1 && (int32_t)N->getZExtValue() < 16;
 138 }]>;
 139
 140 /// imm16_31 predicate - True if the 32-bit immediate is in the range [16,31].
 141 def imm16_31 : PatLeaf<(i32 imm), [{
 142   return (int32_t)N->getZExtValue() >= 16 && (int32_t)N->getZExtValue() < 32;
 143 }]>;
 144
 145 def so_imm_neg :
 146   PatLeaf<(imm), [{
 147     return ARM_AM::getSOImmVal(-(int)N->getZExtValue()) != -1;
 148   }], so_imm_neg_XFORM>;
 149
 150 def so_imm_not :
 151   PatLeaf<(imm), [{
 152     return ARM_AM::getSOImmVal(~(int)N->getZExtValue()) != -1;
 153   }], so_imm_not_XFORM>;
 154
 155 // sext_16_node predicate - True if the SDNode is sign-extended 16 or more bits.
 156 def sext_16_node : PatLeaf<(i32 GPR:$a), [{
 157   return CurDAG->ComputeNumSignBits(SDValue(N,0)) >= 17;
 158 }]>;
 159
 160 class BinOpFrag<dag res> : PatFrag<(ops node:$LHS, node:$RHS), res>;
 161 class UnOpFrag <dag res> : PatFrag<(ops node:$Src), res>;
 162
 163 //===----------------------------------------------------------------------===//
 164 // Operand Definitions.
 165 //
 166
 167 // Branch target.
 168 def brtarget : Operand<OtherVT>;
 169
 170 // A list of registers separated by comma. Used by load/store multiple.
 171 def reglist : Operand<i32> {
 172   let PrintMethod = "printRegisterList";
 173 }
 174
 175 // An operand for the CONSTPOOL_ENTRY pseudo-instruction.
 176 def cpinst_operand : Operand<i32> {
 177   let PrintMethod = "printCPInstOperand";
 178 }
 179
 180 def jtblock_operand : Operand<i32> {
 181   let PrintMethod = "printJTBlockOperand";
 182 }
 183
 184 // Local PC labels.
 185 def pclabel : Operand<i32> {
 186   let PrintMethod = "printPCLabel";
 187 }
 188
 189 // shifter_operand operands: so_reg and so_imm.
 190 def so_reg : Operand<i32>,    // reg reg imm
 191             ComplexPattern<i32, 3, "SelectShifterOperandReg",
 192                             [shl,srl,sra,rotr]> {
 193   let PrintMethod = "printSORegOperand";
 194   let MIOperandInfo = (ops GPR, GPR, i32imm);
 195 }
 196
 197 // so_imm - Match a 32-bit shifter_operand immediate operand, which is an
 198 // 8-bit immediate rotated by an arbitrary number of bits.  so_imm values are
 199 // represented in the imm field in the same 12-bit form that they are encoded
 200 // into so_imm instructions: the 8-bit immediate is the least significant bits
 201 // [bits 0-7], the 4-bit shift amount is the next 4 bits [bits 8-11].
 202 def so_imm : Operand<i32>,
 203              PatLeaf<(imm),
 204                      [{ return ARM_AM::getSOImmVal(N->getZExtValue()) != -1; }],
 205                      so_imm_XFORM> {
 206   let PrintMethod = "printSOImmOperand";
 207 }
 208
 209 // Break so_imm's up into two pieces.  This handles immediates with up to 16
 210 // bits set in them.  This uses so_imm2part to match and so_imm2part_[12] to
 211 // get the first/second pieces.
 212 def so_imm2part : Operand<i32>,
 213                   PatLeaf<(imm), [{
 214       return ARM_AM::isSOImmTwoPartVal((unsigned)N->getZExtValue());
 215     }]> {
 216   let PrintMethod = "printSOImm2PartOperand";
 217 }
 218
 219 def so_imm2part_1 : SDNodeXForm<imm, [{
 220   unsigned V = ARM_AM::getSOImmTwoPartFirst((unsigned)N->getZExtValue());
 221   return CurDAG->getTargetConstant(ARM_AM::getSOImmVal(V), MVT::i32);
 222 }]>;
 223
 224 def so_imm2part_2 : SDNodeXForm<imm, [{
 225   unsigned V = ARM_AM::getSOImmTwoPartSecond((unsigned)N->getZExtValue());
 226   return CurDAG->getTargetConstant(ARM_AM::getSOImmVal(V), MVT::i32);
 227 }]>;
 228
 229
 230 // Define ARM specific addressing modes.
 231
 232 // addrmode2 := reg +/- reg shop imm
 233 // addrmode2 := reg +/- imm12
 234 //
 235 def addrmode2 : Operand<i32>,
 236                 ComplexPattern<i32, 3, "SelectAddrMode2", []> {
 237   let PrintMethod = "printAddrMode2Operand";
 238   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 239 }
 240
 241 def am2offset : Operand<i32>,
 242                 ComplexPattern<i32, 2, "SelectAddrMode2Offset", []> {
 243   let PrintMethod = "printAddrMode2OffsetOperand";
 244   let MIOperandInfo = (ops GPR, i32imm);
 245 }
 246
 247 // addrmode3 := reg +/- reg
 248 // addrmode3 := reg +/- imm8
 249 //
 250 def addrmode3 : Operand<i32>,
 251                 ComplexPattern<i32, 3, "SelectAddrMode3", []> {
 252   let PrintMethod = "printAddrMode3Operand";
 253   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 254 }
 255
 256 def am3offset : Operand<i32>,
 257                 ComplexPattern<i32, 2, "SelectAddrMode3Offset", []> {
 258   let PrintMethod = "printAddrMode3OffsetOperand";
 259   let MIOperandInfo = (ops GPR, i32imm);
 260 }
 261
 262 // addrmode4 := reg, <mode|W>
 263 //
 264 def addrmode4 : Operand<i32>,
 265                 ComplexPattern<i32, 2, "", []> {
 266   let PrintMethod = "printAddrMode4Operand";
 267   let MIOperandInfo = (ops GPR, i32imm);
 268 }
 269
 270 // addrmode5 := reg +/- imm8*4
 271 //
 272 def addrmode5 : Operand<i32>,
 273                 ComplexPattern<i32, 2, "SelectAddrMode5", []> {
 274   let PrintMethod = "printAddrMode5Operand";
 275   let MIOperandInfo = (ops GPR, i32imm);
 276 }
 277
 278 // addrmodepc := pc + reg
 279 //
 280 def addrmodepc : Operand<i32>,
 281                  ComplexPattern<i32, 2, "SelectAddrModePC", []> {
 282   let PrintMethod = "printAddrModePCOperand";
 283   let MIOperandInfo = (ops GPR, i32imm);
 284 }
 285
 286 // ARM Predicate operand. Default to 14 = always (AL). Second part is CC
 287 // register whose default is 0 (no register).
 288 def pred : PredicateOperand<OtherVT, (ops i32imm, CCR),
 289                                      (ops (i32 14), (i32 zero_reg))> {
 290   let PrintMethod = "printPredicateOperand";
 291 }
 292
 293 // Conditional code result for instructions whose 's' bit is set, e.g. subs.
 294 //
 295 def cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 zero_reg))> {
 296   let PrintMethod = "printSBitModifierOperand";
 297 }
 298
 299 //===----------------------------------------------------------------------===//
 300 // ARM Instruction flags.  These need to match ARMInstrInfo.h.
 301 //
 302
 303 // Addressing mode.
 304 class AddrMode<bits<4> val> {
 305   bits<4> Value = val;
 306 }
 307 def AddrModeNone : AddrMode<0>;
 308 def AddrMode1    : AddrMode<1>;
 309 def AddrMode2    : AddrMode<2>;
 310 def AddrMode3    : AddrMode<3>;
 311 def AddrMode4    : AddrMode<4>;
 312 def AddrMode5    : AddrMode<5>;
 313 def AddrModeT1   : AddrMode<6>;
 314 def AddrModeT2   : AddrMode<7>;
 315 def AddrModeT4   : AddrMode<8>;
 316 def AddrModeTs   : AddrMode<9>;
 317
 318 // Instruction size.
 319 class SizeFlagVal<bits<3> val> {
 320   bits<3> Value = val;
 321 }
 322 def SizeInvalid  : SizeFlagVal<0>;  // Unset.
 323 def SizeSpecial  : SizeFlagVal<1>;  // Pseudo or special.
 324 def Size8Bytes   : SizeFlagVal<2>;
 325 def Size4Bytes   : SizeFlagVal<3>;
 326 def Size2Bytes   : SizeFlagVal<4>;
 327
 328 // Load / store index mode.
 329 class IndexMode<bits<2> val> {
 330   bits<2> Value = val;
 331 }
 332 def IndexModeNone : IndexMode<0>;
 333 def IndexModePre  : IndexMode<1>;
 334 def IndexModePost : IndexMode<2>;
 335
 336 //===----------------------------------------------------------------------===//
 337
 338 include "ARMInstrFormats.td"
 339
 340 //===----------------------------------------------------------------------===//
 341 // Multiclass helpers...
 342 //
 343
 344 /// AsI1_bin_irs - Defines a set of (op r, {so_imm|r|so_reg}) patterns for a
 345 /// binop that produces a value.
 346 multiclass AsI1_bin_irs<bits<4> opcod, string opc, PatFrag opnode> {
 347   def ri : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 348                opc, " $dst, $a, $b",
 349                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]>;
 350   def rr : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b), DPFrm,
 351                opc, " $dst, $a, $b",
 352                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]>;
 353   def rs : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 354                opc, " $dst, $a, $b",
 355                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]>;
 356 }
 357
 358 /// ASI1_bin_s_irs - Similar to AsI1_bin_irs except it sets the 's' bit so the
 359 /// instruction modifies the CSPR register.
 360 let Defs = [CPSR] in {
 361 multiclass ASI1_bin_s_irs<bits<4> opcod, string opc, PatFrag opnode> {
 362   def ri : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 363                opc, "s $dst, $a, $b",
 364                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]>;
 365   def rr : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b), DPFrm,
 366                opc, "s $dst, $a, $b",
 367                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]>;
 368   def rs : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 369                opc, "s $dst, $a, $b",
 370                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]>;
 371 }
 372 }
 373
 374 /// AI1_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 375 /// patterns. Similar to AsI1_bin_irs except the instruction does not produce
 376 /// a explicit result, only implicitly set CPSR.
 377 let Defs = [CPSR] in {
 378 multiclass AI1_cmp_irs<bits<4> opcod, string opc, PatFrag opnode> {
 379   def ri : AI1<opcod, (outs), (ins GPR:$a, so_imm:$b), DPFrm,
 380                opc, " $a, $b",
 381                [(opnode GPR:$a, so_imm:$b)]>;
 382   def rr : AI1<opcod, (outs), (ins GPR:$a, GPR:$b), DPFrm,
 383                opc, " $a, $b",
 384                [(opnode GPR:$a, GPR:$b)]>;
 385   def rs : AI1<opcod, (outs), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 386                opc, " $a, $b",
 387                [(opnode GPR:$a, so_reg:$b)]>;
 388 }
 389 }
 390
 391 /// AI_unary_rrot - A unary operation with two forms: one whose operand is a
 392 /// register and one whose operand is a register rotated by 8/16/24.
 393 /// FIXME: Remove the 'r' variant. Its rot_imm is zero.
 394 multiclass AI_unary_rrot<bits<8> opcod, string opc, PatFrag opnode> {
 395   def r     : AExtI<opcod, (outs GPR:$dst), (ins GPR:$Src),
 396                  opc, " $dst, $Src",
 397                  [(set GPR:$dst, (opnode GPR:$Src))]>,
 398               Requires<[IsARM, HasV6]> {
 399                 let Inst{19-16} = 0b1111;
 400               }
 401   def r_rot : AExtI<opcod, (outs GPR:$dst), (ins GPR:$Src, i32imm:$rot),
 402                  opc, " $dst, $Src, ror $rot",
 403                  [(set GPR:$dst, (opnode (rotr GPR:$Src, rot_imm:$rot)))]>,
 404               Requires<[IsARM, HasV6]> {
 405                 let Inst{19-16} = 0b1111;
 406               }
 407 }
 408
 409 /// AI_bin_rrot - A binary operation with two forms: one whose operand is a
 410 /// register and one whose operand is a register rotated by 8/16/24.
 411 multiclass AI_bin_rrot<bits<8> opcod, string opc, PatFrag opnode> {
 412   def rr     : AExtI<opcod, (outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS),
 413                   opc, " $dst, $LHS, $RHS",
 414                   [(set GPR:$dst, (opnode GPR:$LHS, GPR:$RHS))]>,
 415                   Requires<[IsARM, HasV6]>;
 416   def rr_rot : AExtI<opcod, (outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS, i32imm:$rot),
 417                   opc, " $dst, $LHS, $RHS, ror $rot",
 418                   [(set GPR:$dst, (opnode GPR:$LHS,
 419                                           (rotr GPR:$RHS, rot_imm:$rot)))]>,
 420                   Requires<[IsARM, HasV6]>;
 421 }
 422
 423 /// AsXI1_bin_c_irs - Same as AsI1_bin_irs but without the predicate operand and
 424 /// setting carry bit. But it can optionally set CPSR.
 425 let Uses = [CPSR] in {
 426 multiclass AsXI1_bin_c_irs<bits<4> opcod, string opc, PatFrag opnode> {
 427   def ri : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b, cc_out:$s),
 428                 DPFrm, !strconcat(opc, "${s} $dst, $a, $b"),
 429                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]>;
 430   def rr : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b, cc_out:$s),
 431                 DPFrm, !strconcat(opc, "${s} $dst, $a, $b"),
 432                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]>;
 433   def rs : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b, cc_out:$s),
 434                 DPSoRegFrm, !strconcat(opc, "${s} $dst, $a, $b"),
 435                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]>;
 436 }
 437 }
 438
 439 //===----------------------------------------------------------------------===//
 440 // Instructions
 441 //===----------------------------------------------------------------------===//
 442
 443 //===----------------------------------------------------------------------===//
 444 //  Miscellaneous Instructions.
 445 //
 446
 447 /// CONSTPOOL_ENTRY - This instruction represents a floating constant pool in
 448 /// the function.  The first operand is the ID# for this instruction, the second
 449 /// is the index into the MachineConstantPool that this is, the third is the
 450 /// size in bytes of this constant pool entry.
 451 let isNotDuplicable = 1 in
 452 def CONSTPOOL_ENTRY :
 453 PseudoInst<(outs), (ins cpinst_operand:$instid, cpinst_operand:$cpidx,
 454                     i32imm:$size),
 455            "${instid:label} ${cpidx:cpentry}", []>;
 456
 457 let Defs = [SP], Uses = [SP] in {
 458 def ADJCALLSTACKUP :
 459 PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2, pred:$p),
 460            "@ ADJCALLSTACKUP $amt1",
 461            [(ARMcallseq_end timm:$amt1, timm:$amt2)]>;
 462
 463 def ADJCALLSTACKDOWN :
 464 PseudoInst<(outs), (ins i32imm:$amt, pred:$p),
 465            "@ ADJCALLSTACKDOWN $amt",
 466            [(ARMcallseq_start timm:$amt)]>;
 467 }
 468
 469 def DWARF_LOC :
 470 PseudoInst<(outs), (ins i32imm:$line, i32imm:$col, i32imm:$file),
 471            ".loc $file, $line, $col",
 472            [(dwarf_loc (i32 imm:$line), (i32 imm:$col), (i32 imm:$file))]>;
 473
 474
 475 // Address computation and loads and stores in PIC mode.
 476 let isNotDuplicable = 1 in {
 477 def PICADD : AXI1<0b0100, (outs GPR:$dst), (ins GPR:$a, pclabel:$cp, pred:$p),
 478                   Pseudo, "$cp:\n\tadd$p $dst, pc, $a",
 479                    [(set GPR:$dst, (ARMpic_add GPR:$a, imm:$cp))]>;
 480
 481 let AddedComplexity = 10 in {
 482 let canFoldAsLoad = 1 in
 483 def PICLDR  : AXI2ldw<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 484                   Pseudo, "${addr:label}:\n\tldr$p $dst, $addr",
 485                   [(set GPR:$dst, (load addrmodepc:$addr))]>;
 486
 487 def PICLDRH : AXI3ldh<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 488                   Pseudo, "${addr:label}:\n\tldr${p}h $dst, $addr",
 489                   [(set GPR:$dst, (zextloadi16 addrmodepc:$addr))]>;
 490
 491 def PICLDRB : AXI2ldb<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 492                   Pseudo, "${addr:label}:\n\tldr${p}b $dst, $addr",
 493                   [(set GPR:$dst, (zextloadi8 addrmodepc:$addr))]>;
 494
 495 def PICLDRSH : AXI3ldsh<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 496                   Pseudo, "${addr:label}:\n\tldr${p}sh $dst, $addr",
 497                   [(set GPR:$dst, (sextloadi16 addrmodepc:$addr))]>;
 498
 499 def PICLDRSB : AXI3ldsb<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 500                   Pseudo, "${addr:label}:\n\tldr${p}sb $dst, $addr",
 501                   [(set GPR:$dst, (sextloadi8 addrmodepc:$addr))]>;
 502 }
 503 let AddedComplexity = 10 in {
 504 def PICSTR  : AXI2stw<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 505                Pseudo, "${addr:label}:\n\tstr$p $src, $addr",
 506                [(store GPR:$src, addrmodepc:$addr)]>;
 507
 508 def PICSTRH : AXI3sth<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 509                Pseudo, "${addr:label}:\n\tstr${p}h $src, $addr",
 510                [(truncstorei16 GPR:$src, addrmodepc:$addr)]>;
 511
 512 def PICSTRB : AXI2stb<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 513                Pseudo, "${addr:label}:\n\tstr${p}b $src, $addr",
 514                [(truncstorei8 GPR:$src, addrmodepc:$addr)]>;
 515 }
 516 } // isNotDuplicable = 1
 517
 518 //===----------------------------------------------------------------------===//
 519 //  Control Flow Instructions.
 520 //
 521
 522 let isReturn = 1, isTerminator = 1 in
 523   def BX_RET : AI<(outs), (ins), BrMiscFrm, "bx", " lr", [(ARMretflag)]> {
 524   let Inst{7-4}   = 0b0001;
 525   let Inst{19-8}  = 0b111111111111;
 526   let Inst{27-20} = 0b00010010;
 527 }
 528
 529 // FIXME: remove when we have a way to marking a MI with these properties.
 530 // FIXME: $dst1 should be a def. But the extra ops must be in the end of the
 531 // operand list.
 532 // FIXME: Should pc be an implicit operand like PICADD, etc?
 533 let isReturn = 1, isTerminator = 1 in
 534   def LDM_RET : AXI4ld<(outs),
 535                     (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
 536                     LdStMulFrm, "ldm${p}${addr:submode} $addr, $dst1",
 537                     []>;
 538
 539 let isCall = 1,
 540   Defs = [R0, R1, R2, R3, R12, LR,
 541           D0, D1, D2, D3, D4, D5, D6, D7, CPSR] in {
 542   def BL  : ABXI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 543                 "bl ${func:call}",
 544                 [(ARMcall tglobaladdr:$func)]>;
 545
 546   def BL_pred : ABI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 547                    "bl", " ${func:call}",
 548                    [(ARMcall_pred tglobaladdr:$func)]>;
 549
 550   // ARMv5T and above
 551   def BLX : AXI<(outs), (ins GPR:$func, variable_ops), BrMiscFrm,
 552                 "blx $func",
 553                 [(ARMcall GPR:$func)]>, Requires<[IsARM, HasV5T]> {
 554     let Inst{7-4}   = 0b0011;
 555     let Inst{19-8}  = 0b111111111111;
 556     let Inst{27-20} = 0b00010010;
 557   }
 558
 559   let Uses = [LR] in {
 560     // ARMv4T
 561     def BX : ABXIx2<(outs), (ins GPR:$func, variable_ops),
 562                      "mov lr, pc\n\tbx $func",
 563                     [(ARMcall_nolink GPR:$func)]>;
 564   }
 565 }
 566
 567 let isBranch = 1, isTerminator = 1 in {
 568   // B is "predicable" since it can be xformed into a Bcc.
 569   let isBarrier = 1 in {
 570     let isPredicable = 1 in
 571     def B : ABXI<0b1010, (outs), (ins brtarget:$target), "b $target",
 572                 [(br bb:$target)]>;
 573
 574   let isNotDuplicable = 1, isIndirectBranch = 1 in {
 575   def BR_JTr : JTI<(outs), (ins GPR:$target, jtblock_operand:$jt, i32imm:$id),
 576                     "mov pc, $target \n$jt",
 577                     [(ARMbrjt GPR:$target, tjumptable:$jt, imm:$id)]> {
 578     let Inst{20}    = 0; // S Bit
 579     let Inst{24-21} = 0b1101;
 580     let Inst{27-26} = {0,0};
 581   }
 582   def BR_JTm : JTI<(outs),
 583                    (ins addrmode2:$target, jtblock_operand:$jt, i32imm:$id),
 584                    "ldr pc, $target \n$jt",
 585                   [(ARMbrjt (i32 (load addrmode2:$target)), tjumptable:$jt,
 586                     imm:$id)]> {
 587     let Inst{20}    = 1; // L bit
 588     let Inst{21}    = 0; // W bit
 589     let Inst{22}    = 0; // B bit
 590     let Inst{24}    = 1; // P bit
 591     let Inst{27-26} = {0,1};
 592   }
 593   def BR_JTadd : JTI<(outs),
 594                    (ins GPR:$target, GPR:$idx, jtblock_operand:$jt, i32imm:$id),
 595                      "add pc, $target, $idx \n$jt",
 596                     [(ARMbrjt (add GPR:$target, GPR:$idx), tjumptable:$jt,
 597                       imm:$id)]> {
 598     let Inst{20}    = 0; // S bit
 599     let Inst{24-21} = 0b0100;
 600     let Inst{27-26} = {0,0};
 601   }
 602   } // isNotDuplicable = 1, isIndirectBranch = 1
 603   } // isBarrier = 1
 604
 605   // FIXME: should be able to write a pattern for ARMBrcond, but can't use
 606   // a two-value operand where a dag node expects two operands. :(
 607   def Bcc : ABI<0b1010, (outs), (ins brtarget:$target),
 608                "b", " $target",
 609                [/*(ARMbrcond bb:$target, imm:$cc, CCR:$ccr)*/]>;
 610 }
 611
 612 //===----------------------------------------------------------------------===//
 613 //  Load / store Instructions.
 614 //
 615
 616 // Load
 617 let canFoldAsLoad = 1 in
 618 def LDR  : AI2ldw<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm,
 619                "ldr", " $dst, $addr",
 620                [(set GPR:$dst, (load addrmode2:$addr))]>;
 621
 622 // Special LDR for loads from non-pc-relative constpools.
 623 let canFoldAsLoad = 1, mayLoad = 1, isReMaterializable = 1 in
 624 def LDRcp : AI2ldw<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm,
 625                  "ldr", " $dst, $addr", []>;
 626
 627 // Loads with zero extension
 628 def LDRH  : AI3ldh<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 629                  "ldr", "h $dst, $addr",
 630                 [(set GPR:$dst, (zextloadi16 addrmode3:$addr))]>;
 631
 632 def LDRB  : AI2ldb<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm,
 633                  "ldr", "b $dst, $addr",
 634                 [(set GPR:$dst, (zextloadi8 addrmode2:$addr))]>;
 635
 636 // Loads with sign extension
 637 def LDRSH : AI3ldsh<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 638                  "ldr", "sh $dst, $addr",
 639                 [(set GPR:$dst, (sextloadi16 addrmode3:$addr))]>;
 640
 641 def LDRSB : AI3ldsb<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 642                  "ldr", "sb $dst, $addr",
 643                 [(set GPR:$dst, (sextloadi8 addrmode3:$addr))]>;
 644
 645 let mayLoad = 1 in {
 646 // Load doubleword
 647 def LDRD  : AI3ldd<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 648                  "ldr", "d $dst, $addr",
 649                 []>, Requires<[IsARM, HasV5T]>;
 650
 651 // Indexed loads
 652 def LDR_PRE  : AI2ldwpr<(outs GPR:$dst, GPR:$base_wb),
 653                      (ins addrmode2:$addr), LdFrm,
 654                      "ldr", " $dst, $addr!", "$addr.base = $base_wb", []>;
 655
 656 def LDR_POST : AI2ldwpo<(outs GPR:$dst, GPR:$base_wb),
 657                      (ins GPR:$base, am2offset:$offset), LdFrm,
 658                      "ldr", " $dst, [$base], $offset", "$base = $base_wb", []>;
 659
 660 def LDRH_PRE  : AI3ldhpr<(outs GPR:$dst, GPR:$base_wb),
 661                      (ins addrmode3:$addr), LdMiscFrm,
 662                      "ldr", "h $dst, $addr!", "$addr.base = $base_wb", []>;
 663
 664 def LDRH_POST : AI3ldhpo<(outs GPR:$dst, GPR:$base_wb),
 665                      (ins GPR:$base,am3offset:$offset), LdMiscFrm,
 666                      "ldr", "h $dst, [$base], $offset", "$base = $base_wb", []>;
 667
 668 def LDRB_PRE  : AI2ldbpr<(outs GPR:$dst, GPR:$base_wb),
 669                      (ins addrmode2:$addr), LdFrm,
 670                      "ldr", "b $dst, $addr!", "$addr.base = $base_wb", []>;
 671
 672 def LDRB_POST : AI2ldbpo<(outs GPR:$dst, GPR:$base_wb),
 673                      (ins GPR:$base,am2offset:$offset), LdFrm,
 674                      "ldr", "b $dst, [$base], $offset", "$base = $base_wb", []>;
 675
 676 def LDRSH_PRE : AI3ldshpr<(outs GPR:$dst, GPR:$base_wb),
 677                       (ins addrmode3:$addr), LdMiscFrm,
 678                       "ldr", "sh $dst, $addr!", "$addr.base = $base_wb", []>;
 679
 680 def LDRSH_POST: AI3ldshpo<(outs GPR:$dst, GPR:$base_wb),
 681                       (ins GPR:$base,am3offset:$offset), LdMiscFrm,
 682                     "ldr", "sh $dst, [$base], $offset", "$base = $base_wb", []>;
 683
 684 def LDRSB_PRE : AI3ldsbpr<(outs GPR:$dst, GPR:$base_wb),
 685                       (ins addrmode3:$addr), LdMiscFrm,
 686                       "ldr", "sb $dst, $addr!", "$addr.base = $base_wb", []>;
 687
 688 def LDRSB_POST: AI3ldsbpo<(outs GPR:$dst, GPR:$base_wb),
 689                       (ins GPR:$base,am3offset:$offset), LdMiscFrm,
 690                       "ldr", "sb $dst, [$base], $offset", "$base = $base_wb", []>;
 691 }
 692
 693 // Store
 694 def STR  : AI2stw<(outs), (ins GPR:$src, addrmode2:$addr), StFrm,
 695                "str", " $src, $addr",
 696                [(store GPR:$src, addrmode2:$addr)]>;
 697
 698 // Stores with truncate
 699 def STRH : AI3sth<(outs), (ins GPR:$src, addrmode3:$addr), StMiscFrm,
 700                "str", "h $src, $addr",
 701                [(truncstorei16 GPR:$src, addrmode3:$addr)]>;
 702
 703 def STRB : AI2stb<(outs), (ins GPR:$src, addrmode2:$addr), StFrm,
 704                "str", "b $src, $addr",
 705                [(truncstorei8 GPR:$src, addrmode2:$addr)]>;
 706
 707 // Store doubleword
 708 let mayStore = 1 in
 709 def STRD : AI3std<(outs), (ins GPR:$src, addrmode3:$addr), StMiscFrm,
 710                "str", "d $src, $addr",
 711                []>, Requires<[IsARM, HasV5T]>;
 712
 713 // Indexed stores
 714 def STR_PRE  : AI2stwpr<(outs GPR:$base_wb),
 715                      (ins GPR:$src, GPR:$base, am2offset:$offset), StFrm,
 716                     "str", " $src, [$base, $offset]!", "$base = $base_wb",
 717                     [(set GPR:$base_wb,
 718                       (pre_store GPR:$src, GPR:$base, am2offset:$offset))]>;
 719
 720 def STR_POST : AI2stwpo<(outs GPR:$base_wb),
 721                      (ins GPR:$src, GPR:$base,am2offset:$offset), StFrm,
 722                     "str", " $src, [$base], $offset", "$base = $base_wb",
 723                     [(set GPR:$base_wb,
 724                       (post_store GPR:$src, GPR:$base, am2offset:$offset))]>;
 725
 726 def STRH_PRE : AI3sthpr<(outs GPR:$base_wb),
 727                      (ins GPR:$src, GPR:$base,am3offset:$offset), StMiscFrm,
 728                      "str", "h $src, [$base, $offset]!", "$base = $base_wb",
 729                     [(set GPR:$base_wb,
 730                       (pre_truncsti16 GPR:$src, GPR:$base,am3offset:$offset))]>;
 731
 732 def STRH_POST: AI3sthpo<(outs GPR:$base_wb),
 733                      (ins GPR:$src, GPR:$base,am3offset:$offset), StMiscFrm,
 734                      "str", "h $src, [$base], $offset", "$base = $base_wb",
 735                     [(set GPR:$base_wb, (post_truncsti16 GPR:$src,
 736                                          GPR:$base, am3offset:$offset))]>;
 737
 738 def STRB_PRE : AI2stbpr<(outs GPR:$base_wb),
 739                      (ins GPR:$src, GPR:$base,am2offset:$offset), StFrm,
 740                      "str", "b $src, [$base, $offset]!", "$base = $base_wb",
 741                     [(set GPR:$base_wb, (pre_truncsti8 GPR:$src,
 742                                          GPR:$base, am2offset:$offset))]>;
 743
 744 def STRB_POST: AI2stbpo<(outs GPR:$base_wb),
 745                      (ins GPR:$src, GPR:$base,am2offset:$offset), StFrm,
 746                      "str", "b $src, [$base], $offset", "$base = $base_wb",
 747                     [(set GPR:$base_wb, (post_truncsti8 GPR:$src,
 748                                          GPR:$base, am2offset:$offset))]>;
 749
 750 //===----------------------------------------------------------------------===//
 751 //  Load / store multiple Instructions.
 752 //
 753
 754 // FIXME: $dst1 should be a def.
 755 let mayLoad = 1 in
 756 def LDM : AXI4ld<(outs),
 757                (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
 758                LdStMulFrm, "ldm${p}${addr:submode} $addr, $dst1",
 759                []>;
 760
 761 let mayStore = 1 in
 762 def STM : AXI4st<(outs),
 763                (ins addrmode4:$addr, pred:$p, reglist:$src1, variable_ops),
 764                LdStMulFrm, "stm${p}${addr:submode} $addr, $src1",
 765                []>;
 766
 767 //===----------------------------------------------------------------------===//
 768 //  Move Instructions.
 769 //
 770
 771 def MOVr : AsI1<0b1101, (outs GPR:$dst), (ins GPR:$src), DPFrm,
 772                  "mov", " $dst, $src", []>, UnaryDP;
 773 def MOVs : AsI1<0b1101, (outs GPR:$dst), (ins so_reg:$src), DPSoRegFrm,
 774                  "mov", " $dst, $src", [(set GPR:$dst, so_reg:$src)]>, UnaryDP;
 775
 776 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 777 def MOVi : AsI1<0b1101, (outs GPR:$dst), (ins so_imm:$src), DPFrm,
 778                  "mov", " $dst, $src", [(set GPR:$dst, so_imm:$src)]>, UnaryDP;
 779
 780 def MOVrx : AsI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo,
 781                  "mov", " $dst, $src, rrx",
 782                  [(set GPR:$dst, (ARMrrx GPR:$src))]>, UnaryDP;
 783
 784 // These aren't really mov instructions, but we have to define them this way
 785 // due to flag operands.
 786
 787 let Defs = [CPSR] in {
 788 def MOVsrl_flag : AI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo,
 789                       "mov", "s $dst, $src, lsr #1",
 790                       [(set GPR:$dst, (ARMsrl_flag GPR:$src))]>, UnaryDP;
 791 def MOVsra_flag : AI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo,
 792                       "mov", "s $dst, $src, asr #1",
 793                       [(set GPR:$dst, (ARMsra_flag GPR:$src))]>, UnaryDP;
 794 }
 795
 796 //===----------------------------------------------------------------------===//
 797 //  Extend Instructions.
 798 //
 799
 800 // Sign extenders
 801
 802 defm SXTB  : AI_unary_rrot<0b01101010,
 803                            "sxtb", UnOpFrag<(sext_inreg node:$Src, i8)>>;
 804 defm SXTH  : AI_unary_rrot<0b01101011,
 805                            "sxth", UnOpFrag<(sext_inreg node:$Src, i16)>>;
 806
 807 defm SXTAB : AI_bin_rrot<0b01101010,
 808                "sxtab", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS, i8))>>;
 809 defm SXTAH : AI_bin_rrot<0b01101011,
 810                "sxtah", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS,i16))>>;
 811
 812 // TODO: SXT(A){B|H}16
 813
 814 // Zero extenders
 815
 816 let AddedComplexity = 16 in {
 817 defm UXTB   : AI_unary_rrot<0b01101110,
 818                             "uxtb"  , UnOpFrag<(and node:$Src, 0x000000FF)>>;
 819 defm UXTH   : AI_unary_rrot<0b01101111,
 820                             "uxth"  , UnOpFrag<(and node:$Src, 0x0000FFFF)>>;
 821 defm UXTB16 : AI_unary_rrot<0b01101100,
 822                             "uxtb16", UnOpFrag<(and node:$Src, 0x00FF00FF)>>;
 823
 824 def : ARMV6Pat<(and (shl GPR:$Src, 8), 0xFF00FF),
 825                (UXTB16r_rot GPR:$Src, 24)>;
 826 def : ARMV6Pat<(and (srl GPR:$Src, 8), 0xFF00FF),
 827                (UXTB16r_rot GPR:$Src, 8)>;
 828
 829 defm UXTAB : AI_bin_rrot<0b01101110, "uxtab",
 830                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0x00FF))>>;
 831 defm UXTAH : AI_bin_rrot<0b01101111, "uxtah",
 832                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0xFFFF))>>;
 833 }
 834
 835 // This isn't safe in general, the add is two 16-bit units, not a 32-bit add.
 836 //defm UXTAB16 : xxx<"uxtab16", 0xff00ff>;
 837
 838 // TODO: UXT(A){B|H}16
 839
 840 //===----------------------------------------------------------------------===//
 841 //  Arithmetic Instructions.
 842 //
 843
 844 defm ADD  : AsI1_bin_irs<0b0100, "add",
 845                          BinOpFrag<(add  node:$LHS, node:$RHS)>>;
 846 defm SUB  : AsI1_bin_irs<0b0010, "sub",
 847                          BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 848
 849 // ADD and SUB with 's' bit set.
 850 defm ADDS : ASI1_bin_s_irs<0b0100, "add",
 851                            BinOpFrag<(addc node:$LHS, node:$RHS)>>;
 852 defm SUBS : ASI1_bin_s_irs<0b0010, "sub",
 853                            BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 854
 855 // FIXME: Do not allow ADC / SBC to be predicated for now.
 856 defm ADC  : AsXI1_bin_c_irs<0b0101, "adc",
 857                             BinOpFrag<(adde node:$LHS, node:$RHS)>>;
 858 defm SBC  : AsXI1_bin_c_irs<0b0110, "sbc",
 859                             BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 860
 861 // These don't define reg/reg forms, because they are handled above.
 862 def RSBri : AsI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 863                   "rsb", " $dst, $a, $b",
 864                   [(set GPR:$dst, (sub so_imm:$b, GPR:$a))]>;
 865
 866 def RSBrs : AsI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 867                   "rsb", " $dst, $a, $b",
 868                   [(set GPR:$dst, (sub so_reg:$b, GPR:$a))]>;
 869
 870 // RSB with 's' bit set.
 871 let Defs = [CPSR] in {
 872 def RSBSri : AI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 873                  "rsb", "s $dst, $a, $b",
 874                  [(set GPR:$dst, (subc so_imm:$b, GPR:$a))]>;
 875 def RSBSrs : AI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 876                  "rsb", "s $dst, $a, $b",
 877                  [(set GPR:$dst, (subc so_reg:$b, GPR:$a))]>;
 878 }
 879
 880 // FIXME: Do not allow RSC to be predicated for now. But they can set CPSR.
 881 let Uses = [CPSR] in {
 882 def RSCri : AXI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_imm:$b, cc_out:$s),
 883                  DPFrm, "rsc${s} $dst, $a, $b",
 884                  [(set GPR:$dst, (sube so_imm:$b, GPR:$a))]>;
 885 def RSCrs : AXI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_reg:$b, cc_out:$s),
 886                  DPSoRegFrm, "rsc${s} $dst, $a, $b",
 887                  [(set GPR:$dst, (sube so_reg:$b, GPR:$a))]>;
 888 }
 889
 890 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
 891 def : ARMPat<(add    GPR:$src, so_imm_neg:$imm),
 892              (SUBri  GPR:$src, so_imm_neg:$imm)>;
 893
 894 //def : ARMPat<(addc   GPR:$src, so_imm_neg:$imm),
 895 //             (SUBSri GPR:$src, so_imm_neg:$imm)>;
 896 //def : ARMPat<(adde   GPR:$src, so_imm_neg:$imm),
 897 //             (SBCri  GPR:$src, so_imm_neg:$imm)>;
 898
 899 // Note: These are implemented in C++ code, because they have to generate
 900 // ADD/SUBrs instructions, which use a complex pattern that a xform function
 901 // cannot produce.
 902 // (mul X, 2^n+1) -> (add (X << n), X)
 903 // (mul X, 2^n-1) -> (rsb X, (X << n))
 904
 905
 906 //===----------------------------------------------------------------------===//
 907 //  Bitwise Instructions.
 908 //
 909
 910 defm AND   : AsI1_bin_irs<0b0000, "and",
 911                           BinOpFrag<(and node:$LHS, node:$RHS)>>;
 912 defm ORR   : AsI1_bin_irs<0b1100, "orr",
 913                           BinOpFrag<(or  node:$LHS, node:$RHS)>>;
 914 defm EOR   : AsI1_bin_irs<0b0001, "eor",
 915                           BinOpFrag<(xor node:$LHS, node:$RHS)>>;
 916 defm BIC   : AsI1_bin_irs<0b1110, "bic",
 917                           BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
 918
 919 def  MVNr  : AsI1<0b1111, (outs GPR:$dst), (ins GPR:$src), DPFrm,
 920                   "mvn", " $dst, $src",
 921                   [(set GPR:$dst, (not GPR:$src))]>, UnaryDP;
 922 def  MVNs  : AsI1<0b1111, (outs GPR:$dst), (ins so_reg:$src), DPSoRegFrm,
 923                   "mvn", " $dst, $src",
 924                   [(set GPR:$dst, (not so_reg:$src))]>, UnaryDP;
 925 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 926 def  MVNi  : AsI1<0b1111, (outs GPR:$dst), (ins so_imm:$imm), DPFrm,
 927                   "mvn", " $dst, $imm",
 928                   [(set GPR:$dst, so_imm_not:$imm)]>,UnaryDP;
 929
 930 def : ARMPat<(and   GPR:$src, so_imm_not:$imm),
 931              (BICri GPR:$src, so_imm_not:$imm)>;
 932
 933 //===----------------------------------------------------------------------===//
 934 //  Multiply Instructions.
 935 //
 936
 937 def MUL   : AsMul1I<0b0000000, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
 938                     "mul", " $dst, $a, $b",
 939                    [(set GPR:$dst, (mul GPR:$a, GPR:$b))]>;
 940
 941 def MLA   : AsMul1I<0b0000001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 942                     "mla", " $dst, $a, $b, $c",
 943                    [(set GPR:$dst, (add (mul GPR:$a, GPR:$b), GPR:$c))]>;
 944
 945 // Extra precision multiplies with low / high results
 946 def SMULL : AsMul1I<0b0000110, (outs GPR:$ldst, GPR:$hdst),
 947                                (ins GPR:$a, GPR:$b),
 948                     "smull", " $ldst, $hdst, $a, $b", []>;
 949
 950 def UMULL : AsMul1I<0b0000100, (outs GPR:$ldst, GPR:$hdst),
 951                                (ins GPR:$a, GPR:$b),
 952                     "umull", " $ldst, $hdst, $a, $b", []>;
 953
 954 // Multiply + accumulate
 955 def SMLAL : AsMul1I<0b0000111, (outs GPR:$ldst, GPR:$hdst),
 956                                (ins GPR:$a, GPR:$b),
 957                     "smlal", " $ldst, $hdst, $a, $b", []>;
 958
 959 def UMLAL : AsMul1I<0b0000101, (outs GPR:$ldst, GPR:$hdst),
 960                                (ins GPR:$a, GPR:$b),
 961                     "umlal", " $ldst, $hdst, $a, $b", []>;
 962
 963 def UMAAL : AMul1I <0b0000010, (outs GPR:$ldst, GPR:$hdst),
 964                                (ins GPR:$a, GPR:$b),
 965                     "umaal", " $ldst, $hdst, $a, $b", []>,
 966                     Requires<[IsARM, HasV6]>;
 967
 968 // Most significant word multiply
 969 def SMMUL : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
 970                "smmul", " $dst, $a, $b",
 971                [(set GPR:$dst, (mulhs GPR:$a, GPR:$b))]>,
 972             Requires<[IsARM, HasV6]> {
 973   let Inst{7-4}   = 0b0001;
 974   let Inst{15-12} = 0b1111;
 975 }
 976
 977 def SMMLA : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 978                "smmla", " $dst, $a, $b, $c",
 979                [(set GPR:$dst, (add (mulhs GPR:$a, GPR:$b), GPR:$c))]>,
 980             Requires<[IsARM, HasV6]> {
 981   let Inst{7-4}   = 0b0001;
 982 }
 983
 984
 985 def SMMLS : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 986                "smmls", " $dst, $a, $b, $c",
 987                [(set GPR:$dst, (sub GPR:$c, (mulhs GPR:$a, GPR:$b)))]>,
 988             Requires<[IsARM, HasV6]> {
 989   let Inst{7-4}   = 0b1101;
 990 }
 991
 992 multiclass AI_smul<string opc, PatFrag opnode> {
 993   def BB : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
 994               !strconcat(opc, "bb"), " $dst, $a, $b",
 995               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
 996                                       (sext_inreg GPR:$b, i16)))]>,
 997            Requires<[IsARM, HasV5TE]> {
 998              let Inst{5} = 0;
 999              let Inst{6} = 0;
1000            }
1001
1002   def BT : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1003               !strconcat(opc, "bt"), " $dst, $a, $b",
1004               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
1005                                       (sra GPR:$b, 16)))]>,
1006            Requires<[IsARM, HasV5TE]> {
1007              let Inst{5} = 0;
1008              let Inst{6} = 1;
1009            }
1010
1011   def TB : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1012               !strconcat(opc, "tb"), " $dst, $a, $b",
1013               [(set GPR:$dst, (opnode (sra GPR:$a, 16),
1014                                       (sext_inreg GPR:$b, i16)))]>,
1015            Requires<[IsARM, HasV5TE]> {
1016              let Inst{5} = 1;
1017              let Inst{6} = 0;
1018            }
1019
1020   def TT : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1021               !strconcat(opc, "tt"), " $dst, $a, $b",
1022               [(set GPR:$dst, (opnode (sra GPR:$a, 16),
1023                                       (sra GPR:$b, 16)))]>,
1024             Requires<[IsARM, HasV5TE]> {
1025              let Inst{5} = 1;
1026              let Inst{6} = 1;
1027            }
1028
1029   def WB : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1030               !strconcat(opc, "wb"), " $dst, $a, $b",
1031               [(set GPR:$dst, (sra (opnode GPR:$a,
1032                                     (sext_inreg GPR:$b, i16)), 16))]>,
1033            Requires<[IsARM, HasV5TE]> {
1034              let Inst{5} = 1;
1035              let Inst{6} = 0;
1036            }
1037
1038   def WT : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1039               !strconcat(opc, "wt"), " $dst, $a, $b",
1040               [(set GPR:$dst, (sra (opnode GPR:$a,
1041                                     (sra GPR:$b, 16)), 16))]>,
1042             Requires<[IsARM, HasV5TE]> {
1043              let Inst{5} = 1;
1044              let Inst{6} = 1;
1045            }
1046 }
1047
1048
1049 multiclass AI_smla<string opc, PatFrag opnode> {
1050   def BB : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1051               !strconcat(opc, "bb"), " $dst, $a, $b, $acc",
1052               [(set GPR:$dst, (add GPR:$acc,
1053                                (opnode (sext_inreg GPR:$a, i16),
1054                                        (sext_inreg GPR:$b, i16))))]>,
1055            Requires<[IsARM, HasV5TE]> {
1056              let Inst{5} = 0;
1057              let Inst{6} = 0;
1058            }
1059
1060   def BT : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1061               !strconcat(opc, "bt"), " $dst, $a, $b, $acc",
1062               [(set GPR:$dst, (add GPR:$acc, (opnode (sext_inreg GPR:$a, i16),
1063                                                      (sra GPR:$b, 16))))]>,
1064            Requires<[IsARM, HasV5TE]> {
1065              let Inst{5} = 0;
1066              let Inst{6} = 1;
1067            }
1068
1069   def TB : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1070               !strconcat(opc, "tb"), " $dst, $a, $b, $acc",
1071               [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, 16),
1072                                                  (sext_inreg GPR:$b, i16))))]>,
1073            Requires<[IsARM, HasV5TE]> {
1074              let Inst{5} = 1;
1075              let Inst{6} = 0;
1076            }
1077
1078   def TT : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1079               !strconcat(opc, "tt"), " $dst, $a, $b, $acc",
1080               [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, 16),
1081                                                      (sra GPR:$b, 16))))]>,
1082             Requires<[IsARM, HasV5TE]> {
1083              let Inst{5} = 1;
1084              let Inst{6} = 1;
1085            }
1086
1087   def WB : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1088               !strconcat(opc, "wb"), " $dst, $a, $b, $acc",
1089               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
1090                                             (sext_inreg GPR:$b, i16)), 16)))]>,
1091            Requires<[IsARM, HasV5TE]> {
1092              let Inst{5} = 0;
1093              let Inst{6} = 0;
1094            }
1095
1096   def WT : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1097               !strconcat(opc, "wt"), " $dst, $a, $b, $acc",
1098               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
1099                                                    (sra GPR:$b, 16)), 16)))]>,
1100             Requires<[IsARM, HasV5TE]> {
1101              let Inst{5} = 0;
1102              let Inst{6} = 1;
1103            }
1104 }
1105
1106 defm SMUL : AI_smul<"smul", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
1107 defm SMLA : AI_smla<"smla", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
1108
1109 // TODO: Halfword multiple accumulate long: SMLAL<x><y>
1110 // TODO: Dual halfword multiple: SMUAD, SMUSD, SMLAD, SMLSD, SMLALD, SMLSLD
1111
1112 //===----------------------------------------------------------------------===//
1113 //  Misc. Arithmetic Instructions.
1114 //
1115
1116 def CLZ  : AMiscA1I<0b000010110, (outs GPR:$dst), (ins GPR:$src),
1117               "clz", " $dst, $src",
1118               [(set GPR:$dst, (ctlz GPR:$src))]>, Requires<[IsARM, HasV5T]> {
1119   let Inst{7-4}   = 0b0001;
1120   let Inst{11-8}  = 0b1111;
1121   let Inst{19-16} = 0b1111;
1122 }
1123
1124 def REV  : AMiscA1I<0b01101011, (outs GPR:$dst), (ins GPR:$src),
1125               "rev", " $dst, $src",
1126               [(set GPR:$dst, (bswap GPR:$src))]>, Requires<[IsARM, HasV6]> {
1127   let Inst{7-4}   = 0b0011;
1128   let Inst{11-8}  = 0b1111;
1129   let Inst{19-16} = 0b1111;
1130 }
1131
1132 def REV16 : AMiscA1I<0b01101011, (outs GPR:$dst), (ins GPR:$src),
1133                "rev16", " $dst, $src",
1134                [(set GPR:$dst,
1135                    (or (and (srl GPR:$src, 8), 0xFF),
1136                        (or (and (shl GPR:$src, 8), 0xFF00),
1137                            (or (and (srl GPR:$src, 8), 0xFF0000),
1138                                (and (shl GPR:$src, 8), 0xFF000000)))))]>,
1139                Requires<[IsARM, HasV6]> {
1140   let Inst{7-4}   = 0b1011;
1141   let Inst{11-8}  = 0b1111;
1142   let Inst{19-16} = 0b1111;
1143 }
1144
1145 def REVSH : AMiscA1I<0b01101111, (outs GPR:$dst), (ins GPR:$src),
1146                "revsh", " $dst, $src",
1147                [(set GPR:$dst,
1148                   (sext_inreg
1149                     (or (srl (and GPR:$src, 0xFF00), 8),
1150                         (shl GPR:$src, 8)), i16))]>,
1151                Requires<[IsARM, HasV6]> {
1152   let Inst{7-4}   = 0b1011;
1153   let Inst{11-8}  = 0b1111;
1154   let Inst{19-16} = 0b1111;
1155 }
1156
1157 def PKHBT : AMiscA1I<0b01101000, (outs GPR:$dst),
1158                                  (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
1159                "pkhbt", " $dst, $src1, $src2, LSL $shamt",
1160                [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF),
1161                                    (and (shl GPR:$src2, (i32 imm:$shamt)),
1162                                         0xFFFF0000)))]>,
1163                Requires<[IsARM, HasV6]> {
1164   let Inst{6-4} = 0b001;
1165 }
1166
1167 // Alternate cases for PKHBT where identities eliminate some nodes.
1168 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF), (and GPR:$src2, 0xFFFF0000)),
1169                (PKHBT GPR:$src1, GPR:$src2, 0)>;
1170 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF), (shl GPR:$src2, imm16_31:$shamt)),
1171                (PKHBT GPR:$src1, GPR:$src2, imm16_31:$shamt)>;
1172
1173
1174 def PKHTB : AMiscA1I<0b01101000, (outs GPR:$dst),
1175                                  (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
1176                "pkhtb", " $dst, $src1, $src2, ASR $shamt",
1177                [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF0000),
1178                                    (and (sra GPR:$src2, imm16_31:$shamt),
1179                                         0xFFFF)))]>, Requires<[IsARM, HasV6]> {
1180   let Inst{6-4} = 0b101;
1181 }
1182
1183 // Alternate cases for PKHTB where identities eliminate some nodes.  Note that
1184 // a shift amount of 0 is *not legal* here, it is PKHBT instead.
1185 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF0000), (srl GPR:$src2, 16)),
1186                (PKHTB GPR:$src1, GPR:$src2, 16)>;
1187 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF0000),
1188                    (and (srl GPR:$src2, imm1_15:$shamt), 0xFFFF)),
1189                (PKHTB GPR:$src1, GPR:$src2, imm1_15:$shamt)>;
1190
1191 //===----------------------------------------------------------------------===//
1192 //  Comparison Instructions...
1193 //
1194
1195 defm CMP  : AI1_cmp_irs<0b1010, "cmp",
1196                         BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
1197 defm CMN  : AI1_cmp_irs<0b1011, "cmn",
1198                         BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
1199
1200 // Note that TST/TEQ don't set all the same flags that CMP does!
1201 defm TST  : AI1_cmp_irs<0b1000, "tst",
1202                         BinOpFrag<(ARMcmpNZ (and node:$LHS, node:$RHS), 0)>>;
1203 defm TEQ  : AI1_cmp_irs<0b1001, "teq",
1204                         BinOpFrag<(ARMcmpNZ (xor node:$LHS, node:$RHS), 0)>>;
1205
1206 defm CMPnz : AI1_cmp_irs<0b1010, "cmp",
1207                          BinOpFrag<(ARMcmpNZ node:$LHS, node:$RHS)>>;
1208 defm CMNnz : AI1_cmp_irs<0b1011, "cmn",
1209                          BinOpFrag<(ARMcmpNZ node:$LHS,(ineg node:$RHS))>>;
1210
1211 def : ARMPat<(ARMcmp GPR:$src, so_imm_neg:$imm),
1212              (CMNri  GPR:$src, so_imm_neg:$imm)>;
1213
1214 def : ARMPat<(ARMcmpNZ GPR:$src, so_imm_neg:$imm),
1215              (CMNri  GPR:$src, so_imm_neg:$imm)>;
1216
1217
1218 // Conditional moves
1219 // FIXME: should be able to write a pattern for ARMcmov, but can't use
1220 // a two-value operand where a dag node expects two operands. :(
1221 def MOVCCr : AI1<0b1101, (outs GPR:$dst), (ins GPR:$false, GPR:$true), DPFrm,
1222                 "mov", " $dst, $true",
1223       [/*(set GPR:$dst, (ARMcmov GPR:$false, GPR:$true, imm:$cc, CCR:$ccr))*/]>,
1224                 RegConstraint<"$false = $dst">, UnaryDP;
1225
1226 def MOVCCs : AI1<0b1101, (outs GPR:$dst),
1227                         (ins GPR:$false, so_reg:$true), DPSoRegFrm,
1228                 "mov", " $dst, $true",
1229    [/*(set GPR:$dst, (ARMcmov GPR:$false, so_reg:$true, imm:$cc, CCR:$ccr))*/]>,
1230                 RegConstraint<"$false = $dst">, UnaryDP;
1231
1232 def MOVCCi : AI1<0b1101, (outs GPR:$dst),
1233                         (ins GPR:$false, so_imm:$true), DPFrm,
1234                 "mov", " $dst, $true",
1235    [/*(set GPR:$dst, (ARMcmov GPR:$false, so_imm:$true, imm:$cc, CCR:$ccr))*/]>,
1236                 RegConstraint<"$false = $dst">, UnaryDP;
1237
1238
1239 // LEApcrel - Load a pc-relative address into a register without offending the
1240 // assembler.
1241 def LEApcrel : AXI1<0x0, (outs GPR:$dst), (ins i32imm:$label, pred:$p), Pseudo,
1242                    !strconcat(!strconcat(".set PCRELV${:uid}, ($label-(",
1243                                          "${:private}PCRELL${:uid}+8))\n"),
1244                               !strconcat("${:private}PCRELL${:uid}:\n\t",
1245                                          "add$p $dst, pc, #PCRELV${:uid}")),
1246                    []>;
1247
1248 def LEApcrelJT : AXI1<0x0, (outs GPR:$dst), (ins i32imm:$label, i32imm:$id, pred:$p),
1249           Pseudo,
1250           !strconcat(!strconcat(".set PCRELV${:uid}, (${label}_${id:no_hash}-(",
1251                                          "${:private}PCRELL${:uid}+8))\n"),
1252                               !strconcat("${:private}PCRELL${:uid}:\n\t",
1253                                          "add$p $dst, pc, #PCRELV${:uid}")),
1254                    []>;
1255
1256 //===----------------------------------------------------------------------===//
1257 // TLS Instructions
1258 //
1259
1260 // __aeabi_read_tp preserves the registers r1-r3.
1261 let isCall = 1,
1262   Defs = [R0, R12, LR, CPSR] in {
1263   def TPsoft : ABXI<0b1011, (outs), (ins),
1264                "bl __aeabi_read_tp",
1265                [(set R0, ARMthread_pointer)]>;
1266 }
1267
1268 //===----------------------------------------------------------------------===//
1269 // Non-Instruction Patterns
1270 //
1271
1272 // ConstantPool, GlobalAddress, and JumpTable
1273 def : ARMPat<(ARMWrapper  tglobaladdr :$dst), (LEApcrel tglobaladdr :$dst)>;
1274 def : ARMPat<(ARMWrapper  tconstpool  :$dst), (LEApcrel tconstpool  :$dst)>;
1275 def : ARMPat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1276              (LEApcrelJT tjumptable:$dst, imm:$id)>;
1277
1278 // Large immediate handling.
1279
1280 // Two piece so_imms.
1281 let isReMaterializable = 1 in
1282 def MOVi2pieces : AI1x2<(outs GPR:$dst), (ins so_imm2part:$src), Pseudo,
1283                          "mov", " $dst, $src",
1284                          [(set GPR:$dst, so_imm2part:$src)]>;
1285
1286 def : ARMPat<(or GPR:$LHS, so_imm2part:$RHS),
1287               (ORRri (ORRri GPR:$LHS, (so_imm2part_1 imm:$RHS)),
1288                      (so_imm2part_2 imm:$RHS))>;
1289 def : ARMPat<(xor GPR:$LHS, so_imm2part:$RHS),
1290               (EORri (EORri GPR:$LHS, (so_imm2part_1 imm:$RHS)),
1291                      (so_imm2part_2 imm:$RHS))>;
1292
1293 // TODO: add,sub,and, 3-instr forms?
1294
1295
1296 // Direct calls
1297 def : ARMPat<(ARMcall texternalsym:$func), (BL texternalsym:$func)>;
1298
1299 // zextload i1 -> zextload i8
1300 def : ARMPat<(zextloadi1 addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1301
1302 // extload -> zextload
1303 def : ARMPat<(extloadi1  addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1304 def : ARMPat<(extloadi8  addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1305 def : ARMPat<(extloadi16 addrmode3:$addr),  (LDRH addrmode3:$addr)>;
1306
1307 def : ARMPat<(extloadi8  addrmodepc:$addr), (PICLDRB addrmodepc:$addr)>;
1308 def : ARMPat<(extloadi16 addrmodepc:$addr), (PICLDRH addrmodepc:$addr)>;
1309
1310 // smul* and smla*
1311 def : ARMV5TEPat<(mul (sra (shl GPR:$a, 16), 16), (sra (shl GPR:$b, 16), 16)),
1312                  (SMULBB GPR:$a, GPR:$b)>;
1313 def : ARMV5TEPat<(mul sext_16_node:$a, sext_16_node:$b),
1314                  (SMULBB GPR:$a, GPR:$b)>;
1315 def : ARMV5TEPat<(mul (sra (shl GPR:$a, 16), 16), (sra GPR:$b, 16)),
1316                  (SMULBT GPR:$a, GPR:$b)>;
1317 def : ARMV5TEPat<(mul sext_16_node:$a, (sra GPR:$b, 16)),
1318                  (SMULBT GPR:$a, GPR:$b)>;
1319 def : ARMV5TEPat<(mul (sra GPR:$a, 16), (sra (shl GPR:$b, 16), 16)),
1320                  (SMULTB GPR:$a, GPR:$b)>;
1321 def : ARMV5TEPat<(mul (sra GPR:$a, 16), sext_16_node:$b),
1322                 (SMULTB GPR:$a, GPR:$b)>;
1323 def : ARMV5TEPat<(sra (mul GPR:$a, (sra (shl GPR:$b, 16), 16)), 16),
1324                  (SMULWB GPR:$a, GPR:$b)>;
1325 def : ARMV5TEPat<(sra (mul GPR:$a, sext_16_node:$b), 16),
1326                  (SMULWB GPR:$a, GPR:$b)>;
1327
1328 def : ARMV5TEPat<(add GPR:$acc,
1329                       (mul (sra (shl GPR:$a, 16), 16),
1330                            (sra (shl GPR:$b, 16), 16))),
1331                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
1332 def : ARMV5TEPat<(add GPR:$acc,
1333                       (mul sext_16_node:$a, sext_16_node:$b)),
1334                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
1335 def : ARMV5TEPat<(add GPR:$acc,
1336                       (mul (sra (shl GPR:$a, 16), 16), (sra GPR:$b, 16))),
1337                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
1338 def : ARMV5TEPat<(add GPR:$acc,
1339                       (mul sext_16_node:$a, (sra GPR:$b, 16))),
1340                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
1341 def : ARMV5TEPat<(add GPR:$acc,
1342                       (mul (sra GPR:$a, 16), (sra (shl GPR:$b, 16), 16))),
1343                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
1344 def : ARMV5TEPat<(add GPR:$acc,
1345                       (mul (sra GPR:$a, 16), sext_16_node:$b)),
1346                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
1347 def : ARMV5TEPat<(add GPR:$acc,
1348                       (sra (mul GPR:$a, (sra (shl GPR:$b, 16), 16)), 16)),
1349                  (SMLAWB GPR:$a, GPR:$b, GPR:$acc)>;
1350 def : ARMV5TEPat<(add GPR:$acc,
1351                       (sra (mul GPR:$a, sext_16_node:$b), 16)),
1352                  (SMLAWB GPR:$a, GPR:$b, GPR:$acc)>;
1353
1354 //===----------------------------------------------------------------------===//
1355 // Thumb Support
1356 //
1357
1358 include "ARMInstrThumb.td"
1359
1360 //===----------------------------------------------------------------------===//
1361 // Floating Point Support
1362 //
1363
1364 include "ARMInstrVFP.td"