lib/Target/PIC16/PIC16InstrInfo.td

   1 //===- PIC16InstrInfo.td - PIC16 Instruction defs -------------*- tblgen-*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the PIC16 instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // PIC16 Specific Type Constraints.
  16 //===----------------------------------------------------------------------===//
  17 class SDTCisI8<int OpNum> : SDTCisVT<OpNum, i8>;
  18 class SDTCisI16<int OpNum> : SDTCisVT<OpNum, i16>;
  19
  20 //===----------------------------------------------------------------------===//
  21 // PIC16 Specific Type Profiles.
  22 //===----------------------------------------------------------------------===//
  23
  24 // Generic type profiles for i8/i16 unary/binary operations.
  25 // Taking one i8 or i16 and producing void.
  26 def SDTI8VoidOp : SDTypeProfile<0, 1, [SDTCisI8<0>]>;
  27 def SDTI16VoidOp : SDTypeProfile<0, 1, [SDTCisI16<0>]>;
  28
  29 // Taking one value and producing an output of same type.
  30 def SDTI8UnaryOp : SDTypeProfile<1, 1, [SDTCisI8<0>, SDTCisI8<1>]>;
  31 def SDTI16UnaryOp : SDTypeProfile<1, 1, [SDTCisI16<0>, SDTCisI16<1>]>;
  32
  33 // Taking two values and producing an output of same type.
  34 def SDTI8BinOp : SDTypeProfile<1, 2, [SDTCisI8<0>, SDTCisI8<1>, SDTCisI8<2>]>;
  35 def SDTI16BinOp : SDTypeProfile<1, 2, [SDTCisI16<0>, SDTCisI16<1>,
  36                                        SDTCisI16<2>]>;
  37
  38 // Node specific type profiles.
  39 def SDT_PIC16Load : SDTypeProfile<1, 3, [SDTCisI8<0>, SDTCisI8<1>,
  40                                           SDTCisI8<2>, SDTCisI8<3>]>;
  41
  42 def SDT_PIC16Store : SDTypeProfile<0, 4, [SDTCisI8<0>, SDTCisI8<1>,
  43                                           SDTCisI8<2>, SDTCisI8<3>]>;
  44
  45 def SDT_PIC16Connect : SDTypeProfile<1, 2, [SDTCisI8<0>, SDTCisI8<1>,
  46                                             SDTCisI8<2>]>;
  47
  48 // PIC16ISD::CALL type prorile
  49 def SDT_PIC16call : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
  50 def SDT_PIC16callw : SDTypeProfile<1, -1, [SDTCisInt<0>]>;
  51
  52 // PIC16ISD::BRCOND
  53 def SDT_PIC16Brcond: SDTypeProfile<0, 2,
  54                                    [SDTCisVT<0, OtherVT>, SDTCisI8<1>]>;
  55
  56 // PIC16ISD::BRCOND
  57 def SDT_PIC16Selecticc: SDTypeProfile<1, 3,
  58                                    [SDTCisI8<0>, SDTCisI8<1>, SDTCisI8<2>,
  59                                     SDTCisI8<3>]>;
  60
  61 //===----------------------------------------------------------------------===//
  62 // PIC16 addressing modes matching via DAG.
  63 //===----------------------------------------------------------------------===//
  64 def diraddr : ComplexPattern<i8, 1, "SelectDirectAddr", [], []>;
  65
  66 //===----------------------------------------------------------------------===//
  67 // PIC16 Specific Node Definitions.
  68 //===----------------------------------------------------------------------===//
  69 def PIC16callseq_start : SDNode<"ISD::CALLSEQ_START", SDTI8VoidOp,
  70                                 [SDNPHasChain, SDNPOutFlag]>;
  71 def PIC16callseq_end   : SDNode<"ISD::CALLSEQ_END", SDTI8VoidOp,
  72                                 [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  73
  74 // Low 8-bits of GlobalAddress.
  75 def PIC16Lo : SDNode<"PIC16ISD::Lo", SDTI8BinOp>;
  76
  77 // High 8-bits of GlobalAddress.
  78 def PIC16Hi : SDNode<"PIC16ISD::Hi", SDTI8BinOp>;
  79
  80 // The MTHI and MTLO nodes are used only to match them in the incoming
  81 // DAG for replacement by corresponding set_fsrhi, set_fsrlo insntructions.
  82 // These nodes are not used for defining any instructions.
  83 def MTLO     : SDNode<"PIC16ISD::MTLO", SDTI8UnaryOp>;
  84 def MTHI     : SDNode<"PIC16ISD::MTHI", SDTI8UnaryOp>;
  85 def MTPCLATH : SDNode<"PIC16ISD::MTPCLATH", SDTI8UnaryOp>;
  86
  87 // Node to generate Bank Select for a GlobalAddress.
  88 def Banksel : SDNode<"PIC16ISD::Banksel", SDTI8UnaryOp>;
  89
  90 // Node to match a direct store operation.
  91 def PIC16Store : SDNode<"PIC16ISD::PIC16Store", SDT_PIC16Store, [SDNPHasChain]>;
  92 def PIC16StWF : SDNode<"PIC16ISD::PIC16StWF", SDT_PIC16Store,
  93                        [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  94
  95 // Node to match a direct load operation.
  96 def PIC16Load  : SDNode<"PIC16ISD::PIC16Load", SDT_PIC16Load, [SDNPHasChain]>;
  97 def PIC16LdArg  : SDNode<"PIC16ISD::PIC16LdArg", SDT_PIC16Load, [SDNPHasChain]>;
  98 def PIC16LdWF  : SDNode<"PIC16ISD::PIC16LdWF", SDT_PIC16Load,
  99                        [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
 100 def PIC16Connect: SDNode<"PIC16ISD::PIC16Connect", SDT_PIC16Connect, []>;
 101
 102 // Node to match PIC16 call
 103 def PIC16call : SDNode<"PIC16ISD::CALL", SDT_PIC16call,
 104                               [SDNPHasChain , SDNPOptInFlag, SDNPOutFlag]>;
 105 def PIC16callw : SDNode<"PIC16ISD::CALLW", SDT_PIC16callw,
 106                               [SDNPHasChain , SDNPOptInFlag, SDNPOutFlag]>;
 107
 108 // Node to match a comparison instruction.
 109 def PIC16Subcc : SDNode<"PIC16ISD::SUBCC", SDTI8BinOp, [SDNPOutFlag]>;
 110
 111 // Node to match a conditional branch.
 112 def PIC16Brcond : SDNode<"PIC16ISD::BRCOND", SDT_PIC16Brcond,
 113                          [SDNPHasChain, SDNPInFlag]>;
 114
 115 def PIC16Selecticc : SDNode<"PIC16ISD::SELECT_ICC", SDT_PIC16Selecticc,
 116                          [SDNPInFlag]>;
 117
 118 //===----------------------------------------------------------------------===//
 119 // PIC16 Operand Definitions.
 120 //===----------------------------------------------------------------------===//
 121 def i8mem : Operand<i8>;
 122 def brtarget: Operand<OtherVT>;
 123
 124 // Operand for printing out a condition code.
 125 let PrintMethod = "printCCOperand" in
 126   def CCOp : Operand<i8>;
 127
 128 include "PIC16InstrFormats.td"
 129
 130 //===----------------------------------------------------------------------===//
 131 // PIC16 Common Classes.
 132 //===----------------------------------------------------------------------===//
 133
 134 // W = W Op F : Load the value from F and do Op to W.
 135 let isTwoAddress = 1 in
 136 class BinOpFW<bits<6> OpCode, string OpcStr, SDNode OpNode>:
 137   ByteFormat<OpCode, (outs GPR:$dst),
 138              (ins GPR:$src, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 139               !strconcat(OpcStr, " $ptrlo + $offset, W"),
 140              [(set GPR:$dst, (OpNode GPR:$src, (PIC16Load diraddr:$ptrlo,
 141                                              (i8 imm:$ptrhi),
 142                                              (i8 imm:$offset))))]>;
 143
 144 // F = F Op W : Load the value from F, do op with W and store in F.
 145 // This insn class is not marked as TwoAddress because the reg is
 146 // being used as a source operand only. (Remember a TwoAddress insn
 147 // needs a copyRegToReg.)
 148 class BinOpWF<bits<6> OpCode, string OpcStr, SDNode OpNode>:
 149   ByteFormat<OpCode, (outs),
 150              (ins GPR:$src, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 151               !strconcat(OpcStr, " $ptrlo + $offset"),
 152              [(PIC16Store (OpNode GPR:$src, (PIC16Load diraddr:$ptrlo,
 153                                              (i8 imm:$ptrhi),
 154                                              (i8 imm:$offset))),
 155                                              diraddr:$ptrlo,
 156                                              (i8 imm:$ptrhi), (i8 imm:$offset)
 157                                              )]>;
 158
 159 // W = W Op L : Do Op of L with W and place result in W.
 160 let isTwoAddress = 1 in
 161 class BinOpLW<bits<6> opcode, string OpcStr, SDNode OpNode> :
 162   LiteralFormat<opcode, (outs GPR:$dst),
 163                 (ins GPR:$src, i8imm:$literal),
 164                 !strconcat(OpcStr, " $literal"),
 165                 [(set GPR:$dst, (OpNode GPR:$src, (i8 imm:$literal)))]>;
 166
 167 //===----------------------------------------------------------------------===//
 168 // PIC16 Instructions.
 169 //===----------------------------------------------------------------------===//
 170
 171 // Pseudo-instructions.
 172 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins i8imm:$amt),
 173                        "!ADJCALLSTACKDOWN $amt",
 174                        [(PIC16callseq_start imm:$amt)]>;
 175
 176 def ADJCALLSTACKUP : Pseudo<(outs), (ins i8imm:$amt),
 177                        "!ADJCALLSTACKUP $amt",
 178                        [(PIC16callseq_end imm:$amt)]>;
 179
 180 //-----------------------------------
 181 // Vaious movlw insn patterns.
 182 //-----------------------------------
 183 let isReMaterializable = 1 in {
 184 // Move 8-bit literal to W.
 185 def movlw : BitFormat<12, (outs GPR:$dst), (ins i8imm:$src),
 186                       "movlw $src",
 187                       [(set GPR:$dst, (i8 imm:$src))]>;
 188
 189 // Move a Lo(TGA) to W.
 190 def movlw_lo_1 : BitFormat<12, (outs GPR:$dst), (ins i8imm:$src, i8imm:$src2),
 191                       "movlw LOW(${src}) + ${src2}",
 192                       [(set GPR:$dst, (PIC16Lo tglobaladdr:$src, imm:$src2 ))]>;
 193
 194 // Move a Lo(TES) to W.
 195 def movlw_lo_2 : BitFormat<12, (outs GPR:$dst), (ins i8imm:$src, i8imm:$src2),
 196                       "movlw LOW(${src}) + ${src2}",
 197                       [(set GPR:$dst, (PIC16Lo texternalsym:$src, imm:$src2 ))]>;
 198
 199 // Move a Hi(TGA) to W.
 200 def movlw_hi_1 : BitFormat<12, (outs GPR:$dst), (ins i8imm:$src, i8imm:$src2),
 201                       "movlw HIGH(${src}) + ${src2}",
 202                       [(set GPR:$dst, (PIC16Hi tglobaladdr:$src, imm:$src2))]>;
 203
 204 // Move a Hi(TES) to W.
 205 def movlw_hi_2 : BitFormat<12, (outs GPR:$dst), (ins i8imm:$src, i8imm:$src2),
 206                       "movlw HIGH(${src}) + ${src2}",
 207                       [(set GPR:$dst, (PIC16Hi texternalsym:$src, imm:$src2))]>;
 208 }
 209
 210 //-------------------
 211 // FSR setting insns.
 212 //-------------------
 213 // These insns are matched via a DAG replacement pattern.
 214 def set_fsrlo:
 215   ByteFormat<0, (outs FSR16:$fsr),
 216              (ins GPR:$val),
 217              "movwf ${fsr}L",
 218              []>;
 219
 220 let isTwoAddress = 1 in
 221 def set_fsrhi:
 222   ByteFormat<0, (outs FSR16:$dst),
 223              (ins FSR16:$src, GPR:$val),
 224              "movwf ${dst}H",
 225              []>;
 226
 227 def set_pclath:
 228   ByteFormat<0, (outs PCLATHR:$dst),
 229              (ins GPR:$val),
 230              "movwf ${dst}",
 231              [(set PCLATHR:$dst , (MTPCLATH GPR:$val))]>;
 232
 233 //----------------------------
 234 // copyRegToReg
 235 // copyRegToReg insns. These are dummy. They should always be deleted
 236 // by the optimizer and never be present in the final generated code.
 237 // if they are, then we have to write correct macros for these insns.
 238 //----------------------------
 239 def copy_fsr:
 240   Pseudo<(outs FSR16:$dst), (ins FSR16:$src), "copy_fsr $dst, $src", []>;
 241
 242 def copy_w:
 243   Pseudo<(outs GPR:$dst), (ins GPR:$src), "copy_w $dst, $src", []>;
 244
 245 class SAVE_FSR<string OpcStr>:
 246   Pseudo<(outs),
 247          (ins FSR16:$src, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 248          !strconcat(OpcStr, " $ptrlo, $offset"),
 249          []>;
 250
 251 def save_fsr0: SAVE_FSR<"save_fsr0">;
 252 def save_fsr1: SAVE_FSR<"save_fsr1">;
 253
 254 class RESTORE_FSR<string OpcStr>:
 255   Pseudo<(outs FSR16:$dst),
 256          (ins i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 257          !strconcat(OpcStr, " $ptrlo, $offset"),
 258          []>;
 259
 260 def restore_fsr0: RESTORE_FSR<"restore_fsr0">;
 261 def restore_fsr1: RESTORE_FSR<"restore_fsr1">;
 262
 263 //--------------------------
 264 // Store to memory
 265 //-------------------------
 266
 267 // Direct store.
 268 // Input operands are: val = W, ptrlo = GA, offset = offset, ptrhi = banksel.
 269 class MOVWF_INSN<bits<6> OpCode, SDNode OpNodeDest, SDNode Op>:
 270   ByteFormat<0, (outs),
 271              (ins GPR:$val, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 272              "movwf ${ptrlo} + ${offset}",
 273              [(Op GPR:$val, OpNodeDest:$ptrlo, (i8 imm:$ptrhi),
 274                (i8 imm:$offset))]>;
 275
 276 // Store W to a Global Address.
 277 def movwf : MOVWF_INSN<0, tglobaladdr, PIC16Store>;
 278
 279 // Store W to an External Symobol.
 280 def movwf_1 : MOVWF_INSN<0, texternalsym, PIC16Store>;
 281
 282 // Store with InFlag and OutFlag
 283 // This is same as movwf_1 but has a flag. A flag is required to
 284 // order the stores while passing the params to function.
 285 def movwf_2 : MOVWF_INSN<0, texternalsym, PIC16StWF>;
 286
 287 // Indirect store. Matched via a DAG replacement pattern.
 288 def store_indirect :
 289   ByteFormat<0, (outs),
 290              (ins GPR:$val, FSR16:$fsr, i8imm:$offset),
 291              "movwi $offset[$fsr]",
 292              []>;
 293
 294 //----------------------------
 295 // Load from memory
 296 //----------------------------
 297 // Direct load.
 298 // Input Operands are: ptrlo = GA, offset = offset, ptrhi = banksel.
 299 // Output: dst = W
 300 class MOVF_INSN<bits<6> OpCode, SDNode OpNodeSrc, SDNode Op>:
 301   ByteFormat<0, (outs GPR:$dst),
 302              (ins i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 303              "movf ${ptrlo} + ${offset}, W",
 304              [(set GPR:$dst,
 305                (Op OpNodeSrc:$ptrlo, (i8 imm:$ptrhi),
 306                (i8 imm:$offset)))]>;
 307
 308 // Load from a GA.
 309 def movf : MOVF_INSN<0, tglobaladdr, PIC16Load>;
 310
 311 // Load from an ES.
 312 def movf_1 : MOVF_INSN<0, texternalsym, PIC16Load>;
 313 def movf_1_1 : MOVF_INSN<0, texternalsym, PIC16LdArg>;
 314
 315 // Load with InFlag and OutFlag
 316 // This is same as movf_1 but has a flag. A flag is required to
 317 // order the loads while copying the return value of a function.
 318 def movf_2 : MOVF_INSN<0, texternalsym, PIC16LdWF>;
 319
 320 // Indirect load. Matched via a DAG replacement pattern.
 321 def load_indirect :
 322   ByteFormat<0, (outs GPR:$dst),
 323              (ins FSR16:$fsr, i8imm:$offset),
 324              "moviw $offset[$fsr]",
 325              []>;
 326
 327 //-------------------------
 328 // Bitwise operations patterns
 329 //--------------------------
 330 // W = W op [F]
 331 let Defs = [STATUS] in {
 332 def OrFW :  BinOpFW<0, "iorwf", or>;
 333 def XOrFW : BinOpFW<0, "xorwf", xor>;
 334 def AndFW : BinOpFW<0, "andwf", and>;
 335
 336 // F = W op [F]
 337 def OrWF :  BinOpWF<0, "iorwf", or>;
 338 def XOrWF : BinOpWF<0, "xorwf", xor>;
 339 def AndWF : BinOpWF<0, "andwf", and>;
 340
 341 //-------------------------
 342 // Various add/sub patterns.
 343 //-------------------------
 344
 345 // W = W + [F]
 346 def addfw_1: BinOpFW<0, "addwf", add>;
 347 def addfw_2: BinOpFW<0, "addwf", addc>;
 348
 349 let Uses = [STATUS] in
 350 def addfwc: BinOpFW<0, "addwfc", adde>;  // With Carry.
 351
 352 // F = W + [F]
 353 def addwf_1: BinOpWF<0, "addwf", add>;
 354 def addwf_2: BinOpWF<0, "addwf", addc>;
 355 let Uses = [STATUS] in
 356 def addwfc: BinOpWF<0, "addwfc", adde>;  // With Carry.
 357 }
 358
 359 // W -= [F] ; load from F and sub the value from W.
 360 let isTwoAddress = 1 in
 361 class SUBFW<bits<6> OpCode, string OpcStr, SDNode OpNode>:
 362   ByteFormat<OpCode, (outs GPR:$dst),
 363              (ins GPR:$src, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 364               !strconcat(OpcStr, " $ptrlo + $offset, W"),
 365              [(set GPR:$dst, (OpNode (PIC16Load diraddr:$ptrlo,
 366                                       (i8 imm:$ptrhi), (i8 imm:$offset)),
 367                                       GPR:$src))]>;
 368 let Defs = [STATUS] in {
 369 def subfw_1: SUBFW<0, "subwf", sub>;
 370 def subfw_2: SUBFW<0, "subwf", subc>;
 371
 372 let Uses = [STATUS] in
 373 def subfwb: SUBFW<0, "subwfb", sube>;  // With Borrow.
 374
 375 def subfw_cc: SUBFW<0, "subwf", PIC16Subcc>;
 376 }
 377
 378 // [F] -= W ;
 379 class SUBWF<bits<6> OpCode, string OpcStr, SDNode OpNode>:
 380   ByteFormat<OpCode, (outs),
 381              (ins GPR:$src, i8imm:$offset, i8mem:$ptrlo, i8imm:$ptrhi),
 382               !strconcat(OpcStr, " $ptrlo + $offset"),
 383              [(PIC16Store (OpNode (PIC16Load diraddr:$ptrlo,
 384                                       (i8 imm:$ptrhi), (i8 imm:$offset)),
 385                                       GPR:$src), diraddr:$ptrlo,
 386                                       (i8 imm:$ptrhi), (i8 imm:$offset))]>;
 387
 388 let Defs = [STATUS] in {
 389 def subwf_1: SUBWF<0, "subwf", sub>;
 390 def subwf_2: SUBWF<0, "subwf", subc>;
 391
 392 let Uses = [STATUS] in
 393   def subwfb: SUBWF<0, "subwfb", sube>;  // With Borrow.
 394
 395 def subwf_cc: SUBWF<0, "subwf", PIC16Subcc>;
 396 }
 397
 398 // addlw
 399 let Defs = [STATUS] in {
 400 def addlw_1 : BinOpLW<0, "addlw", add>;
 401 def addlw_2 : BinOpLW<0, "addlw", addc>;
 402
 403 let Uses = [STATUS] in
 404 def addlwc : BinOpLW<0, "addlwc", adde>; // With Carry. (Assembler macro).
 405
 406 // bitwise operations involving a literal and w.
 407 def andlw : BinOpLW<0, "andlw", and>;
 408 def xorlw : BinOpLW<0, "xorlw", xor>;
 409 def orlw  : BinOpLW<0, "iorlw", or>;
 410 }
 411
 412 // sublw
 413 // W = C - W ; sub W from literal. (Without borrow).
 414 let isTwoAddress = 1 in
 415 class SUBLW<bits<6> opcode, SDNode OpNode> :
 416   LiteralFormat<opcode, (outs GPR:$dst),
 417                 (ins GPR:$src, i8imm:$literal),
 418                 "sublw $literal",
 419                 [(set GPR:$dst, (OpNode (i8 imm:$literal), GPR:$src))]>;
 420
 421 let Defs = [STATUS] in {
 422 def sublw_1 : SUBLW<0, sub>;
 423 def sublw_2 : SUBLW<0, subc>;
 424 def sublw_cc : SUBLW<0, PIC16Subcc>;
 425 }
 426
 427 // Call instruction.
 428 let isCall = 1,
 429     Defs = [W, FSR0, FSR1] in {
 430     def CALL: LiteralFormat<0x1, (outs), (ins i8imm:$func),
 431             //"call ${func} + 2",
 432             "call ${func}",
 433             [(PIC16call diraddr:$func)]>;
 434 }
 435
 436 let isCall = 1,
 437     Defs = [W, FSR0, FSR1] in {
 438     def CALL_1: LiteralFormat<0x1, (outs), (ins GPR:$func, PCLATHR:$pc),
 439             "callw",
 440             [(PIC16call (PIC16Connect GPR:$func, PCLATHR:$pc))]>;
 441 }
 442
 443 let isCall = 1,
 444     Defs = [FSR0, FSR1] in {
 445     def CALLW: LiteralFormat<0x1, (outs GPR:$dest),
 446                                   (ins GPR:$func, PCLATHR:$pc),
 447             "callw",
 448             [(set GPR:$dest, (PIC16callw (PIC16Connect GPR:$func, PCLATHR:$pc)))]>;
 449 }
 450
 451 let Uses = [STATUS] in
 452 def pic16brcond: ControlFormat<0x0, (outs), (ins brtarget:$dst, CCOp:$cc),
 453                           "b$cc $dst",
 454                           [(PIC16Brcond bb:$dst, imm:$cc)]>;
 455
 456 // Unconditional branch.
 457 def br_uncond: ControlFormat<0x0, (outs), (ins brtarget:$dst),
 458                           "goto $dst",
 459                           [(br bb:$dst)]>;
 460
 461 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded by the
 462 // scheduler into a branch sequence.
 463 let usesCustomDAGSchedInserter = 1 in {   // Expanded by the scheduler.
 464   def SELECT_CC_Int_ICC
 465    : Pseudo<(outs GPR:$dst), (ins GPR:$T, GPR:$F, i8imm:$Cond),
 466             "; SELECT_CC_Int_ICC PSEUDO!",
 467             [(set GPR:$dst, (PIC16Selecticc GPR:$T, GPR:$F,
 468                                              imm:$Cond))]>;
 469 }
 470
 471
 472 // Banksel.
 473 let isReMaterializable = 1 in {
 474 def banksel :
 475   Pseudo<(outs BSR:$dst),
 476          (ins i8mem:$ptr),
 477          "banksel $ptr",
 478          [(set BSR:$dst, (Banksel tglobaladdr:$ptr))]>;
 479 }
 480
 481 // Return insn.
 482 def Return :
 483   ControlFormat<0, (outs), (ins), "return", [(ret)]>;
 484
 485 //===----------------------------------------------------------------------===//
 486 // PIC16 Replacment Patterns.
 487 //===----------------------------------------------------------------------===//
 488
 489 // Identify an indirect store and select insns for it.
 490 def : Pat<(PIC16Store GPR:$val, (MTLO GPR:$loaddr), (MTHI GPR:$hiaddr),
 491            imm:$offset),
 492           (store_indirect GPR:$val,
 493            (set_fsrhi (set_fsrlo GPR:$loaddr), GPR:$hiaddr),
 494            imm:$offset)>;
 495
 496 def : Pat<(PIC16StWF GPR:$val, (MTLO GPR:$loaddr), (MTHI GPR:$hiaddr),
 497            imm:$offset),
 498           (store_indirect GPR:$val,
 499            (set_fsrhi (set_fsrlo GPR:$loaddr), GPR:$hiaddr),
 500            imm:$offset)>;
 501
 502 // Identify an indirect load and select insns for it.
 503 def : Pat<(PIC16Load (MTLO GPR:$loaddr), (MTHI GPR:$hiaddr),
 504            imm:$offset),
 505           (load_indirect  (set_fsrhi (set_fsrlo GPR:$loaddr), GPR:$hiaddr),
 506            imm:$offset)>;
 507
 508 def : Pat<(PIC16LdWF (MTLO GPR:$loaddr), (MTHI GPR:$hiaddr),
 509            imm:$offset),
 510           (load_indirect  (set_fsrhi (set_fsrlo GPR:$loaddr), GPR:$hiaddr),
 511            imm:$offset)>;
 512