cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSourceCompiles)
  11 include(TestBigEndian)
  12
  13 if( UNIX AND NOT BEOS )
  14   # Used by check_symbol_exists:
  15   set(CMAKE_REQUIRED_LIBRARIES m)
  16 endif()
  17
  18 # Helper macros and functions
  19 macro(add_cxx_include result files)
  20   set(${result} "")
  21   foreach (file_name ${files})
  22      set(${result} "${${result}}#include<${file_name}>\n")
  23   endforeach()
  24 endmacro(add_cxx_include files result)
  25
  26 function(check_type_exists type files variable)
  27   add_cxx_include(includes "${files}")
  28   CHECK_CXX_SOURCE_COMPILES("
  29     ${includes} ${type} typeVar;
  30     int main() {
  31         return 0;
  32     }
  33     " ${variable})
  34 endfunction()
  35
  36 # include checks
  37 check_include_file(argz.h HAVE_ARGZ_H)
  38 check_include_file(assert.h HAVE_ASSERT_H)
  39 check_include_file(ctype.h HAVE_CTYPE_H)
  40 check_include_file(dirent.h HAVE_DIRENT_H)
  41 check_include_file(dl.h HAVE_DL_H)
  42 check_include_file(dld.h HAVE_DLD_H)
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(execinfo.h HAVE_EXECINFO_H)
  46 check_include_file(fcntl.h HAVE_FCNTL_H)
  47 check_include_file(inttypes.h HAVE_INTTYPES_H)
  48 check_include_file(limits.h HAVE_LIMITS_H)
  49 check_include_file(link.h HAVE_LINK_H)
  50 check_include_file(malloc.h HAVE_MALLOC_H)
  51 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  52 check_include_file(memory.h HAVE_MEMORY_H)
  53 check_include_file(ndir.h HAVE_NDIR_H)
  54 if( NOT PURE_WINDOWS )
  55   check_include_file(pthread.h HAVE_PTHREAD_H)
  56 endif()
  57 check_include_file(setjmp.h HAVE_SETJMP_H)
  58 check_include_file(signal.h HAVE_SIGNAL_H)
  59 check_include_file(stdint.h HAVE_STDINT_H)
  60 check_include_file(stdio.h HAVE_STDIO_H)
  61 check_include_file(stdlib.h HAVE_STDLIB_H)
  62 check_include_file(string.h HAVE_STRING_H)
  63 check_include_file(strings.h HAVE_STRINGS_H)
  64 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  65 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  66 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  67 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  68 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  69 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  70 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  71 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  72 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  73 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  74 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  75 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  76 check_include_file(termios.h HAVE_TERMIOS_H)
  77 check_include_file(unistd.h HAVE_UNISTD_H)
  78 check_include_file(utime.h HAVE_UTIME_H)
  79 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  80 check_include_file(windows.h HAVE_WINDOWS_H)
  81 check_include_file(fenv.h HAVE_FENV_H)
  82 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  83 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  84
  85 # library checks
  86 if( NOT PURE_WINDOWS )
  87   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  88   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90   check_library_exists(dl dlopen "" HAVE_LIBDL)
  91 endif()
  92
  93 # function checks
  94 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  95 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  96 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  97 check_function_exists(isatty HAVE_ISATTY)
  98 check_symbol_exists(index strings.h HAVE_INDEX)
  99 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 100 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 101 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 102 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 103 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 104 check_symbol_exists(ceilf math.h HAVE_CEILF)
 105 check_symbol_exists(floorf math.h HAVE_FLOORF)
 106 check_symbol_exists(fmodf math.h HAVE_FMODF)
 107 if( HAVE_SETJMP_H )
 108   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 109   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 110   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 111   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 112 endif()
 113 if( HAVE_SYS_UIO_H )
 114   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 115 endif()
 116 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 117 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 118 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 119                     HAVE_MALLOC_ZONE_STATISTICS)
 120 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 121 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 122 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 123 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 124 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 125 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 126 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 127 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 128 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 129 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 130 check_symbol_exists(strchr string.h HAVE_STRCHR)
 131 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 132 check_symbol_exists(strdup string.h HAVE_STRDUP)
 133 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 134 if( NOT PURE_WINDOWS )
 135   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 136 endif()
 137 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 138 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 139 if( HAVE_RAND48_SRAND48 )
 140   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 141   if( HAVE_RAND48_LRAND48 )
 142     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 143     if( HAVE_RAND48_DRAND48 )
 144       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 145     endif()
 146   endif()
 147 endif()
 148 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 149 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 150 check_symbol_exists(strerror string.h HAVE_STRERROR)
 151 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 152 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 153 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 154 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 155 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 156 if( PURE_WINDOWS )
 157   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 158
 159   check_function_exists(_alloca HAVE__ALLOCA)
 160   check_function_exists(__alloca HAVE___ALLOCA)
 161   check_function_exists(__chkstk HAVE___CHKSTK)
 162   check_function_exists(___chkstk HAVE____CHKSTK)
 163
 164   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 165   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 166   check_function_exists(__divdi3 HAVE___DIVDI3)
 167   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 168   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 169   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 170   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 171   check_function_exists(__moddi3 HAVE___MODDI3)
 172   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 173   check_function_exists(__umoddi3 HAVE___UMODDI3)
 174
 175   check_function_exists(__main HAVE___MAIN)
 176   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 177 endif()
 178 if( HAVE_ARGZ_H )
 179   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 180   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 181   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 182   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 183   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 184 endif()
 185 if( HAVE_DLFCN_H )
 186   if( HAVE_LIBDL )
 187     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 188   endif()
 189   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 190   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 191   if( HAVE_LIBDL )
 192     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 193   endif()
 194 endif()
 195
 196 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 197 if( LLVM_USING_GLIBC )
 198   add_llvm_definitions( -D_GNU_SOURCE )
 199 endif()
 200
 201 # Type checks
 202 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 203 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 204 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 205
 206 set(headers "")
 207 if (HAVE_SYS_TYPES_H)
 208   set(headers ${headers} "sys/types.h")
 209 endif()
 210
 211 if (HAVE_INTTYPES_H)
 212   set(headers ${headers} "inttypes.h")
 213 endif()
 214
 215 if (HAVE_STDINT_H)
 216   set(headers ${headers} "stdint.h")
 217 endif()
 218
 219 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 220 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 221 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 222 check_type_exists(error_t errno.h HAVE_ERROR_T)
 223
 224 # available programs checks
 225 function(llvm_find_program name)
 226   string(TOUPPER ${name} NAME)
 227   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 228   find_program(LLVM_PATH_${NAME} ${name})
 229   mark_as_advanced(LLVM_PATH_${NAME})
 230   if(LLVM_PATH_${NAME})
 231     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 232     mark_as_advanced(HAVE_${NAME})
 233   else(LLVM_PATH_${NAME})
 234     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 235   endif(LLVM_PATH_${NAME})
 236 endfunction()
 237
 238 llvm_find_program(gv)
 239 llvm_find_program(circo)
 240 llvm_find_program(twopi)
 241 llvm_find_program(neato)
 242 llvm_find_program(fdp)
 243 llvm_find_program(dot)
 244 llvm_find_program(dotty)
 245 llvm_find_program(xdot.py)
 246
 247 if( LLVM_ENABLE_FFI )
 248   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 249   if( FFI_INCLUDE_PATH )
 250     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 251     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 252   else()
 253     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 254     if( FFI_INCLUDE_PATH )
 255       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 256       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 257     endif()
 258   endif()
 259
 260   if( NOT FFI_HEADER )
 261     message(FATAL_ERROR "libffi includes are not found.")
 262   endif()
 263
 264   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 265   if( NOT FFI_LIBRARY_PATH )
 266     message(FATAL_ERROR "libffi is not found.")
 267   endif()
 268
 269   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 270   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 271   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 272   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 273   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 274 else()
 275   unset(HAVE_FFI_FFI_H CACHE)
 276   unset(HAVE_FFI_H CACHE)
 277   unset(HAVE_FFI_CALL CACHE)
 278 endif( LLVM_ENABLE_FFI )
 279
 280 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 281 include(CheckAtomic)
 282
 283 if( LLVM_ENABLE_PIC )
 284   set(ENABLE_PIC 1)
 285 else()
 286   set(ENABLE_PIC 0)
 287 endif()
 288
 289 include(CheckCXXCompilerFlag)
 290
 291 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 292
 293 include(GetTargetTriple)
 294 get_target_triple(LLVM_HOSTTRIPLE)
 295
 296 # FIXME: We don't distinguish the target and the host. :(
 297 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 298
 299 # Determine the native architecture.
 300 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 301 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 302   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 303 endif ()
 304
 305 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 306   set(LLVM_NATIVE_ARCH X86)
 307 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 308   set(LLVM_NATIVE_ARCH X86)
 309 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 310   set(LLVM_NATIVE_ARCH X86)
 311 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 312   set(LLVM_NATIVE_ARCH X86)
 313 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 314   set(LLVM_NATIVE_ARCH Sparc)
 315 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 316   set(LLVM_NATIVE_ARCH PowerPC)
 317 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 318   set(LLVM_NATIVE_ARCH Alpha)
 319 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 320   set(LLVM_NATIVE_ARCH ARM)
 321 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 322   set(LLVM_NATIVE_ARCH Mips)
 323 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 324   set(LLVM_NATIVE_ARCH XCore)
 325 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 326   set(LLVM_NATIVE_ARCH MSP430)
 327 else ()
 328   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 329 endif ()
 330
 331 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 332 if (NATIVE_ARCH_IDX EQUAL -1)
 333   message(STATUS
 334     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 335 else ()
 336   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 337   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 338   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 339   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 340 endif ()
 341
 342 if( MINGW )
 343   set(HAVE_LIBIMAGEHLP 1)
 344   set(HAVE_LIBPSAPI 1)
 345   # TODO: Check existence of libraries.
 346   #   include(CheckLibraryExists)
 347   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 348 endif( MINGW )
 349
 350 if( MSVC )
 351   set(error_t int)
 352   set(mode_t "unsigned short")
 353   set(LTDL_SHLIBPATH_VAR "PATH")
 354   set(LTDL_SYSSEARCHPATH "")
 355   set(LTDL_DLOPEN_DEPLIBS 1)
 356   set(SHLIBEXT ".lib")
 357   set(LTDL_OBJDIR "_libs")
 358   set(HAVE_STRTOLL 1)
 359   set(strtoll "_strtoi64")
 360   set(strtoull "_strtoui64")
 361   set(stricmp "_stricmp")
 362   set(strdup "_strdup")
 363 else( MSVC )
 364   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 365   set(LTDL_SYSSEARCHPATH "") # TODO
 366   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 367 endif( MSVC )
 368
 369 # FIXME: Signal handler return type, currently hardcoded to 'void'
 370 set(RETSIGTYPE void)
 371
 372 if( LLVM_ENABLE_THREADS )
 373   if( HAVE_PTHREAD_H OR WIN32 )
 374     set(ENABLE_THREADS 1)
 375   endif()
 376 endif()
 377
 378 if( ENABLE_THREADS )
 379   message(STATUS "Threads enabled.")
 380 else( ENABLE_THREADS )
 381   message(STATUS "Threads disabled.")
 382 endif()
 383
 384 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})