lib/Target/X86/X86CallingConv.td

   1 //===- X86CallingConv.td - Calling Conventions X86 32/64 ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<X86Subtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Conventions
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value conventions common to all X86 CC's.
  24 def RetCC_X86Common : CallingConv<[
  25   // Scalar values are returned in AX first, then DX.  For i8, the ABI
  26   // requires the values to be in AL and AH, however this code uses AL and DL
  27   // instead. This is because using AH for the second register conflicts with
  28   // the way LLVM does multiple return values -- a return of {i16,i8} would end
  29   // up in AX and AH, which overlap. Front-ends wishing to conform to the ABI
  30   // for functions that return two i8 values are currently expected to pack the
  31   // values into an i16 (which uses AX, and thus AL:AH).
  32   CCIfType<[i8] , CCAssignToReg<[AL, DL]>>,
  33   CCIfType<[i16], CCAssignToReg<[AX, DX]>>,
  34   CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>,
  35   CCIfType<[i64], CCAssignToReg<[RAX, RDX]>>,
  36
  37   // Vector types are returned in XMM0 and XMM1, when they fit.  XMM2 and XMM3
  38   // can only be used by ABI non-compliant code. If the target doesn't have XMM
  39   // registers, it won't have vector types.
  40   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  41             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
  42
  43   // 256-bit vectors are returned in YMM0 and XMM1, when they fit. YMM2 and YMM3
  44   // can only be used by ABI non-compliant code. This vector type is only
  45   // supported while using the AVX target feature.
  46   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
  47             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
  48
  49   // MMX vector types are always returned in MM0. If the target doesn't have
  50   // MM0, it doesn't support these vector types.
  51   CCIfType<[x86mmx], CCAssignToReg<[MM0]>>,
  52
  53   // Long double types are always returned in ST0 (even with SSE).
  54   CCIfType<[f80], CCAssignToReg<[ST0, ST1]>>
  55 ]>;
  56
  57 // X86-32 C return-value convention.
  58 def RetCC_X86_32_C : CallingConv<[
  59   // The X86-32 calling convention returns FP values in ST0, unless marked
  60   // with "inreg" (used here to distinguish one kind of reg from another,
  61   // weirdly; this is really the sse-regparm calling convention) in which
  62   // case they use XMM0, otherwise it is the same as the common X86 calling
  63   // conv.
  64   CCIfInReg<CCIfSubtarget<"hasXMMInt()",
  65     CCIfType<[f32, f64], CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
  66   CCIfType<[f32,f64], CCAssignToReg<[ST0, ST1]>>,
  67   CCDelegateTo<RetCC_X86Common>
  68 ]>;
  69
  70 // X86-32 FastCC return-value convention.
  71 def RetCC_X86_32_Fast : CallingConv<[
  72   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  73   // SSE2.
  74   // This can happen when a float, 2 x float, or 3 x float vector is split by
  75   // target lowering, and is returned in 1-3 sse regs.
  76   CCIfType<[f32], CCIfSubtarget<"hasXMMInt()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  77   CCIfType<[f64], CCIfSubtarget<"hasXMMInt()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  78
  79   // For integers, ECX can be used as an extra return register
  80   CCIfType<[i8],  CCAssignToReg<[AL, DL, CL]>>,
  81   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
  82   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
  83
  84   // Otherwise, it is the same as the common X86 calling convention.
  85   CCDelegateTo<RetCC_X86Common>
  86 ]>;
  87
  88 // X86-64 C return-value convention.
  89 def RetCC_X86_64_C : CallingConv<[
  90   // The X86-64 calling convention always returns FP values in XMM0.
  91   CCIfType<[f32], CCAssignToReg<[XMM0, XMM1]>>,
  92   CCIfType<[f64], CCAssignToReg<[XMM0, XMM1]>>,
  93
  94   // MMX vector types are always returned in XMM0.
  95   CCIfType<[x86mmx], CCAssignToReg<[XMM0, XMM1]>>,
  96   CCDelegateTo<RetCC_X86Common>
  97 ]>;
  98
  99 // X86-Win64 C return-value convention.
 100 def RetCC_X86_Win64_C : CallingConv<[
 101   // The X86-Win64 calling convention always returns __m64 values in RAX.
 102   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 103
 104   // Otherwise, everything is the same as 'normal' X86-64 C CC.
 105   CCDelegateTo<RetCC_X86_64_C>
 106 ]>;
 107
 108
 109 // This is the root return-value convention for the X86-32 backend.
 110 def RetCC_X86_32 : CallingConv<[
 111   // If FastCC, use RetCC_X86_32_Fast.
 112   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
 113   // Otherwise, use RetCC_X86_32_C.
 114   CCDelegateTo<RetCC_X86_32_C>
 115 ]>;
 116
 117 // This is the root return-value convention for the X86-64 backend.
 118 def RetCC_X86_64 : CallingConv<[
 119   // Mingw64 and native Win64 use Win64 CC
 120   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<RetCC_X86_Win64_C>>,
 121
 122   // Otherwise, drop to normal X86-64 CC
 123   CCDelegateTo<RetCC_X86_64_C>
 124 ]>;
 125
 126 // This is the return-value convention used for the entire X86 backend.
 127 def RetCC_X86 : CallingConv<[
 128   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
 129   CCDelegateTo<RetCC_X86_32>
 130 ]>;
 131
 132 //===----------------------------------------------------------------------===//
 133 // X86-64 Argument Calling Conventions
 134 //===----------------------------------------------------------------------===//
 135
 136 def CC_X86_64_C : CallingConv<[
 137   // Handles byval parameters.
 138   CCIfByVal<CCPassByVal<8, 8>>,
 139
 140   // Promote i8/i16 arguments to i32.
 141   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 142
 143   // The 'nest' parameter, if any, is passed in R10.
 144   CCIfNest<CCAssignToReg<[R10]>>,
 145
 146   // The first 6 integer arguments are passed in integer registers.
 147   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 148   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 149
 150   // The first 8 MMX vector arguments are passed in XMM registers on Darwin.
 151   CCIfType<[x86mmx],
 152             CCIfSubtarget<"isTargetDarwin()",
 153             CCIfSubtarget<"hasXMMInt()",
 154             CCPromoteToType<v2i64>>>>,
 155
 156   // The first 8 FP/Vector arguments are passed in XMM registers.
 157   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 158             CCIfSubtarget<"hasXMM()",
 159             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>,
 160
 161   // The first 8 256-bit vector arguments are passed in YMM registers.
 162   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 163             CCIfSubtarget<"hasAVX()",
 164             CCAssignToReg<[YMM0, YMM1, YMM2, YMM3, YMM4, YMM5, YMM6, YMM7]>>>,
 165
 166   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 167   // 8-byte aligned if there are no more registers to hold them.
 168   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 169
 170   // Long doubles get stack slots whose size and alignment depends on the
 171   // subtarget.
 172   CCIfType<[f80], CCAssignToStack<0, 0>>,
 173
 174   // Vectors get 16-byte stack slots that are 16-byte aligned.
 175   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 176
 177   // 256-bit vectors get 32-byte stack slots that are 32-byte aligned.
 178   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 179            CCAssignToStack<32, 32>>
 180 ]>;
 181
 182 // Calling convention used on Win64
 183 def CC_X86_Win64_C : CallingConv<[
 184   // FIXME: Handle byval stuff.
 185   // FIXME: Handle varargs.
 186
 187   // Promote i8/i16 arguments to i32.
 188   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 189
 190   // The 'nest' parameter, if any, is passed in R10.
 191   CCIfNest<CCAssignToReg<[R10]>>,
 192
 193   // 128 bit vectors are passed by pointer
 194   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCPassIndirect<i64>>,
 195
 196   // The first 4 MMX vector arguments are passed in GPRs.
 197   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 198
 199   // The first 4 integer arguments are passed in integer registers.
 200   CCIfType<[i32], CCAssignToRegWithShadow<[ECX , EDX , R8D , R9D ],
 201                                           [XMM0, XMM1, XMM2, XMM3]>>,
 202
 203   // Do not pass the sret argument in RCX, the Win64 thiscall calling
 204   // convention requires "this" to be passed in RCX.
 205   CCIfCC<"CallingConv::X86_ThisCall",
 206     CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[RDX , R8  , R9  ],
 207                                                      [XMM1, XMM2, XMM3]>>>>,
 208
 209   CCIfType<[i64], CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 210                                           [XMM0, XMM1, XMM2, XMM3]>>,
 211
 212   // The first 4 FP/Vector arguments are passed in XMM registers.
 213   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 214            CCAssignToRegWithShadow<[XMM0, XMM1, XMM2, XMM3],
 215                                    [RCX , RDX , R8  , R9  ]>>,
 216
 217   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 218   // 8-byte aligned if there are no more registers to hold them.
 219   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 220
 221   // Long doubles get stack slots whose size and alignment depends on the
 222   // subtarget.
 223   CCIfType<[f80], CCAssignToStack<0, 0>>
 224 ]>;
 225
 226 def CC_X86_64_GHC : CallingConv<[
 227   // Promote i8/i16/i32 arguments to i64.
 228   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 229
 230   // Pass in STG registers: Base, Sp, Hp, R1, R2, R3, R4, R5, R6, SpLim
 231   CCIfType<[i64],
 232             CCAssignToReg<[R13, RBP, R12, RBX, R14, RSI, RDI, R8, R9, R15]>>,
 233
 234   // Pass in STG registers: F1, F2, F3, F4, D1, D2
 235   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 236             CCIfSubtarget<"hasXMM()",
 237             CCAssignToReg<[XMM1, XMM2, XMM3, XMM4, XMM5, XMM6]>>>
 238 ]>;
 239
 240 //===----------------------------------------------------------------------===//
 241 // X86 C Calling Convention
 242 //===----------------------------------------------------------------------===//
 243
 244 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 245 /// values are spilled on the stack, and the first 4 vector values go in XMM
 246 /// regs.
 247 def CC_X86_32_Common : CallingConv<[
 248   // Handles byval parameters.
 249   CCIfByVal<CCPassByVal<4, 4>>,
 250
 251   // The first 3 float or double arguments, if marked 'inreg' and if the call
 252   // is not a vararg call and if SSE2 is available, are passed in SSE registers.
 253   CCIfNotVarArg<CCIfInReg<CCIfType<[f32,f64],
 254                 CCIfSubtarget<"hasXMMInt()",
 255                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>>,
 256
 257   // The first 3 __m64 vector arguments are passed in mmx registers if the
 258   // call is not a vararg call.
 259   CCIfNotVarArg<CCIfType<[x86mmx],
 260                 CCAssignToReg<[MM0, MM1, MM2]>>>,
 261
 262   // Integer/Float values get stored in stack slots that are 4 bytes in
 263   // size and 4-byte aligned.
 264   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 265
 266   // Doubles get 8-byte slots that are 4-byte aligned.
 267   CCIfType<[f64], CCAssignToStack<8, 4>>,
 268
 269   // Long doubles get slots whose size depends on the subtarget.
 270   CCIfType<[f80], CCAssignToStack<0, 4>>,
 271
 272   // The first 4 SSE vector arguments are passed in XMM registers.
 273   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 274                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 275
 276   // The first 4 AVX 256-bit vector arguments are passed in YMM registers.
 277   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 278                 CCIfSubtarget<"hasAVX()",
 279                 CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>>>,
 280
 281   // Other SSE vectors get 16-byte stack slots that are 16-byte aligned.
 282   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 283
 284   // 256-bit AVX vectors get 32-byte stack slots that are 32-byte aligned.
 285   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 286            CCAssignToStack<32, 32>>,
 287
 288   // __m64 vectors get 8-byte stack slots that are 4-byte aligned. They are
 289   // passed in the parameter area.
 290   CCIfType<[x86mmx], CCAssignToStack<8, 4>>]>;
 291
 292 def CC_X86_32_C : CallingConv<[
 293   // Promote i8/i16 arguments to i32.
 294   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 295
 296   // The 'nest' parameter, if any, is passed in ECX.
 297   CCIfNest<CCAssignToReg<[ECX]>>,
 298
 299   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 300   // a vararg call, are passed in integer registers.
 301   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 302
 303   // Otherwise, same as everything else.
 304   CCDelegateTo<CC_X86_32_Common>
 305 ]>;
 306
 307 def CC_X86_32_FastCall : CallingConv<[
 308   // Promote i8/i16 arguments to i32.
 309   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 310
 311   // The 'nest' parameter, if any, is passed in EAX.
 312   CCIfNest<CCAssignToReg<[EAX]>>,
 313
 314   // The first 2 integer arguments are passed in ECX/EDX
 315   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 316
 317   // Otherwise, same as everything else.
 318   CCDelegateTo<CC_X86_32_Common>
 319 ]>;
 320
 321 def CC_X86_32_ThisCall : CallingConv<[
 322   // Promote i8/i16 arguments to i32.
 323   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 324
 325   // The 'nest' parameter, if any, is passed in EAX.
 326   CCIfNest<CCAssignToReg<[EAX]>>,
 327
 328   // The first integer argument is passed in ECX
 329   CCIfType<[i32], CCAssignToReg<[ECX]>>,
 330
 331   // Otherwise, same as everything else.
 332   CCDelegateTo<CC_X86_32_Common>
 333 ]>;
 334
 335 def CC_X86_32_FastCC : CallingConv<[
 336   // Handles byval parameters.  Note that we can't rely on the delegation
 337   // to CC_X86_32_Common for this because that happens after code that
 338   // puts arguments in registers.
 339   CCIfByVal<CCPassByVal<4, 4>>,
 340
 341   // Promote i8/i16 arguments to i32.
 342   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 343
 344   // The 'nest' parameter, if any, is passed in EAX.
 345   CCIfNest<CCAssignToReg<[EAX]>>,
 346
 347   // The first 2 integer arguments are passed in ECX/EDX
 348   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 349
 350   // The first 3 float or double arguments, if the call is not a vararg
 351   // call and if SSE2 is available, are passed in SSE registers.
 352   CCIfNotVarArg<CCIfType<[f32,f64],
 353                 CCIfSubtarget<"hasXMMInt()",
 354                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
 355
 356   // Doubles get 8-byte slots that are 8-byte aligned.
 357   CCIfType<[f64], CCAssignToStack<8, 8>>,
 358
 359   // Otherwise, same as everything else.
 360   CCDelegateTo<CC_X86_32_Common>
 361 ]>;
 362
 363 def CC_X86_32_GHC : CallingConv<[
 364   // Promote i8/i16 arguments to i32.
 365   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 366
 367   // Pass in STG registers: Base, Sp, Hp, R1
 368   CCIfType<[i32], CCAssignToReg<[EBX, EBP, EDI, ESI]>>
 369 ]>;
 370
 371 //===----------------------------------------------------------------------===//
 372 // X86 Root Argument Calling Conventions
 373 //===----------------------------------------------------------------------===//
 374
 375 // This is the root argument convention for the X86-32 backend.
 376 def CC_X86_32 : CallingConv<[
 377   CCIfCC<"CallingConv::X86_FastCall", CCDelegateTo<CC_X86_32_FastCall>>,
 378   CCIfCC<"CallingConv::X86_ThisCall", CCDelegateTo<CC_X86_32_ThisCall>>,
 379   CCIfCC<"CallingConv::Fast", CCDelegateTo<CC_X86_32_FastCC>>,
 380   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_32_GHC>>,
 381
 382   // Otherwise, drop to normal X86-32 CC
 383   CCDelegateTo<CC_X86_32_C>
 384 ]>;
 385
 386 // This is the root argument convention for the X86-64 backend.
 387 def CC_X86_64 : CallingConv<[
 388   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_64_GHC>>,
 389
 390   // Mingw64 and native Win64 use Win64 CC
 391   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 392
 393   // Otherwise, drop to normal X86-64 CC
 394   CCDelegateTo<CC_X86_64_C>
 395 ]>;
 396
 397 // This is the argument convention used for the entire X86 backend.
 398 def CC_X86 : CallingConv<[
 399   CCIfSubtarget<"is64Bit()", CCDelegateTo<CC_X86_64>>,
 400   CCDelegateTo<CC_X86_32>
 401 ]>;