CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  32   file(GLOB_RECURSE
  33     tablegenned_files_on_include_dir
  34     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  35   file(GLOB_RECURSE
  36     tablegenned_files_on_lib_dir
  37     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  38   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  39     message(FATAL_ERROR "Apparently there is a previous in-source build,
  40 probably as the result of running `configure' and `make' on
  41 ${LLVM_MAIN_SRC_DIR}.
  42 This may cause problems. The suspicious files are:
  43 ${tablegenned_files_on_lib_dir}
  44 ${tablegenned_files_on_include_dir}
  45 Please clean the source directory.")
  46   endif()
  47 endif()
  48
  49 set(LLVM_ALL_TARGETS
  50   Alpha
  51   ARM
  52   CBackend
  53   CellSPU
  54   CppBackend
  55   IA64
  56   Mips
  57   MSIL
  58   MSP430
  59   PIC16
  60   PowerPC
  61   Sparc
  62   X86
  63   XCore
  64   )
  65
  66 # List of targets whose asmprinters need to be forced to link
  67 # into executables on some platforms (i.e. Windows):
  68 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  69
  70 if( MSVC )
  71   set(LLVM_TARGETS_TO_BUILD X86
  72     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  73 else( MSVC )
  74   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  75     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  76 endif( MSVC )
  77
  78 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  79
  80 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  81   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  82 else()
  83   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  84 endif()
  85
  86 if( LLVM_ENABLE_ASSERTIONS )
  87   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  88   if( NOT MSVC )
  89     add_definitions( -D_DEBUG )
  90   endif()
  91   # On Release builds cmake automatically defines NDEBUG, so we
  92   # explicitly undefine it:
  93   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  94     add_definitions( -UNDEBUG )
  95   endif()
  96 else()
  97   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  98     add_definitions( -DNDEBUG )
  99   endif()
 100 endif()
 101
 102 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 103   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 104 endif()
 105
 106 set(LLVM_ENUM_TARGETS "")
 107 foreach(c ${LLVM_TARGETS_TO_BUILD})
 108   list(FIND LLVM_ALL_TARGETS ${c} idx)
 109   if( idx LESS 0 )
 110     message(FATAL_ERROR "The target `${c}' does not exists.
 111     It should be one of\n${LLVM_ALL_TARGETS}")
 112   else()
 113     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 114   endif()
 115 endforeach(c)
 116
 117 # Produce llvm/Config/Targets.def
 118 configure_file(
 119   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 120   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 121   )
 122
 123 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 124
 125 # Add path for custom modules
 126 set(CMAKE_MODULE_PATH
 127   ${CMAKE_MODULE_PATH}
 128   "${LLVM_MAIN_SRC_DIR}/cmake"
 129   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 130   )
 131
 132 include(AddLLVMDefinitions)
 133
 134 if(WIN32)
 135   if(CYGWIN)
 136     set(LLVM_ON_WIN32 0)
 137     set(LLVM_ON_UNIX 1)
 138   else(CYGWIN)
 139     set(LLVM_ON_WIN32 1)
 140     set(LLVM_ON_UNIX 0)
 141   endif(CYGWIN)
 142   set(LTDL_SHLIB_EXT ".dll")
 143   set(EXEEXT ".exe")
 144   # Maximum path length is 160 for non-unicode paths
 145   set(MAXPATHLEN 160)
 146 else(WIN32)
 147   if(UNIX)
 148     set(LLVM_ON_WIN32 0)
 149     set(LLVM_ON_UNIX 1)
 150     set(LTDL_SHLIB_EXT ".so")
 151     set(EXEEXT "")
 152     # FIXME: Maximum path length is currently set to 'safe' fixed value
 153     set(MAXPATHLEN 2024)
 154   else(UNIX)
 155     MESSAGE(SEND_ERROR "Unable to determine platform")
 156   endif(UNIX)
 157 endif(WIN32)
 158
 159 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 160   set(HAVE_LLVM_CONFIG 1)
 161 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 162
 163 include(config-ix)
 164
 165 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 166
 167 set(ENABLE_PIC 0)
 168 if( LLVM_ENABLE_PIC )
 169   if( SUPPORTS_FPIC_FLAG )
 170     message(STATUS "Building with -fPIC")
 171     add_llvm_definitions(-fPIC)
 172     set(ENABLE_PIC 1)
 173  else( SUPPORTS_FPIC_FLAG )
 174     message(STATUS "Warning: -fPIC not supported.")
 175   endif()
 176 endif()
 177
 178 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 179 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 180 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 181
 182 # set(CMAKE_VERBOSE_MAKEFILE true)
 183
 184 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 185 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 186
 187 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 188   # TODO: support other platforms and toolchains.
 189   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 190   if( LLVM_BUILD_32_BITS )
 191     message(STATUS "Building 32 bits executables and libraries.")
 192     add_llvm_definitions( -m32 )
 193     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 194     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 195     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 196   endif( LLVM_BUILD_32_BITS )
 197 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 198
 199 if( MSVC )
 200   # List of valid CRTs for MSVC
 201   set(MSVC_CRT
 202     MD
 203     MDd)
 204
 205   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 206   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 207   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 208   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 209   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 210   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 211
 212   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 213     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 214     if (idx LESS 0)
 215       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 216     endif (idx LESS 0)
 217     add_llvm_definitions("/${LLVM_USE_CRT}")
 218     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 219   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 220 endif( MSVC )
 221
 222 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 223
 224 include(AddLLVM)
 225 include(TableGen)
 226
 227 add_subdirectory(lib/Support)
 228 add_subdirectory(lib/System)
 229
 230 # Everything else depends on Support and System:
 231 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 232
 233 set(LLVM_TABLEGEN "tblgen" CACHE
 234   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 235 # Effective tblgen executable to be used:
 236 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 237
 238 add_subdirectory(utils/TableGen)
 239
 240 if( CMAKE_CROSSCOMPILING )
 241   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 242   include( CrossCompileLLVM )
 243 endif( CMAKE_CROSSCOMPILING )
 244
 245 add_subdirectory(include/llvm)
 246
 247 add_subdirectory(lib/VMCore)
 248 add_subdirectory(lib/CodeGen)
 249 add_subdirectory(lib/CodeGen/SelectionDAG)
 250 add_subdirectory(lib/CodeGen/AsmPrinter)
 251 add_subdirectory(lib/Bitcode/Reader)
 252 add_subdirectory(lib/Bitcode/Writer)
 253 add_subdirectory(lib/Transforms/Utils)
 254 add_subdirectory(lib/Transforms/Instrumentation)
 255 add_subdirectory(lib/Transforms/Scalar)
 256 add_subdirectory(lib/Transforms/IPO)
 257 add_subdirectory(lib/Transforms/Hello)
 258 add_subdirectory(lib/Linker)
 259 add_subdirectory(lib/Analysis)
 260 add_subdirectory(lib/Analysis/IPA)
 261 add_subdirectory(lib/MC)
 262
 263  set(LLVM_ENUM_ASM_PRINTERS "")
 264  foreach(t ${LLVM_TARGETS_TO_BUILD})
 265   message(STATUS "Targeting ${t}")
 266   add_subdirectory(lib/Target/${t})
 267   add_subdirectory(lib/Target/${t}/TargetInfo)
 268   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 269    add_subdirectory(lib/Target/${t}/AsmPrinter)
 270     set(LLVM_ENUM_ASM_PRINTERS
 271         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 272  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 273 endforeach(t)
 274
 275 # Produce llvm/Config/AsmPrinters.def
 276 configure_file(
 277   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 278   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 279   )
 280
 281 add_subdirectory(lib/ExecutionEngine)
 282 add_subdirectory(lib/ExecutionEngine/Interpreter)
 283 add_subdirectory(lib/ExecutionEngine/JIT)
 284 add_subdirectory(lib/Target)
 285 add_subdirectory(lib/AsmParser)
 286 add_subdirectory(lib/Debugger)
 287 add_subdirectory(lib/Archive)
 288
 289 add_subdirectory(projects)
 290 add_subdirectory(tools)
 291
 292 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 293 if (LLVM_EXAMPLES)
 294   add_subdirectory(examples)
 295 endif ()
 296
 297 install(DIRECTORY include
 298   DESTINATION .
 299   PATTERN ".svn" EXCLUDE
 300   PATTERN "*.cmake" EXCLUDE
 301   PATTERN "*.in" EXCLUDE
 302   )
 303
 304 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 305   DESTINATION .
 306   )
 307
 308 # TODO: make and install documentation.