lib/Target/X86/X86InstrCMovSetCC.td

   1 //===- X86InstrCMovSetCC.td - Conditional Move and SetCC ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 conditional move and set on condition
  11 // instructions.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15
  16 // SetCC instructions.
  17 multiclass CMOV<bits<8> opc, string Mnemonic, PatLeaf CondNode> {
  18   let Uses = [EFLAGS], Predicates = [HasCMov], Constraints = "$src1 = $dst",
  19       isCommutable = 1 in {
  20     def #NAME#16rr
  21       : I<opc, MRMSrcReg, (outs GR16:$dst), (ins GR16:$src1, GR16:$src2),
  22           !strconcat(Mnemonic, "{w}\t{$src2, $dst|$dst, $src2}"),
  23           [(set GR16:$dst,
  24                 (X86cmov GR16:$src1, GR16:$src2, CondNode, EFLAGS))]>,TB,OpSize;
  25     def #NAME#32rr
  26       : I<opc, MRMSrcReg, (outs GR32:$dst), (ins GR32:$src1, GR32:$src2),
  27           !strconcat(Mnemonic, "{l}\t{$src2, $dst|$dst, $src2}"),
  28           [(set GR32:$dst,
  29                 (X86cmov GR32:$src1, GR32:$src2, CondNode, EFLAGS))]>, TB;
  30     def #NAME#64rr
  31       :RI<opc, MRMSrcReg, (outs GR64:$dst), (ins GR64:$src1, GR64:$src2),
  32           !strconcat(Mnemonic, "{q}\t{$src2, $dst|$dst, $src2}"),
  33           [(set GR64:$dst,
  34                 (X86cmov GR64:$src1, GR64:$src2, CondNode, EFLAGS))]>, TB;
  35   }
  36
  37   let Uses = [EFLAGS], Predicates = [HasCMov], Constraints = "$src1 = $dst" in {
  38     def #NAME#16rm
  39       : I<opc, MRMSrcMem, (outs GR16:$dst), (ins GR16:$src1, i16mem:$src2),
  40           !strconcat(Mnemonic, "{w}\t{$src2, $dst|$dst, $src2}"),
  41           [(set GR16:$dst, (X86cmov GR16:$src1, (loadi16 addr:$src2),
  42                                     CondNode, EFLAGS))]>, TB, OpSize;
  43     def #NAME#32rm
  44       : I<opc, MRMSrcMem, (outs GR32:$dst), (ins GR32:$src1, i32mem:$src2),
  45           !strconcat(Mnemonic, "{l}\t{$src2, $dst|$dst, $src2}"),
  46           [(set GR32:$dst, (X86cmov GR32:$src1, (loadi32 addr:$src2),
  47                                     CondNode, EFLAGS))]>, TB;
  48     def #NAME#64rm
  49       :RI<opc, MRMSrcMem, (outs GR64:$dst), (ins GR64:$src1, i64mem:$src2),
  50           !strconcat(Mnemonic, "{q}\t{$src2, $dst|$dst, $src2}"),
  51           [(set GR64:$dst, (X86cmov GR64:$src1, (loadi64 addr:$src2),
  52                                     CondNode, EFLAGS))]>, TB;
  53   } // Uses = [EFLAGS], Predicates = [HasCMov], Constraints = "$src1 = $dst"
  54 } // end multiclass
  55
  56
  57 // Conditional Moves.
  58 defm CMOVO  : CMOV<0x40, "cmovo" , X86_COND_O>;
  59 defm CMOVNO : CMOV<0x41, "cmovno", X86_COND_NO>;
  60 defm CMOVB  : CMOV<0x42, "cmovb" , X86_COND_B>;
  61 defm CMOVAE : CMOV<0x43, "cmovae", X86_COND_AE>;
  62 defm CMOVE  : CMOV<0x44, "cmove" , X86_COND_E>;
  63 defm CMOVNE : CMOV<0x45, "cmovne", X86_COND_NE>;
  64 defm CMOVBE : CMOV<0x46, "cmovbe", X86_COND_BE>;
  65 defm CMOVA  : CMOV<0x47, "cmova" , X86_COND_A>;
  66 defm CMOVS  : CMOV<0x48, "cmovs" , X86_COND_S>;
  67 defm CMOVNS : CMOV<0x49, "cmovns", X86_COND_NS>;
  68 defm CMOVP  : CMOV<0x4A, "cmovp" , X86_COND_P>;
  69 defm CMOVNP : CMOV<0x4B, "cmovnp", X86_COND_NP>;
  70 defm CMOVL  : CMOV<0x4C, "cmovl" , X86_COND_L>;
  71 defm CMOVGE : CMOV<0x4D, "cmovge", X86_COND_GE>;
  72 defm CMOVLE : CMOV<0x4E, "cmovle", X86_COND_LE>;
  73 defm CMOVG  : CMOV<0x4F, "cmovg" , X86_COND_G>;
  74
  75
  76 // SetCC instructions.
  77 multiclass SETCC<bits<8> opc, string Mnemonic, PatLeaf OpNode> {
  78   let Uses = [EFLAGS] in {
  79     def r    : I<opc, MRM0r,  (outs GR8:$dst), (ins),
  80                      !strconcat(Mnemonic, "\t$dst"),
  81                      [(set GR8:$dst, (X86setcc OpNode, EFLAGS))]>, TB;
  82     def m    : I<opc, MRM0m,  (outs), (ins i8mem:$dst),
  83                      !strconcat(Mnemonic, "\t$dst"),
  84                      [(store (X86setcc OpNode, EFLAGS), addr:$dst)]>, TB;
  85   } // Uses = [EFLAGS]
  86 }
  87
  88 defm SETO  : SETCC<0x90, "seto",  X86_COND_O>;   // is overflow bit set
  89 defm SETNO : SETCC<0x91, "setno", X86_COND_NO>;  // is overflow bit not set
  90 defm SETB  : SETCC<0x92, "setb",  X86_COND_B>;   // unsigned less than
  91 defm SETAE : SETCC<0x93, "setae", X86_COND_AE>;  // unsigned greater or equal
  92 defm SETE  : SETCC<0x94, "sete",  X86_COND_E>;   // equal to
  93 defm SETNE : SETCC<0x95, "setne", X86_COND_NE>;  // not equal to
  94 defm SETBE : SETCC<0x96, "setbe", X86_COND_BE>;  // unsigned less than or equal
  95 defm SETA  : SETCC<0x97, "seta",  X86_COND_A>;   // unsigned greater than
  96 defm SETS  : SETCC<0x98, "sets",  X86_COND_S>;   // is signed bit set
  97 defm SETNS : SETCC<0x99, "setns", X86_COND_NS>;  // is not signed
  98 defm SETP  : SETCC<0x9A, "setp",  X86_COND_P>;   // is parity bit set
  99 defm SETNP : SETCC<0x9B, "setnp", X86_COND_NP>;  // is parity bit not set
 100 defm SETL  : SETCC<0x9C, "setl",  X86_COND_L>;   // signed less than
 101 defm SETGE : SETCC<0x9D, "setge", X86_COND_GE>;  // signed greater or equal
 102 defm SETLE : SETCC<0x9E, "setle", X86_COND_LE>;  // signed less than or equal
 103 defm SETG  : SETCC<0x9F, "setg",  X86_COND_G>;   // signed greater than
 104