lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet2    : SDTypeProfile<2, 0, [SDTCisVT<0, f80>,
  21                                            SDTCisVT<1, f80>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def SDTX86CwdStore  : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  33
  34 def X86fld          : SDNode<"X86ISD::FLD", SDTX86Fld,
  35                              [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
  36 def X86fst          : SDNode<"X86ISD::FST", SDTX86Fst,
  37                              [SDNPHasChain, SDNPInFlag, SDNPMayStore,
  38                               SDNPMemOperand]>;
  39 def X86fild         : SDNode<"X86ISD::FILD", SDTX86Fild,
  40                              [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
  41 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG", SDTX86Fild,
  42                              [SDNPHasChain, SDNPOutFlag, SDNPMayLoad,
  43                               SDNPMemOperand]>;
  44 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  45                              [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
  46 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  47                              [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
  48 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  49                              [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
  50 def X86fp_cwd_get16 : SDNode<"X86ISD::FNSTCW16m",          SDTX86CwdStore,
  51                              [SDNPHasChain, SDNPMayStore, SDNPSideEffect,
  52                               SDNPMemOperand]>;
  53
  54 //===----------------------------------------------------------------------===//
  55 // FPStack pattern fragments
  56 //===----------------------------------------------------------------------===//
  57
  58 def fpimm0 : PatLeaf<(fpimm), [{
  59   return N->isExactlyValue(+0.0);
  60 }]>;
  61
  62 def fpimmneg0 : PatLeaf<(fpimm), [{
  63   return N->isExactlyValue(-0.0);
  64 }]>;
  65
  66 def fpimm1 : PatLeaf<(fpimm), [{
  67   return N->isExactlyValue(+1.0);
  68 }]>;
  69
  70 def fpimmneg1 : PatLeaf<(fpimm), [{
  71   return N->isExactlyValue(-1.0);
  72 }]>;
  73
  74 // Some 'special' instructions
  75 let usesCustomInserter = 1 in {  // Expanded after instruction selection.
  76   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  77                               (outs), (ins i16mem:$dst, RFP32:$src),
  78                               "##FP32_TO_INT16_IN_MEM PSEUDO!",
  79                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  80   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  81                               (outs), (ins i32mem:$dst, RFP32:$src),
  82                               "##FP32_TO_INT32_IN_MEM PSEUDO!",
  83                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  84   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  85                               (outs), (ins i64mem:$dst, RFP32:$src),
  86                               "##FP32_TO_INT64_IN_MEM PSEUDO!",
  87                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  88   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  89                               (outs), (ins i16mem:$dst, RFP64:$src),
  90                               "##FP64_TO_INT16_IN_MEM PSEUDO!",
  91                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  92   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  93                               (outs), (ins i32mem:$dst, RFP64:$src),
  94                               "##FP64_TO_INT32_IN_MEM PSEUDO!",
  95                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  96   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  97                               (outs), (ins i64mem:$dst, RFP64:$src),
  98                               "##FP64_TO_INT64_IN_MEM PSEUDO!",
  99                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
 100   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
 101                               (outs), (ins i16mem:$dst, RFP80:$src),
 102                               "##FP80_TO_INT16_IN_MEM PSEUDO!",
 103                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 104   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 105                               (outs), (ins i32mem:$dst, RFP80:$src),
 106                               "##FP80_TO_INT32_IN_MEM PSEUDO!",
 107                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 108   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 109                               (outs), (ins i64mem:$dst, RFP80:$src),
 110                               "##FP80_TO_INT64_IN_MEM PSEUDO!",
 111                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 112 }
 113
 114 // All FP Stack operations are represented with four instructions here.  The
 115 // first three instructions, generated by the instruction selector, use "RFP32"
 116 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 117 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 118 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 119 // copied to each other without losing information.  These instructions are all
 120 // pseudo instructions and use the "_Fp" suffix.
 121 // In some cases there are additional variants with a mixture of different
 122 // register sizes.
 123 // The second instruction is defined with FPI, which is the actual instruction
 124 // emitted by the assembler.  These use "RST" registers, although frequently
 125 // the actual register(s) used are implicit.  These are always 80 bits.
 126 // The FP stackifier pass converts one to the other after register allocation
 127 // occurs.
 128 //
 129 // Note that the FpI instruction should have instruction selection info (e.g.
 130 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 131 // encoding and asm printing info).
 132
 133 // Pseudo Instructions for FP stack return values.
 134 def FpGET_ST0_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 135 def FpGET_ST0_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 136 def FpGET_ST0_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 137
 138 // FpGET_ST1* should only be issued *after* an FpGET_ST0* has been issued when
 139 // there are two values live out on the stack from a call or inlineasm.  This
 140 // magic is handled by the stackifier.  It is not valid to emit FpGET_ST1* and
 141 // then FpGET_ST0*.  In addition, it is invalid for any FP-using operations to
 142 // occur between them.
 143 def FpGET_ST1_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 144 def FpGET_ST1_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 145 def FpGET_ST1_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 146
 147 let Defs = [ST0] in {
 148 def FpSET_ST0_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(0) = FPR
 149 def FpSET_ST0_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(0) = FPR
 150 def FpSET_ST0_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(0) = FPR
 151 }
 152
 153 let Defs = [ST1] in {
 154 def FpSET_ST1_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(1) = FPR
 155 def FpSET_ST1_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(1) = FPR
 156 def FpSET_ST1_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(1) = FPR
 157 }
 158
 159 // FpIf32, FpIf64 - Floating Point Pseudo Instruction template.
 160 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 161 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 162 // f80 instructions cannot use SSE and use neither of these.
 163 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 164   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 165 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 166   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 167
 168 // Register copies.  Just copies, the shortening ones do not truncate.
 169 let neverHasSideEffects = 1 in {
 170   def MOV_Fp3232 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 171   def MOV_Fp3264 : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 172   def MOV_Fp6432 : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 173   def MOV_Fp6464 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 174   def MOV_Fp8032 : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 175   def MOV_Fp3280 : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 176   def MOV_Fp8064 : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 177   def MOV_Fp6480 : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 178   def MOV_Fp8080 : FpI_  <(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 179 }
 180
 181 // Factoring for arithmetic.
 182 multiclass FPBinary_rr<SDNode OpNode> {
 183 // Register op register -> register
 184 // These are separated out because they have no reversed form.
 185 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 186                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 187 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 188                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 189 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 190                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 191 }
 192 // The FopST0 series are not included here because of the irregularities
 193 // in where the 'r' goes in assembly output.
 194 // These instructions cannot address 80-bit memory.
 195 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 196 // ST(0) = ST(0) + [mem]
 197 def _Fp32m  : FpIf32<(outs RFP32:$dst),
 198                      (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 199                   [(set RFP32:$dst,
 200                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 201 def _Fp64m  : FpIf64<(outs RFP64:$dst),
 202                      (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 203                   [(set RFP64:$dst,
 204                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 205 def _Fp64m32: FpIf64<(outs RFP64:$dst),
 206                      (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 207                   [(set RFP64:$dst,
 208                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 209 def _Fp80m32: FpI_<(outs RFP80:$dst),
 210                    (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 211                   [(set RFP80:$dst,
 212                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 213 def _Fp80m64: FpI_<(outs RFP80:$dst),
 214                    (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 215                   [(set RFP80:$dst,
 216                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 217 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 218                  !strconcat("f", asmstring, "{s}\t$src")> {
 219   let mayLoad = 1;
 220 }
 221 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 222                  !strconcat("f", asmstring, "{l}\t$src")> {
 223   let mayLoad = 1;
 224 }
 225 // ST(0) = ST(0) + [memint]
 226 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2),
 227                        OneArgFPRW,
 228                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 229                                        (X86fild addr:$src2, i16)))]>;
 230 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2),
 231                        OneArgFPRW,
 232                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 233                                        (X86fild addr:$src2, i32)))]>;
 234 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2),
 235                        OneArgFPRW,
 236                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 237                                        (X86fild addr:$src2, i16)))]>;
 238 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2),
 239                        OneArgFPRW,
 240                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 241                                        (X86fild addr:$src2, i32)))]>;
 242 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2),
 243                        OneArgFPRW,
 244                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 245                                        (X86fild addr:$src2, i16)))]>;
 246 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2),
 247                        OneArgFPRW,
 248                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 249                                        (X86fild addr:$src2, i32)))]>;
 250 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 251                   !strconcat("fi", asmstring, "{s}\t$src")> {
 252   let mayLoad = 1;
 253 }
 254 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 255                   !strconcat("fi", asmstring, "{l}\t$src")> {
 256   let mayLoad = 1;
 257 }
 258 }
 259
 260 defm ADD : FPBinary_rr<fadd>;
 261 defm SUB : FPBinary_rr<fsub>;
 262 defm MUL : FPBinary_rr<fmul>;
 263 defm DIV : FPBinary_rr<fdiv>;
 264 defm ADD : FPBinary<fadd, MRM0m, "add">;
 265 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 266 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 267 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 268 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 269 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 270
 271 class FPST0rInst<bits<8> o, string asm>
 272   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 273 class FPrST0Inst<bits<8> o, string asm>
 274   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 275 class FPrST0PInst<bits<8> o, string asm>
 276   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 277
 278 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 279 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 280 // we have to put some 'r's in and take them out of weird places.
 281 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 282 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 283 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 284 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 285 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 286 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 287 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 288 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 289 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 290 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 291 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 292 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 293 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 294 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 295 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 296 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 297 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 298 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 299
 300 def COM_FST0r   : FPST0rInst <0xD0, "fcom\t$op">;
 301 def COMP_FST0r  : FPST0rInst <0xD8, "fcomp\t$op">;
 302
 303 // Unary operations.
 304 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 305 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 306                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 307 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 308                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 309 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 310                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 311 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 312 }
 313
 314 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 315 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 316 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 317 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 318 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 319
 320 let neverHasSideEffects = 1 in {
 321 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP, []>;
 322 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP, []>;
 323 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP, []>;
 324 }
 325 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 326
 327 // Versions of FP instructions that take a single memory operand.  Added for the
 328 //   disassembler; remove as they are included with patterns elsewhere.
 329 def FCOM32m  : FPI<0xD8, MRM2m, (outs), (ins f32mem:$src), "fcom{s}\t$src">;
 330 def FCOMP32m : FPI<0xD8, MRM3m, (outs), (ins f32mem:$src), "fcomp{s}\t$src">;
 331
 332 def FLDENVm  : FPI<0xD9, MRM4m, (outs), (ins f32mem:$src), "fldenv\t$src">;
 333 def FSTENVm  : FPI<0xD9, MRM6m, (outs f32mem:$dst), (ins), "fnstenv\t$dst">;
 334
 335 def FICOM32m : FPI<0xDA, MRM2m, (outs), (ins i32mem:$src), "ficom{l}\t$src">;
 336 def FICOMP32m: FPI<0xDA, MRM3m, (outs), (ins i32mem:$src), "ficomp{l}\t$src">;
 337
 338 def FCOM64m  : FPI<0xDC, MRM2m, (outs), (ins f64mem:$src), "fcom{l}\t$src">;
 339 def FCOMP64m : FPI<0xDC, MRM3m, (outs), (ins f64mem:$src), "fcomp{l}\t$src">;
 340
 341 def FRSTORm  : FPI<0xDD, MRM4m, (outs f32mem:$dst), (ins), "frstor\t$dst">;
 342 def FSAVEm   : FPI<0xDD, MRM6m, (outs f32mem:$dst), (ins), "fnsave\t$dst">;
 343 def FNSTSWm  : FPI<0xDD, MRM7m, (outs f32mem:$dst), (ins), "fnstsw\t$dst">;
 344
 345 def FICOM16m : FPI<0xDE, MRM2m, (outs), (ins i16mem:$src), "ficom{s}\t$src">;
 346 def FICOMP16m: FPI<0xDE, MRM3m, (outs), (ins i16mem:$src), "ficomp{s}\t$src">;
 347
 348 def FBLDm    : FPI<0xDF, MRM4m, (outs), (ins f32mem:$src), "fbld\t$src">;
 349 def FBSTPm   : FPI<0xDF, MRM6m, (outs f32mem:$dst), (ins), "fbstp\t$dst">;
 350
 351 // Floating point cmovs.
 352 class FpIf32CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 353   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32, HasCMov]>;
 354 class FpIf64CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 355   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64, HasCMov]>;
 356
 357 multiclass FPCMov<PatLeaf cc> {
 358   def _Fp32  : FpIf32CMov<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 359                        CondMovFP,
 360                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 361                                         cc, EFLAGS))]>;
 362   def _Fp64  : FpIf64CMov<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 363                        CondMovFP,
 364                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 365                                         cc, EFLAGS))]>;
 366   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 367                      CondMovFP,
 368                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 369                                         cc, EFLAGS))]>,
 370                                         Requires<[HasCMov]>;
 371 }
 372
 373 let Uses = [EFLAGS], Constraints = "$src1 = $dst" in {
 374 defm CMOVB  : FPCMov<X86_COND_B>;
 375 defm CMOVBE : FPCMov<X86_COND_BE>;
 376 defm CMOVE  : FPCMov<X86_COND_E>;
 377 defm CMOVP  : FPCMov<X86_COND_P>;
 378 defm CMOVNB : FPCMov<X86_COND_AE>;
 379 defm CMOVNBE: FPCMov<X86_COND_A>;
 380 defm CMOVNE : FPCMov<X86_COND_NE>;
 381 defm CMOVNP : FPCMov<X86_COND_NP>;
 382 } // Uses = [EFLAGS], Constraints = "$src1 = $dst"
 383
 384 let Predicates = [HasCMov] in {
 385 // These are not factored because there's no clean way to pass DA/DB.
 386 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 387                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 388 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 389                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 390 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 391                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 392 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 393                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 394 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 395                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 396 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 397                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 398 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 399                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 400 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 401                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 402 } // Predicates = [HasCMov]
 403
 404 // Floating point loads & stores.
 405 let canFoldAsLoad = 1 in {
 406 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 407                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 408 let isReMaterializable = 1 in
 409   def LD_Fp64m : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 410                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 411 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 412                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 413 }
 414 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 415                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 416 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 417                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 418 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 419                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 420 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 421                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 422 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 423                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 424 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 425                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 426 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 427                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 428 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 429                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 430 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 431                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 432 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 433                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 434 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 435                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 436 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 437                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 438
 439 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 440                   [(store RFP32:$src, addr:$op)]>;
 441 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 442                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 443 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 444                   [(store RFP64:$src, addr:$op)]>;
 445 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 446                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 447 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 448                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 449 // FST does not support 80-bit memory target; FSTP must be used.
 450
 451 let mayStore = 1, neverHasSideEffects = 1 in {
 452 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 453 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 454 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 455 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 456 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 457 }
 458 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 459                     [(store RFP80:$src, addr:$op)]>;
 460 let mayStore = 1, neverHasSideEffects = 1 in {
 461 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 462 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 463 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 464 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 465 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 466 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 467 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 468 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 469 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 470 }
 471
 472 let mayLoad = 1 in {
 473 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 474 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 475 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 476 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 477 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 478 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 479 }
 480 let mayStore = 1 in {
 481 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 482 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 483 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 484 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 485 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 486 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 487 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 488 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 489 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 490 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 491 }
 492
 493 // FISTTP requires SSE3 even though it's a FPStack op.
 494 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 495                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 496                     Requires<[HasSSE3]>;
 497 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 498                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 499                     Requires<[HasSSE3]>;
 500 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 501                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 502                     Requires<[HasSSE3]>;
 503 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 504                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 505                     Requires<[HasSSE3]>;
 506 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 507                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 508                     Requires<[HasSSE3]>;
 509 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 510                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 511                     Requires<[HasSSE3]>;
 512 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 513                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 514                     Requires<[HasSSE3]>;
 515 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 516                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 517                     Requires<[HasSSE3]>;
 518 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 519                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 520                     Requires<[HasSSE3]>;
 521
 522 let mayStore = 1 in {
 523 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 524 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 525 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst),
 526   "fisttp{ll}\t$dst">;
 527 }
 528
 529 // FP Stack manipulation instructions.
 530 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 531 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 532 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 533 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 534
 535 // Floating point constant loads.
 536 let isReMaterializable = 1 in {
 537 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 538                 [(set RFP32:$dst, fpimm0)]>;
 539 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 540                 [(set RFP32:$dst, fpimm1)]>;
 541 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 542                 [(set RFP64:$dst, fpimm0)]>;
 543 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 544                 [(set RFP64:$dst, fpimm1)]>;
 545 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 546                 [(set RFP80:$dst, fpimm0)]>;
 547 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 548                 [(set RFP80:$dst, fpimm1)]>;
 549 }
 550
 551 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 552 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 553
 554
 555 // Floating point compares.
 556 let Defs = [EFLAGS] in {
 557 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 558                         []>;  // FPSW = cmp ST(0) with ST(i)
 559 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 560                         []>;  // FPSW = cmp ST(0) with ST(i)
 561 def UCOM_Fpr80 : FpI_  <(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 562                         []>;  // FPSW = cmp ST(0) with ST(i)
 563
 564 // CC = ST(0) cmp ST(i)
 565 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 566                   [(set EFLAGS, (X86cmp RFP32:$lhs, RFP32:$rhs))]>;
 567 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 568                   [(set EFLAGS, (X86cmp RFP64:$lhs, RFP64:$rhs))]>;
 569 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 570                   [(set EFLAGS, (X86cmp RFP80:$lhs, RFP80:$rhs))]>;
 571 }
 572
 573 let Defs = [EFLAGS], Uses = [ST0] in {
 574 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 575                     (outs), (ins RST:$reg),
 576                     "fucom\t$reg">, DD;
 577 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 578                     (outs), (ins RST:$reg),
 579                     "fucomp\t$reg">, DD;
 580 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 581                     (outs), (ins),
 582                     "fucompp">, DA;
 583
 584 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 585                     (outs), (ins RST:$reg),
 586                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 587 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 588                     (outs), (ins RST:$reg),
 589                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 590 }
 591
 592 def COM_FIr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 593                   "fcomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 594 def COM_FIPr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 595                    "fcomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 596
 597 // Floating point flag ops.
 598 let Defs = [AX] in
 599 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 600                   (outs), (ins), "fnstsw %ax", []>, DF;
 601
 602 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 603                   (outs), (ins i16mem:$dst), "fnstcw\t$dst",
 604                   [(X86fp_cwd_get16 addr:$dst)]>;
 605
 606 let mayLoad = 1 in
 607 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 608                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 609
 610 // FPU control instructions
 611 def FNINIT : I<0xE3, RawFrm, (outs), (ins), "fninit", []>, DB;
 612 def FFREE : FPI<0xC0, AddRegFrm, (outs), (ins RST:$reg),
 613                 "ffree\t$reg">, DD;
 614
 615 // Clear exceptions
 616
 617 def FNCLEX : I<0xE2, RawFrm, (outs), (ins), "fnclex", []>, DB;
 618
 619 // Operandless floating-point instructions for the disassembler.
 620 def WAIT : I<0x9B, RawFrm, (outs), (ins), "wait", []>;
 621
 622 def FNOP : I<0xD0, RawFrm, (outs), (ins), "fnop", []>, D9;
 623 def FXAM : I<0xE5, RawFrm, (outs), (ins), "fxam", []>, D9;
 624 def FLDL2T : I<0xE9, RawFrm, (outs), (ins), "fldl2t", []>, D9;
 625 def FLDL2E : I<0xEA, RawFrm, (outs), (ins), "fldl2e", []>, D9;
 626 def FLDPI : I<0xEB, RawFrm, (outs), (ins), "fldpi", []>, D9;
 627 def FLDLG2 : I<0xEC, RawFrm, (outs), (ins), "fldlg2", []>, D9;
 628 def FLDLN2 : I<0xED, RawFrm, (outs), (ins), "fldln2", []>, D9;
 629 def F2XM1 : I<0xF0, RawFrm, (outs), (ins), "f2xm1", []>, D9;
 630 def FYL2X : I<0xF1, RawFrm, (outs), (ins), "fyl2x", []>, D9;
 631 def FPTAN : I<0xF2, RawFrm, (outs), (ins), "fptan", []>, D9;
 632 def FPATAN : I<0xF3, RawFrm, (outs), (ins), "fpatan", []>, D9;
 633 def FXTRACT : I<0xF4, RawFrm, (outs), (ins), "fxtract", []>, D9;
 634 def FPREM1 : I<0xF5, RawFrm, (outs), (ins), "fprem1", []>, D9;
 635 def FDECSTP : I<0xF6, RawFrm, (outs), (ins), "fdecstp", []>, D9;
 636 def FINCSTP : I<0xF7, RawFrm, (outs), (ins), "fincstp", []>, D9;
 637 def FPREM : I<0xF8, RawFrm, (outs), (ins), "fprem", []>, D9;
 638 def FYL2XP1 : I<0xF9, RawFrm, (outs), (ins), "fyl2xp1", []>, D9;
 639 def FSINCOS : I<0xFB, RawFrm, (outs), (ins), "fsincos", []>, D9;
 640 def FRNDINT : I<0xFC, RawFrm, (outs), (ins), "frndint", []>, D9;
 641 def FSCALE : I<0xFD, RawFrm, (outs), (ins), "fscale", []>, D9;
 642 def FCOMPP : I<0xD9, RawFrm, (outs), (ins), "fcompp", []>, DE;
 643
 644 def FXSAVE : I<0xAE, MRM0m, (outs opaque512mem:$dst), (ins),
 645                "fxsave\t$dst", []>, TB;
 646 def FXRSTOR : I<0xAE, MRM1m, (outs), (ins opaque512mem:$src),
 647                 "fxrstor\t$src", []>, TB;
 648
 649 //===----------------------------------------------------------------------===//
 650 // Non-Instruction Patterns
 651 //===----------------------------------------------------------------------===//
 652
 653 // Required for RET of f32 / f64 / f80 values.
 654 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 655 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 656 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 657
 658 // Required for CALL which return f32 / f64 / f80 values.
 659 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 660 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op,
 661                                                           RFP64:$src)>;
 662 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 663 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op,
 664                                                           RFP80:$src)>;
 665 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op,
 666                                                           RFP80:$src)>;
 667 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op,
 668                                                          RFP80:$src)>;
 669
 670 // Floating point constant -0.0 and -1.0
 671 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 672 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 673 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 674 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 675 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 676 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 677
 678 // Used to conv. i64 to f64 since there isn't a SSE version.
 679 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 680
 681 // FP extensions map onto simple pseudo-value conversions if they are to/from
 682 // the FP stack.
 683 def : Pat<(f64 (fextend RFP32:$src)), (COPY_TO_REGCLASS RFP32:$src, RFP64)>,
 684           Requires<[FPStackf32]>;
 685 def : Pat<(f80 (fextend RFP32:$src)), (COPY_TO_REGCLASS RFP32:$src, RFP80)>,
 686            Requires<[FPStackf32]>;
 687 def : Pat<(f80 (fextend RFP64:$src)), (COPY_TO_REGCLASS RFP64:$src, RFP80)>,
 688            Requires<[FPStackf64]>;
 689
 690 // FP truncations map onto simple pseudo-value conversions if they are to/from
 691 // the FP stack.  We have validated that only value-preserving truncations make
 692 // it through isel.
 693 def : Pat<(f32 (fround RFP64:$src)), (COPY_TO_REGCLASS RFP64:$src, RFP32)>,
 694           Requires<[FPStackf32]>;
 695 def : Pat<(f32 (fround RFP80:$src)), (COPY_TO_REGCLASS RFP80:$src, RFP32)>,
 696            Requires<[FPStackf32]>;
 697 def : Pat<(f64 (fround RFP80:$src)), (COPY_TO_REGCLASS RFP80:$src, RFP64)>,
 698            Requires<[FPStackf64]>;