cmake/modules/LLVMConfig.cmake

   1 function(get_system_libs return_var)
   2   # Returns in `return_var' a list of system libraries used by LLVM.
   3   if( NOT MSVC )
   4     if( MINGW )
   5       set(system_libs ${system_libs} imagehlp psapi)
   6     elseif( CMAKE_HOST_UNIX )
   7       if( HAVE_LIBDL )
   8         set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
   9       endif()
  10       if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  11         set(system_libs ${system_libs} pthread)
  12       endif()
  13     endif( MINGW )
  14   endif( NOT MSVC )
  15   set(${return_var} ${system_libs} PARENT_SCOPE)
  16 endfunction(get_system_libs)
  17
  18
  19 function(is_llvm_target_library library return_var)
  20   # Sets variable `return_var' to ON if `library' corresponds to a
  21   # LLVM supported target. To OFF if it doesn't.
  22   set(${return_var} OFF PARENT_SCOPE)
  23   string(TOUPPER "${library}" capitalized_lib)
  24   string(TOUPPER "${LLVM_ALL_TARGETS}" targets)
  25   foreach(t ${targets})
  26     if( capitalized_lib STREQUAL "LLVM${t}" OR
  27         capitalized_lib STREQUAL "LLVM${t}CODEGEN" OR
  28         capitalized_lib STREQUAL "LLVM${t}ASMPARSER" OR
  29         capitalized_lib STREQUAL "LLVM${t}ASMPRINTER" OR
  30         capitalized_lib STREQUAL "LLVM${t}DISASSEMBLER" OR
  31         capitalized_lib STREQUAL "LLVM${t}INFO" )
  32       set(${return_var} ON PARENT_SCOPE)
  33       break()
  34     endif()
  35   endforeach()
  36 endfunction(is_llvm_target_library)
  37
  38
  39 macro(llvm_config executable)
  40   explicit_llvm_config(${executable} ${ARGN})
  41 endmacro(llvm_config)
  42
  43
  44 function(explicit_llvm_config executable)
  45   set( link_components ${ARGN} )
  46
  47   explicit_map_components_to_libraries(LIBRARIES ${link_components})
  48   target_link_libraries(${executable} ${LIBRARIES})
  49 endfunction(explicit_llvm_config)
  50
  51
  52 # This is a variant intended for the final user:
  53 function(llvm_map_components_to_libraries OUT_VAR)
  54   explicit_map_components_to_libraries(result ${ARGN})
  55   get_system_libs(sys_result)
  56   set( ${OUT_VAR} ${result} ${sys_result} PARENT_SCOPE )
  57 endfunction(llvm_map_components_to_libraries)
  58
  59
  60 function(explicit_map_components_to_libraries out_libs)
  61   set( link_components ${ARGN} )
  62   string(TOUPPER "${llvm_libs}" capitalized_libs)
  63   # Translate symbolic component names to real libraries:
  64   foreach(c ${link_components})
  65     # add codegen, asmprinter, asmparser, disassembler
  66     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  67     if( NOT idx LESS 0 )
  68       list(FIND llvm_libs "LLVM${c}CodeGen" idx)
  69       if( NOT idx LESS 0 )
  70         list(APPEND expanded_components "LLVM${c}CodeGen")
  71       else()
  72         list(FIND llvm_libs "LLVM${c}" idx)
  73         if( NOT idx LESS 0 )
  74           list(APPEND expanded_components "LLVM${c}")
  75         else()
  76           message(FATAL_ERROR "Target ${c} is not in the set of libraries.")
  77         endif()
  78       endif()
  79       list(FIND llvm_libs "LLVM${c}AsmPrinter" asmidx)
  80       if( NOT asmidx LESS 0 )
  81         list(APPEND expanded_components "LLVM${c}AsmPrinter")
  82       endif()
  83       list(FIND llvm_libs "LLVM${c}AsmParser" asmidx)
  84       if( NOT asmidx LESS 0 )
  85         list(APPEND expanded_components "LLVM${c}AsmParser")
  86       endif()
  87       list(FIND llvm_libs "LLVM${c}Info" asmidx)
  88       if( NOT asmidx LESS 0 )
  89         list(APPEND expanded_components "LLVM${c}Info")
  90       endif()
  91       list(FIND llvm_libs "LLVM${c}Disassembler" asmidx)
  92       if( NOT asmidx LESS 0 )
  93         list(APPEND expanded_components "LLVM${c}Disassembler")
  94       endif()
  95     elseif( c STREQUAL "native" )
  96       list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}CodeGen")
  97     elseif( c STREQUAL "nativecodegen" )
  98       list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}CodeGen")
  99     elseif( c STREQUAL "backend" )
 100       # same case as in `native'.
 101     elseif( c STREQUAL "engine" )
 102       # TODO: as we assume we are on X86, this is `jit'.
 103       list(APPEND expanded_components "LLVMJIT")
 104     elseif( c STREQUAL "all" )
 105       list(APPEND expanded_components ${llvm_libs})
 106     else( NOT idx LESS 0 )
 107       # Canonize the component name:
 108       string(TOUPPER "${c}" capitalized)
 109       list(FIND capitalized_libs LLVM${capitalized} lib_idx)
 110       if( lib_idx LESS 0 )
 111         # The component is unkown. Maybe is an ommitted target?
 112         is_llvm_target_library(${c} iltl_result)
 113         if( NOT iltl_result )
 114           message(FATAL_ERROR "Library `${c}' not found in list of llvm libraries.")
 115         endif()
 116       else( lib_idx LESS 0 )
 117         list(GET llvm_libs ${lib_idx} canonical_lib)
 118         list(APPEND expanded_components ${canonical_lib})
 119       endif( lib_idx LESS 0 )
 120     endif( NOT idx LESS 0 )
 121   endforeach(c)
 122   # Expand dependencies while topologically sorting the list of libraries:
 123   list(LENGTH expanded_components lst_size)
 124   set(cursor 0)
 125   set(processed)
 126   while( cursor LESS lst_size )
 127     list(GET expanded_components ${cursor} lib)
 128     list(APPEND expanded_components ${MSVC_LIB_DEPS_${lib}})
 129     # Remove duplicates at the front:
 130     list(REVERSE expanded_components)
 131     list(REMOVE_DUPLICATES expanded_components)
 132     list(REVERSE expanded_components)
 133     list(APPEND processed ${lib})
 134     # Find the maximum index that doesn't have to be re-processed:
 135     while(NOT "${expanded_components}" MATCHES "^${processed}.*" )
 136       list(REMOVE_AT processed -1)
 137     endwhile()
 138     list(LENGTH processed cursor)
 139     list(LENGTH expanded_components lst_size)
 140   endwhile( cursor LESS lst_size )
 141   # Return just the libraries included in this build:
 142   set(result)
 143   foreach(c ${expanded_components})
 144     list(FIND llvm_libs ${c} lib_idx)
 145     if( NOT lib_idx LESS 0 )
 146       set(result ${result} ${c})
 147     endif()
 148   endforeach(c)
 149   set(${out_libs} ${result} PARENT_SCOPE)
 150 endfunction(explicit_map_components_to_libraries)
 151
 152
 153 # The library dependency data is contained in the file
 154 # LLVMLibDeps.cmake on this directory. It is automatically generated
 155 # by tools/llvm-config/CMakeLists.txt when the build comprises all the
 156 # targets and we are on a environment Posix enough to build the
 157 # llvm-config script. This, in practice, just excludes MSVC.
 158
 159 # When you remove or rename a library from the build, be sure to
 160 # remove its file from lib/ as well, or the GenLibDeps.pl script will
 161 # include it on its analysis!
 162
 163 # The format generated by GenLibDeps.pl
 164
 165 # LLVMARMAsmPrinter.o: LLVMARMCodeGen.o libLLVMAsmPrinter.a libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMTarget.a
 166
 167 # is translated to:
 168
 169 # set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 170
 171 # It is necessary to remove the `lib' prefix and the `.a'.
 172
 173 # This 'sed' script should do the trick:
 174 # sed -e s'#\.a##g' -e 's#libLLVM#LLVM#g' -e 's#: # #' -e 's#\(.*\)#set(MSVC_LIB_DEPS_\1)#' ~/llvm/tools/llvm-config/LibDeps.txt
 175
 176 include(LLVMLibDeps)