cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVMConfig)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set( llvm_libs ${llvm_libs} ${name} PARENT_SCOPE)
   8   set( llvm_lib_targets ${llvm_lib_targets} ${name} PARENT_SCOPE )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     get_system_libs(sl)
  15     target_link_libraries( ${name} ${sl} )
  16   endif()
  17
  18   install(TARGETS ${name}
  19     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  20     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  21   # The LLVM Target library shall be built before its sublibraries
  22   # (asmprinter, etc) because those may use tablegenned files which
  23   # generation is triggered by the main LLVM target library. Necessary
  24   # for parallel builds:
  25   if( CURRENT_LLVM_TARGET )
  26     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  27   endif()
  28 endmacro(add_llvm_library name)
  29
  30
  31 macro(add_llvm_loadable_module name)
  32   if( NOT LLVM_ON_UNIX OR CYGWIN )
  33     message(STATUS "Loadable modules not supported on this platform.
  34 ${name} ignored.")
  35   else()
  36     llvm_process_sources( ALL_FILES ${ARGN} )
  37     add_library( ${name} MODULE ${ALL_FILES} )
  38     set_target_properties( ${name} PROPERTIES PREFIX "" )
  39
  40     if (APPLE)
  41       # Darwin-specific linker flags for loadable modules.
  42       set_target_properties(${name} PROPERTIES
  43         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  44     endif()
  45
  46     install(TARGETS ${name}
  47       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  48       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  49   endif()
  50 endmacro(add_llvm_loadable_module name)
  51
  52
  53 macro(add_llvm_executable name)
  54   llvm_process_sources( ALL_FILES ${ARGN} )
  55   if( EXCLUDE_FROM_ALL )
  56     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  57   else()
  58     add_executable(${name} ${ALL_FILES})
  59   endif()
  60   set(EXCLUDE_FROM_ALL OFF)
  61   if( LLVM_USED_LIBS )
  62     foreach(lib ${LLVM_USED_LIBS})
  63       target_link_libraries( ${name} ${lib} )
  64     endforeach(lib)
  65   endif( LLVM_USED_LIBS )
  66   if( LLVM_LINK_COMPONENTS )
  67     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
  68   endif( LLVM_LINK_COMPONENTS )
  69   if( LLVM_COMMON_DEPENDS )
  70     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  71   endif( LLVM_COMMON_DEPENDS )
  72   if( NOT MINGW )
  73     get_system_libs(llvm_system_libs)
  74     if( llvm_system_libs )
  75       target_link_libraries(${name} ${llvm_system_libs})
  76     endif()
  77   endif()
  78 endmacro(add_llvm_executable name)
  79
  80
  81 macro(add_llvm_tool name)
  82   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  83   if( NOT LLVM_BUILD_TOOLS )
  84     set(EXCLUDE_FROM_ALL ON)
  85   endif()
  86   add_llvm_executable(${name} ${ARGN})
  87   if( LLVM_BUILD_TOOLS )
  88     install(TARGETS ${name} RUNTIME DESTINATION bin)
  89   endif()
  90 endmacro(add_llvm_tool name)
  91
  92
  93 macro(add_llvm_example name)
  94 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
  95   if( NOT LLVM_BUILD_EXAMPLES )
  96     set(EXCLUDE_FROM_ALL ON)
  97   endif()
  98   add_llvm_executable(${name} ${ARGN})
  99   if( LLVM_BUILD_EXAMPLES )
 100     install(TARGETS ${name} RUNTIME DESTINATION examples)
 101   endif()
 102 endmacro(add_llvm_example name)
 103
 104
 105 macro(add_llvm_target target_name)
 106   if( TABLEGEN_OUTPUT )
 107     add_custom_target(${target_name}Table_gen
 108       DEPENDS ${TABLEGEN_OUTPUT})
 109     add_dependencies(${target_name}Table_gen ${LLVM_COMMON_DEPENDS})
 110   endif( TABLEGEN_OUTPUT )
 111   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 112   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 113   if ( TABLEGEN_OUTPUT )
 114     add_dependencies(LLVM${target_name} ${target_name}Table_gen)
 115   endif (TABLEGEN_OUTPUT)
 116   set(CURRENT_LLVM_TARGET LLVM${target_name} PARENT_SCOPE)
 117 endmacro(add_llvm_target)