src/main/javacc/ESFParser.jj

   1 options {
   2   DEBUG_PARSER=false;
   3   DEBUG_LOOKAHEAD=false;
   4   DEBUG_TOKEN_MANAGER=false;
   5   STATIC=false;
   6 }
   7
   8 PARSER_BEGIN(ESFParser)
   9
  10 package org.lwes.db;
  11
  12 import org.lwes.util.Log;
  13
  14 public class ESFParser
  15 {
  16   private String currentEvent;
  17   private EventTemplateDB eventTemplateDB;
  18
  19   public void setEventTemplateDB(EventTemplateDB DB)
  20     { eventTemplateDB = DB; }
  21
  22   public EventTemplateDB getEventTemplateDB()
  23     { return eventTemplateDB; }
  24
  25   public void setCurrentEvent(String evt)
  26     { currentEvent = evt; }
  27
  28   public String getCurrentEvent()
  29     { return currentEvent; }
  30 }
  31
  32 PARSER_END(ESFParser)
  33
  34 SKIP :
  35 {
  36   " "
  37 | "\t"
  38 | "\n"
  39 | "\r"
  40 | "#" : IN_LINE_COMMENT
  41 }
  42
  43 <IN_LINE_COMMENT> SKIP:
  44 {
  45    "\n" : DEFAULT
  46 |  "\r" : DEFAULT
  47 |  "\r\n" : DEFAULT
  48 }
  49
  50 <IN_LINE_COMMENT> MORE:
  51 {
  52   < ~[] >
  53 }
  54
  55
  56 TOKEN :
  57 {
  58     < ID: ["a"-"z","A"-"Z","_",":","0"-"9"] (["a"-"z","A"-"Z","_",":","0"-"9"])* >
  59   | < LBRACKET: "[" >
  60   | < RBRACKET: "]" >
  61 }
  62
  63 /**
  64  * A list of events
  65  */
  66 void eventlist() :
  67 {
  68 }
  69 {
  70   event() ( event() )* <EOF>
  71 }
  72
  73 /**
  74  * a single event
  75  */
  76 void event() :
  77 {
  78 }
  79 {
  80   eventName() "{" [ attributeList() ] "}"
  81 }
  82
  83 /**
  84  * The name of an event, should be max 256 chars ([a-zA-Z0-9_]*)
  85  */
  86 void eventName() :
  87 {
  88   Token t;
  89 }
  90 {
  91   t=<ID>
  92   {
  93     if ( getEventTemplateDB().addEvent(t.image))
  94     {
  95       setCurrentEvent(t.image);
  96     }
  97     else
  98     {
  99       throw new ParseException("Problem adding event "+t.image);
 100     }
 101   }
 102 }
 103
 104 void attributeList() :
 105 {}
 106 {
 107   attribute() ( attribute() )*
 108 }
 109
 110 int arraySize() :
 111 {
 112   Token t;
 113 }
 114 {
 115     t = <ID>
 116     {
 117     return Integer.parseInt(t.image);
 118     }
 119 }
 120
 121 void attribute() :
 122 {
 123   String aType;
 124   String anAttribute;
 125   int anArraySize = 0;
 126 }
 127 {
 128   aType=type() anAttribute=attributeName() [ "[" anArraySize = arraySize() "]" ] ";" {
 129       if ( !( aType.equals("uint16")  ||
 130               aType.equals("int16")   ||
 131               aType.equals("uint32")  ||
 132               aType.equals("int32")   ||
 133               aType.equals("string")  ||
 134               aType.equals("ip_addr") ||
 135               aType.equals("int64")   ||
 136               aType.equals("uint64")  ||
 137               aType.equals("byte")    ||
 138               aType.equals("boolean")
 139             )
 140          )
 141        {
 142          throw new ParseException("No such type '"+aType+"'");
 143        }
 144
 145       String evt = getCurrentEvent();
 146       if ( evt == null ) throw new ParseException("Bad Event");
 147
 148       if (anArraySize > 0) {
 149          if (Log.isLogTrace()) {
 150            Log.trace("ARRAY! type: "+aType+" attr: "+anAttribute+" size: "+anArraySize);
 151          }
 152          aType = "[L"+aType;
 153        }
 154
 155       if ( !getEventTemplateDB().addEventAttribute(evt, anAttribute, aType, anArraySize))
 156       {
 157         throw new ParseException("Problem adding attribute "+evt+"("
 158                                  +aType+","+anAttribute+")");
 159       }
 160    }
 161 }
 162
 163 String type() :
 164 {
 165   Token t;
 166 }
 167 {
 168   t=<ID>
 169   {
 170     return t.image;
 171   }
 172 }
 173
 174 String attributeName() :
 175 {
 176   Token t;
 177 }
 178 {
 179   t=<ID>
 180   {
 181     return t.image;
 182   }
 183 }