src/main/javacc/ESFParser.jj

   1 /*======================================================================*
   2  * Copyright (c) 2008, Yahoo! Inc. All rights reserved.                 *
   3  *                                                                      *
   4  * Licensed under the New BSD License (the "License"); you may not use  *
   5  * this file except in compliance with the License.  Unless required    *
   6  * by applicable law or agreed to in writing, software distributed      *
   7  * under the License is distributed on an "AS IS" BASIS, WITHOUT        *
   8  * WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.     *
   9  * See the License for the specific language governing permissions and  *
  10  * limitations under the License. See accompanying LICENSE file.        *
  11  *======================================================================*/
  12
  13 options {
  14   DEBUG_PARSER=false;
  15   DEBUG_LOOKAHEAD=false;
  16   DEBUG_TOKEN_MANAGER=false;
  17   STATIC=false;
  18 }
  19
  20 PARSER_BEGIN(ESFParser)
  21
  22 package org.lwes.db;
  23
  24 import org.apache.commons.logging.Log;
  25 import org.apache.commons.logging.LogFactory;
  26
  27 public class ESFParser
  28 {
  29
  30     private static transient Log log = LogFactory.getLog(ESFParser.class);
  31
  32   private String currentEvent;
  33   private EventTemplateDB eventTemplateDB;
  34
  35   public void setEventTemplateDB(EventTemplateDB DB)
  36     { eventTemplateDB = DB; }
  37
  38   public EventTemplateDB getEventTemplateDB()
  39     { return eventTemplateDB; }
  40
  41   public void setCurrentEvent(String evt)
  42     { currentEvent = evt; }
  43
  44   public String getCurrentEvent()
  45     { return currentEvent; }
  46
  47   public String removeQuotes(String str) {
  48     return str.replace("\"","");
  49   }
  50 }
  51
  52 PARSER_END(ESFParser)
  53
  54 SKIP :
  55 {
  56   " "
  57 | "\t"
  58 | "\n"
  59 | "\r"
  60 | "#" : IN_LINE_COMMENT
  61 }
  62
  63 <IN_LINE_COMMENT> SKIP:
  64 {
  65    "\n" : DEFAULT
  66 |  "\r" : DEFAULT
  67 |  "\r\n" : DEFAULT
  68 }
  69
  70 <IN_LINE_COMMENT> MORE:
  71 {
  72   < ~[] >
  73 }
  74
  75
  76 TOKEN :
  77 {
  78     < REQ: "required" >
  79   | < OPT: "optional" >
  80   | < TRUE: "true" >
  81   | < FALSE: "false" >
  82   | < LBRACKET: "[" >
  83   | < RBRACKET: "]" >
  84   | < INTEGER_LITERAL: ["1"-"9"] (["0"-"9"])* >
  85   | < STRING_LITERAL: "\""(<ID>)"\"" >
  86   | < DOUBLE_LITERAL: (["0"-"9"])+ "." (["0"-"9"])* >
  87   | < ID: ["a"-"z","A"-"Z","_",":","0"-"9","."] (["a"-"z","A"-"Z","_",":","0"-"9","."])* >
  88
  89 }
  90
  91 /**
  92  * A list of events
  93  */
  94 void eventlist() :
  95 {
  96 }
  97 {
  98   event() ( event() )* <EOF>
  99 }
 100
 101 /**
 102  * a single event
 103  */
 104 void event() :
 105 {
 106 }
 107 {
 108   eventName() "{" [ attributeList() ] "}"
 109 }
 110
 111 /**
 112  * The name of an event, should be max 256 chars ([a-zA-Z0-9_]*)
 113  */
 114 void eventName() :
 115 {
 116   Token t;
 117 }
 118 {
 119   t=<ID>
 120   {
 121     if ( getEventTemplateDB().addEvent(t.image))
 122     {
 123       setCurrentEvent(t.image);
 124     }
 125     else
 126     {
 127       throw new ParseException("Problem adding event "+t.image);
 128     }
 129   }
 130 }
 131
 132 void attributeList() :
 133 {}
 134 {
 135   attribute() ( attribute() )*
 136 }
 137
 138 String stringLiteral() :
 139 {
 140     Token t;
 141 }
 142 {
 143     t = <STRING_LITERAL>
 144     {
 145        return removeQuotes(t.image);
 146     }
 147 }
 148
 149 boolean booleanLiteral() :
 150 {}
 151 {
 152   <TRUE>
 153   {
 154     return true;
 155   }
 156   |
 157   <FALSE>
 158   {
 159     return false;
 160   }
 161 }
 162
 163 int integerLiteral() :
 164 {
 165     Token t;
 166 }
 167 {
 168   t = <INTEGER_LITERAL>
 169   {
 170     try {
 171       return Integer.parseInt(t.image);
 172     } catch (NumberFormatException e) {
 173       throw new Error();
 174     }
 175   }
 176 }
 177
 178 double doubleLiteral() :
 179 {
 180     Token t;
 181 }
 182 {
 183     t = <DOUBLE_LITERAL>
 184     {
 185        try {
 186          return Double.parseDouble(t.image);
 187        } catch (NumberFormatException e) {
 188          throw new Error();
 189        }
 190     }
 191 }
 192
 193 Object defaultValue() :
 194 {
 195     Object obj;
 196 }
 197 {
 198     obj = integerLiteral()
 199     {
 200       return obj;
 201     }
 202     | obj = doubleLiteral()
 203     {
 204       return obj;
 205     }
 206     | obj = booleanLiteral()
 207     {
 208       return obj;
 209     }
 210     | obj = stringLiteral()
 211     {
 212       return obj;
 213     }
 214 }
 215
 216 boolean required() :
 217 {
 218 }
 219 {
 220     <REQ>
 221     {
 222       return true;
 223     }
 224     | <OPT>
 225     {
 226       return false;
 227     }
 228 }
 229
 230 void attribute() :
 231 {
 232   String aType;
 233   String anAttribute;
 234   int anArraySize = 0;
 235   boolean required = false;
 236   Object aDefaultValue = null;
 237 }
 238 {
 239   (((required = required()) (aType=type() anAttribute=attributeName() [ "[" anArraySize = integerLiteral() "]" ] [ "=" aDefaultValue = defaultValue() ] ";"))
 240 |
 241   (aType=type() anAttribute=attributeName() [ "[" anArraySize = integerLiteral() "]" ] [ "=" aDefaultValue = defaultValue() ] ";")  ) {
 242       if ( !( aType.equals("uint16")  ||
 243               aType.equals("int16")   ||
 244               aType.equals("uint32")  ||
 245               aType.equals("int32")   ||
 246               aType.equals("string")  ||
 247               aType.equals("ip_addr") ||
 248               aType.equals("int64")   ||
 249               aType.equals("uint64")  ||
 250               aType.equals("byte")    ||
 251               aType.equals("double")  ||
 252               aType.equals("float")   ||
 253               aType.equals("ipv4")    ||
 254               aType.equals("boolean")
 255             )
 256          )
 257        {
 258          throw new ParseException("No such type '"+aType+"'");
 259        }
 260
 261       String evt = getCurrentEvent();
 262       if ( evt == null ) throw new ParseException("Bad Event");
 263
 264       if (log.isTraceEnabled()) {
 265         log.trace("Type: "+aType+" attr: "+anAttribute+" size: "+anArraySize);
 266         log.trace("Required: "+required);
 267         log.trace("default value: "+aDefaultValue);
 268       }
 269
 270       if (anArraySize > 0) {
 271         aType = "[L"+aType;
 272       }
 273
 274       if ( !getEventTemplateDB().addEventAttribute(evt,
 275                                                    anAttribute,
 276                                                    aType,
 277                                                    anArraySize,
 278                                                    required,
 279                                                    aDefaultValue))
 280       {
 281         throw new ParseException("Problem adding attribute "+evt+"("
 282                                  +aType+","+anAttribute+")");
 283       }
 284    }
 285 }
 286
 287 String type() :
 288 {
 289   Token t;
 290 }
 291 {
 292   t=<ID>
 293   {
 294     return t.image;
 295   }
 296 }
 297
 298 String attributeName() :
 299 {
 300   Token t;
 301 }
 302 {
 303   t=<ID>
 304   {
 305     return t.image;
 306   }
 307 }