i386/linux-2.3.21/arch/sparc/vmlinux.lds

   1 /* ld script to make SparcLinux kernel */
   2 OUTPUT_FORMAT("elf32-sparc", "elf32-sparc", "elf32-sparc")
   3 OUTPUT_ARCH(sparc)
   4 ENTRY(_start)
   5 SECTIONS
   6 {
   7   . = 0x10000 + SIZEOF_HEADERS;
   8   .text 0xf0004000 :
   9   {
  10     *(.text)
  11     *(.gnu.warning)
  12   } =0
  13   _etext = .;
  14   PROVIDE (etext = .);
  15   .rodata    : { *(.rodata)  }
  16   .rodata1   : { *(.rodata1) }
  17   .data    :
  18   {
  19     *(.data)
  20     CONSTRUCTORS
  21   }
  22   .data1   : { *(.data1) }
  23   _edata  =  .;
  24   PROVIDE (edata = .);
  25   __start___fixup = .;
  26   .fixup   : { *(.fixup) }
  27   __stop___fixup = .;
  28   __start___ex_table = .;
  29   __ex_table : { *(__ex_table) }
  30   __stop___ex_table = .;
  31   __start___ksymtab = .;
  32   __ksymtab  : { *(__ksymtab) }
  33   __stop___ksymtab = .;
  34
  35   . = ALIGN(4096);
  36   __init_begin = .;
  37   .text.init : { *(.text.init) }
  38   __init_text_end = .;
  39   .data.init : { *(.data.init) }
  40   . = ALIGN(16);
  41   __setup_start = .;
  42   .setup_init : { *(.setup.init) }
  43   __setup_end = .;
  44   __initcall_start = .;
  45   .initcall.init : { *(.initcall.init) }
  46   __initcall_end = .;
  47   . = ALIGN(4096);
  48   __init_end = .;
  49   . = ALIGN(32);
  50   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  51
  52   __bss_start = .;
  53   .sbss      : { *(.sbss) *(.scommon) }
  54   .bss       :
  55   {
  56    *(.dynbss)
  57    *(.bss)
  58    *(COMMON)
  59   }
  60   _end = . ;
  61   PROVIDE (end = .);
  62   /* Stabs debugging sections.  */
  63   .stab 0 : { *(.stab) }
  64   .stabstr 0 : { *(.stabstr) }
  65   .stab.excl 0 : { *(.stab.excl) }
  66   .stab.exclstr 0 : { *(.stab.exclstr) }
  67   .stab.index 0 : { *(.stab.index) }
  68   .stab.indexstr 0 : { *(.stab.indexstr) }
  69   .comment 0 : { *(.comment) }
  70   .debug          0 : { *(.debug) }
  71   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  72   .debug_aranges  0 : { *(.debug_aranges) }
  73   .debug_pubnames 0 : { *(.debug_pubnames) }
  74   .debug_sfnames  0 : { *(.debug_sfnames) }
  75   .line           0 : { *(.line) }
  76 }