i386/junos/ucla/src/lab4/kern/entry.S

   1 /* See COPYRIGHT for copyright information. */
   2
   3 #include <inc/mmu.h>
   4 #include <inc/memlayout.h>
   5 #include <inc/trap.h>
   6
   7 # Shift Right Logical
   8 #define SRL(val, shamt)         (((val) >> (shamt)) & ~(-1 << (32 - (shamt))))
   9
  10
  11 ###################################################################
  12 # The kernel (this code) is linked at address ~(KERNBASE + 1 Meg),
  13 # but the bootloader loads it at address ~1 Meg.
  14 #
  15 # RELOC(x) maps a symbol x from its link address to its actual
  16 # location in physical memory (its load address).
  17 ###################################################################
  18
  19 #define RELOC(x) ((x) - KERNBASE)
  20
  21
  22 .set CODE_SEL,0x8               # index of code seg within mygdt
  23 .set DATA_SEL,0x10              # index of data seg within mygdt
  24
  25 #define MULTIBOOT_PAGE_ALIGN  (1<<0)
  26 #define MULTIBOOT_MEMORY_INFO (1<<1)
  27 #define MULTIBOOT_HEADER_MAGIC (0x1BADB002)
  28 #define MULTIBOOT_HEADER_FLAGS (MULTIBOOT_MEMORY_INFO | MULTIBOOT_PAGE_ALIGN)
  29 #define CHECKSUM (-(MULTIBOOT_HEADER_MAGIC + MULTIBOOT_HEADER_FLAGS))
  30
  31 ###################################################################
  32 # entry point
  33 ###################################################################
  34
  35 .text
  36
  37 # The Multiboot header
  38 .align 4
  39 .long MULTIBOOT_HEADER_MAGIC
  40 .long MULTIBOOT_HEADER_FLAGS
  41 .long CHECKSUM
  42
  43 .globl          _start
  44 _start:
  45         movw    $0x1234,0x472                   # warm boot
  46
  47         # Establish our own GDT in place of the boot loader's temporary GDT.
  48         lgdt    RELOC(mygdtdesc)                # load descriptor table
  49
  50         # Immediately reload all segment registers (including CS!)
  51         # with segment selectors from the new GDT.
  52         movl    $DATA_SEL, %eax                 # Data segment selector
  53         movw    %ax,%ds                         # -> DS: Data Segment
  54         movw    %ax,%es                         # -> ES: Extra Segment
  55         movw    %ax,%ss                         # -> SS: Stack Segment
  56         ljmp    $CODE_SEL,$relocated            # reload CS by jumping
  57 relocated:
  58
  59         # Clear the frame pointer register (EBP)
  60         # so that once we get into debugging C code,
  61         # stack backtraces will be terminated properly.
  62         movl    $0x0,%ebp                       # nuke frame pointer
  63
  64         # Leave a few words on the stack for the user trap frame
  65         movl    $(bootstacktop-SIZEOF_STRUCT_TRAPFRAME),%esp
  66
  67         # now to C code
  68         call    i386_init
  69
  70         # Should never get here, but in case we do, just spin.
  71 spin:   jmp     spin
  72
  73
  74 ###################################################################
  75 # boot stack
  76 ###################################################################
  77 .data
  78         .p2align        PGSHIFT         # force page alignment
  79         .globl          bootstack
  80 bootstack:
  81         .space          KSTKSIZE
  82         .globl          bootstacktop
  83 bootstacktop:
  84
  85 ###################################################################
  86 # setup the GDT
  87 ###################################################################
  88         .p2align        2               # force 4 byte alignment
  89 mygdt:
  90         SEG_NULL                                # null seg
  91         SEG(STA_X|STA_R, -KERNBASE, 0xffffffff) # code seg
  92         SEG(STA_W, -KERNBASE, 0xffffffff)       # data seg
  93 mygdtdesc:
  94         .word   0x17                    # sizeof(mygdt) - 1
  95         .long   RELOC(mygdt)            # address mygdt
  96