i386/linux/linux-2.3.21/arch/alpha/vmlinux.lds

   1 OUTPUT_FORMAT("elf64-alpha")
   2 ENTRY(__start)
   3 SECTIONS
   4 {
   5   . = 0xfffffc0000310000;
   6   _text = .;
   7   .text : { *(.text) }
   8   .text2 : { *(.text2) }
   9   _etext = .;
  10
  11   /* Exception table */
  12   . = ALIGN(16);
  13   __start___ex_table = .;
  14   __ex_table : { *(__ex_table) }
  15   __stop___ex_table = .;
  16
  17   /* Kernel symbol table */
  18   . = ALIGN(8);
  19   __start___ksymtab = .;
  20   __ksymtab : { *(__ksymtab) }
  21   __stop___ksymtab = .;
  22   .kstrtab : { *(.kstrtab) }
  23
  24   /* Startup code */
  25   . = ALIGN(8192);
  26   __init_begin = .;
  27   .text.init : { *(.text.init) }
  28   .data.init : { *(.data.init) }
  29
  30   . = ALIGN(16);
  31   __setup_start = .;
  32   .setup.init : { *(.setup.init) }
  33   __setup_end = .;
  34
  35   . = ALIGN(8);
  36   __initcall_start = .;
  37   .initcall.init : { *(.initcall.init) }
  38   __initcall_end = .;
  39
  40   . = ALIGN(2*8192);    /* Align double page for init_task_union */
  41   __init_end = .;
  42
  43   /* The initial task and kernel stack */
  44   init_task : { *(init_task) }
  45
  46   /* Global data */
  47   _data = .;
  48   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  49   .rodata : { *(.rodata) }
  50   .data : { *(.data) CONSTRUCTORS }
  51   .got : { *(.got) }
  52   .sdata : { *(.sdata) }
  53   _edata = .;
  54   _bss = .;
  55   .sbss : { *(.sbss) *(.scommon) }
  56   .bss : { *(.bss) *(COMMON) }
  57   _end = .;
  58
  59   .mdebug 0 : { *(.mdebug) }
  60   .note 0 : { *(.note) }
  61   .comment 0 : { *(.comment) }
  62
  63   /* DWARF 1 */
  64   .debug          0 : { *(.debug) }
  65   .line           0 : { *(.line) }
  66   /* GNU DWARF 1 extensions */
  67   .debug_srcinfo  0 : { *(.debug_srcinfo) }
  68   .debug_sfnames  0 : { *(.debug_sfnames) }
  69   /* DWARF 1.1 and DWARF 2 */
  70   .debug_aranges  0 : { *(.debug_aranges) }
  71   .debug_pubnames 0 : { *(.debug_pubnames) }
  72   /* DWARF 2 */
  73   .debug_info     0 : { *(.debug_info) }
  74   .debug_abbrev   0 : { *(.debug_abbrev) }
  75   .debug_line     0 : { *(.debug_line) }
  76   .debug_frame    0 : { *(.debug_frame) }
  77   .debug_str      0 : { *(.debug_str) }
  78   .debug_loc      0 : { *(.debug_loc) }
  79   .debug_macinfo  0 : { *(.debug_macinfo) }
  80   /* SGI/MIPS DWARF 2 extensions */
  81   .debug_weaknames 0 : { *(.debug_weaknames) }
  82   .debug_funcnames 0 : { *(.debug_funcnames) }
  83   .debug_typenames 0 : { *(.debug_typenames) }
  84   .debug_varnames  0 : { *(.debug_varnames) }
  85 }