share/tensor/itensor8.dem

   1 /*
   2  * This program is free software; you can redistribute it and/or
   3  * modify it under the terms of the GNU General Public License as
   4  * published by the Free Software Foundation; either version 2 of
   5  * the License, or (at your option) any later version.
   6  *
   7  * This program is distributed in the hope that it will be
   8  * useful, but WITHOUT ANY WARRANTY; without even the implied
   9  * warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  10  * PURPOSE.  See the GNU General Public License for more details.
  11  *
  12  * Demonstrating ic_convert()
  13  */
  14 if get('itensor,'version)=false then load(itensor);
  15 if get('ctensor,'version)=false then load(ctensor);
  16 ("The RHS of the heat transport equation")$
  17 dim:3;
  18 remcomps(g);
  19 imetric(g);
  20 eqn:ishow(td = canform(rename(expand(covdiff(
  21      -k([],[])*covdiff(t([],[]),i),j)*g([],[i,j]))))+ source)$
  22
  23 ("Convert it to a CTENSOR program")$
  24 heat:ic_convert(eqn);
  25
  26 ("Next, write the equation in Cartesian coordinates:")$
  27 ct_coords:[x,y,z];
  28 lg:ident(3);
  29 ug:invert(lg);
  30 christof(mcs);
  31 depends([t,k],ct_coords);
  32 ev(heat);
  33
  34 ("Now get the equation in spherical coordinates.")$
  35 ct_coords:[r,th,ph];
  36 lg:matrix([1,0,0],[0,r^2,0],[0,0,r^2*sin(th)^2])$
  37 ug:invert(lg)$
  38 christof(all);
  39 remove([t,k],dependency);
  40 depends(t,ct_coords);
  41 ev(heat);
  42
  43 /* End of demo -- comment line needed by MAXIMA to resume demo menu */