doc/info/ja/Introduction.texi

   1 コマンド"maxima"でMaximaを起動してください。
   2 Maximaがバージョン情報とプロンプトを表示します。
   3 それぞれのMaximaコマンドにはセミコロンを終わりに付けてください。
   4 コマンド"quit();"でセッションが終了します。
   5 以下は、セッションのサンプルです。
   6
   7 @example
   8 [wfs@@chromium]$ maxima
   9 Maxima 5.9.1 http://maxima.sourceforge.net
  10 Using Lisp CMU Common Lisp 19a
  11 Distributed under the GNU Public License. See the file COPYING.
  12 Dedicated to the memory of William Schelter.
  13 This is a development version of Maxima. The function bug_report()
  14 provides bug reporting information.
  15 (%i1) factor(10!);
  16                             8  4  2
  17 (%o1)                      2  3  5  7
  18 (%i2) expand ((x + y)^6);
  19        6        5       2  4       3  3       4  2      5      6
  20 (%o2) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
  21 (%i3) factor (x^6 - 1);
  22                               2            2
  23 (%o3)       (x - 1) (x + 1) (x  - x + 1) (x  + x + 1)
  24 (%i4) quit();
  25 [wfs@@chromium]$
  26 @end example
  27
  28 Maximaはインフォページを検索できます。
  29 コマンドの情報や、文字列を含むコマンドや変数すべてを表示させるには、
  30 @mref{describe}コマンドを使ってください。
  31 クエスチョンマーク@mref{?} (完全一致検索)と
  32 二重クエスチョンマーク@mref{??}(部分一致検索)は@code{describe}の省略形です:
  33
  34 @example
  35 (%i1) ?? integ
  36  0: Functions and Variables for Elliptic Integrals
  37  1: Functions and Variables for Integration
  38  2: Introduction to Elliptic Functions and Integrals
  39  3: Introduction to Integration
  40  4: askinteger  (Functions and Variables for Simplification)
  41  5: integerp  (Functions and Variables for Miscellaneous Options)
  42  6: integer_partitions  (Functions and Variables for Sets)
  43  7: integrate  (Functions and Variables for Integration)
  44  8: integrate_use_rootsof  (Functions and Variables for Integration)
  45  9: integration_constant_counter  (Functions and Variables for
  46     Integration)
  47  10: nonnegintegerp  (Functions and Variables for linearalgebra)
  48 Enter space-separated numbers, `all' or `none': 5 4
  49
  50  -- Function: integerp (<expr>)
  51      Returns `true' if <expr> is a literal numeric integer, otherwise
  52      `false'.
  53
  54      `integerp' returns false if its argument is a symbol, even if the
  55      argument is declared integer.
  56
  57      Examples:
  58
  59           (%i1) integerp (0);
  60           (%o1)                         true
  61           (%i2) integerp (1);
  62           (%o2)                         true
  63           (%i3) integerp (-17);
  64           (%o3)                         true
  65           (%i4) integerp (0.0);
  66           (%o4)                         false
  67           (%i5) integerp (1.0);
  68           (%o5)                         false
  69           (%i6) integerp (%pi);
  70           (%o6)                         false
  71           (%i7) integerp (n);
  72           (%o7)                         false
  73           (%i8) declare (n, integer);
  74           (%o8)                         done
  75           (%i9) integerp (n);
  76           (%o9)                         false
  77
  78  -- Function: askinteger (<expr>, integer)
  79  -- Function: askinteger (<expr>)
  80  -- Function: askinteger (<expr>, even)
  81  -- Function: askinteger (<expr>, odd)
  82      `askinteger (<expr>, integer)' attempts to determine from the
  83      `assume' database whether <expr> is an integer.  `askinteger'
  84      prompts the user if it cannot tell otherwise, and attempt to
  85      install the information in the database if possible.  `askinteger
  86      (<expr>)' is equivalent to `askinteger (<expr>, integer)'.
  87
  88      `askinteger (<expr>, even)' and `askinteger (<expr>, odd)'
  89      likewise attempt to determine if <expr> is an even integer or odd
  90      integer, respectively.
  91
  92 (%o1)                                true
  93 @end example
  94
  95 結果を後で使うには、結果を変数に割り当てるか、
  96 自動的に供給されるラベルで参照することができます。
  97 加えて、@mref{%}は直前の計算結果を示します:
  98
  99 @example
 100 (%i1) u: expand ((x + y)^6);
 101        6        5       2  4       3  3       4  2      5      6
 102 (%o1) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
 103 (%i2) diff (u, x);
 104          5         4       2  3       3  2       4        5
 105 (%o2) 6 y  + 30 x y  + 60 x  y  + 60 x  y  + 30 x  y + 6 x
 106 (%i3) factor (%o2);
 107                                     5
 108 (%o3)                      6 (y + x)
 109 @end example
 110
 111 Maximaは複素数や数値定数について知っています:
 112
 113 @example
 114 (%i1) cos(%pi);
 115 (%o1)                          - 1
 116 (%i2) exp(%i*%pi);
 117 (%o2)                          - 1
 118 @end example
 119
 120 Maximaは微積分法ができます:
 121
 122 @example
 123 (%i1) u: expand ((x + y)^6);
 124        6        5       2  4       3  3       4  2      5      6
 125 (%o1) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
 126 (%i2) diff (%, x);
 127          5         4       2  3       3  2       4        5
 128 (%o2) 6 y  + 30 x y  + 60 x  y  + 60 x  y  + 30 x  y + 6 x
 129 (%i3) integrate (1/(1 + x^3), x);
 130                                   2 x - 1
 131                 2            atan(-------)
 132            log(x  - x + 1)        sqrt(3)    log(x + 1)
 133 (%o3)    - --------------- + ------------- + ----------
 134                   6             sqrt(3)          3
 135 @end example
 136
 137 Maximaは1次方程式系や3次方程式を解くことができます:
 138
 139 @example
 140 (%i1) linsolve ([3*x + 4*y = 7, 2*x + a*y = 13], [x, y]);
 141                         7 a - 52        25
 142 (%o1)              [x = --------, y = -------]
 143                         3 a - 8       3 a - 8
 144 (%i2) solve (x^3 - 3*x^2 + 5*x = 15, x);
 145 (%o2)       [x = - sqrt(5) %i, x = sqrt(5) %i, x = 3]
 146 @end example
 147
 148 Maximaは非線形方程式系を解くことができます。
 149 もし結果を表示させたくなければ、コマンドの終わりに@kbd{;}の代わりに@kbd{$}をつければよいことに注意してください:
 150
 151 @example
 152 (%i1) eq_1: x^2 + 3*x*y + y^2 = 0$
 153 (%i2) eq_2: 3*x + y = 1$
 154 (%i3) solve ([eq_1, eq_2]);
 155               3 sqrt(5) + 7      sqrt(5) + 3
 156 (%o3) [[y = - -------------, x = -----------],
 157                     2                 2
 158
 159                                3 sqrt(5) - 7        sqrt(5) - 3
 160                           [y = -------------, x = - -----------]]
 161                                      2                   2
 162 @end example
 163
 164 Maximaは関数のプロットが生成できます:
 165
 166 @example
 167 (%i1) plot2d (sin(x)/x, [x, -20, 20])$
 168 @end example
 169 @ifnotinfo
 170 @image{@value{figuresfolder}/introduction1, 10cm}
 171 @end ifnotinfo
 172 @example
 173 (%i2) plot2d ([atan(x), erf(x), tanh(x)], [x, -5, 5], [y, -1.5, 2])$
 174 @end example
 175 @ifnotinfo
 176 @image{@value{figuresfolder}/introduction2, 10cm}
 177 @end ifnotinfo
 178 @example
 179 @group
 180 (%i3) plot3d (sin(sqrt(x^2 + y^2))/sqrt(x^2 + y^2),
 181          [x, -12, 12], [y, -12, 12])$
 182 @end group
 183 @end example
 184 @ifnotinfo
 185 @image{@value{figuresfolder}/introduction3, 12cm}
 186 @end ifnotinfo
 187
 188 @c FOLLOWING TEXT DESCRIBES THE TCL/TK PLOT WINDOW WHICH IS NO LONGER THE DEFAULT
 189 @c Moving the cursor to the top left corner of the plot window will pop up
 190 @c a menu that will, among other things, let you generate a PostScript file
 191 @c of the plot.  (By default, the file is placed in your home directory.)
 192 @c You can rotate a 3D plot.
 193
 194 @opencatbox
 195 @category{Help}
 196 @closecatbox
 197