share/tensor/bianchi.dem

   1 /*
   2  * This program is free software; you can redistribute it and/or
   3  * modify it under the terms of the GNU General Public License as
   4  * published by the Free Software Foundation; either version 2 of
   5  * the License, or (at your option) any later version.
   6  *
   7  * This program is distributed in the hope that it will be
   8  * useful, but WITHOUT ANY WARRANTY; without even the implied
   9  * warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  10  * PURPOSE.  See the GNU General Public License for more details.
  11  *
  12  * Demonstrating the Bianchi identities and related results
  13  */
  14 if get('itensor,'version)=false then load(itensor);
  15 ("The curvature tensor satisfies the cyclic identity:")$
  16 icurvature([j,k,l],[i])+icurvature([k,l,j],[i])+icurvature([l,j,k],[i])$
  17 ishow(%)$
  18 canform(%);
  19 ("And the Bianchi identity:")$
  20 canform(covdiff(icurvature([j,k,l],[i]),m)+covdiff(icurvature([j,l,m],[i]),k)+
  21 covdiff(icurvature([j,m,k],[i]),l));
  22
  23 ("A consequence is that the Einstein-tensor is divergence-free")$
  24 ("We prove this for a conformal metric in the weak field:")$
  25 remcomps(g);
  26 imetric(g);
  27 declare(e,constant);
  28 defcon(e,e,kdelta);
  29 defcon(e,p,p);
  30 defcon(p,e,p);
  31 remsym(e,0,2);
  32 decsym(e,0,2,[],[sym(all)]);
  33 (ratfac:false,ratvars(l),ratweight(l,1),ratwtlvl:1);
  34 components(g([i,j],[]),e([i,j],[])+2*l*p([i,j],[]));
  35 components(g([],[i,j]),e([],[i,j])-2*l*p([],[i,j]));
  36 ishow(g([i,j],[]))$
  37 ishow(g([],[i,j]))$
  38
  39 scurv:g([],[r,t])*icurvature([r,s,t],[s])$
  40 ricci:g([],[i,r])*g([],[j,t])*icurvature([r,s,t],[s])$
  41 canform(rename(contract(ratexpand(ev(-(ricci-1/2*scurv*g([],[i,j])))))))$
  42 ishow(%)$
  43 covdiff(%,j)$
  44 %,ichr2$
  45 ishow(canform(contract(ratexpand(%))))$
  46
  47 /* End of demo -- comment line needed by MAXIMA to resume demo menu */