share/odepack/fortran/dcopy.f

   1 *DECK DCOPY
   2       SUBROUTINE DCOPY (N, DX, INCX, DY, INCY)
   3 C***BEGIN PROLOGUE  DCOPY
   4 C***PURPOSE  Copy a vector.
   5 C***CATEGORY  D1A5
   6 C***TYPE      DOUBLE PRECISION (SCOPY-S, DCOPY-D, CCOPY-C, ICOPY-I)
   7 C***KEYWORDS  BLAS, COPY, LINEAR ALGEBRA, VECTOR
   8 C***AUTHOR  Lawson, C. L., (JPL)
   9 C           Hanson, R. J., (SNLA)
  10 C           Kincaid, D. R., (U. of Texas)
  11 C           Krogh, F. T., (JPL)
  12 C***DESCRIPTION
  13 C
  14 C                B L A S  Subprogram
  15 C    Description of Parameters
  16 C
  17 C     --Input--
  18 C        N  number of elements in input vector(s)
  19 C       DX  double precision vector with N elements
  20 C     INCX  storage spacing between elements of DX
  21 C       DY  double precision vector with N elements
  22 C     INCY  storage spacing between elements of DY
  23 C
  24 C     --Output--
  25 C       DY  copy of vector DX (unchanged if N .LE. 0)
  26 C
  27 C     Copy double precision DX to double precision DY.
  28 C     For I = 0 to N-1, copy DX(LX+I*INCX) to DY(LY+I*INCY),
  29 C     where LX = 1 if INCX .GE. 0, else LX = 1+(1-N)*INCX, and LY is
  30 C     defined in a similar way using INCY.
  31 C
  32 C***REFERENCES  C. L. Lawson, R. J. Hanson, D. R. Kincaid and F. T.
  33 C                 Krogh, Basic linear algebra subprograms for Fortran
  34 C                 usage, Algorithm No. 539, Transactions on Mathematical
  35 C                 Software 5, 3 (September 1979), pp. 308-323.
  36 C***ROUTINES CALLED  (NONE)
  37 C***REVISION HISTORY  (YYMMDD)
  38 C   791001  DATE WRITTEN
  39 C   890831  Modified array declarations.  (WRB)
  40 C   890831  REVISION DATE from Version 3.2
  41 C   891214  Prologue converted to Version 4.0 format.  (BAB)
  42 C   920310  Corrected definition of LX in DESCRIPTION.  (WRB)
  43 C   920501  Reformatted the REFERENCES section.  (WRB)
  44 C***END PROLOGUE  DCOPY
  45       DOUBLE PRECISION DX(*), DY(*)
  46 C***FIRST EXECUTABLE STATEMENT  DCOPY
  47       IF (N .LE. 0) RETURN
  48       IF (INCX .EQ. INCY) IF (INCX-1) 5,20,60
  49 C
  50 C     Code for unequal or nonpositive increments.
  51 C
  52     5 IX = 1
  53       IY = 1
  54       IF (INCX .LT. 0) IX = (-N+1)*INCX + 1
  55       IF (INCY .LT. 0) IY = (-N+1)*INCY + 1
  56       DO 10 I = 1,N
  57         DY(IY) = DX(IX)
  58         IX = IX + INCX
  59         IY = IY + INCY
  60    10 CONTINUE
  61       RETURN
  62 C
  63 C     Code for both increments equal to 1.
  64 C
  65 C     Clean-up loop so remaining vector length is a multiple of 7.
  66 C
  67    20 M = MOD(N,7)
  68       IF (M .EQ. 0) GO TO 40
  69       DO 30 I = 1,M
  70         DY(I) = DX(I)
  71    30 CONTINUE
  72       IF (N .LT. 7) RETURN
  73    40 MP1 = M + 1
  74       DO 50 I = MP1,N,7
  75         DY(I) = DX(I)
  76         DY(I+1) = DX(I+1)
  77         DY(I+2) = DX(I+2)
  78         DY(I+3) = DX(I+3)
  79         DY(I+4) = DX(I+4)
  80         DY(I+5) = DX(I+5)
  81         DY(I+6) = DX(I+6)
  82    50 CONTINUE
  83       RETURN
  84 C
  85 C     Code for equal, positive, non-unit increments.
  86 C
  87    60 NS = N*INCX
  88       DO 70 I = 1,NS,INCX
  89         DY(I) = DX(I)
  90    70 CONTINUE
  91       RETURN
  92       END