share/tensor/friedmann.dem

   1 /* Copyright (C) 2007 Viktor T. Toth <http://www.vttoth.com/>
   2  *
   3  * This program is free software; you can redistribute it and/or
   4  * modify it under the terms of the GNU General Public License as
   5  * published by the Free Software Foundation; either version 2 of
   6  * the License, or (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be
   9  * useful, but WITHOUT ANY WARRANTY; without even the implied
  10  * warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  11  * PURPOSE.  See the GNU General Public License for more details.
  12  *
  13  * Deriving the Friedmann-equations of cosmology
  14  *
  15  */
  16 ("Deriving the Friedmann-equations of cosmology" )$
  17 if get('ctensor,'version)=false then load(ctensor);
  18 ("We start with the Friedmann-Lemaitre-Robertson-Walker metric")$
  19 ("This metric describes a homogeneous, isotropic universe.")$
  20 ("Our coordinate system is spherical:")$
  21 dim:4;
  22 ct_coords:[t,r,u,v];
  23 lg:ident(4);
  24 lg[2,2]:-a^2/(1-k*r^2);
  25 lg[3,3]:-a^2*r^2;
  26 lg[4,4]:-a^2*r^2*sin(u)^2;
  27 dependencies(a(t));
  28 cmetric();
  29 ("Let us review the contravariant and covariant metric tensor:")$
  30 ug;
  31 lg;
  32 ("And let us calculate the Einstein tensor.")$
  33 derivabbrev:true;
  34 christof(mcs);
  35 ricci(true);
  36 einstein(true);
  37 ("The Weyl tensor is null. No gravitational waves in this metric!")$
  38 weyl(true);
  39 ("The energy-momentum tensor is that of an ideal fluid with")$
  40 ("energy density e and pressure p:")$
  41 T:-p*ident(4);
  42 T[1,1]:e;
  43 T;
  44 ("The Einstein field equations are reduced to two differential equations:")$
  45 expand(ein[1,1]/3=(8*%pi*G*T[1,1]+L)/3);
  46 expand(ein[2,2]-ein[1,1]/3)/2=factor(8*%pi*G*(T[2,2]-T[1,1]/3)/2)+(L-L/3)/2;
  47 ("These two are known as the Friedmann equations of cosmology.")$
  48 ("The size of the universe is proportional to the scale factor a;")$
  49 ("L (Lambda) is the infamous cosmological constant; k (=0, +1, or -1)")$
  50 ("determines the curvature (flat, closed, or open universe, respectively.)")$
  51 /* End of demo -- comment line needed by MAXIMA to resume demo menu */
  52