doc/info/es/Introduction.es.texi

   1 @c English version 2011-05-31
   2 Se puede iniciar Maxima con el comando "maxima". Maxima desplegará alguna información importante acerca de la versión que se está usando y un prompt. Cada comando que vaya a ser ejecutado por Maxima debe terminar con un punto y coma. Para finalizar una sesión en Maxima se emplea el comando "quit();". A continuación se presenta un breve ejemplo de sesión:
   3
   4 @example
   5 [wfs@@chromium]$ maxima
   6 Maxima 5.9.1 http://maxima.sourceforge.net
   7 Using Lisp CMU Common Lisp 19a
   8 Distributed under the GNU Public License. See the file COPYING.
   9 Dedicated to the memory of William Schelter.
  10 This is a development version of Maxima. The function bug_report()
  11 provides bug reporting information.
  12 (%i1) factor(10!);
  13                             8  4  2
  14 (%o1)                      2  3  5  7
  15 (%i2) expand ((x + y)^6);
  16        6        5       2  4       3  3       4  2      5      6
  17 (%o2) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
  18 (%i3) factor (x^6 - 1);
  19                               2            2
  20 (%o3)       (x - 1) (x + 1) (x  - x + 1) (x  + x + 1)
  21 (%i4) quit();
  22 [wfs@@chromium]$
  23 @end example
  24
  25 Maxima puede hacer consultas en la documentación. La instrucción @code{describe} mostrará
  26 información sobre una función o la lista de todas las funciones y variables que
  27 contengan el texto pasado a @code{describe}. La interrogación @code{?}
  28 (búsqueda exacta) y la doble interrogación @code{??} (búsqueda aproximada)
  29 son abreviaturas de la instrucción @code{describe}:
  30
  31 @example
  32 (%i1) ?? integ
  33  0: Functions and Variables for Elliptic Integrals
  34  1: Functions and Variables for Integration
  35  2: Introduction to Elliptic Functions and Integrals
  36  3: Introduction to Integration
  37  4: askinteger  (Functions and Variables for Simplification)
  38  5: integerp  (Functions and Variables for Miscellaneous Options)
  39  6: integer_partitions  (Functions and Variables for Sets)
  40  7: integrate  (Functions and Variables for Integration)
  41  8: integrate_use_rootsof  (Functions and Variables for Integration)
  42  9: integration_constant_counter  (Functions and Variables for
  43     Integration)
  44  10: nonnegintegerp  (Functions and Variables for linearalgebra)
  45 Enter space-separated numbers, `all' or `none': 5 4
  46
  47  -- Function: integerp (<expr>)
  48      Returns `true' if <expr> is a literal numeric integer, otherwise
  49      `false'.
  50
  51      `integerp' returns false if its argument is a symbol, even if the
  52      argument is declared integer.
  53
  54      Examples:
  55
  56           (%i1) integerp (0);
  57           (%o1)                         true
  58           (%i2) integerp (1);
  59           (%o2)                         true
  60           (%i3) integerp (-17);
  61           (%o3)                         true
  62           (%i4) integerp (0.0);
  63           (%o4)                         false
  64           (%i5) integerp (1.0);
  65           (%o5)                         false
  66           (%i6) integerp (%pi);
  67           (%o6)                         false
  68           (%i7) integerp (n);
  69           (%o7)                         false
  70           (%i8) declare (n, integer);
  71           (%o8)                         done
  72           (%i9) integerp (n);
  73           (%o9)                         false
  74
  75  -- Function: askinteger (<expr>, integer)
  76  -- Function: askinteger (<expr>)
  77  -- Function: askinteger (<expr>, even)
  78  -- Function: askinteger (<expr>, odd)
  79      `askinteger (<expr>, integer)' attempts to determine from the
  80      `assume' database whether <expr> is an integer.  `askinteger'
  81      prompts the user if it cannot tell otherwise, and attempt to
  82      install the information in the database if possible.  `askinteger
  83      (<expr>)' is equivalent to `askinteger (<expr>, integer)'.
  84
  85      `askinteger (<expr>, even)' and `askinteger (<expr>, odd)'
  86      likewise attempt to determine if <expr> is an even integer or odd
  87      integer, respectively.
  88
  89 (%o1)                                true
  90 @end example
  91
  92 Para usar posteriormente un resultado, se puede asignar dicho resultado a
  93 una variable o referirse a él por medio de la etiqueta asociada (@code{%i*} o @code{%o*}).
  94 Además, se puede utilizar @code{%} para referirse al último resultado obtenido.
  95
  96 @example
  97 (%i1) u: expand ((x + y)^6);
  98        6        5       2  4       3  3       4  2      5      6
  99 (%o1) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
 100 (%i2) diff (u, x);
 101          5         4       2  3       3  2       4        5
 102 (%o2) 6 y  + 30 x y  + 60 x  y  + 60 x  y  + 30 x  y + 6 x
 103 (%i3) factor (%o2);
 104                                     5
 105 (%o3)                      6 (y + x)
 106 @end example
 107
 108 Maxima manipula sin ningún problema números complejos y constantes numéricas:
 109
 110 @example
 111 (%i1) cos(%pi);
 112 (%o1)                          - 1
 113 (%i2) exp(%i*%pi);
 114 (%o2)                          - 1
 115 @end example
 116
 117
 118 Maxima puede hacer derivadas  e integrales:
 119
 120 @example
 121 (%i1) u: expand ((x + y)^6);
 122        6        5       2  4       3  3       4  2      5      6
 123 (%o1) y  + 6 x y  + 15 x  y  + 20 x  y  + 15 x  y  + 6 x  y + x
 124 (%i2) diff (%, x);
 125          5         4       2  3       3  2       4        5
 126 (%o2) 6 y  + 30 x y  + 60 x  y  + 60 x  y  + 30 x  y + 6 x
 127 (%i3) integrate (1/(1 + x^3), x);
 128                                   2 x - 1
 129                 2            atan(-------)
 130            log(x  - x + 1)        sqrt(3)    log(x + 1)
 131 (%o3)    - --------------- + ------------- + ----------
 132                   6             sqrt(3)          3
 133 @end example
 134
 135 Maxima puede resolver sistemas de ecuaciones lineales y cúbicas:
 136
 137 @example
 138 (%i1) linsolve ([3*x + 4*y = 7, 2*x + a*y = 13], [x, y]);
 139                         7 a - 52        25
 140 (%o1)              [x = --------, y = -------]
 141                         3 a - 8       3 a - 8
 142 (%i2) solve (x^3 - 3*x^2 + 5*x = 15, x);
 143 (%o2)       [x = - sqrt(5) %i, x = sqrt(5) %i, x = 3]
 144 @end example
 145
 146 Maxima puede resolver sistemas de ecuaciones no lineales. Tenga en cuenta que si usted no desea que el resultado sea impreso, puede finalizar el comando con @kbd{$} en vez de @kbd{;}.
 147
 148 @example
 149 (%i1) eq_1: x^2 + 3*x*y + y^2 = 0$
 150 (%i2) eq_2: 3*x + y = 1$
 151 (%i3) solve ([eq_1, eq_2]);
 152               3 sqrt(5) + 7      sqrt(5) + 3
 153 (%o3) [[y = - -------------, x = -----------],
 154                     2                 2
 155
 156                                3 sqrt(5) - 7        sqrt(5) - 3
 157                           [y = -------------, x = - -----------]]
 158                                      2                   2
 159 @end example
 160
 161 Maxima puede generar gráficos de una o más funciones:
 162
 163 @example
 164 (%i1) plot2d (sin(x)/x, [x, -20, 20])$
 165 @end example
 166 @ifnotinfo
 167 @image{@value{figuresfolder}/introduction1, 10cm}
 168 @end ifnotinfo
 169 @example
 170 (%i2) plot2d ([atan(x), erf(x), tanh(x)], [x, -5, 5], [y, -1.5, 2])$
 171 @end example
 172 @ifnotinfo
 173 @image{@value{figuresfolder}/introduction2, 10cm}
 174 @end ifnotinfo
 175 @example
 176 @group
 177 (%i3) plot3d (sin(sqrt(x^2 + y^2))/sqrt(x^2 + y^2),
 178          [x, -12, 12], [y, -12, 12])$
 179 @end group
 180 @end example
 181 @ifnotinfo
 182 @image{@value{figuresfolder}/introduction3, 12cm}
 183 @end ifnotinfo
 184
 185 @c Traducido por: Juan Pablo Romero Bernal
 186 @c Revisado por : Juan Pablo Romero Bernal
 187 @c correo-e     : jpromerobx@linuxmail.org
 188 @c Grupo Linux Universidad Distrital
 189 @c http://glud.udistrital.edu.co
 190 @c Proyecto GLUD-CLog
 191 @c http://glud.udistrital.edu.co/clog
 192 @c Bogota - Colombia
 193