doc/info/romberg.texi

   1 @menu
   2 * Functions and Variables for romberg::
   3 @end menu
   4
   5 @node Functions and Variables for romberg, , Package romberg, Package romberg
   6 @section Functions and Variables for romberg
   7
   8 @anchor{romberg_function}
   9 @deffn {Function} romberg @
  10 @fname{romberg} (@var{expr}, @var{x}, @var{a}, @var{b}) @
  11 @fname{romberg} (@var{F}, @var{a}, @var{b})
  12
  13 Computes a numerical integration by Romberg's method.
  14
  15 @code{romberg(@var{expr}, @var{x}, @var{a}, @var{b})}
  16 returns an estimate of the integral @code{integrate(@var{expr}, @var{x}, @var{a}, @var{b})}.
  17 @var{expr} must be an expression which evaluates to a floating point value
  18 when @var{x} is bound to a floating point value.
  19
  20 @code{romberg(@var{F}, @var{a}, @var{b})}
  21 returns an estimate of the integral @code{integrate(@var{F}(x), x, @var{a}, @var{b})}
  22 where @code{x} represents the unnamed, sole argument of @var{F};
  23 the actual argument is not named @code{x}.
  24 @var{F} must be a Maxima or Lisp function which returns a floating point value
  25 when the argument is a floating point value.
  26 @var{F} may name a translated or compiled Maxima function.
  27
  28 The accuracy of @code{romberg} is governed by the global variables
  29 @code{rombergabs} and @code{rombergtol}.
  30 @code{romberg} terminates successfully when
  31 the absolute difference between successive approximations is less than @code{rombergabs},
  32 or the relative difference in successive approximations is less than @code{rombergtol}.
  33 Thus when @code{rombergabs} is 0.0 (the default)
  34 only the relative error test has any effect on @code{romberg}.
  35
  36 @code{romberg} halves the stepsize at most @code{rombergit} times before it gives up;
  37 the maximum number of function evaluations is therefore @code{2^rombergit}.
  38 If the error criterion established by @code{rombergabs} and @code{rombergtol}
  39 is not satisfied, @code{romberg} prints an error message.
  40 @code{romberg} always makes at least @code{rombergmin} iterations;
  41 this is a heuristic intended to prevent spurious termination when the integrand is oscillatory.
  42
  43 @code{romberg} repeatedly evaluates the integrand after binding the variable
  44 of integration to a specific value (and not before).
  45 This evaluation policy makes it possible to nest calls to @code{romberg},
  46 to compute multidimensional integrals.
  47 However, the error calculations do not take the errors of nested integrations
  48 into account, so errors may be underestimated.
  49 Also, methods devised especially for multidimensional problems may yield
  50 the same accuracy with fewer function evaluations.
  51
  52 See also @mref{Introduction to QUADPACK}, a collection of numerical integration functions.
  53
  54 Examples:
  55
  56 A 1-dimensional integration.
  57 @c ===beg===
  58 @c f(x) := 1/((x - 1)^2 + 1/100) + 1/((x - 2)^2 + 1/1000)
  59 @c               + 1/((x - 3)^2 + 1/200);
  60 @c rombergtol : 1e-6;
  61 @c rombergit : 15;
  62 @c estimate : romberg (f(x), x, -5, 5);
  63 @c exact : integrate (f(x), x, -5, 5);
  64 @c abs (estimate - exact) / exact, numer;
  65 @c ===end===
  66 @example
  67 @group
  68 (%i1) f(x) := 1/((x - 1)^2 + 1/100) + 1/((x - 2)^2 + 1/1000)
  69               + 1/((x - 3)^2 + 1/200);
  70                     1                 1                1
  71 (%o1) f(x) := -------------- + --------------- + --------------
  72                      2    1           2    1            2    1
  73               (x - 1)  + ---   (x - 2)  + ----   (x - 3)  + ---
  74                          100              1000              200
  75 @end group
  76 @group
  77 (%i2) rombergtol : 1e-6;
  78 (%o2)                 9.999999999999999e-7
  79 @end group
  80 @group
  81 (%i3) rombergit : 15;
  82 (%o3)                          15
  83 @end group
  84 @group
  85 (%i4) estimate : romberg (f(x), x, -5, 5);
  86 (%o4)                   173.6730736617464
  87 @end group
  88 @group
  89 (%i5) exact : integrate (f(x), x, -5, 5);
  90         3/2          3/2      3/2          3/2
  91 (%o5) 10    atan(7 10   ) + 10    atan(3 10   )
  92       3/2         9/2       3/2         5/2
  93  + 5 2    atan(5 2   ) + 5 2    atan(5 2   ) + 10 atan(60)
  94  + 10 atan(40)
  95 @end group
  96 @group
  97 (%i6) abs (estimate - exact) / exact, numer;
  98 (%o6)                 7.552722451569877e-11
  99 @end group
 100 @end example
 101
 102 A 2-dimensional integration, implemented by nested calls to @code{romberg}.
 103 @c ===beg===
 104 @c g(x, y) := x*y / (x + y);
 105 @c rombergtol : 1e-6;
 106 @c estimate : romberg (romberg (g(x, y), y, 0, x/2), x, 1, 3);
 107 @c assume (x > 0);
 108 @c integrate (integrate (g(x, y), y, 0, x/2), x, 1, 3);
 109 @c exact : radcan (%);
 110 @c abs (estimate - exact) / exact, numer;
 111 @c ===end===
 112 @example
 113 @group
 114 (%i1) g(x, y) := x*y / (x + y);
 115                                     x y
 116 (%o1)                   g(x, y) := -----
 117                                    x + y
 118 @end group
 119 @group
 120 (%i2) rombergtol : 1e-6;
 121 (%o2)                 9.999999999999999e-7
 122 @end group
 123 @group
 124 (%i3) estimate : romberg (romberg (g(x, y), y, 0, x/2), x, 1, 3);
 125 (%o3)                  0.8193023962835647
 126 @end group
 127 @group
 128 (%i4) assume (x > 0);
 129 (%o4)                        [x > 0]
 130 @end group
 131 @group
 132 (%i5) integrate (integrate (g(x, y), y, 0, x/2), x, 1, 3);
 133                                            3
 134                                      2 log(-) - 1
 135                     9                      2        9
 136 (%o5)      (- 9 log(-)) + 9 log(3) + ------------ + -
 137                     2                     6         2
 138 @end group
 139 @group
 140 (%i6) exact : radcan (%);
 141                     26 log(3) - 26 log(2) - 13
 142 (%o6)             - --------------------------
 143                                 3
 144 @end group
 145 @group
 146 (%i7) abs (estimate - exact) / exact, numer;
 147 (%o7)                 1.371197987185102e-10
 148 @end group
 149 @end example
 150
 151 @opencatbox{Categories:}
 152 @category{Package romberg}
 153 @category{Numerical methods}
 154 @closecatbox
 155
 156 @end deffn
 157
 158 @anchor{rombergabs}
 159 @defvr {Option variable} rombergabs
 160 Default value: 0.0
 161
 162 The accuracy of @code{romberg} is governed by the global variables
 163 @code{rombergabs} and @code{rombergtol}.
 164 @code{romberg} terminates successfully when
 165 the absolute difference between successive approximations is less than @code{rombergabs},
 166 or the relative difference in successive approximations is less than @code{rombergtol}.
 167 Thus when @code{rombergabs} is 0.0 (the default)
 168 only the relative error test has any effect on @code{romberg}.
 169
 170 See also @mref{rombergit} and @mref{rombergmin}.
 171
 172 @opencatbox{Categories:}
 173 @category{Package romberg}
 174 @closecatbox
 175
 176 @end defvr
 177
 178 @anchor{rombergit}
 179 @defvr {Option variable} rombergit
 180 Default value: 11
 181
 182 @code{romberg} halves the stepsize at most @code{rombergit} times before it gives up;
 183 the maximum number of function evaluations is therefore @code{2^rombergit}.
 184 @code{romberg} always makes at least @code{rombergmin} iterations;
 185 this is a heuristic intended to prevent spurious termination when the integrand is oscillatory.
 186
 187 See also @mref{rombergabs} and @mref{rombergtol}.
 188
 189 @opencatbox{Categories:}
 190 @category{Package romberg}
 191 @closecatbox
 192
 193 @end defvr
 194
 195 @anchor{rombergmin}
 196 @defvr {Option variable} rombergmin
 197 Default value: 0
 198
 199 @code{romberg} always makes at least @code{rombergmin} iterations;
 200 this is a heuristic intended to prevent spurious termination when the integrand is oscillatory.
 201
 202 See also @mref{rombergit}, @mref{rombergabs}, and @mref{rombergtol}.
 203
 204 @opencatbox{Categories:}
 205 @category{Package romberg}
 206 @closecatbox
 207
 208 @end defvr
 209
 210 @anchor{rombergtol}
 211 @defvr {Option variable} rombergtol
 212 Default value: 1e-4
 213
 214 The accuracy of @code{romberg} is governed by the global variables
 215 @code{rombergabs} and @code{rombergtol}.
 216 @code{romberg} terminates successfully when
 217 the absolute difference between successive approximations is less than @code{rombergabs},
 218 or the relative difference in successive approximations is less than @code{rombergtol}.
 219 Thus when @code{rombergabs} is 0.0 (the default)
 220 only the relative error test has any effect on @code{romberg}.
 221
 222 See also @mref{rombergit} and @mref{rombergmin}.
 223
 224 @opencatbox{Categories:}
 225 @category{Package romberg}
 226 @closecatbox
 227
 228 @end defvr
 229