doc/info/Runtime.texi

   1 @menu
   2 * Introduction for Runtime Environment::
   3 * Interrupts::
   4 * Functions and Variables for Runtime Environment::
   5 @end menu
   6
   7 @c -----------------------------------------------------------------------------
   8 @node Introduction for Runtime Environment, Interrupts, Runtime Environment, Runtime Environment
   9 @section Introduction for Runtime Environment
  10 @c -----------------------------------------------------------------------------
  11
  12 @c THIS DISCUSSION OF maxima-init.mac REPLACES AN EARLIER WRITE-UP. !!!
  13 @c HOWEVER IT SEEMS THAT THIS TEXT REALLY WANTS TO BE UNDER A DIFFERENT HEADING. !!!
  14 @code{maxima-init.mac} is a file which is loaded automatically when Maxima
  15 starts.  You can use @code{maxima-init.mac} to customize your Maxima
  16 environment.  @code{maxima-init.mac}, if it exists, is typically placed in the
  17 directory named by @code{maxima_userdir},
  18 although it can be in any directory searched by the function @code{file_search}.
  19
  20 Here is an example @code{maxima-init.mac} file:
  21
  22 @example
  23 setup_autoload ("specfun.mac", ultraspherical, assoc_legendre_p);
  24 showtime:all;
  25 @end example
  26
  27 In this example, @code{setup_autoload} tells Maxima to load the
  28 specified file
  29 (@code{specfun.mac}) if any of the functions (@code{ultraspherical},
  30 @code{assoc_legendre_p}) are called but not yet defined.
  31 Thus you needn't remember to load the file before calling the functions.
  32
  33 The statement @code{showtime: all} tells Maxima to set the @code{showtime}
  34 variable.  The @code{maxima-init.mac} file can contain any other assignments or
  35 other Maxima statements.
  36
  37 @opencatbox{Categories:}
  38 @category{Session management}
  39 @closecatbox
  40
  41 @c -----------------------------------------------------------------------------
  42 @node Interrupts, Functions and Variables for Runtime Environment, Introduction for Runtime Environment, Runtime Environment
  43 @section Interrupts
  44 @c -----------------------------------------------------------------------------
  45
  46 The user can stop a time-consuming computation with the
  47 ^C (control-C) character.
  48 The default action is to stop the computation
  49 and print another user prompt.
  50 In this case, it is not possible to restart a stopped computation.
  51
  52 If the Lisp variable @code{*debugger-hook*} is set to @code{nil}, by executing
  53
  54 @example
  55 :lisp (setq *debugger-hook* nil)
  56 @end example
  57
  58 @noindent
  59 then upon receiving ^C, Maxima will enter the Lisp debugger,
  60 and the user may use the debugger to inspect the Lisp environment.
  61 The stopped computation can be restarted by entering
  62 @code{continue} in the Lisp debugger.
  63 The means of returning to Maxima from the Lisp debugger
  64 (other than running the computation to completion)
  65 is different for each version of Lisp.
  66
  67 On Unix systems, the character ^Z (control-Z) causes Maxima
  68 to stop altogether, and control is returned to the shell prompt.
  69 The @code{fg} command causes Maxima
  70 to resume from the point at which it was stopped.
  71
  72 @opencatbox{Categories:}
  73 @category{Console interaction}
  74 @closecatbox
  75
  76 @c end concepts Runtime Environment
  77
  78 @c -----------------------------------------------------------------------------
  79 @node Functions and Variables for Runtime Environment,  , Interrupts, Runtime Environment
  80 @section Functions and Variables for Runtime Environment
  81 @c -----------------------------------------------------------------------------
  82
  83 @c -----------------------------------------------------------------------------
  84 @anchor{maxima_tempdir}
  85 @defvr {System variable} maxima_tempdir
  86
  87 @code{maxima_tempdir} names the directory in which Maxima creates some temporary
  88 files.  In particular, temporary files for plotting are created in
  89 @code{maxima_tempdir}.
  90
  91 The initial value of @code{maxima_tempdir} is the user's home directory, if
  92 Maxima can locate it; otherwise Maxima makes a guess about a suitable directory.
  93
  94 @code{maxima_tempdir} may be assigned a string which names a directory.
  95
  96 @opencatbox{Categories:}
  97 @category{Global variables}
  98 @closecatbox
  99 @end defvr
 100
 101 @c -----------------------------------------------------------------------------
 102 @anchor{maxima_userdir}
 103 @defvr {System variable} maxima_userdir
 104
 105 @code{maxima_userdir} names a directory which Maxima searches to find Maxima and
 106 Lisp files.  (Maxima searches some other directories as well;
 107 @code{file_search_maxima} and @code{file_search_lisp} are the complete lists.)
 108
 109 The initial value of @code{maxima_userdir} is a subdirectory of the user's home
 110 directory, if Maxima can locate it; otherwise Maxima makes a guess about a
 111 suitable directory.
 112
 113 @code{maxima_userdir} may be assigned a string which names a directory.
 114 However, assigning to @code{maxima_userdir} does not automatically change
 115 @code{file_search_maxima} and @code{file_search_lisp};
 116 those variables must be changed separately.
 117
 118 @opencatbox{Categories:}
 119 @category{Global variables}
 120 @closecatbox
 121 @end defvr
 122
 123 @c -----------------------------------------------------------------------------
 124 @anchor{room}
 125 @deffn  {Function} room @
 126 @fname{room} () @
 127 @fname{room} (true) @
 128 @fname{room} (false)
 129
 130 Prints out a description of the state of storage and
 131 stack management in Maxima.  @code{room} calls the Lisp function of
 132 the same name.
 133
 134 @itemize @bullet
 135 @item
 136 @code{room ()} prints out a moderate description.
 137 @item
 138 @code{room (true)} prints out a verbose description.
 139 @item
 140 @code{room (false)} prints out a terse description.
 141 @end itemize
 142
 143 @opencatbox{Categories:}
 144 @category{Debugging}
 145 @closecatbox
 146 @end deffn
 147
 148 @c -----------------------------------------------------------------------------
 149 @anchor{sstatus}
 150 @deffn {Function} sstatus (@var{keyword}, @var{item})
 151
 152 When @var{keyword} is the symbol @code{feature}, @var{item} is put on the list
 153 of system features.  After @code{sstatus (keyword, item)} is executed,
 154 @code{status (feature, item)} returns @code{true}.  If @var{keyword} is the
 155 symbol @code{nofeature}, @var{item} is deleted from the list of system features.
 156 This can be useful for package writers, to keep track of what features they have
 157 loaded in.
 158
 159 See also @mrefdot{status}
 160
 161 @opencatbox{Categories:}
 162 @category{Programming}
 163 @closecatbox
 164 @end deffn
 165
 166 @c -----------------------------------------------------------------------------
 167 @anchor{status}
 168 @deffn  {Function} status @
 169 @fname{status} (@code{feature}) @
 170 @fname{status} (@code{feature}, @var{item})
 171
 172 Returns information about the presence or absence of certain system-dependent
 173 features.
 174
 175 @itemize @bullet
 176 @item
 177 @code{status (feature)} returns a list of system features. These include Lisp
 178 version, operating system type, etc. The list may vary from one Lisp type to
 179 another.
 180
 181 @item
 182 @code{status (feature, item)} returns @code{true} if @var{item} is on the
 183 list of items returned by @code{status (feature)} and @code{false} otherwise.
 184 @code{status} quotes the argument @var{item}. The quote-quote operator
 185 @code{'@w{}'} defeats quotation. A feature whose name contains a special
 186 character, such as a hyphen, must be given as a string argument. For example,
 187 @code{status (feature, "ansi-cl")}.
 188 @end itemize
 189
 190 See also @mrefdot{sstatus}
 191
 192 The variable @code{features} contains a list of features which apply to
 193 mathematical expressions. See @code{features} and @code{featurep} for more
 194 information.
 195
 196 @opencatbox{Categories:}
 197 @category{Programming}
 198 @closecatbox
 199 @end deffn
 200
 201 @c NEEDS CLARIFICATION
 202
 203 @c -----------------------------------------------------------------------------
 204 @anchor{system}
 205 @deffn {Function} system (@var{command})
 206
 207 Executes @var{command} as a separate process.  The command is passed to the
 208 default shell for execution.  @code{system} is not supported by all operating
 209 systems, but generally exists in Unix and Unix-like environments.
 210
 211 Supposing @code{_hist.out} is a list of frequencies which you wish to plot as a
 212 bar graph using @code{xgraph}.
 213
 214 @example
 215 (%i1) (with_stdout("_hist.out",
 216            for i:1 thru length(hist) do (
 217              print(i,hist[i]))),
 218        system("xgraph -bar -brw .7 -nl < _hist.out"));
 219 @end example
 220
 221 In order to make the plot be done in the background (returning control to
 222 Maxima) and remove the temporary file after it is done do:
 223
 224 @example
 225 system("(xgraph -bar -brw .7 -nl < _hist.out;  rm -f _hist.out)&")
 226 @end example
 227 @end deffn
 228
 229 @c -----------------------------------------------------------------------------
 230 @anchor{time}
 231 @deffn {Function} time (%o1, %o2, %o3, @dots{})
 232
 233 Returns a list of the times, in seconds, taken to compute the output lines
 234 @code{%o1}, @code{%o2}, @code{%o3}, @dots{} The time returned is Maxima's
 235 estimate of the internal computation time, not the elapsed time.  @code{time}
 236 can only be applied to output line variables; for any other variables,
 237 @code{time} returns @code{unknown}.
 238
 239 Set @code{showtime: true} to make Maxima print out the computation time
 240 and elapsed time with each output line.
 241
 242 @opencatbox{Categories:}
 243 @category{Debugging}
 244 @closecatbox
 245 @end deffn
 246
 247 @c -----------------------------------------------------------------------------
 248 @anchor{timedate}
 249 @deffn {Function} timedate @
 250 @fname{timedate} (@var{T}, @var{tz_offset}) @
 251 @fname{timedate} (@var{T}) @
 252 @fname{timedate} ()
 253
 254 @code{timedate(@var{T}, @var{tz_offset})} returns a string
 255 representing the time @var{T} in the time zone @var{tz_offset}.
 256 The string format is @code{YYYY-MM-DD HH:MM:SS.NNN[+|-]ZZ:ZZ}
 257 (using as many digits as necessary to represent the fractional part)
 258 if @var{T} has a nonzero fractional part,
 259 or @code{YYYY-MM-DD HH:MM:SS[+|-]ZZ:ZZ} if its fractional part is zero.
 260
 261 @var{T} measures time, in seconds, since midnight, January 1, 1900,
 262 in the GMT time zone.
 263
 264 @var{tz_offset} measures the offset of the time zone, in hours,
 265 east (positive) or west (negative) of GMT.
 266 @var{tz_offset} must be an integer, rational, or float between -24 and 24, inclusive.
 267 If @var{tz_offset} is not a multiple of 1/60,
 268 it is rounded to the nearest multiple of 1/60.
 269
 270 @code{timedate(@var{T})} is equivalent to @code{timedate(@var{T}, @var{tz_offset})}
 271 with @var{tz_offset} equal to the offset of the local time zone.
 272
 273 @code{timedate()} is equivalent to @code{timedate(absolute_real_time())}.
 274 That is, it returns the current time in the local time zone.
 275
 276 Example:
 277
 278 @code{timedate} with no argument returns a string representing the current time and date.
 279
 280 @c ===beg===
 281 @c d : timedate ();
 282 @c print ("timedate reports current time", d) $
 283 @c ===end===
 284 @example
 285 (%i1) d : timedate ();
 286 (%o1)                      2010-06-08 04:08:09+01:00
 287 (%i2) print ("timedate reports current time", d) $
 288 timedate reports current time 2010-06-08 04:08:09+01:00
 289 @end example
 290
 291 @code{timedate} with an argument returns a string representing the argument.
 292
 293 @c ===beg===
 294 @c timedate (0);
 295 @c timedate (absolute_real_time () - 7*24*3600);
 296 @c ===end===
 297 @example
 298 (%i1) timedate (0);
 299 (%o1)                      1900-01-01 01:00:00+01:00
 300 (%i2) timedate (absolute_real_time () - 7*24*3600);
 301 (%o2)                      2010-06-01 04:19:51+01:00
 302 @end example
 303
 304 @code{timedate} with optional timezone offset.
 305
 306 @c ===beg===
 307 @c timedate (1000000000, -9.5);
 308 @c ===end===
 309 @example
 310 (%i1) timedate (1000000000, -9.5);
 311 (%o1)               1931-09-09 16:16:40-09:30
 312 @end example
 313
 314 @opencatbox{Categories:}
 315 @category{Time and date functions}
 316 @closecatbox
 317 @end deffn
 318
 319 @c -----------------------------------------------------------------------------
 320 @anchor{parse_timedate}
 321 @deffn  {Function} parse_timedate @
 322 @fname{parse_timedate} (@var{S})
 323
 324 Parses a string @var{S} representing a date or date and time of day
 325 and returns the number of seconds since midnight, January 1, 1900 GMT.
 326 If there is a nonzero fractional part, the value returned is a rational number,
 327 otherwise, it is an integer.
 328 @code{parse_timedate} returns @code{false}
 329 if it cannot parse @var{S} according to any of the allowed formats.
 330
 331 The string @var{S} must have one of the following formats,
 332 optionally followed by a timezone designation:
 333
 334 @itemize @bullet
 335 @item
 336 @code{YYYY-MM-DD[ T]hh:mm:ss[,.]nnn}
 337 @item
 338 @code{YYYY-MM-DD[ T]hh:mm:ss}
 339 @item
 340 @code{YYYY-MM-DD}
 341 @end itemize
 342
 343 where the fields are year, month, day, hours, minutes, seconds, and fraction of a second,
 344 and square brackets indicate acceptable alternatives.
 345 The fraction may contain one or more digits.
 346
 347 Except for the fraction of a second,
 348 each field must have exactly the number of digits indicated:
 349 four digits for the year, and two for the month, day of the month, hours, minutes, and seconds.
 350
 351 A timezone designation must have one of the following forms:
 352
 353 @itemize @bullet
 354 @item
 355 @code{[+-]hh:mm}
 356 @item
 357 @code{[+-]hhmm}
 358 @item
 359 @code{[+-]hh}
 360 @item
 361 @code{Z}
 362 @end itemize
 363
 364 where @code{hh} and @code{mm} indicate hours and minutes east (@code{+}) or west (@code{-}) of GMT.
 365 The timezone may be from +24 hours (inclusive) to -24 hours (inclusive).
 366
 367 A literal character @code{Z} is equivalent to @code{+00:00} and its variants,
 368 indicating GMT.
 369
 370 If no timezone is indicated,
 371 the time is assumed to be in the local time zone.
 372
 373 Any leading or trailing whitespace (space, tab, newline, and carriage return) is ignored,
 374 but any other leading or trailing characters cause @code{parse_timedate} to fail and return @code{false}.
 375
 376 See also @mref{timedate} and @mrefdot{absolute_real_time}
 377
 378 Examples:
 379
 380 Midnight, January 1, 1900, in the local time zone, in each acceptable format.
 381 The result is the number of seconds the local time zone
 382 is ahead (negative result) or behind (positive result) GMT.
 383 In this example, the local time zone is 8 hours behind GMT.
 384
 385 @c ===beg===
 386 @c parse_timedate ("1900-01-01 00:00:00,000");
 387 @c parse_timedate ("1900-01-01 00:00:00.000");
 388 @c parse_timedate ("1900-01-01T00:00:00,000");
 389 @c parse_timedate ("1900-01-01T00:00:00.000");
 390 @c parse_timedate ("1900-01-01 00:00:00");
 391 @c parse_timedate ("1900-01-01T00:00:00");
 392 @c parse_timedate ("1900-01-01");
 393 @c ===end===
 394 @example
 395 (%i1) parse_timedate ("1900-01-01 00:00:00,000");
 396 (%o1)                         28800
 397 (%i2) parse_timedate ("1900-01-01 00:00:00.000");
 398 (%o2)                         28800
 399 (%i3) parse_timedate ("1900-01-01T00:00:00,000");
 400 (%o3)                         28800
 401 (%i4) parse_timedate ("1900-01-01T00:00:00.000");
 402 (%o4)                         28800
 403 (%i5) parse_timedate ("1900-01-01 00:00:00");
 404 (%o5)                         28800
 405 (%i6) parse_timedate ("1900-01-01T00:00:00");
 406 (%o6)                         28800
 407 (%i7) parse_timedate ("1900-01-01");
 408 (%o7)                         28800
 409 @end example
 410
 411 Midnight, January 1, 1900, GMT, in different indicated time zones.
 412
 413 @c ===beg===
 414 @c parse_timedate ("1900-01-01 19:00:00+19:00");
 415 @c parse_timedate ("1900-01-01 07:00:00+07:00");
 416 @c parse_timedate ("1900-01-01 01:00:00+01:00");
 417 @c parse_timedate ("1900-01-01Z");
 418 @c parse_timedate ("1899-12-31 21:00:00-03:00");
 419 @c parse_timedate ("1899-12-31 13:00:00-11:00");
 420 @c parse_timedate ("1899-12-31 08:00:00-16:00");
 421 @c ===end===
 422 @example
 423 (%i1) parse_timedate ("1900-01-01 19:00:00+19:00");
 424 (%o1)                           0
 425 (%i2) parse_timedate ("1900-01-01 07:00:00+07:00");
 426 (%o2)                           0
 427 (%i3) parse_timedate ("1900-01-01 01:00:00+01:00");
 428 (%o3)                           0
 429 (%i4) parse_timedate ("1900-01-01Z");
 430 (%o4)                           0
 431 (%i5) parse_timedate ("1899-12-31 21:00:00-03:00");
 432 (%o5)                           0
 433 (%i6) parse_timedate ("1899-12-31 13:00:00-11:00");
 434 (%o6)                           0
 435 (%i7) parse_timedate ("1899-12-31 08:00:00-16:00");
 436 (%o7)                           0
 437 @end example
 438
 439 @opencatbox{Categories:}
 440 @category{Time and date functions}
 441 @closecatbox
 442 @end deffn
 443
 444 @c -----------------------------------------------------------------------------
 445 @anchor{encode_time}
 446 @deffn {Function} encode_time @
 447 @fname{encode_time} (@var{year}, @var{month}, @var{day}, @var{hours}, @var{minutes}, @var{seconds}, @var{tz_offset}) @
 448 @fname{encode_time} (@var{year}, @var{month}, @var{day}, @var{hours}, @var{minutes}, @var{seconds})
 449
 450 Given a time and date specified by
 451 @var{year}, @var{month}, @var{day}, @var{hours}, @var{minutes}, and @var{seconds},
 452 @code{encode_time} returns the number of seconds (possibly including a fractional part)
 453 since midnight, January 1, 1900 GMT.
 454
 455 @var{year} must be an integer greater than or equal to 1899.
 456 However, 1899 is allowed only if the resulting encoded time is greater than or equal to 0.
 457
 458 @var{month} must be an integer from 1 to 12, inclusive.
 459
 460 @var{day} must be an integer from 1 to @var{n}, inclusive,
 461 where @var{n} is the number of days in the month specified by @var{month}.
 462
 463 @var{hours} must be an integer from 0 to 23, inclusive.
 464
 465 @var{minutes} must be an integer from 0 to 59, inclusive.
 466
 467 @var{seconds} must be an integer, rational, or float
 468 greater than or equal to 0 and less than 60.
 469 When @var{seconds} is not an integer,
 470 @code{encode_time} returns a rational,
 471 such that the fractional part of the return value is equal to the fractional part of @var{seconds}.
 472 Otherwise, @var{seconds} is an integer, and the return value is likewise an integer.
 473
 474 @var{tz_offset} measures the offset of the time zone, in hours,
 475 east (positive) or west (negative) of GMT.
 476 @var{tz_offset} must be an integer, rational, or float between -24 and 24, inclusive.
 477 If @var{tz_offset} is not a multiple of 1/3600,
 478 it is rounded to the nearest multiple of 1/3600.
 479
 480 If @var{tz_offset} is not present, the offset of the local time zone is assumed.
 481
 482 See also @mrefdot{decode_time}
 483
 484 Examples:
 485
 486 @c ===beg===
 487 @c encode_time (1900, 1, 1, 0, 0, 0, 0);
 488 @c encode_time (1970, 1, 1, 0, 0, 0, 0);
 489 @c encode_time (1970, 1, 1, 8, 30, 0, 8.5);
 490 @c encode_time (1969, 12, 31, 16, 0, 0, -8);
 491 @c encode_time (1969, 12, 31, 16, 0, 1/1000, -8);
 492 @c % - 2208988800;
 493 @c ===end===
 494 @example
 495 (%i1) encode_time (1900, 1, 1, 0, 0, 0, 0);
 496 (%o1)                           0
 497 (%i2) encode_time (1970, 1, 1, 0, 0, 0, 0);
 498 (%o2)                      2208988800
 499 (%i3) encode_time (1970, 1, 1, 8, 30, 0, 8.5);
 500 (%o3)                      2208988800
 501 (%i4) encode_time (1969, 12, 31, 16, 0, 0, -8);
 502 (%o4)                      2208988800
 503 (%i5) encode_time (1969, 12, 31, 16, 0, 1/1000, -8);
 504                           2208988800001
 505 (%o5)                     -------------
 506                               1000
 507 (%i6) % - 2208988800;
 508                                1
 509 (%o6)                         ----
 510                               1000
 511 @end example
 512
 513 @opencatbox{Categories:}
 514 @category{Time and date functions}
 515 @closecatbox
 516 @end deffn
 517
 518 @c -----------------------------------------------------------------------------
 519 @anchor{decode_time}
 520 @deffn {Function} decode_time @
 521 @fname{decode_time} (@var{T}, @var{tz_offset}) @
 522 @fname{decode_time} (@var{T})
 523
 524 Given the number of seconds (possibly including a fractional part)
 525 since midnight, January 1, 1900 GMT,
 526 returns the date and time as represented by a list comprising
 527 the year, month, day of the month, hours, minutes, seconds, and time zone offset.
 528
 529 @var{tz_offset} measures the offset of the time zone, in hours,
 530 east (positive) or west (negative) of GMT.
 531 @var{tz_offset} must be an integer, rational, or float between -24 and 24, inclusive.
 532 If @var{tz_offset} is not a multiple of 1/3600,
 533 it is rounded to the nearest multiple of 1/3600.
 534
 535 If @var{tz_offset} is not present, the offset of the local time zone is assumed.
 536
 537 See also @mrefdot{encode_time}
 538
 539 Examples:
 540
 541 @c ===beg===
 542 @c decode_time (0, 0);
 543 @c decode_time (0);
 544 @c decode_time (2208988800, 9.25);
 545 @c decode_time (2208988800);
 546 @c decode_time (2208988800 + 1729/1000, -6);
 547 @c decode_time (2208988800 + 1729/1000);
 548 @c ===end===
 549 @example
 550 (%i1) decode_time (0, 0);
 551 (%o1)               [1900, 1, 1, 0, 0, 0, 0]
 552 (%i2) decode_time (0);
 553 (%o2)             [1899, 12, 31, 16, 0, 0, - 8]
 554 (%i3) decode_time (2208988800, 9.25);
 555                                           37
 556 (%o3)              [1970, 1, 1, 9, 15, 0, --]
 557                                           4
 558 (%i4) decode_time (2208988800);
 559 (%o4)             [1969, 12, 31, 16, 0, 0, - 8]
 560 (%i5) decode_time (2208988800 + 1729/1000, -6);
 561                                       1729
 562 (%o5)           [1969, 12, 31, 18, 0, ----, - 6]
 563                                       1000
 564 (%i6) decode_time (2208988800 + 1729/1000);
 565                                       1729
 566 (%o6)           [1969, 12, 31, 16, 0, ----, - 8]
 567                                       1000
 568 @end example
 569
 570 @opencatbox{Categories:}
 571 @category{Time and date functions}
 572 @closecatbox
 573 @end deffn
 574
 575 @c -----------------------------------------------------------------------------
 576 @anchor{absolute_real_time}
 577 @deffn {Function} absolute_real_time ()
 578
 579 Returns the number of seconds since midnight, January 1, 1900 GMT.
 580 The return value is an integer.
 581
 582 See also @mref{elapsed_real_time} and @mrefdot{elapsed_run_time}
 583
 584 Example:
 585
 586 @c ===beg===
 587 @c absolute_real_time ();
 588 @c 1900 + absolute_real_time () / (365.25 * 24 * 3600);
 589 @c ===end===
 590 @example
 591 (%i1) absolute_real_time ();
 592 (%o1)                      3385045277
 593 (%i2) 1900 + absolute_real_time () / (365.25 * 24 * 3600);
 594 (%o2)                   2007.265612087104
 595 @end example
 596
 597 @opencatbox{Categories:}
 598 @category{Time and date functions}
 599 @closecatbox
 600 @end deffn
 601
 602 @c -----------------------------------------------------------------------------
 603 @anchor{elapsed_real_time}
 604 @deffn {Function} elapsed_real_time ()
 605
 606 Returns the number of seconds (including fractions of a second)
 607 since Maxima was most recently started or restarted.
 608 The return value is a floating-point number.
 609
 610 See also @mref{absolute_real_time} and @mrefdot{elapsed_run_time}
 611
 612 Example:
 613
 614 @c ===beg===
 615 @c elapsed_real_time ();
 616 @c expand ((a + b)^500)$
 617 @c elapsed_real_time ();
 618 @c ===end===
 619 @example
 620 (%i1) elapsed_real_time ();
 621 (%o1)                       2.559324
 622 (%i2) expand ((a + b)^500)$
 623 (%i3) elapsed_real_time ();
 624 (%o3)                       7.552087
 625 @end example
 626
 627 @opencatbox{Categories:}
 628 @category{Time and date functions}
 629 @closecatbox
 630 @end deffn
 631
 632 @c -----------------------------------------------------------------------------
 633 @anchor{elapsed_run_time}
 634 @deffn {Function} elapsed_run_time ()
 635
 636 Returns an estimate of the number of seconds (including fractions of a second)
 637 which Maxima has spent in computations since Maxima was most recently started
 638 or restarted.  The return value is a floating-point number.
 639
 640 See also @mref{absolute_real_time} and @mrefdot{elapsed_real_time}
 641
 642 Example:
 643
 644 @c ===beg===
 645 @c elapsed_run_time ();
 646 @c expand ((a + b)^500)$
 647 @c elapsed_run_time ();
 648 @c ===end===
 649 @example
 650 (%i1) elapsed_run_time ();
 651 (%o1)                         0.04
 652 (%i2) expand ((a + b)^500)$
 653 (%i3) elapsed_run_time ();
 654 (%o3)                         1.26
 655 @end example
 656
 657 @opencatbox{Categories:}
 658 @category{Time and date functions}
 659 @closecatbox
 660 @end deffn
 661