configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.3
  22 DRI2PROTO_REQUIRED=1.99.3
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  33 dnl configuration in that case.
  34 AC_PROG_INSTALL
  35 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  36
  37 dnl We need a POSIX shell for parts of the build. Assume we have one
  38 dnl in most cases.
  39 case "$host_os" in
  40 solaris*)
  41     # Solaris /bin/sh is too old/non-POSIX compliant
  42     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  43     SHELL="$POSIX_SHELL"
  44     ;;
  45 esac
  46
  47 MKDEP_OPTIONS=-fdepend
  48 dnl Ask gcc where it's keeping its secret headers
  49 if test "x$GCC" = xyes; then
  50     for dir in include include-fixed; do
  51         GCC_INCLUDES=`$CC -print-file-name=$dir`
  52         if test "x$GCC_INCLUDES" != x && \
  53            test "$GCC_INCLUDES" != "$dir" && \
  54            test -d "$GCC_INCLUDES"; then
  55             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  56         fi
  57     done
  58 fi
  59 AC_SUBST([MKDEP_OPTIONS])
  60
  61 dnl Make sure the pkg-config macros are defined
  62 m4_ifndef([PKG_PROG_PKG_CONFIG],
  63     [m4_fatal([Could not locate the pkg-config autoconf macros.
  64   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  65   are in a different location, try setting the environment variable
  66   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  67 PKG_PROG_PKG_CONFIG()
  68
  69 dnl LIB_DIR - library basename
  70 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  71 AC_SUBST([LIB_DIR])
  72
  73 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  74 _SAVE_LDFLAGS="$LDFLAGS"
  75 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  76 AC_SUBST([EXTRA_LIB_PATH])
  77
  78 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  79 _SAVE_CPPFLAGS="$CPPFLAGS"
  80 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  81 AC_SUBST([X11_INCLUDES])
  82
  83 dnl Compiler macros
  84 DEFINES=""
  85 AC_SUBST([DEFINES])
  86 case "$host_os" in
  87 linux*|*-gnu*|gnu*)
  88     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  89     ;;
  90 solaris*)
  91     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  92     ;;
  93 esac
  94
  95 dnl Add flags for gcc and g++
  96 if test "x$GCC" = xyes; then
  97     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  98
  99     # Work around aliasing bugs - developers should comment this out
 100     CFLAGS="$CFLAGS -fno-strict-aliasing"
 101 fi
 102 if test "x$GXX" = xyes; then
 103     CXXFLAGS="$CXXFLAGS -Wall"
 104
 105     # Work around aliasing bugs - developers should comment this out
 106     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 107 fi
 108
 109 dnl These should be unnecessary, but let the user set them if they want
 110 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 111     Default is to use CFLAGS.])
 112 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 113     compiler. Default is to use CFLAGS.])
 114 AC_SUBST([OPT_FLAGS])
 115 AC_SUBST([ARCH_FLAGS])
 116
 117 dnl
 118 dnl Hacks to enable 32 or 64 bit build
 119 dnl
 120 AC_ARG_ENABLE([32-bit],
 121     [AS_HELP_STRING([--enable-32-bit],
 122         [build 32-bit libraries @<:@default=auto@:>@])],
 123     [enable_32bit="$enableval"],
 124     [enable_32bit=auto]
 125 )
 126 if test "x$enable_32bit" = xyes; then
 127     if test "x$GCC" = xyes; then
 128         CFLAGS="$CFLAGS -m32"
 129     fi
 130     if test "x$GXX" = xyes; then
 131         CXXFLAGS="$CXXFLAGS -m32"
 132     fi
 133 fi
 134 AC_ARG_ENABLE([64-bit],
 135     [AS_HELP_STRING([--enable-64-bit],
 136         [build 64-bit libraries @<:@default=auto@:>@])],
 137     [enable_64bit="$enableval"],
 138     [enable_64bit=auto]
 139 )
 140 if test "x$enable_64bit" = xyes; then
 141     if test "x$GCC" = xyes; then
 142         CFLAGS="$CFLAGS -m64"
 143     fi
 144     if test "x$GXX" = xyes; then
 145         CXXFLAGS="$CXXFLAGS -m64"
 146     fi
 147 fi
 148
 149 dnl
 150 dnl shared/static libraries, mimic libtool options
 151 dnl
 152 AC_ARG_ENABLE([static],
 153     [AS_HELP_STRING([--enable-static],
 154         [build static libraries @<:@default=disabled@:>@])],
 155     [enable_static="$enableval"],
 156     [enable_static=no]
 157 )
 158 case "x$enable_static" in
 159 xyes|xno ) ;;
 160 x ) enable_static=no ;;
 161 * )
 162     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 163     ;;
 164 esac
 165 AC_ARG_ENABLE([shared],
 166     [AS_HELP_STRING([--disable-shared],
 167         [build shared libraries @<:@default=enabled@:>@])],
 168     [enable_shared="$enableval"],
 169     [enable_shared=yes]
 170 )
 171 case "x$enable_shared" in
 172 xyes|xno ) ;;
 173 x ) enable_shared=yes ;;
 174 * )
 175     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 176     ;;
 177 esac
 178
 179 dnl Can't have static and shared libraries, default to static if user
 180 dnl explicitly requested. If both disabled, set to static since shared
 181 dnl was explicitly requirested.
 182 case "x$enable_static$enable_shared" in
 183 xyesyes )
 184     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 185     enable_shared=no
 186     ;;
 187 xnono )
 188     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 189     enable_static=yes
 190     ;;
 191 esac
 192
 193 dnl
 194 dnl mklib options
 195 dnl
 196 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 197 if test "$enable_static" = yes; then
 198     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 199 fi
 200 AC_SUBST([MKLIB_OPTIONS])
 201
 202 dnl
 203 dnl other compiler options
 204 dnl
 205 AC_ARG_ENABLE([debug],
 206     [AS_HELP_STRING([--enable-debug],
 207         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 208     [enable_debug="$enableval"],
 209     [enable_debug=no]
 210 )
 211 if test "x$enable_debug" = xyes; then
 212     DEFINES="$DEFINES -DDEBUG"
 213     if test "x$GCC" = xyes; then
 214         CFLAGS="$CFLAGS -g"
 215     fi
 216     if test "x$GXX" = xyes; then
 217         CXXFLAGS="$CXXFLAGS -g"
 218     fi
 219 fi
 220
 221 dnl
 222 dnl library names
 223 dnl
 224 if test "$enable_static" = yes; then
 225     LIB_EXTENSION='a'
 226 else
 227     case "$host_os" in
 228     darwin* )
 229         LIB_EXTENSION='dylib' ;;
 230     cygwin* )
 231         LIB_EXTENSION='dll' ;;
 232     * )
 233         LIB_EXTENSION='so' ;;
 234     esac
 235 fi
 236
 237 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 238 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 239 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 240 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 241 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 242
 243 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 244 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 245 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 246 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 247 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 248
 249 AC_SUBST([GL_LIB_NAME])
 250 AC_SUBST([GLU_LIB_NAME])
 251 AC_SUBST([GLUT_LIB_NAME])
 252 AC_SUBST([GLW_LIB_NAME])
 253 AC_SUBST([OSMESA_LIB_NAME])
 254
 255 AC_SUBST([GL_LIB_GLOB])
 256 AC_SUBST([GLU_LIB_GLOB])
 257 AC_SUBST([GLUT_LIB_GLOB])
 258 AC_SUBST([GLW_LIB_GLOB])
 259 AC_SUBST([OSMESA_LIB_GLOB])
 260
 261 dnl
 262 dnl Arch/platform-specific settings
 263 dnl
 264 AC_ARG_ENABLE([asm],
 265     [AS_HELP_STRING([--disable-asm],
 266         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 267     [enable_asm="$enableval"],
 268     [enable_asm=yes]
 269 )
 270 asm_arch=""
 271 ASM_FLAGS=""
 272 MESA_ASM_SOURCES=""
 273 GLAPI_ASM_SOURCES=""
 274 AC_MSG_CHECKING([whether to enable assembly])
 275 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 276 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 277 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 278     case "$host_cpu" in
 279     i?86 | x86_64)
 280         enable_asm=no
 281         AC_MSG_RESULT([no, cross compiling])
 282         ;;
 283     esac
 284 fi
 285 # check for supported arches
 286 if test "x$enable_asm" = xyes; then
 287     case "$host_cpu" in
 288     i?86)
 289         case "$host_os" in
 290         linux* | *freebsd* | dragonfly*)
 291             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 292             ;;
 293         esac
 294         ;;
 295     x86_64)
 296         case "$host_os" in
 297         linux* | *freebsd* | dragonfly*)
 298             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 299             ;;
 300         esac
 301         ;;
 302     powerpc)
 303         case "$host_os" in
 304         linux*)
 305             asm_arch=ppc
 306             ;;
 307         esac
 308         ;;
 309     sparc*)
 310         case "$host_os" in
 311         linux*)
 312             asm_arch=sparc
 313             ;;
 314         esac
 315         ;;
 316     esac
 317
 318     case "$asm_arch" in
 319     x86)
 320         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 321         MESA_ASM_SOURCES='$(X86_SOURCES)'
 322         GLAPI_ASM_SOURCES='$(X86_API)'
 323         AC_MSG_RESULT([yes, x86])
 324         ;;
 325     x86_64)
 326         ASM_FLAGS="-DUSE_X86_64_ASM"
 327         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 328         GLAPI_ASM_SOURCES='$(X86-64_API)'
 329         AC_MSG_RESULT([yes, x86_64])
 330         ;;
 331     ppc)
 332         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 333         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 334         AC_MSG_RESULT([yes, ppc])
 335         ;;
 336     sparc)
 337         ASM_FLAGS="-DUSE_SPARC_ASM"
 338         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 339         GLAPI_ASM_SOURCES='$(SPARC_API)'
 340         AC_MSG_RESULT([yes, sparc])
 341         ;;
 342     *)
 343         AC_MSG_RESULT([no, platform not supported])
 344         ;;
 345     esac
 346 fi
 347 AC_SUBST([ASM_FLAGS])
 348 AC_SUBST([MESA_ASM_SOURCES])
 349 AC_SUBST([GLAPI_ASM_SOURCES])
 350
 351 dnl PIC code macro
 352 MESA_PIC_FLAGS
 353
 354 dnl Check to see if dlopen is in default libraries (like Solaris, which
 355 dnl has it in libc), or if libdl is needed to get it.
 356 AC_CHECK_FUNC([dlopen], [],
 357     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 358
 359 dnl See if posix_memalign is available
 360 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 361
 362 dnl SELinux awareness.
 363 AC_ARG_ENABLE([selinux],
 364     [AS_HELP_STRING([--enable-selinux],
 365         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 366     [MESA_SELINUX="$enableval"],
 367     [MESA_SELINUX=no])
 368 if test "x$enable_selinux" = "xyes"; then
 369     AC_CHECK_HEADER([selinux/selinux.h],[],
 370                     [AC_MSG_ERROR([SELinux headers not found])])
 371     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 372                  [AC_MSG_ERROR([SELinux library not found])])
 373     SELINUX_LIBS="-lselinux"
 374     DEFINES="$DEFINES -DMESA_SELINUX"
 375 fi
 376
 377 dnl
 378 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 379 dnl More later: directfb, fbdev, ...
 380 dnl
 381 default_driver="xlib"
 382
 383 case "$host_os" in
 384 linux*)
 385     case "$host_cpu" in
 386     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 387     esac
 388     ;;
 389 *freebsd* | dragonfly*)
 390     case "$host_cpu" in
 391     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 392     esac
 393     ;;
 394 esac
 395
 396 AC_ARG_WITH([driver],
 397     [AS_HELP_STRING([--with-driver=DRIVER],
 398         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 399     [mesa_driver="$withval"],
 400     [mesa_driver="$default_driver"])
 401 dnl Check for valid option
 402 case "x$mesa_driver" in
 403 xxlib|xdri|xosmesa)
 404     ;;
 405 *)
 406     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 407     ;;
 408 esac
 409
 410 dnl
 411 dnl Driver specific build directories
 412 dnl
 413 SRC_DIRS="mesa glew"
 414 GLU_DIRS="sgi"
 415 WINDOW_SYSTEM=""
 416 GALLIUM_DIRS="auxiliary drivers state_trackers"
 417 GALLIUM_WINSYS_DIRS=""
 418 GALLIUM_WINSYS_DRM_DIRS=""
 419 GALLIUM_AUXILIARY_DIRS="rbug draw translate cso_cache pipebuffer tgsi sct rtasm util indices"
 420 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 421 GALLIUM_STATE_TRACKERS_DIRS=""
 422
 423 case "$mesa_driver" in
 424 xlib)
 425     DRIVER_DIRS="x11"
 426     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS xlib"
 427     ;;
 428 dri)
 429     SRC_DIRS="glx/x11 $SRC_DIRS"
 430     DRIVER_DIRS="dri"
 431     WINDOW_SYSTEM="dri"
 432     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS drm"
 433     ;;
 434 osmesa)
 435     DRIVER_DIRS="osmesa"
 436     ;;
 437 esac
 438 AC_SUBST([SRC_DIRS])
 439 AC_SUBST([GLU_DIRS])
 440 AC_SUBST([DRIVER_DIRS])
 441 AC_SUBST([WINDOW_SYSTEM])
 442 AC_SUBST([GALLIUM_DIRS])
 443 AC_SUBST([GALLIUM_WINSYS_DIRS])
 444 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 445 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 446 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 447 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 448 AC_SUBST([RADEON_CFLAGS])
 449 AC_SUBST([RADEON_LDFLAGS])
 450
 451 dnl
 452 dnl User supplied program configuration
 453 dnl
 454 if test -d "$srcdir/progs/demos"; then
 455     default_demos=yes
 456 else
 457     default_demos=no
 458 fi
 459 AC_ARG_WITH([demos],
 460     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 461         [optional comma delimited demo directories to build
 462         @<:@default=auto if source available@:>@])],
 463     [with_demos="$withval"],
 464     [with_demos="$default_demos"])
 465 if test "x$with_demos" = x; then
 466     with_demos=no
 467 fi
 468
 469 dnl If $with_demos is yes, directories will be added as libs available
 470 PROGRAM_DIRS=""
 471 case "$with_demos" in
 472 no) ;;
 473 yes)
 474     # If the driver isn't osmesa, we have libGL and can build xdemos
 475     if test "$mesa_driver" != osmesa; then
 476         PROGRAM_DIRS="xdemos"
 477     fi
 478     ;;
 479 *)
 480     # verify the requested demos directories exist
 481     demos=`IFS=,; echo $with_demos`
 482     for demo in $demos; do
 483         test -d "$srcdir/progs/$demo" || \
 484             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 485     done
 486     PROGRAM_DIRS="$demos"
 487     ;;
 488 esac
 489
 490 dnl
 491 dnl Find out if X is available. The variable have_x is set if libX11 is
 492 dnl found to mimic AC_PATH_XTRA.
 493 dnl
 494 if test -n "$PKG_CONFIG"; then
 495     AC_MSG_CHECKING([pkg-config files for X11 are available])
 496     PKG_CHECK_EXISTS([x11],[
 497         x11_pkgconfig=yes
 498         have_x=yes
 499         ],[
 500         x11_pkgconfig=no
 501     ])
 502     AC_MSG_RESULT([$x11_pkgconfig])
 503 else
 504     x11_pkgconfig=no
 505 fi
 506 dnl Use the autoconf macro if no pkg-config files
 507 if test "$x11_pkgconfig" = no; then
 508     AC_PATH_XTRA
 509 fi
 510
 511 dnl Try to tell the user that the --x-* options are only used when
 512 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 513 m4_divert_once([HELP_BEGIN],
 514 [These options are only used when the X libraries cannot be found by the
 515 pkg-config utility.])
 516
 517 dnl We need X for xlib and dri, so bomb now if it's not found
 518 case "$mesa_driver" in
 519 xlib|dri)
 520     if test "$no_x" = yes; then
 521         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 522     fi
 523     ;;
 524 esac
 525
 526 dnl XCB - this is only used for GLX right now
 527 AC_ARG_ENABLE([xcb],
 528     [AS_HELP_STRING([--enable-xcb],
 529         [use XCB for GLX @<:@default=disabled@:>@])],
 530     [enable_xcb="$enableval"],
 531     [enable_xcb=no])
 532 if test "x$enable_xcb" = xyes; then
 533     DEFINES="$DEFINES -DUSE_XCB"
 534 else
 535     enable_xcb=no
 536 fi
 537
 538 dnl
 539 dnl libGL configuration per driver
 540 dnl
 541 case "$mesa_driver" in
 542 xlib)
 543     if test "$x11_pkgconfig" = yes; then
 544         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 545         GL_PC_REQ_PRIV="x11 xext"
 546         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 547         GL_LIB_DEPS="$XLIBGL_LIBS"
 548     else
 549         # should check these...
 550         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 551         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 552         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 553         GL_PC_CFLAGS="$X11_INCLUDES"
 554     fi
 555     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 556     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 557
 558     # if static, move the external libraries to the programs
 559     # and empty the libraries for libGL
 560     if test "$enable_static" = yes; then
 561         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 562         GL_LIB_DEPS=""
 563     fi
 564     ;;
 565 dri)
 566     # DRI must be shared, I think
 567     if test "$enable_static" = yes; then
 568         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 569     fi
 570
 571     # Check for libdrm
 572     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 573     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 574     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 575     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 576
 577     PKG_CHECK_MODULES([LIBDRM_RADEON], [libdrm_radeon], HAVE_LIBDRM_RADEON=yes, HAVE_LIBDRM_RADEON=no)
 578
 579     if test "$HAVE_LIBDRM_RADEON" = yes; then
 580         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 581         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 582     fi
 583
 584     # find the DRI deps for libGL
 585     if test "$x11_pkgconfig" = yes; then
 586         # add xcb modules if necessary
 587         dri_modules="x11 xext xxf86vm xdamage xfixes"
 588         if test "$enable_xcb" = yes; then
 589             dri_modules="$dri_modules x11-xcb xcb-glx"
 590         fi
 591
 592         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 593         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 594         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 595         GL_LIB_DEPS="$DRIGL_LIBS"
 596     else
 597         # should check these...
 598         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 599         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 600         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 601         GL_PC_CFLAGS="$X11_INCLUDES"
 602
 603         # XCB can only be used from pkg-config
 604         if test "$enable_xcb" = yes; then
 605             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 606             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 607             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 608             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 609         fi
 610     fi
 611
 612     # need DRM libs, -lpthread, etc.
 613     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 614     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 615     ;;
 616 osmesa)
 617     # No libGL for osmesa
 618     GL_LIB_DEPS=""
 619     ;;
 620 esac
 621 AC_SUBST([GL_LIB_DEPS])
 622 AC_SUBST([GL_PC_REQ_PRIV])
 623 AC_SUBST([GL_PC_LIB_PRIV])
 624 AC_SUBST([GL_PC_CFLAGS])
 625 AC_SUBST([DRI_PC_REQ_PRIV])
 626
 627 dnl
 628 dnl More X11 setup
 629 dnl
 630 if test "$mesa_driver" = xlib; then
 631     DEFINES="$DEFINES -DUSE_XSHM"
 632 fi
 633
 634 dnl
 635 dnl More DRI setup
 636 dnl
 637 AC_ARG_ENABLE([glx-tls],
 638     [AS_HELP_STRING([--enable-glx-tls],
 639         [enable TLS support in GLX @<:@default=disabled@:>@])],
 640     [GLX_USE_TLS="$enableval"],
 641     [GLX_USE_TLS=no])
 642 dnl Directory for DRI drivers
 643 AC_ARG_WITH([dri-driverdir],
 644     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 645         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 646     [DRI_DRIVER_INSTALL_DIR="$withval"],
 647     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 648 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 649 dnl Direct rendering or just indirect rendering
 650 AC_ARG_ENABLE([driglx-direct],
 651     [AS_HELP_STRING([--disable-driglx-direct],
 652         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 653     [driglx_direct="$enableval"],
 654     [driglx_direct="yes"])
 655 dnl Which drivers to build - default is chosen by platform
 656 AC_ARG_WITH([dri-drivers],
 657     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 658         [comma delimited DRI drivers list, e.g.
 659         "swrast,i965,radeon" @<:@default=auto@:>@])],
 660     [with_dri_drivers="$withval"],
 661     [with_dri_drivers=yes])
 662 if test "x$with_dri_drivers" = x; then
 663     with_dri_drivers=no
 664 fi
 665
 666 dnl If $with_dri_drivers is yes, directories will be added through
 667 dnl platform checks
 668 DRI_DIRS=""
 669 case "$with_dri_drivers" in
 670 no) ;;
 671 yes)
 672     DRI_DIRS="yes"
 673     ;;
 674 *)
 675     # verify the requested driver directories exist
 676     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 677     for driver in $dri_drivers; do
 678         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 679             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 680     done
 681     DRI_DIRS="$dri_drivers"
 682     ;;
 683 esac
 684
 685 dnl Just default to no EGL for now
 686 USING_EGL=0
 687 AC_SUBST([USING_EGL])
 688
 689 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 690 if test "$mesa_driver" = dri; then
 691     # Use TLS in GLX?
 692     if test "x$GLX_USE_TLS" = xyes; then
 693         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 694     fi
 695
 696     if test "x$USING_EGL" = x1; then
 697         PROGRAM_DIRS="egl"
 698     fi
 699
 700     # Platform specific settings and drivers to build
 701     case "$host_os" in
 702     linux*)
 703         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 704         if test "x$driglx_direct" = xyes; then
 705             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 706         fi
 707         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 708
 709         case "$host_cpu" in
 710         x86_64)
 711             # ffb, gamma, and sis are missing because they have not be
 712             # converted to use the new interface.  i810 are missing
 713             # because there is no x86-64 system where they could *ever*
 714             # be used.
 715             if test "x$DRI_DIRS" = "xyes"; then
 716                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 717                     savage tdfx unichrome swrast"
 718             fi
 719             ;;
 720         powerpc*)
 721             # Build only the drivers for cards that exist on PowerPC.
 722             # At some point MGA will be added, but not yet.
 723             if test "x$DRI_DIRS" = "xyes"; then
 724                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 725             fi
 726             ;;
 727         sparc*)
 728             # Build only the drivers for cards that exist on sparc`
 729             if test "x$DRI_DIRS" = "xyes"; then
 730                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon ffb swrast"
 731             fi
 732             ;;
 733         esac
 734         ;;
 735     freebsd* | dragonfly*)
 736         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 737         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 738         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 739         if test "x$driglx_direct" = xyes; then
 740             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 741         fi
 742         if test "x$GXX" = xyes; then
 743             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 744         fi
 745
 746         # ffb and gamma are missing because they have not been converted
 747         # to use the new interface.
 748         if test "x$DRI_DIRS" = "xyes"; then
 749             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 750                 unichrome savage sis swrast"
 751         fi
 752         ;;
 753     gnu*)
 754         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 755         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 756         ;;
 757     solaris*)
 758         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 759         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 760         if test "x$driglx_direct" = xyes; then
 761             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 762         fi
 763         ;;
 764     esac
 765
 766     # default drivers
 767     if test "x$DRI_DIRS" = "xyes"; then
 768         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon s3v \
 769             savage sis tdfx trident unichrome ffb swrast"
 770     fi
 771
 772     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 773
 774     # Check for expat
 775     EXPAT_INCLUDES=""
 776     EXPAT_LIB=-lexpat
 777     AC_ARG_WITH([expat],
 778         [AS_HELP_STRING([--with-expat=DIR],
 779             [expat install directory])],[
 780         EXPAT_INCLUDES="-I$withval/include"
 781         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 782         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 783         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 784         ])
 785     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 786     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 787         [AC_MSG_ERROR([Expat required for DRI.])])
 788
 789     # put all the necessary libs together
 790     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 791 fi
 792 AC_SUBST([DRI_DIRS])
 793 AC_SUBST([EXPAT_INCLUDES])
 794 AC_SUBST([DRI_LIB_DEPS])
 795
 796 dnl
 797 dnl OSMesa configuration
 798 dnl
 799 if test "$mesa_driver" = xlib; then
 800     default_gl_osmesa=yes
 801 else
 802     default_gl_osmesa=no
 803 fi
 804 AC_ARG_ENABLE([gl-osmesa],
 805     [AS_HELP_STRING([--enable-gl-osmesa],
 806         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 807     [gl_osmesa="$enableval"],
 808     [gl_osmesa="$default_gl_osmesa"])
 809 if test "x$gl_osmesa" = xyes; then
 810     if test "$mesa_driver" = osmesa; then
 811         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 812     else
 813         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 814     fi
 815 fi
 816
 817 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 818 AC_ARG_WITH([osmesa-bits],
 819     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 820         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 821     [osmesa_bits="$withval"],
 822     [osmesa_bits=8])
 823 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 824     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 825     osmesa_bits=8
 826 fi
 827 case "x$osmesa_bits" in
 828 x8)
 829     OSMESA_LIB=OSMesa
 830     ;;
 831 x16|x32)
 832     OSMESA_LIB="OSMesa$osmesa_bits"
 833     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 834     ;;
 835 *)
 836     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 837     ;;
 838 esac
 839 AC_SUBST([OSMESA_LIB])
 840
 841 case "$mesa_driver" in
 842 osmesa)
 843     # only link libraries with osmesa if shared
 844     if test "$enable_static" = no; then
 845         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 846     else
 847         OSMESA_LIB_DEPS=""
 848     fi
 849     OSMESA_MESA_DEPS=""
 850     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 851     ;;
 852 *)
 853     # Link OSMesa to libGL otherwise
 854     OSMESA_LIB_DEPS=""
 855     # only link libraries with osmesa if shared
 856     if test "$enable_static" = no; then
 857         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 858     else
 859         OSMESA_MESA_DEPS=""
 860     fi
 861     OSMESA_PC_REQ="gl"
 862     ;;
 863 esac
 864 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 865 AC_SUBST([OSMESA_LIB_DEPS])
 866 AC_SUBST([OSMESA_MESA_DEPS])
 867 AC_SUBST([OSMESA_PC_REQ])
 868 AC_SUBST([OSMESA_PC_LIB_PRIV])
 869
 870 dnl
 871 dnl EGL configuration
 872 dnl
 873 AC_ARG_ENABLE([egl],
 874     [AS_HELP_STRING([--disable-egl],
 875         [disable EGL library @<:@default=enabled@:>@])],
 876     [enable_egl="$enableval"],
 877     [enable_egl=yes])
 878 if test "x$enable_egl" = xyes; then
 879     SRC_DIRS="$SRC_DIRS egl"
 880
 881     if test "$x11_pkgconfig" = yes; then
 882         PKG_CHECK_MODULES([EGL], [x11])
 883         EGL_LIB_DEPS="$EGL_LIBS"
 884     else
 885         # should check these...
 886         EGL_LIB_DEPS="$X_LIBS -lX11"
 887     fi
 888     EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS"
 889 fi
 890 AC_SUBST([EGL_LIB_DEPS])
 891
 892 dnl
 893 dnl GLU configuration
 894 dnl
 895 AC_ARG_ENABLE([glu],
 896     [AS_HELP_STRING([--disable-glu],
 897         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 898     [enable_glu="$enableval"],
 899     [enable_glu=yes])
 900 if test "x$enable_glu" = xyes; then
 901     SRC_DIRS="$SRC_DIRS glu"
 902
 903     case "$mesa_driver" in
 904     osmesa)
 905         # If GLU is available and we have libOSMesa (not 16 or 32),
 906         # we can build the osdemos
 907         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 908             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 909         fi
 910
 911         # Link libGLU to libOSMesa instead of libGL
 912         GLU_LIB_DEPS=""
 913         GLU_PC_REQ="osmesa"
 914         if test "$enable_static" = no; then
 915             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 916         else
 917             GLU_MESA_DEPS=""
 918         fi
 919         ;;
 920     *)
 921         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 922         GLU_PC_REQ="gl"
 923         GLU_PC_LIB_PRIV="-lm"
 924         if test "$enable_static" = no; then
 925             GLU_LIB_DEPS="-lm"
 926             GLU_MESA_DEPS='-l$(GL_LIB)'
 927         else
 928             GLU_LIB_DEPS=""
 929             GLU_MESA_DEPS=""
 930             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 931         fi
 932         ;;
 933     esac
 934 fi
 935 if test "$enable_static" = no; then
 936     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 937 fi
 938 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 939 AC_SUBST([GLU_LIB_DEPS])
 940 AC_SUBST([GLU_MESA_DEPS])
 941 AC_SUBST([GLU_PC_REQ])
 942 AC_SUBST([GLU_PC_REQ_PRIV])
 943 AC_SUBST([GLU_PC_LIB_PRIV])
 944 AC_SUBST([GLU_PC_CFLAGS])
 945
 946 dnl
 947 dnl GLw configuration
 948 dnl
 949 AC_ARG_ENABLE([glw],
 950     [AS_HELP_STRING([--disable-glw],
 951         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 952     [enable_glw="$enableval"],
 953     [enable_glw=yes])
 954 dnl Don't build GLw on osmesa
 955 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 956     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 957     enable_glw=no
 958 fi
 959 AC_ARG_ENABLE([motif],
 960     [AS_HELP_STRING([--enable-motif],
 961         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 962     [enable_motif="$enableval"],
 963     [enable_motif=no])
 964
 965 if test "x$enable_glw" = xyes; then
 966     SRC_DIRS="$SRC_DIRS glw"
 967     if test "$x11_pkgconfig" = yes; then
 968         PKG_CHECK_MODULES([GLW],[x11 xt])
 969         GLW_PC_REQ_PRIV="x11 xt"
 970         GLW_LIB_DEPS="$GLW_LIBS"
 971     else
 972         # should check these...
 973         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 974         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 975         GLW_PC_CFLAGS="$X11_INCLUDES"
 976     fi
 977
 978     GLW_SOURCES="GLwDrawA.c"
 979     MOTIF_CFLAGS=
 980     if test "x$enable_motif" = xyes; then
 981         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 982         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 983         if test "x$MOTIF_CONFIG" != xno; then
 984             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 985             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 986         else
 987             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 988                 [AC_MSG_ERROR([Can't locate Motif headers])])
 989             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 990                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 991         fi
 992         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 993         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 994         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 995         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 996     fi
 997
 998     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 999     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1000     if test "$enable_static" = no; then
1001         GLW_MESA_DEPS='-l$(GL_LIB)'
1002         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1003     else
1004         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1005         GLW_LIB_DEPS=""
1006         GLW_MESA_DEPS=""
1007     fi
1008 fi
1009 AC_SUBST([GLW_LIB_DEPS])
1010 AC_SUBST([GLW_MESA_DEPS])
1011 AC_SUBST([GLW_SOURCES])
1012 AC_SUBST([MOTIF_CFLAGS])
1013 AC_SUBST([GLW_PC_REQ_PRIV])
1014 AC_SUBST([GLW_PC_LIB_PRIV])
1015 AC_SUBST([GLW_PC_CFLAGS])
1016
1017 dnl
1018 dnl GLUT configuration
1019 dnl
1020 if test -f "$srcdir/include/GL/glut.h"; then
1021     default_glut=yes
1022 else
1023     default_glut=no
1024 fi
1025 AC_ARG_ENABLE([glut],
1026     [AS_HELP_STRING([--disable-glut],
1027         [enable GLUT library @<:@default=enabled if source available@:>@])],
1028     [enable_glut="$enableval"],
1029     [enable_glut="$default_glut"])
1030
1031 dnl Can't build glut if GLU not available
1032 if test "x$enable_glu$enable_glut" = xnoyes; then
1033     AC_MSG_WARN([Disabling glut since GLU is disabled])
1034     enable_glut=no
1035 fi
1036 dnl Don't build glut on osmesa
1037 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1038     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1039     enable_glut=no
1040 fi
1041
1042 if test "x$enable_glut" = xyes; then
1043     SRC_DIRS="$SRC_DIRS glut/glx"
1044     GLUT_CFLAGS=""
1045     if test "x$GCC" = xyes; then
1046         GLUT_CFLAGS="-fexceptions"
1047     fi
1048     if test "$x11_pkgconfig" = yes; then
1049         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1050         GLUT_PC_REQ_PRIV="x11 xmu xi"
1051         GLUT_LIB_DEPS="$GLUT_LIBS"
1052     else
1053         # should check these...
1054         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1055         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1056         GLUT_PC_CFLAGS="$X11_INCLUDES"
1057     fi
1058     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1059     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1060
1061     # If glut is available, we can build most programs
1062     if test "$with_demos" = yes; then
1063         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1064     fi
1065
1066     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1067     if test "$enable_static" = no; then
1068         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1069     else
1070         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1071         GLUT_LIB_DEPS=""
1072         GLUT_MESA_DEPS=""
1073     fi
1074 fi
1075 AC_SUBST([GLUT_LIB_DEPS])
1076 AC_SUBST([GLUT_MESA_DEPS])
1077 AC_SUBST([GLUT_CFLAGS])
1078 AC_SUBST([GLUT_PC_REQ_PRIV])
1079 AC_SUBST([GLUT_PC_LIB_PRIV])
1080 AC_SUBST([GLUT_PC_CFLAGS])
1081
1082 dnl
1083 dnl Program library dependencies
1084 dnl    Only libm is added here if necessary as the libraries should
1085 dnl    be pulled in by the linker
1086 dnl
1087 if test "x$APP_LIB_DEPS" = x; then
1088     case "$host_os" in
1089     solaris*)
1090         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1091         ;;
1092     cygwin*)
1093         APP_LIB_DEPS="-lX11"
1094         ;;
1095     *)
1096         APP_LIB_DEPS="-lm"
1097         ;;
1098     esac
1099 fi
1100 AC_SUBST([APP_LIB_DEPS])
1101 AC_SUBST([PROGRAM_DIRS])
1102
1103 dnl
1104 dnl Gallium configuration
1105 dnl
1106 AC_ARG_ENABLE([gallium],
1107     [AS_HELP_STRING([--disable-gallium],
1108         [build gallium @<:@default=enabled@:>@])],
1109     [enable_gallium="$enableval"],
1110     [enable_gallium=yes])
1111 if test "x$enable_gallium" = xyes; then
1112     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1113 fi
1114
1115 dnl
1116 dnl Gallium state trackers configuration
1117 dnl
1118 AC_ARG_WITH([state-trackers],
1119     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1120         [comma delimited state_trackers list, e.g.
1121         "egl,glx" @<:@default=auto@:>@])],
1122     [with_state_trackers="$withval"],
1123     [with_state_trackers=yes])
1124
1125 case "$with_state_trackers" in
1126 no)
1127     GALLIUM_STATE_TRACKERS_DIRS=""
1128     ;;
1129 yes)
1130     # look at what else is built
1131     case "$mesa_driver" in
1132     xlib)
1133         GALLIUM_STATE_TRACKERS_DIRS=glx
1134         ;;
1135     dri)
1136         test "x$enable_egl" = xyes && GALLIUM_STATE_TRACKERS_DIRS=egl
1137         ;;
1138     esac
1139     ;;
1140 *)
1141     # verify the requested state tracker exist
1142     state_trackers=`IFS=', '; echo $with_state_trackers`
1143     for tracker in $state_trackers; do
1144         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1145             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1146
1147         if test "$tracker" = egl && test "x$enable_egl" != xyes; then
1148             AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1149         fi
1150     done
1151     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1152     ;;
1153 esac
1154
1155 AC_ARG_WITH([xorg-driver-dir],
1156     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1157                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1158     [XORG_DRIVER_INSTALL_DIR="$withval"],
1159     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1160 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1161
1162 dnl
1163 dnl Gallium Intel configuration
1164 dnl
1165 AC_ARG_ENABLE([gallium-intel],
1166     [AS_HELP_STRING([--disable-gallium-intel],
1167         [build gallium intel @<:@default=enabled@:>@])],
1168     [enable_gallium_intel="$enableval"],
1169     [enable_gallium_intel=yes])
1170 if test "x$enable_gallium_intel" = xyes; then
1171     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1172     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1173 fi
1174
1175 dnl
1176 dnl Gallium Radeon configuration
1177 dnl
1178 AC_ARG_ENABLE([gallium-radeon],
1179     [AS_HELP_STRING([--enable-gallium-radeon],
1180         [build gallium radeon @<:@default=disabled@:>@])],
1181     [enable_gallium_radeon="$enableval"],
1182     [enable_gallium_radeon=no])
1183 if test "x$enable_gallium_radeon" = xyes; then
1184     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1185     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1186 fi
1187
1188 dnl
1189 dnl Gallium Radeon configuration
1190 dnl
1191 AC_ARG_ENABLE([gallium-nouveau],
1192     [AS_HELP_STRING([--enable-gallium-nouveau],
1193         [build gallium nouveau @<:@default=disabled@:>@])],
1194     [enable_gallium_nouveau="$enableval"],
1195     [enable_gallium_nouveau=no])
1196 if test "x$enable_gallium_nouveau" = xyes; then
1197     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1198     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv04 nv10 nv20 nv30 nv40 nv50"
1199 fi
1200
1201
1202 dnl Restore LDFLAGS and CPPFLAGS
1203 LDFLAGS="$_SAVE_LDFLAGS"
1204 CPPFLAGS="$_SAVE_CPPFLAGS"
1205
1206 dnl Substitute the config
1207 AC_CONFIG_FILES([configs/autoconf])
1208
1209 dnl Replace the configs/current symlink
1210 AC_CONFIG_COMMANDS([configs],[
1211 if test -f configs/current || test -L configs/current; then
1212     rm -f configs/current
1213 fi
1214 ln -s autoconf configs/current
1215 ])
1216
1217 AC_OUTPUT
1218
1219 dnl
1220 dnl Output some configuration info for the user
1221 dnl
1222 echo ""
1223 echo "        prefix:          $prefix"
1224 echo "        exec_prefix:     $exec_prefix"
1225 echo "        libdir:          $libdir"
1226 echo "        includedir:      $includedir"
1227
1228 dnl Driver info
1229 echo ""
1230 echo "        Driver:          $mesa_driver"
1231 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1232     echo "        OSMesa:          lib$OSMESA_LIB"
1233 else
1234     echo "        OSMesa:          no"
1235 fi
1236 if test "$mesa_driver" = dri; then
1237     # cleanup the drivers var
1238     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1239 if test "x$DRI_DIRS" = x; then
1240     echo "        DRI drivers:     no"
1241 else
1242     echo "        DRI drivers:     $dri_dirs"
1243 fi
1244     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1245 fi
1246 echo "        Use XCB:         $enable_xcb"
1247
1248 echo ""
1249 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1250     echo "        Gallium:         yes"
1251     echo "        Gallium dirs:    $GALLIUM_DIRS"
1252     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1253     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1254     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1255     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1256     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1257 else
1258     echo "        Gallium:         no"
1259 fi
1260
1261 dnl Libraries
1262 echo ""
1263 echo "        Shared libs:     $enable_shared"
1264 echo "        Static libs:     $enable_static"
1265 echo "        EGL:             $enable_egl"
1266 echo "        GLU:             $enable_glu"
1267 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1268 echo "        glut:            $enable_glut"
1269
1270 dnl Programs
1271 # cleanup the programs var for display
1272 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1273 if test "x$program_dirs" = x; then
1274     echo "        Demos:           no"
1275 else
1276     echo "        Demos:           $program_dirs"
1277 fi
1278
1279 dnl Compiler options
1280 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1281 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1282     $SED 's/^ *//;s/  */ /;s/ *$//'`
1283 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1284     $SED 's/^ *//;s/  */ /;s/ *$//'`
1285 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1286 echo ""
1287 echo "        CFLAGS:          $cflags"
1288 echo "        CXXFLAGS:        $cxxflags"
1289 echo "        Macros:          $defines"
1290
1291 echo ""
1292 echo "        Run '${MAKE-make}' to build Mesa"
1293 echo ""