CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (mesademos)
   4
   5 include (FindPkgConfig)
   6 include (CheckCCompilerFlag)
   7 include (CheckSymbolExists)
   8
   9 find_package (OpenGL REQUIRED)
  10 find_package (GLUT REQUIRED)
  11 find_package (X11)
  12
  13 find_library (GLEW_glew_LIBRARY GLEW
  14         /usr/lib
  15 )
  16
  17 find_path (GLEW_INCLUDE_DIR GL/glew.h
  18       /usr/include/GL
  19 )
  20
  21 if (PKG_CONFIG_FOUND AND NOT WIN32)
  22         pkg_check_modules (GLEW REQUIRED glew>=1.5.4)
  23         pkg_check_modules (EGL egl)
  24         pkg_check_modules (GLESV1 glesv1_cm)
  25         pkg_check_modules (GLESV2 glesv2)
  26         pkg_check_modules (VG vg)
  27         pkg_check_modules (OSMESA osmesa)
  28 endif ()
  29
  30 # Check for FreeGLUT 2.6 or later
  31 set (CMAKE_REQUIRED_INCLUDES "${GLUT_INCLUDE_DIR}")
  32 set (CMAKE_REQUIRED_LIBRARIES "${GLUT_glut_LIBRARY}")
  33 check_symbol_exists ("glutInitContextProfile" "GL/glut.h;GL/freeglut.h" HAVE_FREEGLUT)
  34 if (HAVE_FREEGLUT)
  35         add_definitions (-DHAVE_FREEGLUT)
  36 endif ()
  37
  38 if (UNIX)
  39         link_libraries(m)
  40 endif (UNIX)
  41
  42 # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  43 # from the standard OpenGL framework which provides support for GLUT and native
  44 # Mac OS X applications.
  45 if (X11_FOUND)
  46         if (APPLE)
  47                 find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  48                 if (NOT X11_GL_INCLUDE_PATH)
  49                         message (WARNING "Could not find GL/glx.h")
  50                         set (X11_FOUND FALSE)
  51                 endif (NOT X11_GL_INCLUDE_PATH)
  52                 set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  53
  54                 find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  55                 if (NOT X11_GL_LIB)
  56                         message (WARNING "Could not find libGL.dylib")
  57                         set (X11_FOUND FALSE)
  58                 endif (NOT X11_GL_LIB)
  59
  60                 find_library (X11_GLU_LIB GLU ${X11_LIB_SEARCH_PATH})
  61                 if (NOT X11_GLU_LIB)
  62                         message (WARNING "Could not find libGLU.dylib")
  63                         set (X11_FOUND FALSE)
  64                 endif (NOT X11_GLU_LIB)
  65         else ()
  66                 set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  67                 set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  68                 set (X11_GLU_LIB ${OPENGL_glu_LIBRARY})
  69         endif ()
  70 endif (X11_FOUND)
  71
  72 if (CMAKE_COMPILER_IS_GNUCC)
  73         add_definitions(
  74                 -Wall
  75                 -Wpointer-arith
  76                 -Wmissing-declarations
  77                 -fno-strict-aliasing
  78                 #-Wold-style-definition
  79                 #-Wdeclaration-after-statement
  80         )
  81         set (CMAKE_C_FLAGS "-Wstrict-prototypes -Wmissing-prototypes -Wnested-externs -Wbad-function-cast ${CMAKE_CXX_FLAGS}")
  82 endif ()
  83
  84 if (WIN32)
  85         # Nobody likes to include windows.h:
  86         # - Microsoft's GL/gl.h header depends on windows.h but doesn't include it;
  87         # - GLEW temporarily defines the necessary defines but undefines them later
  88         # - certain GLUT distributions don't include it;
  89         # - most of our programs are meant to be portable so don't include it.
  90         #
  91         # We could try to replicate the windows.h definitions required by
  92         # GL/gl.h, but the build time savings don't compensate the constant
  93         # headaches that brings, so instead we force windows.h to be included
  94         # on every file.
  95         if (MSVC)
  96                 add_definitions (-FIwindows.h)
  97         else (MSVC)
  98                 add_definitions (--include windows.h)
  99         endif (MSVC)
 100
 101         # Don't define min/max macros
 102         add_definitions (-DNOMINMAX)
 103
 104         # MSVC & MinGW only define & use APIENTRY
 105         add_definitions (-DGLAPIENTRY=__stdcall)
 106
 107         link_libraries (winmm)
 108 endif (WIN32)
 109
 110 if (MSVC)
 111         # Enable math constants defines
 112         add_definitions (-D_USE_MATH_DEFINES)
 113
 114         # Silence several MSVC pedantic warnings
 115         add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 116         add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 117         add_definitions (-wd4244) # conversion' conversion from 'type1' to 'type2', possible loss of data
 118
 119         # Use static runtime
 120         # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 121         foreach (flag_var
 122                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 123                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 124         )
 125                 if (${flag_var} MATCHES "/MD")
 126                         string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 127                 endif ()
 128         endforeach (flag_var)
 129 endif (MSVC)
 130
 131 if (MINGW)
 132         # Avoid depending on MinGW runtime DLLs
 133         check_c_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 134         if (HAVE_STATIC_LIBGCC_FLAG)
 135                 set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 136                 set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 137                 set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 138         endif ()
 139         check_c_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 140         if (HAVE_STATIC_LIBSTDCXX_FLAG)
 141                 set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 142                 set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 143                 set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 144         endif ()
 145 endif ()
 146
 147 if (APPLE)
 148         # Silence deprecated function warnings (we rely on GLUT which is now
 149         # declared as deprecated)
 150         add_definitions (-Wno-deprecated-declarations)
 151 endif ()
 152
 153 add_definitions(-DDEMOS_DATA_DIR=\"../data/\")
 154
 155 if (BUILD_SHARED_LIBS AND NOT DEFINED LIBDIR)
 156         set(LIBDIR lib)
 157 endif (BUILD_SHARED_LIBS AND NOT DEFINED LIBDIR)
 158
 159 add_subdirectory (src)
 160
 161
 162 install (FILES index.html DESTINATION doc)
 163
 164 set (CPACK_PACKAGE_NAME "mesa-demos")
 165 set (CPACK_PACKAGE_VERSION_MAJOR "8")
 166 set (CPACK_PACKAGE_VERSION_MINOR "4")
 167 set (CPACK_PACKAGE_VERSION_PATCH "0")
 168
 169 if (WIN32)
 170     set (CPACK_GENERATOR "ZIP")
 171 elseif (APPLE)
 172     set (CPACK_GENERATOR "DragNDrop")
 173     set (CPACK_DMG_FORMAT "UDBZ")
 174 else ()
 175     set (CPACK_GENERATOR "TBZ2")
 176 endif ()
 177
 178 include(CPack)