| blob | bcf4104515e5f96e83f510704e395ce3a499a790 |
1 dnl Process this file with autoconf to create configure.
3 AC_PREREQ([2.59])
5 dnl Versioning - scrape the version from configs/default
6 m4_define([mesa_version],
7 [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
8 m4_ifval(mesa_version,,
9 [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
11 dnl Tell the user about autoconf.html in the --help output
12 m4_divert_once([HELP_END], [
13 See docs/autoconf.html for more details on the options for Mesa.])
15 AC_INIT([Mesa],[mesa_version],
16 [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
17 AC_CONFIG_AUX_DIR([bin])
18 AC_CANONICAL_HOST
20 dnl Versions for external dependencies
21 LIBDRM_REQUIRED=2.4.15
22 LIBDRM_RADEON_REQUIRED=2.4.17
23 DRI2PROTO_REQUIRED=2.1
24 GLPROTO_REQUIRED=1.4.11
25 LIBDRM_XORG_REQUIRED=2.4.17
26 LIBKMS_XORG_REQUIRED=1.0.0
28 dnl Check for progs
29 AC_PROG_CPP
30 AC_PROG_CC
31 AC_PROG_CXX
32 AC_CHECK_PROGS([MAKE], [gmake make])
33 AC_PATH_PROG([MKDEP], [makedepend])
34 AC_PATH_PROG([SED], [sed])
36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
37 dnl configuration in that case.
38 AC_PROG_INSTALL
39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
41 dnl We need a POSIX shell for parts of the build. Assume we have one
42 dnl in most cases.
43 case "$host_os" in
44 solaris*)
45 # Solaris /bin/sh is too old/non-POSIX compliant
46 AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
47 SHELL="$POSIX_SHELL"
48 ;;
49 esac
51 dnl If we're using GCC, make sure that it is at least version 3.3.0. Older
52 dnl versions are explictly not supported.
53 if test "x$GCC" = xyes; then
54 AC_MSG_CHECKING([whether gcc version is sufficient])
55 major=0
56 minor=0
58 GCC_VERSION=`$CC -dumpversion`
59 if test $? -eq 0; then
60 major=`echo $GCC_VERSION | cut -d. -f1`
61 minor=`echo $GCC_VERSION | cut -d. -f1`
62 fi
64 if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
65 AC_MSG_RESULT([no])
66 AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
67 else
68 AC_MSG_RESULT([yes])
69 fi
70 fi
73 MKDEP_OPTIONS=-fdepend
74 dnl Ask gcc where it's keeping its secret headers
75 if test "x$GCC" = xyes; then
76 for dir in include include-fixed; do
77 GCC_INCLUDES=`$CC -print-file-name=$dir`
78 if test "x$GCC_INCLUDES" != x && \
79 test "$GCC_INCLUDES" != "$dir" && \
80 test -d "$GCC_INCLUDES"; then
81 MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
82 fi
83 done
84 fi
85 AC_SUBST([MKDEP_OPTIONS])
87 dnl Make sure the pkg-config macros are defined
88 m4_ifndef([PKG_PROG_PKG_CONFIG],
89 [m4_fatal([Could not locate the pkg-config autoconf macros.
90 These are usually located in /usr/share/aclocal/pkg.m4. If your macros
91 are in a different location, try setting the environment variable
92 ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
93 PKG_PROG_PKG_CONFIG()
95 dnl LIB_DIR - library basename
96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
97 AC_SUBST([LIB_DIR])
99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
100 _SAVE_LDFLAGS="$LDFLAGS"
101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
102 AC_SUBST([EXTRA_LIB_PATH])
104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
105 _SAVE_CPPFLAGS="$CPPFLAGS"
106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
107 AC_SUBST([X11_INCLUDES])
109 dnl Compiler macros
110 DEFINES=""
111 AC_SUBST([DEFINES])
112 case "$host_os" in
113 linux*|*-gnu*|gnu*)
114 DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
115 ;;
116 solaris*)
117 DEFINES="$DEFINES -DPTHREADS -DSVR4"
118 ;;
119 cygwin*)
120 DEFINES="$DEFINES -DPTHREADS"
121 ;;
122 esac
124 dnl Add flags for gcc and g++
125 if test "x$GCC" = xyes; then
126 CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
128 # Enable -fvisibility=hidden if using a gcc that supports it
129 save_CFLAGS="$CFLAGS"
130 AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
131 CFLAGS="$CFLAGS -fvisibility=hidden"
132 AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
133 [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
135 # Work around aliasing bugs - developers should comment this out
136 CFLAGS="$CFLAGS -fno-strict-aliasing"
137 fi
138 if test "x$GXX" = xyes; then
139 CXXFLAGS="$CXXFLAGS -Wall"
141 # Work around aliasing bugs - developers should comment this out
142 CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
143 fi
145 dnl These should be unnecessary, but let the user set them if they want
146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
147 Default is to use CFLAGS.])
148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
149 compiler. Default is to use CFLAGS.])
150 AC_SUBST([OPT_FLAGS])
151 AC_SUBST([ARCH_FLAGS])
153 dnl
154 dnl Hacks to enable 32 or 64 bit build
155 dnl
156 AC_ARG_ENABLE([32-bit],
157 [AS_HELP_STRING([--enable-32-bit],
158 [build 32-bit libraries @<:@default=auto@:>@])],
159 [enable_32bit="$enableval"],
160 [enable_32bit=auto]
161 )
162 if test "x$enable_32bit" = xyes; then
163 if test "x$GCC" = xyes; then
164 CFLAGS="$CFLAGS -m32"
165 ARCH_FLAGS="$ARCH_FLAGS -m32"
166 fi
167 if test "x$GXX" = xyes; then
168 CXXFLAGS="$CXXFLAGS -m32"
169 fi
170 fi
171 AC_ARG_ENABLE([64-bit],
172 [AS_HELP_STRING([--enable-64-bit],
173 [build 64-bit libraries @<:@default=auto@:>@])],
174 [enable_64bit="$enableval"],
175 [enable_64bit=auto]
176 )
177 if test "x$enable_64bit" = xyes; then
178 if test "x$GCC" = xyes; then
179 CFLAGS="$CFLAGS -m64"
180 fi
181 if test "x$GXX" = xyes; then
182 CXXFLAGS="$CXXFLAGS -m64"
183 fi
184 fi
186 dnl
187 dnl shared/static libraries, mimic libtool options
188 dnl
189 AC_ARG_ENABLE([static],
190 [AS_HELP_STRING([--enable-static],
191 [build static libraries @<:@default=disabled@:>@])],
192 [enable_static="$enableval"],
193 [enable_static=no]
194 )
195 case "x$enable_static" in
196 xyes|xno ) ;;
197 x ) enable_static=no ;;
198 * )
199 AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
200 ;;
201 esac
202 AC_ARG_ENABLE([shared],
203 [AS_HELP_STRING([--disable-shared],
204 [build shared libraries @<:@default=enabled@:>@])],
205 [enable_shared="$enableval"],
206 [enable_shared=yes]
207 )
208 case "x$enable_shared" in
209 xyes|xno ) ;;
210 x ) enable_shared=yes ;;
211 * )
212 AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
213 ;;
214 esac
216 dnl Can't have static and shared libraries, default to static if user
217 dnl explicitly requested. If both disabled, set to static since shared
218 dnl was explicitly requirested.
219 case "x$enable_static$enable_shared" in
220 xyesyes )
221 AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
222 enable_shared=no
223 ;;
224 xnono )
225 AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
226 enable_static=yes
227 ;;
228 esac
230 dnl
231 dnl mklib options
232 dnl
233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
234 if test "$enable_static" = yes; then
235 MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
236 fi
237 AC_SUBST([MKLIB_OPTIONS])
239 dnl
240 dnl other compiler options
241 dnl
242 AC_ARG_ENABLE([debug],
243 [AS_HELP_STRING([--enable-debug],
244 [use debug compiler flags and macros @<:@default=disabled@:>@])],
245 [enable_debug="$enableval"],
246 [enable_debug=no]
247 )
248 if test "x$enable_debug" = xyes; then
249 DEFINES="$DEFINES -DDEBUG"
250 if test "x$GCC" = xyes; then
251 CFLAGS="$CFLAGS -g"
252 fi
253 if test "x$GXX" = xyes; then
254 CXXFLAGS="$CXXFLAGS -g"
255 fi
256 fi
258 dnl
259 dnl library names
260 dnl
261 if test "$enable_static" = yes; then
262 LIB_EXTENSION='a'
263 else
264 case "$host_os" in
265 darwin* )
266 LIB_EXTENSION='dylib' ;;
267 cygwin* )
268 LIB_EXTENSION='dll' ;;
269 aix* )
270 LIB_EXTENSION='a' ;;
271 * )
272 LIB_EXTENSION='so' ;;
273 esac
274 fi
276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
283 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
284 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
285 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
286 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
287 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
288 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
290 AC_SUBST([GL_LIB_NAME])
291 AC_SUBST([GLU_LIB_NAME])
292 AC_SUBST([GLUT_LIB_NAME])
293 AC_SUBST([GLW_LIB_NAME])
294 AC_SUBST([OSMESA_LIB_NAME])
295 AC_SUBST([EGL_LIB_NAME])
297 AC_SUBST([GL_LIB_GLOB])
298 AC_SUBST([GLU_LIB_GLOB])
299 AC_SUBST([GLUT_LIB_GLOB])
300 AC_SUBST([GLW_LIB_GLOB])
301 AC_SUBST([OSMESA_LIB_GLOB])
302 AC_SUBST([EGL_LIB_GLOB])
304 dnl
305 dnl Arch/platform-specific settings
306 dnl
307 AC_ARG_ENABLE([asm],
308 [AS_HELP_STRING([--disable-asm],
309 [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
310 [enable_asm="$enableval"],
311 [enable_asm=yes]
312 )
313 asm_arch=""
314 ASM_FLAGS=""
315 MESA_ASM_SOURCES=""
316 GLAPI_ASM_SOURCES=""
317 AC_MSG_CHECKING([whether to enable assembly])
318 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
319 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
320 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
321 case "$host_cpu" in
322 i?86 | x86_64)
323 enable_asm=no
324 AC_MSG_RESULT([no, cross compiling])
325 ;;
326 esac
327 fi
328 # check for supported arches
329 if test "x$enable_asm" = xyes; then
330 case "$host_cpu" in
331 i?86)
332 case "$host_os" in
333 linux* | *freebsd* | dragonfly*)
334 test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
335 ;;
336 esac
337 ;;
338 x86_64)
339 case "$host_os" in
340 linux* | *freebsd* | dragonfly*)
341 test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
342 ;;
343 esac
344 ;;
345 powerpc)
346 case "$host_os" in
347 linux*)
348 asm_arch=ppc
349 ;;
350 esac
351 ;;
352 sparc*)
353 case "$host_os" in
354 linux*)
355 asm_arch=sparc
356 ;;
357 esac
358 ;;
359 esac
361 case "$asm_arch" in
362 x86)
363 ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
364 MESA_ASM_SOURCES='$(X86_SOURCES)'
365 GLAPI_ASM_SOURCES='$(X86_API)'
366 AC_MSG_RESULT([yes, x86])
367 ;;
368 x86_64)
369 ASM_FLAGS="-DUSE_X86_64_ASM"
370 MESA_ASM_SOURCES='$(X86-64_SOURCES)'
371 GLAPI_ASM_SOURCES='$(X86-64_API)'
372 AC_MSG_RESULT([yes, x86_64])
373 ;;
374 ppc)
375 ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
376 MESA_ASM_SOURCES='$(PPC_SOURCES)'
377 AC_MSG_RESULT([yes, ppc])
378 ;;
379 sparc)
380 ASM_FLAGS="-DUSE_SPARC_ASM"
381 MESA_ASM_SOURCES='$(SPARC_SOURCES)'
382 GLAPI_ASM_SOURCES='$(SPARC_API)'
383 AC_MSG_RESULT([yes, sparc])
384 ;;
385 *)
386 AC_MSG_RESULT([no, platform not supported])
387 ;;
388 esac
389 fi
390 AC_SUBST([ASM_FLAGS])
391 AC_SUBST([MESA_ASM_SOURCES])
392 AC_SUBST([GLAPI_ASM_SOURCES])
394 dnl PIC code macro
395 MESA_PIC_FLAGS
397 dnl Check to see if dlopen is in default libraries (like Solaris, which
398 dnl has it in libc), or if libdl is needed to get it.
399 AC_CHECK_FUNC([dlopen], [],
400 [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
402 dnl See if posix_memalign is available
403 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
405 dnl SELinux awareness.
406 AC_ARG_ENABLE([selinux],
407 [AS_HELP_STRING([--enable-selinux],
408 [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
409 [MESA_SELINUX="$enableval"],
410 [MESA_SELINUX=no])
411 if test "x$enable_selinux" = "xyes"; then
412 AC_CHECK_HEADER([selinux/selinux.h],[],
413 [AC_MSG_ERROR([SELinux headers not found])])
414 AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
415 [AC_MSG_ERROR([SELinux library not found])])
416 SELINUX_LIBS="-lselinux"
417 DEFINES="$DEFINES -DMESA_SELINUX"
418 fi
420 dnl
421 dnl Driver configuration. Options are xlib, dri and osmesa right now.
422 dnl More later: fbdev, ...
423 dnl
424 default_driver="xlib"
426 case "$host_os" in
427 linux*)
428 case "$host_cpu" in
429 i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
430 esac
431 ;;
432 *freebsd* | dragonfly*)
433 case "$host_cpu" in
434 i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
435 esac
436 ;;
437 esac
439 AC_ARG_WITH([driver],
440 [AS_HELP_STRING([--with-driver=DRIVER],
441 [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
442 [mesa_driver="$withval"],
443 [mesa_driver="$default_driver"])
444 dnl Check for valid option
445 case "x$mesa_driver" in
446 xxlib|xdri|xosmesa)
447 ;;
448 *)
449 AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
450 ;;
451 esac
453 dnl
454 dnl Driver specific build directories
455 dnl
457 dnl this variable will be prepended to SRC_DIRS and is not exported
458 CORE_DIRS="glsl mesa"
460 SRC_DIRS="glew"
461 GLU_DIRS="sgi"
462 GALLIUM_DIRS="auxiliary drivers state_trackers"
463 GALLIUM_TARGET_DIRS=""
464 GALLIUM_WINSYS_DIRS="sw"
465 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
466 GALLIUM_STATE_TRACKERS_DIRS=""
468 case "$mesa_driver" in
469 xlib)
470 DRIVER_DIRS="x11"
471 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
472 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
473 ;;
474 dri)
475 SRC_DIRS="$SRC_DIRS glx"
476 DRIVER_DIRS="dri"
477 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
478 ;;
479 osmesa)
480 DRIVER_DIRS="osmesa"
481 ;;
482 esac
483 AC_SUBST([SRC_DIRS])
484 AC_SUBST([GLU_DIRS])
485 AC_SUBST([DRIVER_DIRS])
486 AC_SUBST([GALLIUM_DIRS])
487 AC_SUBST([GALLIUM_TARGET_DIRS])
488 AC_SUBST([GALLIUM_WINSYS_DIRS])
489 AC_SUBST([GALLIUM_DRIVERS_DIRS])
490 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
491 AC_SUBST([MESA_LLVM])
493 dnl
494 dnl User supplied program configuration
495 dnl
496 if test -d "$srcdir/progs/demos"; then
497 default_demos=yes
498 else
499 default_demos=no
500 fi
501 AC_ARG_WITH([demos],
502 [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
503 [optional comma delimited demo directories to build
504 @<:@default=auto if source available@:>@])],
505 [with_demos="$withval"],
506 [with_demos="$default_demos"])
507 if test "x$with_demos" = x; then
508 with_demos=no
509 fi
511 dnl If $with_demos is yes, directories will be added as libs available
512 PROGRAM_DIRS=""
513 case "$with_demos" in
514 no) ;;
515 yes)
516 # If the driver isn't osmesa, we have libGL and can build xdemos
517 if test "$mesa_driver" != osmesa; then
518 PROGRAM_DIRS="xdemos"
519 fi
520 ;;
521 *)
522 # verify the requested demos directories exist
523 demos=`IFS=,; echo $with_demos`
524 for demo in $demos; do
525 test -d "$srcdir/progs/$demo" || \
526 AC_MSG_ERROR([Program directory '$demo' doesn't exist])
527 done
528 PROGRAM_DIRS="$demos"
529 ;;
530 esac
532 dnl
533 dnl Find out if X is available. The variable have_x is set if libX11 is
534 dnl found to mimic AC_PATH_XTRA.
535 dnl
536 if test -n "$PKG_CONFIG"; then
537 AC_MSG_CHECKING([pkg-config files for X11 are available])
538 PKG_CHECK_EXISTS([x11],[
539 x11_pkgconfig=yes
540 have_x=yes
541 ],[
542 x11_pkgconfig=no
543 ])
544 AC_MSG_RESULT([$x11_pkgconfig])
545 else
546 x11_pkgconfig=no
547 fi
548 dnl Use the autoconf macro if no pkg-config files
549 if test "$x11_pkgconfig" = yes; then
550 PKG_CHECK_MODULES([X11], [x11])
551 else
552 AC_PATH_XTRA
553 test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
554 test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
555 AC_SUBST([X11_CFLAGS])
556 AC_SUBST([X11_LIBS])
557 fi
559 dnl Try to tell the user that the --x-* options are only used when
560 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
561 m4_divert_once([HELP_BEGIN],
562 [These options are only used when the X libraries cannot be found by the
563 pkg-config utility.])
565 dnl We need X for xlib and dri, so bomb now if it's not found
566 case "$mesa_driver" in
567 xlib|dri)
568 if test "$no_x" = yes; then
569 AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
570 fi
571 ;;
572 esac
574 dnl XCB - this is only used for GLX right now
575 AC_ARG_ENABLE([xcb],
576 [AS_HELP_STRING([--enable-xcb],
577 [use XCB for GLX @<:@default=disabled@:>@])],
578 [enable_xcb="$enableval"],
579 [enable_xcb=no])
580 if test "x$enable_xcb" = xyes; then
581 DEFINES="$DEFINES -DUSE_XCB"
582 else
583 enable_xcb=no
584 fi
586 dnl
587 dnl libGL configuration per driver
588 dnl
589 case "$mesa_driver" in
590 xlib)
591 if test "$x11_pkgconfig" = yes; then
592 PKG_CHECK_MODULES([XLIBGL], [x11 xext])
593 GL_PC_REQ_PRIV="x11 xext"
594 X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
595 GL_LIB_DEPS="$XLIBGL_LIBS"
596 else
597 # should check these...
598 X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
599 GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
600 GL_PC_LIB_PRIV="$GL_LIB_DEPS"
601 GL_PC_CFLAGS="$X11_INCLUDES"
602 fi
603 GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
604 GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
606 # if static, move the external libraries to the programs
607 # and empty the libraries for libGL
608 if test "$enable_static" = yes; then
609 APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
610 GL_LIB_DEPS=""
611 fi
612 ;;
613 dri)
614 # DRI must be shared, I think
615 if test "$enable_static" = yes; then
616 AC_MSG_ERROR([Can't use static libraries for DRI drivers])
617 fi
619 # Check for libdrm
620 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
621 PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
622 PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
623 GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
624 DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
626 # find the DRI deps for libGL
627 if test "$x11_pkgconfig" = yes; then
628 # add xcb modules if necessary
629 dri_modules="x11 xext xxf86vm xdamage xfixes"
630 if test "$enable_xcb" = yes; then
631 dri_modules="$dri_modules x11-xcb xcb-glx"
632 fi
634 PKG_CHECK_MODULES([DRIGL], [$dri_modules])
635 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
636 X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
637 GL_LIB_DEPS="$DRIGL_LIBS"
638 else
639 # should check these...
640 X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
641 GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
642 GL_PC_LIB_PRIV="$GL_LIB_DEPS"
643 GL_PC_CFLAGS="$X11_INCLUDES"
645 # XCB can only be used from pkg-config
646 if test "$enable_xcb" = yes; then
647 PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
648 GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
649 X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
650 GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
651 fi
652 fi
654 # need DRM libs, -lpthread, etc.
655 GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
656 GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
657 ;;
658 osmesa)
659 # No libGL for osmesa
660 GL_LIB_DEPS=""
661 ;;
662 esac
663 AC_SUBST([GL_LIB_DEPS])
664 AC_SUBST([GL_PC_REQ_PRIV])
665 AC_SUBST([GL_PC_LIB_PRIV])
666 AC_SUBST([GL_PC_CFLAGS])
667 AC_SUBST([DRI_PC_REQ_PRIV])
669 dnl
670 dnl More X11 setup
671 dnl
672 if test "$mesa_driver" = xlib; then
673 DEFINES="$DEFINES -DUSE_XSHM"
674 fi
676 dnl
677 dnl More DRI setup
678 dnl
679 AC_ARG_ENABLE([glx-tls],
680 [AS_HELP_STRING([--enable-glx-tls],
681 [enable TLS support in GLX @<:@default=disabled@:>@])],
682 [GLX_USE_TLS="$enableval"],
683 [GLX_USE_TLS=no])
684 dnl Directory for DRI drivers
685 AC_ARG_WITH([dri-driverdir],
686 [AS_HELP_STRING([--with-dri-driverdir=DIR],
687 [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
688 [DRI_DRIVER_INSTALL_DIR="$withval"],
689 [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
690 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
691 dnl Extra search path for DRI drivers
692 AC_ARG_WITH([dri-searchpath],
693 [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
694 [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
695 [DRI_DRIVER_SEARCH_DIR="$withval"],
696 [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
697 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
698 dnl Direct rendering or just indirect rendering
699 AC_ARG_ENABLE([driglx-direct],
700 [AS_HELP_STRING([--disable-driglx-direct],
701 [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
702 [driglx_direct="$enableval"],
703 [driglx_direct="yes"])
704 dnl Which drivers to build - default is chosen by platform
705 AC_ARG_WITH([dri-drivers],
706 [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
707 [comma delimited DRI drivers list, e.g.
708 "swrast,i965,radeon" @<:@default=auto@:>@])],
709 [with_dri_drivers="$withval"],
710 [with_dri_drivers=yes])
711 if test "x$with_dri_drivers" = x; then
712 with_dri_drivers=no
713 fi
715 dnl If $with_dri_drivers is yes, directories will be added through
716 dnl platform checks
717 DRI_DIRS=""
718 case "$with_dri_drivers" in
719 no) ;;
720 yes)
721 DRI_DIRS="yes"
722 ;;
723 *)
724 # verify the requested driver directories exist
725 dri_drivers=`IFS=', '; echo $with_dri_drivers`
726 for driver in $dri_drivers; do
727 test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
728 AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
729 done
730 DRI_DIRS="$dri_drivers"
731 ;;
732 esac
734 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
735 if test "$mesa_driver" = dri; then
736 # Use TLS in GLX?
737 if test "x$GLX_USE_TLS" = xyes; then
738 DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
739 fi
741 # Platform specific settings and drivers to build
742 case "$host_os" in
743 linux*)
744 DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
745 if test "x$driglx_direct" = xyes; then
746 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
747 fi
748 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
750 case "$host_cpu" in
751 x86_64)
752 # sis is missing because they have not be converted to use
753 # the new interface. i810 are missing because there is no
754 # x86-64 system where they could *ever* be used.
755 if test "x$DRI_DIRS" = "xyes"; then
756 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
757 savage tdfx unichrome swrast"
758 fi
759 ;;
760 powerpc*)
761 # Build only the drivers for cards that exist on PowerPC.
762 # At some point MGA will be added, but not yet.
763 if test "x$DRI_DIRS" = "xyes"; then
764 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
765 fi
766 ;;
767 sparc*)
768 # Build only the drivers for cards that exist on sparc`
769 if test "x$DRI_DIRS" = "xyes"; then
770 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
771 fi
772 ;;
773 esac
774 ;;
775 freebsd* | dragonfly*)
776 DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
777 DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
778 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
779 if test "x$driglx_direct" = xyes; then
780 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
781 fi
782 if test "x$GXX" = xyes; then
783 CXXFLAGS="$CXXFLAGS -ansi -pedantic"
784 fi
786 if test "x$DRI_DIRS" = "xyes"; then
787 DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
788 unichrome savage sis swrast"
789 fi
790 ;;
791 gnu*)
792 DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
793 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
794 ;;
795 solaris*)
796 DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
797 DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
798 if test "x$driglx_direct" = xyes; then
799 DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
800 fi
801 ;;
802 esac
804 # default drivers
805 if test "x$DRI_DIRS" = "xyes"; then
806 DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
807 savage sis tdfx unichrome swrast"
808 fi
810 DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/ */ /g'`
812 # Check for expat
813 EXPAT_INCLUDES=""
814 EXPAT_LIB=-lexpat
815 AC_ARG_WITH([expat],
816 [AS_HELP_STRING([--with-expat=DIR],
817 [expat install directory])],[
818 EXPAT_INCLUDES="-I$withval/include"
819 CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
820 LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
821 EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
822 ])
823 AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
824 AC_CHECK_LIB([expat],[XML_ParserCreate],[],
825 [AC_MSG_ERROR([Expat required for DRI.])])
827 # put all the necessary libs together
828 DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
829 fi
830 AC_SUBST([DRI_DIRS])
831 AC_SUBST([EXPAT_INCLUDES])
832 AC_SUBST([DRI_LIB_DEPS])
834 case $DRI_DIRS in
835 *i915*|*i965*)
836 PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
837 ;;
838 esac
840 case $DRI_DIRS in
841 *radeon*|*r200*|*r300*|*r600*)
842 PKG_CHECK_MODULES([LIBDRM_RADEON],
843 [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
844 HAVE_LIBDRM_RADEON=yes,
845 HAVE_LIBDRM_RADEON=no)
847 if test "$HAVE_LIBDRM_RADEON" = yes; then
848 RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
849 RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
850 fi
851 ;;
852 esac
853 AC_SUBST([RADEON_CFLAGS])
854 AC_SUBST([RADEON_LDFLAGS])
857 dnl
858 dnl OSMesa configuration
859 dnl
860 if test "$mesa_driver" = xlib; then
861 default_gl_osmesa=yes
862 else
863 default_gl_osmesa=no
864 fi
865 AC_ARG_ENABLE([gl-osmesa],
866 [AS_HELP_STRING([--enable-gl-osmesa],
867 [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
868 [gl_osmesa="$enableval"],
869 [gl_osmesa="$default_gl_osmesa"])
870 if test "x$gl_osmesa" = xyes; then
871 if test "$mesa_driver" = osmesa; then
872 AC_MSG_ERROR([libGL is not available for OSMesa driver])
873 else
874 DRIVER_DIRS="$DRIVER_DIRS osmesa"
875 fi
876 fi
878 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
879 AC_ARG_WITH([osmesa-bits],
880 [AS_HELP_STRING([--with-osmesa-bits=BITS],
881 [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
882 [osmesa_bits="$withval"],
883 [osmesa_bits=8])
884 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
885 AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
886 osmesa_bits=8
887 fi
888 case "x$osmesa_bits" in
889 x8)
890 OSMESA_LIB=OSMesa
891 ;;
892 x16|x32)
893 OSMESA_LIB="OSMesa$osmesa_bits"
894 DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
895 ;;
896 *)
897 AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
898 ;;
899 esac
900 AC_SUBST([OSMESA_LIB])
902 case "$mesa_driver" in
903 osmesa)
904 # only link libraries with osmesa if shared
905 if test "$enable_static" = no; then
906 OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
907 else
908 OSMESA_LIB_DEPS=""
909 fi
910 OSMESA_MESA_DEPS=""
911 OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
912 ;;
913 *)
914 # Link OSMesa to libGL otherwise
915 OSMESA_LIB_DEPS=""
916 # only link libraries with osmesa if shared
917 if test "$enable_static" = no; then
918 OSMESA_MESA_DEPS='-l$(GL_LIB)'
919 else
920 OSMESA_MESA_DEPS=""
921 fi
922 OSMESA_PC_REQ="gl"
923 ;;
924 esac
925 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
926 AC_SUBST([OSMESA_LIB_DEPS])
927 AC_SUBST([OSMESA_MESA_DEPS])
928 AC_SUBST([OSMESA_PC_REQ])
929 AC_SUBST([OSMESA_PC_LIB_PRIV])
931 dnl
932 dnl EGL configuration
933 dnl
934 AC_ARG_ENABLE([egl],
935 [AS_HELP_STRING([--disable-egl],
936 [disable EGL library @<:@default=enabled@:>@])],
937 [enable_egl="$enableval"],
938 [enable_egl=yes])
939 if test "x$enable_egl" = xyes; then
940 SRC_DIRS="$SRC_DIRS egl"
941 EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
942 EGL_DRIVERS_DIRS=""
943 if test "$enable_static" != yes; then
944 # build egl_glx when libGL is built
945 if test "$mesa_driver" != osmesa; then
946 EGL_DRIVERS_DIRS="glx"
947 fi
949 # build egl_dri2 when xcb-dri2 is available
950 PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
951 [have_xcb_dri2=yes],[have_xcb_dri2=no])
952 if test "$have_xcb_dri2" = yes; then
953 EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
954 fi
955 fi
957 if test "$with_demos" = yes; then
958 PROGRAM_DIRS="$PROGRAM_DIRS egl/opengl"
959 fi
960 fi
961 AC_SUBST([EGL_LIB_DEPS])
962 AC_SUBST([EGL_DRIVERS_DIRS])
964 dnl
965 dnl GLU configuration
966 dnl
967 AC_ARG_ENABLE([glu],
968 [AS_HELP_STRING([--disable-glu],
969 [enable OpenGL Utility library @<:@default=enabled@:>@])],
970 [enable_glu="$enableval"],
971 [enable_glu=yes])
972 if test "x$enable_glu" = xyes; then
973 SRC_DIRS="$SRC_DIRS glu"
975 case "$mesa_driver" in
976 osmesa)
977 # If GLU is available and we have libOSMesa (not 16 or 32),
978 # we can build the osdemos
979 if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
980 PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
981 fi
983 # Link libGLU to libOSMesa instead of libGL
984 GLU_LIB_DEPS=""
985 GLU_PC_REQ="osmesa"
986 if test "$enable_static" = no; then
987 GLU_MESA_DEPS='-l$(OSMESA_LIB)'
988 else
989 GLU_MESA_DEPS=""
990 fi
991 ;;
992 *)
993 # If static, empty GLU_LIB_DEPS and add libs for programs to link
994 GLU_PC_REQ="gl"
995 GLU_PC_LIB_PRIV="-lm"
996 if test "$enable_static" = no; then
997 GLU_LIB_DEPS="-lm"
998 GLU_MESA_DEPS='-l$(GL_LIB)'
999 else
1000 GLU_LIB_DEPS=""
1001 GLU_MESA_DEPS=""
1002 APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1003 fi
1004 ;;
1005 esac
1006 fi
1007 if test "$enable_static" = no; then
1008 GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1009 fi
1010 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1011 AC_SUBST([GLU_LIB_DEPS])
1012 AC_SUBST([GLU_MESA_DEPS])
1013 AC_SUBST([GLU_PC_REQ])
1014 AC_SUBST([GLU_PC_REQ_PRIV])
1015 AC_SUBST([GLU_PC_LIB_PRIV])
1016 AC_SUBST([GLU_PC_CFLAGS])
1018 dnl
1019 dnl GLw configuration
1020 dnl
1021 AC_ARG_ENABLE([glw],
1022 [AS_HELP_STRING([--disable-glw],
1023 [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1024 [enable_glw="$enableval"],
1025 [enable_glw=yes])
1026 dnl Don't build GLw on osmesa
1027 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1028 AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1029 enable_glw=no
1030 fi
1031 AC_ARG_ENABLE([motif],
1032 [AS_HELP_STRING([--enable-motif],
1033 [use Motif widgets in GLw @<:@default=disabled@:>@])],
1034 [enable_motif="$enableval"],
1035 [enable_motif=no])
1037 if test "x$enable_glw" = xyes; then
1038 SRC_DIRS="$SRC_DIRS glw"
1039 if test "$x11_pkgconfig" = yes; then
1040 PKG_CHECK_MODULES([GLW],[x11 xt])
1041 GLW_PC_REQ_PRIV="x11 xt"
1042 GLW_LIB_DEPS="$GLW_LIBS"
1043 else
1044 # should check these...
1045 GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1046 GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1047 GLW_PC_CFLAGS="$X11_INCLUDES"
1048 fi
1050 GLW_SOURCES="GLwDrawA.c"
1051 MOTIF_CFLAGS=
1052 if test "x$enable_motif" = xyes; then
1053 GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1054 AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1055 if test "x$MOTIF_CONFIG" != xno; then
1056 MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1057 MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1058 else
1059 AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1060 [AC_MSG_ERROR([Can't locate Motif headers])])
1061 AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1062 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1063 fi
1064 # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1065 GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1066 GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1067 GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1068 fi
1070 # If static, empty GLW_LIB_DEPS and add libs for programs to link
1071 GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1072 if test "$enable_static" = no; then
1073 GLW_MESA_DEPS='-l$(GL_LIB)'
1074 GLW_LIB_DEPS="$GLW_LIB_DEPS"
1075 else
1076 APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1077 GLW_LIB_DEPS=""
1078 GLW_MESA_DEPS=""
1079 fi
1080 fi
1081 AC_SUBST([GLW_LIB_DEPS])
1082 AC_SUBST([GLW_MESA_DEPS])
1083 AC_SUBST([GLW_SOURCES])
1084 AC_SUBST([MOTIF_CFLAGS])
1085 AC_SUBST([GLW_PC_REQ_PRIV])
1086 AC_SUBST([GLW_PC_LIB_PRIV])
1087 AC_SUBST([GLW_PC_CFLAGS])
1089 dnl
1090 dnl GLUT configuration
1091 dnl
1092 if test -f "$srcdir/include/GL/glut.h"; then
1093 default_glut=yes
1094 else
1095 default_glut=no
1096 fi
1097 AC_ARG_ENABLE([glut],
1098 [AS_HELP_STRING([--disable-glut],
1099 [enable GLUT library @<:@default=enabled if source available@:>@])],
1100 [enable_glut="$enableval"],
1101 [enable_glut="$default_glut"])
1103 dnl Can't build glut if GLU not available
1104 if test "x$enable_glu$enable_glut" = xnoyes; then
1105 AC_MSG_WARN([Disabling glut since GLU is disabled])
1106 enable_glut=no
1107 fi
1108 dnl Don't build glut on osmesa
1109 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1110 AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1111 enable_glut=no
1112 fi
1114 if test "x$enable_glut" = xyes; then
1115 SRC_DIRS="$SRC_DIRS glut/glx"
1116 GLUT_CFLAGS=""
1117 if test "x$GCC" = xyes; then
1118 GLUT_CFLAGS="-fexceptions"
1119 fi
1120 if test "$x11_pkgconfig" = yes; then
1121 PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1122 GLUT_PC_REQ_PRIV="x11 xmu xi"
1123 GLUT_LIB_DEPS="$GLUT_LIBS"
1124 else
1125 # should check these...
1126 GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1127 GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1128 GLUT_PC_CFLAGS="$X11_INCLUDES"
1129 fi
1130 GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1131 GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1133 # If glut is available, we can build most programs
1134 if test "$with_demos" = yes; then
1135 PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1136 fi
1138 # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1139 if test "$enable_static" = no; then
1140 GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1141 else
1142 APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1143 GLUT_LIB_DEPS=""
1144 GLUT_MESA_DEPS=""
1145 fi
1146 fi
1147 AC_SUBST([GLUT_LIB_DEPS])
1148 AC_SUBST([GLUT_MESA_DEPS])
1149 AC_SUBST([GLUT_CFLAGS])
1150 AC_SUBST([GLUT_PC_REQ_PRIV])
1151 AC_SUBST([GLUT_PC_LIB_PRIV])
1152 AC_SUBST([GLUT_PC_CFLAGS])
1154 dnl
1155 dnl Program library dependencies
1156 dnl Only libm is added here if necessary as the libraries should
1157 dnl be pulled in by the linker
1158 dnl
1159 if test "x$APP_LIB_DEPS" = x; then
1160 case "$host_os" in
1161 solaris*)
1162 APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1163 ;;
1164 cygwin*)
1165 APP_LIB_DEPS="-lX11"
1166 ;;
1167 *)
1168 APP_LIB_DEPS="-lm"
1169 ;;
1170 esac
1171 fi
1172 AC_SUBST([APP_LIB_DEPS])
1173 AC_SUBST([PROGRAM_DIRS])
1175 dnl
1176 dnl Gallium configuration
1177 dnl
1178 AC_ARG_ENABLE([gallium],
1179 [AS_HELP_STRING([--disable-gallium],
1180 [build gallium @<:@default=enabled@:>@])],
1181 [enable_gallium="$enableval"],
1182 [enable_gallium=yes])
1183 if test "x$enable_gallium" = xyes; then
1184 SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1185 AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1186 [HAS_UDIS86="no"])
1187 AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1188 if test "x$LLVM_CONFIG" != xno; then
1189 LLVM_VERSION=`$LLVM_CONFIG --version`
1190 LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1191 LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1193 if test "x$HAS_UDIS86" != xno; then
1194 LLVM_LIBS="$LLVM_LIBS -ludis86"
1195 fi
1196 LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1197 fi
1198 fi
1200 AC_SUBST([LLVM_CFLAGS])
1201 AC_SUBST([LLVM_LIBS])
1202 AC_SUBST([LLVM_LDFLAGS])
1203 AC_SUBST([LLVM_VERSION])
1205 dnl
1206 dnl Gallium state trackers configuration
1207 dnl
1208 AC_ARG_WITH([state-trackers],
1209 [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1210 [comma delimited state_trackers list, e.g.
1211 "egl,glx" @<:@default=auto@:>@])],
1212 [with_state_trackers="$withval"],
1213 [with_state_trackers=yes])
1215 case "$with_state_trackers" in
1216 no)
1217 GALLIUM_STATE_TRACKERS_DIRS=""
1218 ;;
1219 yes)
1220 # look at what else is built
1221 case "$mesa_driver" in
1222 xlib)
1223 GALLIUM_STATE_TRACKERS_DIRS=glx
1224 ;;
1225 dri)
1226 GALLIUM_STATE_TRACKERS_DIRS="dri"
1227 HAVE_ST_DRI="yes"
1228 if test "x$enable_egl" = xyes; then
1229 GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1230 HAVE_ST_EGL="yes"
1231 fi
1232 # Have only tested st/xorg on 1.6.0 servers
1233 PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1234 HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1235 HAVE_ST_XORG="no")
1236 ;;
1237 esac
1238 ;;
1239 *)
1240 # verify the requested state tracker exist
1241 state_trackers=`IFS=', '; echo $with_state_trackers`
1242 for tracker in $state_trackers; do
1243 test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1244 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1246 case "$tracker" in
1247 dri)
1248 if test "x$mesa_driver" != xdri; then
1249 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1250 fi
1251 HAVE_ST_DRI="yes"
1252 ;;
1253 egl)
1254 if test "x$enable_egl" != xyes; then
1255 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1256 fi
1257 HAVE_ST_EGL="yes"
1258 ;;
1259 xorg)
1260 PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1261 PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1262 HAVE_ST_XORG="yes"
1263 ;;
1264 es)
1265 # mesa/es is required to build es state tracker
1266 CORE_DIRS="$CORE_DIRS mesa/es"
1267 ;;
1268 esac
1269 done
1270 GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1271 ;;
1272 esac
1274 if test "x$HAVE_ST_XORG" = xyes; then
1275 PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1276 HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1277 HAVE_XEXTPROTO_71="no")
1278 fi
1280 AC_ARG_WITH([egl-displays],
1281 [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1282 [comma delimited native displays libEGL supports, e.g.
1283 "x11,kms" @<:@default=auto@:>@])],
1284 [with_egl_displays="$withval"],
1285 [with_egl_displays=yes])
1287 EGL_DISPLAYS=""
1288 case "$with_egl_displays" in
1289 yes)
1290 if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1291 EGL_DISPLAYS="x11"
1292 fi
1293 ;;
1294 *)
1295 if test "x$enable_egl" != xyes; then
1296 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1297 fi
1298 # verify the requested driver directories exist
1299 egl_displays=`IFS=', '; echo $with_egl_displays`
1300 for dpy in $egl_displays; do
1301 test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1302 AC_MSG_ERROR([EGL display '$dpy' does't exist])
1303 done
1304 EGL_DISPLAYS="$egl_displays"
1305 ;;
1306 esac
1307 AC_SUBST([EGL_DISPLAYS])
1309 AC_ARG_WITH([egl-driver-dir],
1310 [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1311 [directory for EGL drivers [[default=${libdir}/egl]]])],
1312 [EGL_DRIVER_INSTALL_DIR="$withval"],
1313 [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1314 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1316 AC_ARG_WITH([xorg-driver-dir],
1317 [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1318 [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1319 [XORG_DRIVER_INSTALL_DIR="$withval"],
1320 [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1321 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1323 AC_ARG_WITH([max-width],
1324 [AS_HELP_STRING([--with-max-width=N],
1325 [Maximum framebuffer width (4096)])],
1326 [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1327 AS_IF([test "${withval}" -gt "4096"],
1328 [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1329 )
1330 AC_ARG_WITH([max-height],
1331 [AS_HELP_STRING([--with-max-height=N],
1332 [Maximum framebuffer height (4096)])],
1333 [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1334 AS_IF([test "${withval}" -gt "4096"],
1335 [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1336 )
1338 dnl
1339 dnl Gallium LLVM
1340 dnl
1341 AC_ARG_ENABLE([gallium-llvm],
1342 [AS_HELP_STRING([--enable-gallium-llvm],
1343 [build gallium LLVM support @<:@default=disabled@:>@])],
1344 [enable_gallium_llvm="$enableval"],
1345 [enable_gallium_llvm=auto])
1346 if test "x$enable_gallium_llvm" = xyes; then
1347 if test "x$LLVM_CONFIG" != xno; then
1348 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1349 DEFINES="$DEFINES -DMESA_LLVM -D__STDC_CONSTANT_MACROS"
1350 if test "x$HAS_UDIS86" != xno; then
1351 DEFINES="$DEFINES -DHAVE_UDIS86"
1352 fi
1353 MESA_LLVM=1
1354 else
1355 MESA_LLVM=0
1356 fi
1357 else
1358 MESA_LLVM=0
1359 fi
1361 dnl
1362 dnl Gallium helper functions
1363 dnl
1364 gallium_check_st() {
1365 if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1366 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1367 fi
1368 if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1369 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1370 fi
1371 if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1372 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1373 fi
1374 if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1375 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1376 fi
1377 }
1380 dnl
1381 dnl Gallium SVGA configuration
1382 dnl
1383 AC_ARG_ENABLE([gallium-svga],
1384 [AS_HELP_STRING([--enable-gallium-svga],
1385 [build gallium SVGA @<:@default=disabled@:>@])],
1386 [enable_gallium_svga="$enableval"],
1387 [enable_gallium_svga=auto])
1388 if test "x$enable_gallium_svga" = xyes; then
1389 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1390 gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1391 elif test "x$enable_gallium_svga" = xauto; then
1392 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1393 fi
1395 dnl
1396 dnl Gallium Intel configuration
1397 dnl
1398 AC_ARG_ENABLE([gallium-intel],
1399 [AS_HELP_STRING([--enable-gallium-intel],
1400 [build gallium intel @<:@default=disabled@:>@])],
1401 [enable_gallium_intel="$enableval"],
1402 [enable_gallium_intel=auto])
1403 if test "x$enable_gallium_intel" = xyes; then
1404 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1405 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1406 gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1407 elif test "x$enable_gallium_intel" = xauto; then
1408 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1409 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1410 fi
1412 dnl
1413 dnl Gallium Radeon configuration
1414 dnl
1415 AC_ARG_ENABLE([gallium-radeon],
1416 [AS_HELP_STRING([--enable-gallium-radeon],
1417 [build gallium radeon @<:@default=disabled@:>@])],
1418 [enable_gallium_radeon="$enableval"],
1419 [enable_gallium_radeon=auto])
1420 if test "x$enable_gallium_radeon" = xyes; then
1421 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1422 gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1423 elif test "x$enable_gallium_radeon" = xauto; then
1424 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1425 fi
1427 dnl
1428 dnl Gallium Nouveau configuration
1429 dnl
1430 AC_ARG_ENABLE([gallium-nouveau],
1431 [AS_HELP_STRING([--enable-gallium-nouveau],
1432 [build gallium nouveau @<:@default=disabled@:>@])],
1433 [enable_gallium_nouveau="$enableval"],
1434 [enable_gallium_nouveau=no])
1435 if test "x$enable_gallium_nouveau" = xyes; then
1436 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1437 gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1438 fi
1440 dnl
1441 dnl Gallium swrast configuration
1442 dnl
1443 AC_ARG_ENABLE([gallium-swrast],
1444 [AS_HELP_STRING([--enable-gallium-swrast],
1445 [build gallium swrast @<:@default=auto@:>@])],
1446 [enable_gallium_swrast="$enableval"],
1447 [enable_gallium_swrast=auto])
1448 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1449 if test "x$HAVE_ST_DRI" = xyes; then
1450 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1451 fi
1452 if test "x$HAVE_ST_EGL" = xyes; then
1453 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1454 fi
1455 fi
1457 dnl prepend CORE_DIRS to SRC_DIRS
1458 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1460 dnl Restore LDFLAGS and CPPFLAGS
1461 LDFLAGS="$_SAVE_LDFLAGS"
1462 CPPFLAGS="$_SAVE_CPPFLAGS"
1464 dnl Substitute the config
1465 AC_CONFIG_FILES([configs/autoconf])
1467 dnl Replace the configs/current symlink
1468 AC_CONFIG_COMMANDS([configs],[
1469 if test -f configs/current || test -L configs/current; then
1470 rm -f configs/current
1471 fi
1472 ln -s autoconf configs/current
1473 ])
1475 AC_OUTPUT
1477 dnl
1478 dnl Output some configuration info for the user
1479 dnl
1480 echo ""
1481 echo " prefix: $prefix"
1482 echo " exec_prefix: $exec_prefix"
1483 echo " libdir: $libdir"
1484 echo " includedir: $includedir"
1486 dnl Driver info
1487 echo ""
1488 echo " Driver: $mesa_driver"
1489 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1490 echo " OSMesa: lib$OSMESA_LIB"
1491 else
1492 echo " OSMesa: no"
1493 fi
1494 if test "$mesa_driver" = dri; then
1495 # cleanup the drivers var
1496 dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/ */ /;s/ *$//'`
1497 if test "x$DRI_DIRS" = x; then
1498 echo " DRI drivers: no"
1499 else
1500 echo " DRI drivers: $dri_dirs"
1501 fi
1502 echo " DRI driver dir: $DRI_DRIVER_INSTALL_DIR"
1503 fi
1504 echo " Use XCB: $enable_xcb"
1506 echo ""
1507 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1508 echo " Gallium: yes"
1509 echo " Gallium dirs: $GALLIUM_DIRS"
1510 echo " Target dirs: $GALLIUM_TARGET_DIRS"
1511 echo " Winsys dirs: $GALLIUM_WINSYS_DIRS"
1512 echo " Driver dirs: $GALLIUM_DRIVERS_DIRS"
1513 echo " Trackers dirs: $GALLIUM_STATE_TRACKERS_DIRS"
1514 else
1515 echo " Gallium: no"
1516 fi
1518 dnl Libraries
1519 echo ""
1520 echo " Shared libs: $enable_shared"
1521 echo " Static libs: $enable_static"
1522 if test "$enable_egl" = yes; then
1523 echo " EGL: $EGL_DRIVERS_DIRS"
1524 else
1525 echo " EGL: no"
1526 fi
1527 echo " GLU: $enable_glu"
1528 echo " GLw: $enable_glw (Motif: $enable_motif)"
1529 echo " glut: $enable_glut"
1531 dnl Programs
1532 # cleanup the programs var for display
1533 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/ */ /;s/ *$//'`
1534 if test "x$program_dirs" = x; then
1535 echo " Demos: no"
1536 else
1537 echo " Demos: $program_dirs"
1538 fi
1540 dnl Compiler options
1541 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1542 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1543 $SED 's/^ *//;s/ */ /;s/ *$//'`
1544 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1545 $SED 's/^ *//;s/ */ /;s/ *$//'`
1546 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/ */ /;s/ *$//'`
1547 echo ""
1548 echo " CFLAGS: $cflags"
1549 echo " CXXFLAGS: $cxxflags"
1550 echo " Macros: $defines"
1552 echo ""
1553 echo " Run '${MAKE-make}' to build Mesa"
1554 echo ""