meson.build

   1 # Copyright © 2017 Dylan Baker
   2 # Copyright © 2018-2019 Intel Corporation
   3 #
   4 # All rights reserved.
   5 #
   6 # Redistribution and use in source and binary forms, with or without
   7 # modification, are permitted provided that the following conditions are met:
   8 #
   9 # - Redistributions of source code must retain the above copyright notice, this
  10 #   list of conditions and the following disclaimer.
  11 #
  12 # - Redistributions in binary form must reproduce the above copyright notice,
  13 #   this list of conditions and the following disclaimer in the documentation
  14 #   and/or other materials provided with the distribution.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  17 # AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  19 # DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  22 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
  23 # CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  24 # OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  25 # OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26
  27 project(
  28   'waffle',
  29   ['c'],
  30   version : '1.6.90',
  31   license : 'BSD2',
  32   meson_version : '>= 0.49',
  33   default_options : ['c_std=c99', 'buildtype=debugoptimized'],
  34 )
  35
  36 python = import('python').find_installation('python3')
  37
  38 waffle_name = meson.project_name() + '-1'
  39 docdir = join_paths(get_option('datadir'), 'doc', meson.project_name() + '1')
  40
  41 build_x11_egl = false
  42 build_wayland = false
  43 build_glx = false
  44 build_gbm = false
  45 build_surfaceless = false
  46 build_nacl = get_option('nacl')
  47 build_wgl = ['windows', 'cygwin'].contains(host_machine.system())
  48 build_cgl = host_machine.system() == 'darwin'
  49
  50 if build_nacl
  51   add_languages('cpp')
  52 endif
  53
  54 if build_cgl
  55   add_languages('objc')
  56 endif
  57
  58 cc = meson.get_compiler('c')
  59
  60 _dep_null = dependency('', required : false)
  61 dep_threads = dependency('threads')
  62 dep_dl = cc.find_library('dl', required : false)
  63 dep_nacl = _dep_null
  64 dep_gl = _dep_null
  65 dep_egl = _dep_null
  66 dep_wayland_client = _dep_null
  67 dep_wayland_egl = _dep_null
  68 dep_x11_xcb = _dep_null
  69 dep_gbm = _dep_null
  70 dep_udev = _dep_null
  71 dep_cocoa = _dep_null
  72 dep_core_foundation = _dep_null
  73 dep_gl_headers = _dep_null
  74
  75 # Get dependencies
  76 if build_wgl
  77   if not cc.has_header('GL/wglext.h')
  78     _sub = subproject('opengl_headers')
  79     dep_gl_headers = _sub.get_variable('ext_headers')
  80   endif
  81   dep_gl = cc.find_library('opengl32')
  82 elif build_cgl
  83   dep_cocoa = dependency('cocoa')
  84   dep_core_foundation = dependency('corefoundation')
  85   dep_gl = dependency('gl')
  86 else
  87   dep_gl = dependency('gl', required : get_option('glx'))
  88   dep_x11_xcb = dependency('x11-xcb', required : get_option('glx'))
  89   build_glx = dep_gl.found() and dep_x11_xcb.found()
  90
  91   dep_egl = dependency('egl', required : get_option('x11_egl'))
  92   dep_x11_xcb = dependency('x11-xcb', required : get_option('x11_egl'))
  93   build_x11_egl = dep_egl.found() and dep_x11_xcb.found()
  94
  95   dep_egl = dependency('egl', required : get_option('gbm'))
  96   dep_gbm = dependency('gbm', required : get_option('gbm'))
  97   dep_udev = dependency('libudev', required : get_option('gbm'))
  98   build_gbm = dep_egl.found() and dep_gbm.found() and dep_udev.found()
  99
 100   dep_egl = dependency('egl', required : get_option('surfaceless_egl'))
 101   build_surfaceless = dep_egl.found()
 102
 103   dep_egl = dependency('egl', required : get_option('wayland'))
 104   dep_wayland_client = dependency(
 105     'wayland-client', version : '>= 1.10', required : get_option('wayland'),
 106   )
 107   dep_wayland_egl = dependency(
 108     'wayland-egl', version : '>= 9.1', required : get_option('wayland'),
 109   )
 110   build_wayland = dep_egl.found() and dep_wayland_client.found() and dep_wayland_egl.found()
 111 endif
 112
 113 dep_bash = dependency('bash-completion', required : false)
 114 if dep_bash.found()
 115   bashcompletiondir = dep_bash.get_pkgconfig_variable('completionsdir')
 116 else
 117   bashcompletiondir = join_paths(get_option('datadir'), 'bash-completion/completions')
 118 endif
 119 install_data('shell-completion/bash/wflinfo', install_dir : bashcompletiondir)
 120
 121 # Set pre-processor flags
 122 if build_wgl
 123     add_project_arguments('-DWAFFLE_HAS_WGL', language : ['c', 'cpp'])
 124 elif build_cgl
 125     add_project_arguments('-DWAFFLE_HAS_CGL -DGL_SILENCE_DEPRECATION', language : ['c', 'obj'])
 126 else
 127   if build_x11_egl
 128     add_project_arguments('-DWAFFLE_HAS_X11_EGL', language : ['c', 'cpp'])
 129   endif
 130   if build_glx
 131     add_project_arguments('-DWAFFLE_HAS_GLX', language : ['c', 'cpp'])
 132   endif
 133   if build_wayland
 134     add_project_arguments('-DWAFFLE_HAS_WAYLAND', language : ['c', 'cpp'])
 135   endif
 136   if build_gbm
 137     add_project_arguments('-DWAFFLE_HAS_GBM', language : ['c', 'cpp'])
 138   endif
 139   if build_surfaceless
 140     add_project_arguments('-DWAFFLE_HAS_SURFACELESS_EGL', language : ['c', 'cpp'])
 141   endif
 142 endif
 143
 144 if build_nacl
 145   add_project_arguments('-DWAFFLE_HAS_NACL', language : ['c', 'cpp'])
 146 endif
 147
 148 if cc.get_argument_syntax() == 'gcc'
 149   if cc.compiles('''
 150       static __thread int x;
 151       int main() {
 152         x = 42;
 153         return x;
 154       }''',
 155       args : '-Werror',
 156       name : 'Thread Local Storage')
 157     add_project_arguments('-DWAFFLE_HAS_TLS', language : ['c', 'cpp'])
 158
 159     if cc.compiles('''
 160         static __thread int x __attribute__((tls_model("initial-exec")));
 161         int main() {
 162           x = 42;
 163           return x;
 164         }''',
 165         args : '-Werror',
 166         name : 'TLS model "Initial Exec"')
 167       add_project_arguments('-DWAFFLE_HAS_TLS_MODEL_INITIAL_EXEC', language : ['c', 'cpp'])
 168     endif
 169   endif
 170
 171   add_project_arguments('-D_XOPEN_SOURCE=700', language : ['c', 'cpp'])
 172
 173   if not build_nacl
 174     add_project_arguments(
 175       cc.get_supported_arguments([
 176         '-Werror=implicit-function-declaration',
 177       ]),
 178       language : ['c', 'cpp'],
 179     )
 180   endif
 181
 182   add_project_arguments(
 183     cc.get_supported_arguments([
 184       '-Werror=incompatible-pointer-types',
 185       '-Werror=int-conversion',
 186       '-Werror=missing-prototypes',  # TODO: breaks on MacOS?
 187     ]),
 188     language : ['c', 'cpp'],
 189   )
 190
 191   if host_machine.system() == 'windows'
 192     if cc.has_argument('-static-libgcc')
 193       add_project_link_arguments('-static-libgcc', language : ['c', 'cpp'])
 194     endif
 195   endif
 196 elif cc.get_argument_syntax() == 'msvc'
 197   add_project_arguments(
 198     '/D_win32_WINNT=0x0601',
 199     '/DWINVER=0x0601',
 200     '/D_CRT_NONSTDC_NO_WARNINGS',
 201     '/D_CRT_SECURE_NO_WARNINGS',
 202     language : ['c'],
 203   )
 204 endif
 205
 206 if build_nacl
 207   add_project_arguments('-DWAFFLE_HAS_NACL', language : ['c', 'cpp'])
 208 endif
 209
 210 install_data('README.md', 'LICENSE.txt', 'HACKING.txt', install_dir : docdir)
 211 install_subdir('doc/release-notes', install_dir : docdir)
 212
 213 api_c_args = [
 214   '-DWAFFLE_API_VERSION=@0@'.format('0x0106'),
 215   '-DWAFFLE_API_EXPERIMENTAL',
 216 ]
 217
 218 if get_option('build-tests')
 219   dep_cmocka = dependency('cmocka', fallback : ['cmocka', 'dep_cmocka'])
 220 else
 221   dep_cmocka = _dep_null
 222 endif
 223
 224 subdir('include')
 225 subdir('third_party')
 226 subdir('src')
 227 subdir('doc')
 228 subdir('man')
 229 if get_option('build-tests')
 230   subdir('tests')
 231 endif
 232 if get_option('build-examples')
 233   subdir('examples')
 234 endif