SConstruct

   1 #######################################################################
   2 # Top-level SConstruct
   3 #
   4 # For example, invoke scons as
   5 #
   6 #   scons debug=1 dri=0 machine=x86
   7 #
   8 # to set configuration variables. Or you can write those options to a file
   9 # named config.py:
  10 #
  11 #   # config.py
  12 #   debug=1
  13 #   dri=0
  14 #   machine='x86'
  15 #
  16 # Invoke
  17 #
  18 #   scons -h
  19 #
  20 # to get the full list of options. See scons manpage for more info.
  21 #
  22
  23 import os
  24 import os.path
  25 import sys
  26 import SCons.Util
  27
  28 import common
  29
  30 #######################################################################
  31 # Configuration options
  32
  33 default_statetrackers = 'mesa'
  34
  35 if common.default_platform in ('linux', 'freebsd', 'darwin'):
  36         default_drivers = 'softpipe,failover,svga,i915,i965,trace,identity,llvmpipe'
  37         default_winsys = 'xlib'
  38 elif common.default_platform in ('winddk',):
  39         default_drivers = 'softpipe,svga,i915,i965,trace,identity'
  40         default_winsys = 'all'
  41 elif common.default_platform in ('embedded',):
  42         default_drivers = 'softpipe,llvmpipe'
  43         default_winsys = 'xlib'
  44 else:
  45         default_drivers = 'all'
  46         default_winsys = 'all'
  47
  48 opts = Variables('config.py')
  49 common.AddOptions(opts)
  50 opts.Add(ListVariable('statetrackers', 'state trackers to build', default_statetrackers,
  51                      ['mesa', 'python', 'xorg']))
  52 opts.Add(ListVariable('drivers', 'pipe drivers to build', default_drivers,
  53                      ['softpipe', 'failover', 'svga', 'i915', 'i965', 'trace', 'r300', 'identity', 'llvmpipe']))
  54 opts.Add(ListVariable('winsys', 'winsys drivers to build', default_winsys,
  55                      ['xlib', 'vmware', 'intel', 'i965', 'gdi', 'radeon']))
  56
  57 opts.Add(EnumVariable('MSVS_VERSION', 'MS Visual C++ version', None, allowed_values=('7.1', '8.0', '9.0')))
  58
  59 env = Environment(
  60         options = opts,
  61         tools = ['gallium'],
  62         toolpath = ['#scons'],
  63         ENV = os.environ,
  64 )
  65
  66 if os.environ.has_key('CC'):
  67         env['CC'] = os.environ['CC']
  68 if os.environ.has_key('CFLAGS'):
  69         env['CCFLAGS'] += SCons.Util.CLVar(os.environ['CFLAGS'])
  70 if os.environ.has_key('CXX'):
  71         env['CXX'] = os.environ['CXX']
  72 if os.environ.has_key('CXXFLAGS'):
  73         env['CXXFLAGS'] += SCons.Util.CLVar(os.environ['CXXFLAGS'])
  74 if os.environ.has_key('LDFLAGS'):
  75         env['LINKFLAGS'] += SCons.Util.CLVar(os.environ['LDFLAGS'])
  76
  77 Help(opts.GenerateHelpText(env))
  78
  79 # replicate options values in local variables
  80 debug = env['debug']
  81 dri = env['dri']
  82 machine = env['machine']
  83 platform = env['platform']
  84 drawllvm = 'llvmpipe' in env['drivers']
  85
  86 # LLVM support in the Draw module
  87 if drawllvm:
  88         env.Tool('llvm')
  89         if not env.has_key('LLVM_VERSION'):
  90            drawllvm = False
  91
  92 # derived options
  93 x86 = machine == 'x86'
  94 ppc = machine == 'ppc'
  95 gcc = platform in ('linux', 'freebsd', 'darwin', 'embedded')
  96 msvc = platform in ('windows', 'winddk')
  97
  98 Export([
  99         'debug',
 100         'x86',
 101         'ppc',
 102         'dri',
 103         'drawllvm',
 104         'platform',
 105         'gcc',
 106         'msvc',
 107 ])
 108
 109
 110 #######################################################################
 111 # Environment setup
 112
 113 # Always build trace and identity drivers
 114 if 'trace' not in env['drivers']:
 115     env['drivers'].append('trace')
 116 if 'identity' not in env['drivers']:
 117     env['drivers'].append('identity')
 118
 119 # Includes
 120 env.Append(CPPPATH = [
 121         '#/include',
 122         '#/src/gallium/include',
 123         '#/src/gallium/auxiliary',
 124         '#/src/gallium/drivers',
 125         '#/src/gallium/winsys',
 126 ])
 127
 128 if env['msvc']:
 129     env.Append(CPPPATH = ['#include/c99'])
 130
 131 # Embedded
 132 if platform == 'embedded':
 133         env.Append(CPPDEFINES = [
 134                 '_POSIX_SOURCE',
 135                 ('_POSIX_C_SOURCE', '199309L'),
 136                 '_SVID_SOURCE',
 137                 '_BSD_SOURCE',
 138                 '_GNU_SOURCE',
 139
 140                 'PTHREADS',
 141         ])
 142         env.Append(LIBS = [
 143                 'm',
 144                 'pthread',
 145                 'dl',
 146         ])
 147
 148 # Posix
 149 if platform in ('posix', 'linux', 'freebsd', 'darwin'):
 150         env.Append(CPPDEFINES = [
 151                 '_POSIX_SOURCE',
 152                 ('_POSIX_C_SOURCE', '199309L'),
 153                 '_SVID_SOURCE',
 154                 '_BSD_SOURCE',
 155                 '_GNU_SOURCE',
 156
 157                 'PTHREADS',
 158                 'HAVE_POSIX_MEMALIGN',
 159         ])
 160         if platform == 'darwin':
 161                 env.Append(CPPDEFINES = ['_DARWIN_C_SOURCE'])
 162         env.Append(CPPPATH = ['/usr/X11R6/include'])
 163         env.Append(LIBPATH = ['/usr/X11R6/lib'])
 164         env.Append(LIBS = [
 165                 'm',
 166                 'pthread',
 167                 'expat',
 168                 'dl',
 169         ])
 170
 171 # DRI
 172 if dri:
 173         env.ParseConfig('pkg-config --cflags --libs libdrm')
 174         env.Append(CPPDEFINES = [
 175                 ('USE_EXTERNAL_DXTN_LIB', '1'),
 176                 'IN_DRI_DRIVER',
 177                 'GLX_DIRECT_RENDERING',
 178                 'GLX_INDIRECT_RENDERING',
 179         ])
 180
 181 # LLVM support in the Draw module
 182 if drawllvm:
 183     env.Append(CPPDEFINES = ['DRAW_LLVM'])
 184
 185 # libGL
 186 if platform in ('linux', 'freebsd', 'darwin'):
 187         env.Append(LIBS = [
 188                 'X11',
 189                 'Xext',
 190                 'Xxf86vm',
 191                 'Xdamage',
 192                 'Xfixes',
 193         ])
 194
 195 # for debugging
 196 #print env.Dump()
 197
 198 Export('env')
 199
 200
 201 #######################################################################
 202 # Invoke SConscripts
 203
 204 # TODO: Build several variants at the same time?
 205 # http://www.scons.org/wiki/SimultaneousVariantBuilds
 206
 207 if env['platform'] != common.default_platform:
 208     # GLSL code has to be built twice -- one for the host OS, another for the target OS...
 209
 210     host_env = Environment(
 211         # options are ignored
 212         # default tool is used
 213         tools = ['default', 'custom'],
 214         toolpath = ['#scons'],
 215         ENV = os.environ,
 216     )
 217
 218     host_env['platform'] = common.default_platform
 219     host_env['machine'] = common.default_machine
 220     host_env['debug'] = env['debug']
 221
 222     SConscript(
 223         'src/glsl/SConscript',
 224         variant_dir = os.path.join(env['build'], 'host'),
 225         duplicate = 0, # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 226         exports={'env':host_env},
 227     )
 228
 229 SConscript(
 230         'src/SConscript',
 231         variant_dir = env['build'],
 232         duplicate = 0 # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 233 )
 234
 235 env.Default('src')
 236
 237 SConscript(
 238     'progs/SConscript',
 239     variant_dir = os.path.join('progs', env['build']),
 240     duplicate = 0 # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
 241 )