uuu/CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4)
   2
   3 set(CMAKE_CXX_STANDARD 14)
   4 set(CMAKE_CXX_STANDARD_REQUIRED ON)
   5 set(CMAKE_SKIP_RPATH ON)
   6
   7 find_package(PkgConfig REQUIRED)
   8 pkg_check_modules(LIBUSB REQUIRED libusb-1.0>=1.0.16)
   9 pkg_check_modules(LIBZ REQUIRED zlib)
  10 pkg_check_modules(LIBZSTD REQUIRED libzstd)
  11 find_package(Threads)
  12 pkg_check_modules(TINYXML2 REQUIRED tinyxml2)
  13
  14 if (STATIC)
  15 set(OPENSSL_USE_STATIC_LIBS TRUE)
  16 endif()
  17
  18 find_package(OpenSSL)
  19
  20 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread -O2")
  21
  22 if (STATIC)
  23 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -static-libstdc++ -static-libgcc")
  24 endif()
  25
  26 set(LSTS
  27         uuu.lst
  28         emmc_burn_loader.lst
  29         emmc_burn_all.lst
  30         fat_write.lst
  31         qspi_burn_loader.lst
  32         fspinand_burn_loader.lst
  33         sd_burn_loader.lst
  34         spl_boot.lst
  35         sd_burn_all.lst
  36         nand_burn_loader.lst
  37         nvme_burn_all.lst
  38 )
  39
  40 link_directories(${CMAKE_CURRENT_SOURCE_DIR}/libuuu ${LIBUSB_LIBRARY_DIRS} ${LIBZSTD_LIBRARY_DIRS} ${LIBZ_LIBRARY_DIRS} ${TINYXML2_LIBRARY_DIRS})
  41
  42 set(CLIST_EXECUTABLE ${CMAKE_CURRENT_SOURCE_DIR}/gen_txt_include.sh)
  43 set(generated_files_dir "${CMAKE_BINARY_DIR}/uuu/gen")
  44
  45 function(preprocess_clst out_var)
  46         set(result)
  47         foreach(in_f ${ARGN})
  48                 set(out_f "${generated_files_dir}/${in_f}")
  49                 string(REPLACE ".lst" ".clst" out_f ${out_f})
  50                 add_custom_command(OUTPUT ${out_f}
  51                         PRE_BUILD
  52                                 COMMAND mkdir -p ${generated_files_dir}
  53                         COMMAND ${CLIST_EXECUTABLE} ${in_f} ${out_f}
  54                         DEPENDS ${in_f}
  55                         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  56                         COMMENT "Creating preprocessed clst file ${out_f}"
  57                         VERBATIM
  58                 )
  59                 list(APPEND result ${out_f})
  60         endforeach()
  61         set(${out_var} "${result}" PARENT_SCOPE)
  62 endfunction()
  63
  64 preprocess_clst(CLSTS ${LSTS})
  65
  66 include_directories(${generated_files_dir})
  67
  68 set(SOURCES
  69         uuu.cpp
  70         buildincmd.cpp
  71         autocomplete.cpp
  72         ${CLSTS}
  73 )
  74
  75 add_executable(uuu ${SOURCES})
  76 target_link_libraries(uuu uuc_s ${OPENSSL_LIBRARIES} ${LIBUSB_LIBRARIES} ${LIBZ_LIBRARIES} ${LIBZSTD_LIBRARIES} ${TINYXML2_LIBRARIES} dl bz2)
  77
  78 install(TARGETS uuu DESTINATION bin)
  79 target_compile_definitions(uuu
  80     PRIVATE "TARGET_PATH=\"${CMAKE_INSTALL_PREFIX}/bin/uuu\""
  81 )