configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ(2.64)
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 dnl This should be checked before toolchain macros, otherwise they will remember
  40 dnl that ar cannot be found and linking via libtool will fail at a later stage
  41 AC_CHECK_TOOLS([AR], [ar gar])
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_C_O
  45
  46 mc_CHECK_CFLAGS
  47
  48 CFLAGS_OPTS=""
  49 if test "x$CFLAGS" = "x"; then
  50     CFLAGS_OPTS=" -O2 "
  51 fi
  52 if test x$USE_MAINTAINER_MODE = xyes; then
  53     CFLAGS_OPTS="-g3 -O -ggdb"
  54     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  55 fi
  56
  57 AC_ARG_ENABLE([werror],
  58     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  59 if test "x$enable_werror" = xyes; then
  60     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  61 fi
  62
  63 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  64 dnl which causes attribute checks to fail
  65 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  66 _AC_LANG_PREFIX[]FLAGS=
  67 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  68 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  69 unset ax_gcc_func_attribute_save_flags
  70
  71 LT_INIT
  72
  73
  74 dnl ############################################################################
  75 dnl Check for programs
  76 dnl ############################################################################
  77
  78 AC_PROG_SED
  79 PKG_PROG_PKG_CONFIG
  80 AC_PROG_INSTALL
  81 AC_PROG_LN_S
  82 dnl See also the "OS specific stuff" section below.
  83
  84 dnl Check nroff and the options it supports
  85 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  86 dnl Default values
  87 MANDOC=-man
  88 MAN_FLAGS=
  89 if $HAVE_nroff; then
  90     AC_MSG_CHECKING([for manual formatting macros])
  91     AC_CACHE_VAL(mc_cv_mandoc, [
  92     nroff -mandoc < /dev/null > /dev/null 2>&1
  93     if test $? = 0; then
  94         mc_cv_mandoc=-mandoc
  95     else
  96         mc_cv_mandoc=-man
  97     fi
  98     ])
  99     MANDOC=$mc_cv_mandoc
 100     AC_MSG_RESULT([$MANDOC])
 101
 102     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 103     AC_CACHE_VAL(mc_cv_man_nocolor, [
 104     nroff -c < /dev/null > /dev/null 2>&1
 105     if test $? = 0; then
 106         mc_cv_man_nocolor=-c
 107     else
 108         mc_cv_man_nocolor=
 109     fi
 110     ])
 111     MAN_FLAGS=$mc_cv_man_nocolor
 112     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 113
 114     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 115     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 116     mc_cv_nroff_tascii=
 117     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 118     if test $? = 0; then
 119         mc_cv_nroff_tascii=-Tlatin1
 120     else
 121         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 122         if test $? = 0; then
 123             mc_cv_nroff_tascii=-Tascii
 124         fi
 125     fi
 126     ])
 127     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 128     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 129 fi
 130
 131 AC_SUBST(MANDOC)
 132 AC_SUBST(MAN_FLAGS)
 133
 134 dnl Check for -z, -b, -L, and -S options to file
 135 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 136 if $HAVE_FILECMD; then
 137     dnl Don't use the file command if it doesn't accept the -z option
 138     AC_MSG_CHECKING([for -z option to file command])
 139     AC_CACHE_VAL(mc_cv_file_z, [
 140         file -z . > /dev/null 2>&1
 141         if test $? = 0; then
 142             mc_cv_file_z=yes
 143         else
 144             mc_cv_file_z=no
 145         fi
 146     ])
 147     AC_MSG_RESULT([$mc_cv_file_z])
 148
 149     if test x$mc_cv_file_z = xyes; then
 150         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 151     else
 152         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 153     fi
 154
 155     if test x$mc_cv_file_z = xyes; then
 156         dnl file is used; check -b, -L and -S options
 157
 158         AC_MSG_CHECKING([for -b option to file command])
 159         AC_CACHE_VAL(mc_cv_file_b, [
 160             file -b . > /dev/null 2>&1
 161             if test $? = 0; then
 162                 mc_cv_file_b=yes
 163             else
 164                 mc_cv_file_b=no
 165             fi
 166         ])
 167         AC_MSG_RESULT([$mc_cv_file_b])
 168
 169         if test x$mc_cv_file_b = xyes; then
 170             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 171         fi
 172
 173         AC_MSG_CHECKING([for -L option to file command])
 174         AC_CACHE_VAL(mc_cv_file_L, [
 175             file -L . > /dev/null 2>&1
 176             if test $? = 0; then
 177                 mc_cv_file_L=yes
 178             else
 179                 mc_cv_file_L=no
 180             fi
 181         ])
 182         AC_MSG_RESULT([$mc_cv_file_L])
 183
 184         if test x$mc_cv_file_L = xyes; then
 185             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 186         else
 187             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 188         fi
 189
 190         dnl The file command accepts the -S option since 5.33
 191         AC_MSG_CHECKING([for -S option to file command])
 192         AC_CACHE_VAL(mc_cv_file_S, [
 193             file -S . > /dev/null 2>&1
 194             if test $? = 0; then
 195                 mc_cv_file_S=yes
 196             else
 197                 mc_cv_file_S=no
 198             fi
 199         ])
 200         AC_MSG_RESULT([$mc_cv_file_S])
 201
 202         if test x$mc_cv_file_S = xyes; then
 203             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 204         else
 205             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 206         fi
 207     fi
 208 fi
 209
 210 dnl Only list browsers here that can be run in background (i.e. with `&')
 211 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 212
 213
 214 dnl ############################################################################
 215 dnl Check for other tools
 216 dnl ############################################################################
 217
 218 AC_CHECK_TOOLS([INDENT], [gindent indent])
 219 mc_UNIT_TESTS
 220
 221
 222 dnl ############################################################################
 223 dnl Check for main libraries
 224 dnl ############################################################################
 225
 226 mc_CHECK_GLIB
 227 mc_G_MODULE_SUPPORTED
 228 mc_WITH_SCREEN
 229 mc_CHECK_SEARCH_TYPE
 230 dnl X11 support. Used to read keyboard modifiers when running under X11.
 231 mc_WITH_X
 232
 233
 234 dnl ############################################################################
 235 dnl Check for header files
 236 dnl ############################################################################
 237
 238 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 239         utime.h sys/statfs.h sys/vfs.h \
 240         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 241         sys/socket.h])
 242 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 243 dnl   to work around a buggy version in autoconf <= 2.69.
 244 AC_HEADER_MAJOR
 245
 246 mc_CHECK_HEADER_STDCKDINT
 247
 248
 249 dnl ############################################################################
 250 dnl Check for types
 251 dnl ############################################################################
 252
 253 dnl Check largefile before type sizeof checks
 254 AC_SYS_LARGEFILE
 255
 256 AC_CHECK_SIZEOF(long)
 257 AC_TYPE_UINTMAX_T
 258 AC_CHECK_SIZEOF(uintmax_t)
 259 AC_TYPE_OFF_T
 260 AC_CHECK_SIZEOF(off_t)
 261 AC_TYPE_MODE_T
 262 gl_PROMOTED_TYPE_MODE_T
 263 AC_TYPE_PID_T
 264 AC_TYPE_UID_T
 265 AC_CHECK_TYPE([major_t], [], [AC_DEFINE([major_t], [int], [Type of major device numbers.])])
 266 AC_CHECK_TYPE([minor_t], [], [AC_DEFINE([minor_t], [int], [Type of minor device numbers.])])
 267
 268 AC_STRUCT_ST_BLOCKS
 269 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim, struct stat.st_mtimespec, struct stat.st_mtimensec])
 270 gl_STAT_SIZE
 271
 272 AH_TEMPLATE([sig_atomic_t],
 273             [/* Define to `int' if <signal.h> doesn't define.])
 274 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 275             [Some systems declare sig_atomic_t as volatile, some others -- no.
 276              This define will have value `sig_atomic_t' or
 277              `volatile sig_atomic_t' accordingly.])
 278
 279 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 280 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 281   [
 282     ac_cv_type_sig_atomic_t=yes;
 283     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 284                     signal.h,
 285                     [
 286                         is_sig_atomic_t_volatile=yes;
 287                         AC_MSG_RESULT([yes, volatile])
 288                     ],
 289                     [
 290                         is_sig_atomic_t_volatile=no;
 291                         AC_MSG_RESULT([yes, non volatile])
 292                     ])
 293   ],
 294   [
 295     AC_MSG_RESULT(no)
 296     AC_CHECK_TYPE(sig_atomic_t, int)
 297     is_sig_atomic_t_volatile=no
 298   ])
 299 if test $is_sig_atomic_t_volatile = 'yes'
 300 then
 301     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 302 else
 303     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 304 fi
 305
 306
 307 dnl ############################################################################
 308 dnl Check for functions
 309 dnl ############################################################################
 310
 311 AC_CHECK_FUNCS([\
 312         strverscmp \
 313         strncasecmp \
 314         realpath
 315 ])
 316
 317 dnl getpt is a GNU Extension (glibc 2.1.x)
 318 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 319 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 320
 321 dnl replacing lstat with statlstat on sco makes it more portable between
 322 dnl sco clones
 323 AC_CHECK_FUNCS(statlstat)
 324
 325 mc_GET_FS_INFO
 326
 327
 328 dnl ############################################################################
 329 dnl Internationalization
 330 dnl ############################################################################
 331
 332 AC_CHECK_FUNCS([setlocale])
 333
 334 AM_GNU_GETTEXT([external], [need-ngettext])
 335 AM_GNU_GETTEXT_VERSION([0.18.2])
 336
 337 mc_I18N
 338
 339 dnl ############################################################################
 340 dnl OS specific stuff
 341 dnl ############################################################################
 342
 343 case $host_os in
 344 *os400)
 345     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 346     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/QOpenSys/pkgs/bin/perl])
 347     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 348     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 349     ;;
 350 *)
 351     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 352     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/usr/bin/perl])
 353     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 354     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 355 esac
 356
 357 case $host_os in
 358 aux*)
 359     # A/UX
 360     LIBS="$LIBS -lposix"
 361     AC_DEFINE(_POSIX_SOURCE)
 362     ;;
 363 esac
 364
 365 dnl If running under AIX, AC_AIX does not tell us that
 366 AC_MSG_CHECKING([for AIX defines])
 367 AC_EGREP_CPP([yes],
 368     [
 369         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 370         yes
 371         #endif
 372     ],
 373     [
 374         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 375         AC_MSG_RESULT(yes)
 376     ],
 377     [
 378         AC_MSG_RESULT(no)
 379     ])
 380
 381 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 382 AC_CHECK_FUNCS([utimensat])
 383
 384 case $host_os in
 385 *os400)
 386     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 387 esac
 388
 389 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 390 case $host_os in
 391 linux*)
 392     AC_CHECK_HEADERS([linux/fs.h])
 393 esac
 394
 395 dnl Check if the OS is supported by the console saver.
 396 cons_saver=""
 397 case $host_os in
 398 linux*)
 399     cons_saver=yes
 400 esac
 401
 402 dnl Check for gpm mouse support (Linux only)
 403 mouse_lib="xterm only"
 404 AC_ARG_WITH([gpm-mouse],
 405     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 406
 407 case $host_os in
 408 linux*)
 409     if test x$with_gpm_mouse != xno; then
 410         AC_CHECK_LIB(gpm, Gpm_Repeat,
 411             [AC_DEFINE(HAVE_LIBGPM, 1,
 412                        [Define to enable gpm mouse support on Linux])
 413             mouse_lib="gpm and xterm"
 414             MCLIBS="$MCLIBS -lgpm"],
 415             if test "x$with_gpm_mouse" = "xyes"; then
 416                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 417             else
 418                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 419             fi
 420         )
 421     fi
 422     ;;
 423 esac
 424
 425
 426 dnl ############################################################################
 427 dnl libmc
 428 dnl ############################################################################
 429
 430 LIBMC_VERSION="0.0.1"
 431 LIBMC_RELEASE="1"
 432 AC_SUBST(LIBMC_VERSION)
 433 AC_SUBST(LIBMC_RELEASE)
 434
 435 AC_ARG_ENABLE([mclib],
 436         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 437         [
 438             if test "x$enableval" = "xno" ; then
 439                 enable_mclib=no
 440             else
 441                 if test "x$enable_shared" = "xno" ; then
 442                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 443                     enable_mclib=no
 444                 else
 445                     enable_mclib=yes
 446                 fi
 447             fi
 448         ],
 449         [enable_mclib=no])
 450
 451 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 452
 453
 454 dnl ############################################################################
 455 dnl MC options
 456 dnl ############################################################################
 457
 458 mc_ASSERT
 459
 460 mc_WITH_INTERNAL_EDIT
 461
 462 dnl Diff viewer support.
 463 AC_ARG_WITH([diff_viewer],
 464     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 465
 466 if test x$with_diff_viewer != xno; then
 467         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 468         use_diff=yes
 469         diff_msg="yes"
 470         AC_MSG_NOTICE([using diff viewer])
 471 else
 472         diff_msg="no"
 473 fi
 474
 475 mc_SUBSHELL
 476 mc_BACKGROUND
 477 mc_EXT2FS_ATTR
 478 mc_VFS_CHECKS
 479
 480 dnl ############################################################################
 481 dnl Directories
 482 dnl ############################################################################
 483
 484 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 485 dnl Let define ${prefix} and ${exec_prefix}
 486 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 487 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 488
 489 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 490     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 491 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 492     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 493 else
 494     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 495 fi
 496 AC_SUBST(EXTHELPERSDIR)
 497
 498
 499 dnl ############################################################################
 500 dnl Documentation
 501 dnl ############################################################################
 502
 503 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 504 AC_SUBST(MAN_DATE)
 505
 506 dnl Determine which help translations we want to install.
 507 ALL_DOC_LINGUAS="es hu it pl ru sr"
 508
 509 DOC_LINGUAS=
 510 if test "x$USE_NLS" = xyes; then
 511     if test -z "$LINGUAS"; then
 512         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 513     else
 514         langs="$LINGUAS"
 515     fi
 516 else
 517     langs=
 518 fi
 519
 520 for h_lang in $ALL_DOC_LINGUAS; do
 521     for lang in $langs; do
 522         if test "$lang" = "$h_lang"; then
 523             DOC_LINGUAS="$DOC_LINGUAS $lang"
 524             break
 525         fi
 526     done
 527 done
 528 AC_SUBST(DOC_LINGUAS)
 529
 530 DX_HTML_FEATURE(ON)
 531 DX_CHM_FEATURE(OFF)
 532 DX_CHI_FEATURE(OFF)
 533 DX_MAN_FEATURE(OFF)
 534 DX_RTF_FEATURE(OFF)
 535 DX_XML_FEATURE(OFF)
 536 DX_PDF_FEATURE(OFF)
 537 DX_PS_FEATURE(OFF)
 538 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 539
 540
 541 dnl ############################################################################
 542 dnl Configure results
 543 dnl ############################################################################
 544
 545 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 546
 547 AC_SUBST(MCLIBS)
 548 AC_SUBST(CFLAGS)
 549 AC_SUBST(CPPFLAGS)
 550 AC_SUBST(LDFLAGS)
 551 AC_SUBST(LIBS)
 552
 553 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 554 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 555 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 556 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 557 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 558 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 559 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 560 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 561 dnl Clarify do we really need GModule
 562 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 563                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 564
 565 AC_ARG_ENABLE([configure-args],
 566     AS_HELP_STRING([--enable-configure-args], [Embed ./configure arguments into binaries]))
 567 if test "x$enable_configure_args" != xno; then
 568     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 569     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 570 fi
 571
 572
 573 AC_CONFIG_FILES(
 574 [
 575 src/man2hlp/man2hlp
 576 ],
 577 [
 578 chmod +x src/man2hlp/man2hlp
 579 ])
 580
 581 AC_CONFIG_FILES([
 582 Makefile
 583
 584 contrib/Makefile
 585
 586 misc/Makefile
 587 misc/mc.charsets
 588 misc/mc.menu
 589 misc/mcedit.menu
 590 misc/skins/Makefile
 591 misc/ext.d/Makefile
 592 misc/ext.d/doc.sh
 593 misc/ext.d/misc.sh
 594 misc/ext.d/text.sh
 595 misc/ext.d/web.sh
 596 misc/macros.d/Makefile
 597 misc/mc.ext.ini
 598
 599 src/Makefile
 600 src/consaver/Makefile
 601 src/editor/Makefile
 602 src/man2hlp/Makefile
 603 src/subshell/Makefile
 604 src/viewer/Makefile
 605 src/diffviewer/Makefile
 606 src/filemanager/Makefile
 607
 608 src/vfs/Makefile
 609
 610 src/vfs/cpio/Makefile
 611
 612 src/vfs/extfs/Makefile
 613 src/vfs/extfs/helpers/Makefile
 614 src/vfs/extfs/helpers/a+
 615 src/vfs/extfs/helpers/apt+
 616 src/vfs/extfs/helpers/audio
 617 src/vfs/extfs/helpers/deb
 618 src/vfs/extfs/helpers/deba
 619 src/vfs/extfs/helpers/debd
 620 src/vfs/extfs/helpers/dpkg+
 621 src/vfs/extfs/helpers/iso9660
 622 src/vfs/extfs/helpers/hp48+
 623 src/vfs/extfs/helpers/lslR
 624 src/vfs/extfs/helpers/mailfs
 625 src/vfs/extfs/helpers/patchfs
 626 src/vfs/extfs/helpers/rpms+
 627 src/vfs/extfs/helpers/s3+
 628 src/vfs/extfs/helpers/uace
 629 src/vfs/extfs/helpers/ualz
 630 src/vfs/extfs/helpers/uar
 631 src/vfs/extfs/helpers/uarc
 632 src/vfs/extfs/helpers/uarj
 633 src/vfs/extfs/helpers/ucab
 634 src/vfs/extfs/helpers/uha
 635 src/vfs/extfs/helpers/ulha
 636 src/vfs/extfs/helpers/ulib
 637 src/vfs/extfs/helpers/unar
 638 src/vfs/extfs/helpers/urar
 639 src/vfs/extfs/helpers/uwim
 640 src/vfs/extfs/helpers/uzip
 641 src/vfs/extfs/helpers/uzoo
 642
 643 src/vfs/shell/Makefile
 644 src/vfs/shell/helpers/Makefile
 645
 646 src/vfs/ftpfs/Makefile
 647
 648 src/vfs/sftpfs/Makefile
 649
 650 src/vfs/local/Makefile
 651
 652 src/vfs/sfs/Makefile
 653
 654 src/vfs/tar/Makefile
 655
 656 src/vfs/undelfs/Makefile
 657
 658 lib/Makefile
 659 lib/event/Makefile
 660 lib/filehighlight/Makefile
 661 lib/mcconfig/Makefile
 662 lib/search/Makefile
 663 lib/skin/Makefile
 664 lib/strutil/Makefile
 665 lib/tty/Makefile
 666
 667 lib/vfs/Makefile
 668
 669 lib/widget/Makefile
 670
 671 misc/syntax/Makefile
 672
 673 doc/Makefile
 674
 675 doc/hints/Makefile
 676 doc/hints/l10n/Makefile
 677
 678 doc/man/Makefile
 679 doc/man/es/Makefile
 680 doc/man/hu/Makefile
 681 doc/man/it/Makefile
 682 doc/man/pl/Makefile
 683 doc/man/ru/Makefile
 684 doc/man/sr/Makefile
 685
 686 doc/hlp/Makefile
 687 doc/hlp/es/Makefile
 688 doc/hlp/hu/Makefile
 689 doc/hlp/it/Makefile
 690 doc/hlp/pl/Makefile
 691 doc/hlp/ru/Makefile
 692 doc/hlp/sr/Makefile
 693
 694 po/Makefile.in
 695 ])
 696
 697 dnl https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable/30932102#30932102
 698 AC_CONFIG_FILES(
 699 [misc/syntax/Syntax], [${SED-sed} -e "s%\${prefix}%$PREFIX%" misc/syntax/Syntax > misc/syntax/Syntax.tmp && \
 700   mv -f misc/syntax/Syntax.tmp misc/syntax/Syntax], [export PREFIX=$prefix]
 701 )
 702
 703 AC_CONFIG_FILES([
 704 tests/Makefile
 705 tests/lib/Makefile
 706 tests/lib/mcconfig/Makefile
 707 tests/lib/search/Makefile
 708 tests/lib/strutil/Makefile
 709 tests/lib/vfs/Makefile
 710 tests/lib/vfs/mc.charsets
 711 tests/lib/widget/Makefile
 712 tests/src/Makefile
 713 tests/src/filemanager/Makefile
 714 tests/src/editor/Makefile
 715 tests/src/editor/test-data.txt
 716 tests/src/vfs/Makefile
 717 tests/src/vfs/extfs/Makefile
 718 tests/src/vfs/extfs/helpers-list/Makefile
 719 tests/src/vfs/extfs/helpers-list/data/config.sh
 720 tests/src/vfs/extfs/helpers-list/misc/Makefile
 721 tests/src/vfs/ftpfs/Makefile
 722 ])
 723
 724 AC_OUTPUT
 725
 726 AC_MSG_NOTICE([
 727
 728 Configuration:
 729
 730   Source code location:           ${srcdir}
 731   Compiler:                       ${CC}
 732   Compiler flags:                 ${CFLAGS}
 733   Assertions:                     ${enable_assert}
 734   Unit tests:                     ${tests_msg}
 735   File system:                    ${vfs_type}
 736                                   ${vfs_flags}
 737   Screen library:                 ${screen_msg}
 738   Mouse support:                  ${mouse_lib}
 739   X11 events support:             ${textmode_x11_support}
 740   With subshell support:          ${subshell}
 741   With background operations:     ${enable_background}
 742   With ext2fs attributes support: ${ext2fs_attr_msg}
 743   Internal editor:                ${edit_msg}
 744   Diff viewer:                    ${diff_msg}
 745   Support for charset:            ${charset_msg}
 746   Search type:                    ${SEARCH_TYPE}
 747 ])
 748
 749 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 750 dnl we enable it back for top-level ./configure
 751 if test -n "$ac_unrecognized_opts"; then
 752   case $enable_option_checking in
 753     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 754     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 755   esac
 756 fi