configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ(2.64)
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 dnl This should be checked before toolchain macros, otherwise they will remember
  40 dnl that ar cannot be found and linking via libtool will fail at a later stage
  41 AC_CHECK_TOOLS([AR], [ar gar])
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_C_O
  45
  46 mc_CHECK_CFLAGS
  47
  48 CFLAGS_OPTS=""
  49 if test "x$CFLAGS" = "x"; then
  50     CFLAGS_OPTS=" -O2 "
  51 fi
  52 if test x$USE_MAINTAINER_MODE = xyes; then
  53     CFLAGS_OPTS="-g3 -O -ggdb"
  54     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  55 fi
  56
  57 AC_ARG_ENABLE([werror],
  58     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  59 if test "x$enable_werror" = xyes; then
  60     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  61 fi
  62
  63 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  64 dnl which causes attribute checks to fail
  65 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  66 _AC_LANG_PREFIX[]FLAGS=
  67 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  68 AX_GCC_FUNC_ATTRIBUTE([weak])
  69 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  70 unset ax_gcc_func_attribute_save_flags
  71
  72 LT_INIT
  73
  74
  75 dnl ############################################################################
  76 dnl Check for programs
  77 dnl ############################################################################
  78
  79 AC_PROG_SED
  80 PKG_PROG_PKG_CONFIG
  81 AC_PROG_INSTALL
  82 AC_PROG_LN_S
  83 dnl See also the "OS specific stuff" section below.
  84
  85 dnl Check nroff and the options it supports
  86 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  87 dnl Default values
  88 MANDOC=-man
  89 MAN_FLAGS=
  90 if $HAVE_nroff; then
  91     AC_MSG_CHECKING([for manual formatting macros])
  92     AC_CACHE_VAL(mc_cv_mandoc, [
  93     nroff -mandoc < /dev/null > /dev/null 2>&1
  94     if test $? = 0; then
  95         mc_cv_mandoc=-mandoc
  96     else
  97         mc_cv_mandoc=-man
  98     fi
  99     ])
 100     MANDOC=$mc_cv_mandoc
 101     AC_MSG_RESULT([$MANDOC])
 102
 103     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 104     AC_CACHE_VAL(mc_cv_man_nocolor, [
 105     nroff -c < /dev/null > /dev/null 2>&1
 106     if test $? = 0; then
 107         mc_cv_man_nocolor=-c
 108     else
 109         mc_cv_man_nocolor=
 110     fi
 111     ])
 112     MAN_FLAGS=$mc_cv_man_nocolor
 113     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 114
 115     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 116     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 117     mc_cv_nroff_tascii=
 118     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 119     if test $? = 0; then
 120         mc_cv_nroff_tascii=-Tlatin1
 121     else
 122         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 123         if test $? = 0; then
 124             mc_cv_nroff_tascii=-Tascii
 125         fi
 126     fi
 127     ])
 128     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 129     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 130 fi
 131
 132 AC_SUBST(MANDOC)
 133 AC_SUBST(MAN_FLAGS)
 134
 135 dnl Check for -z, -b, -L, and -S options to file
 136 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 137 if $HAVE_FILECMD; then
 138     dnl Don't use the file command if it doesn't accept the -z option
 139     AC_MSG_CHECKING([for -z option to file command])
 140     AC_CACHE_VAL(mc_cv_file_z, [
 141         file -z . > /dev/null 2>&1
 142         if test $? = 0; then
 143             mc_cv_file_z=yes
 144         else
 145             mc_cv_file_z=no
 146         fi
 147     ])
 148     AC_MSG_RESULT([$mc_cv_file_z])
 149
 150     if test x$mc_cv_file_z = xyes; then
 151         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 152     else
 153         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 154     fi
 155
 156     if test x$mc_cv_file_z = xyes; then
 157         dnl file is used; check -b, -L and -S options
 158
 159         AC_MSG_CHECKING([for -b option to file command])
 160         AC_CACHE_VAL(mc_cv_file_b, [
 161             file -b . > /dev/null 2>&1
 162             if test $? = 0; then
 163                 mc_cv_file_b=yes
 164             else
 165                 mc_cv_file_b=no
 166             fi
 167         ])
 168         AC_MSG_RESULT([$mc_cv_file_b])
 169
 170         if test x$mc_cv_file_b = xyes; then
 171             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 172         fi
 173
 174         AC_MSG_CHECKING([for -L option to file command])
 175         AC_CACHE_VAL(mc_cv_file_L, [
 176             file -L . > /dev/null 2>&1
 177             if test $? = 0; then
 178                 mc_cv_file_L=yes
 179             else
 180                 mc_cv_file_L=no
 181             fi
 182         ])
 183         AC_MSG_RESULT([$mc_cv_file_L])
 184
 185         if test x$mc_cv_file_L = xyes; then
 186             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 187         else
 188             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 189         fi
 190
 191         dnl The file command accepts the -S option since 5.33
 192         AC_MSG_CHECKING([for -S option to file command])
 193         AC_CACHE_VAL(mc_cv_file_S, [
 194             file -S . > /dev/null 2>&1
 195             if test $? = 0; then
 196                 mc_cv_file_S=yes
 197             else
 198                 mc_cv_file_S=no
 199             fi
 200         ])
 201         AC_MSG_RESULT([$mc_cv_file_S])
 202
 203         if test x$mc_cv_file_S = xyes; then
 204             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 205         else
 206             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 207         fi
 208     fi
 209 fi
 210
 211 dnl Only list browsers here that can be run in background (i.e. with `&')
 212 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 213
 214
 215 dnl ############################################################################
 216 dnl Check for other tools
 217 dnl ############################################################################
 218
 219 AC_CHECK_TOOLS([INDENT], [gindent indent])
 220 mc_UNIT_TESTS
 221
 222
 223 dnl ############################################################################
 224 dnl Check for main libraries
 225 dnl ############################################################################
 226
 227 mc_CHECK_GLIB
 228 mc_G_MODULE_SUPPORTED
 229 mc_WITH_SCREEN
 230 mc_CHECK_SEARCH_TYPE
 231 dnl X11 support. Used to read keyboard modifiers when running under X11.
 232 mc_WITH_X
 233
 234
 235 dnl ############################################################################
 236 dnl Check for header files
 237 dnl ############################################################################
 238
 239 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 240         utime.h sys/statfs.h sys/vfs.h \
 241         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 242         sys/socket.h])
 243 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 244 dnl   to work around a buggy version in autoconf <= 2.69.
 245 AC_HEADER_MAJOR
 246
 247 mc_CHECK_HEADER_STDCKDINT
 248
 249
 250 dnl ############################################################################
 251 dnl Check for types
 252 dnl ############################################################################
 253
 254 dnl Check largefile before type sizeof checks
 255 AC_SYS_LARGEFILE
 256
 257 AC_CHECK_SIZEOF(long)
 258 AC_TYPE_UINTMAX_T
 259 AC_CHECK_SIZEOF(uintmax_t)
 260 AC_TYPE_OFF_T
 261 AC_CHECK_SIZEOF(off_t)
 262 AC_TYPE_MODE_T
 263 gl_PROMOTED_TYPE_MODE_T
 264 AC_TYPE_PID_T
 265 AC_TYPE_UID_T
 266
 267 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 268 AC_CHECK_TYPE([dev_t], [unsigned long long int])
 269 AC_CHECK_TYPE([ino_t], [unsigned long long int])
 270
 271 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 272 AC_CHECK_TYPE([major_t], [unsigned int])
 273 AC_CHECK_TYPE([minor_t], [unsigned int])
 274
 275 AC_STRUCT_ST_BLOCKS
 276 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim, struct stat.st_mtimespec, struct stat.st_mtimensec])
 277 gl_STAT_SIZE
 278
 279 AH_TEMPLATE([sig_atomic_t],
 280             [/* Define to `int' if <signal.h> doesn't define.])
 281 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 282             [Some systems declare sig_atomic_t as volatile, some others -- no.
 283              This define will have value `sig_atomic_t' or
 284              `volatile sig_atomic_t' accordingly.])
 285
 286 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 287 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 288   [
 289     ac_cv_type_sig_atomic_t=yes;
 290     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 291                     signal.h,
 292                     [
 293                         is_sig_atomic_t_volatile=yes;
 294                         AC_MSG_RESULT([yes, volatile])
 295                     ],
 296                     [
 297                         is_sig_atomic_t_volatile=no;
 298                         AC_MSG_RESULT([yes, non volatile])
 299                     ])
 300   ],
 301   [
 302     AC_MSG_RESULT(no)
 303     AC_CHECK_TYPE(sig_atomic_t, int)
 304     is_sig_atomic_t_volatile=no
 305   ])
 306 if test $is_sig_atomic_t_volatile = 'yes'
 307 then
 308     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 309 else
 310     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 311 fi
 312
 313
 314 dnl ############################################################################
 315 dnl Check for functions
 316 dnl ############################################################################
 317
 318 AC_CHECK_FUNCS([\
 319         strverscmp \
 320         strncasecmp \
 321         realpath
 322 ])
 323
 324 dnl getpt is a GNU Extension (glibc 2.1.x)
 325 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 326 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 327
 328 dnl replacing lstat with statlstat on sco makes it more portable between
 329 dnl sco clones
 330 AC_CHECK_FUNCS(statlstat)
 331
 332 mc_GET_FS_INFO
 333
 334
 335 dnl ############################################################################
 336 dnl Internationalization
 337 dnl ############################################################################
 338
 339 AC_CHECK_FUNCS([setlocale])
 340
 341 AM_GNU_GETTEXT([external], [need-ngettext])
 342 AM_GNU_GETTEXT_VERSION([0.18.2])
 343
 344 mc_I18N
 345
 346 dnl ############################################################################
 347 dnl OS specific stuff
 348 dnl ############################################################################
 349
 350 AC_CHECK_DECLS([environ], , ,
 351   [ #include <unistd.h>
 352     #include <stdlib.h> ])
 353
 354 case $host_os in
 355 *os400)
 356     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 357     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/QOpenSys/pkgs/bin/perl])
 358     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 359     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 360     ;;
 361 *)
 362     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 363     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/usr/bin/perl])
 364     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 365     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 366 esac
 367
 368 case $host_os in
 369 aux*)
 370     # A/UX
 371     LIBS="$LIBS -lposix"
 372     AC_DEFINE(_POSIX_SOURCE)
 373     ;;
 374 esac
 375
 376 dnl If running under AIX, AC_AIX does not tell us that
 377 AC_MSG_CHECKING([for AIX defines])
 378 AC_EGREP_CPP([yes],
 379     [
 380         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 381         yes
 382         #endif
 383     ],
 384     [
 385         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 386         AC_MSG_RESULT(yes)
 387     ],
 388     [
 389         AC_MSG_RESULT(no)
 390     ])
 391
 392 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 393 AC_CHECK_FUNCS([utimensat])
 394
 395 case $host_os in
 396 *os400)
 397     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 398 esac
 399
 400 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 401 case $host_os in
 402 linux*)
 403     AC_CHECK_HEADERS([linux/fs.h])
 404 esac
 405
 406 dnl Check if the OS is supported by the console saver.
 407 cons_saver=""
 408 case $host_os in
 409 linux*)
 410     cons_saver=yes
 411 esac
 412
 413 dnl Check for gpm mouse support (Linux only)
 414 mouse_lib="xterm only"
 415 AC_ARG_WITH([gpm-mouse],
 416     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 417
 418 case $host_os in
 419 linux*)
 420     if test x$with_gpm_mouse != xno; then
 421         AC_CHECK_LIB(gpm, Gpm_Repeat,
 422             [AC_DEFINE(HAVE_LIBGPM, 1,
 423                        [Define to enable gpm mouse support on Linux])
 424             mouse_lib="gpm and xterm"
 425             MCLIBS="$MCLIBS -lgpm"],
 426             if test "x$with_gpm_mouse" = "xyes"; then
 427                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 428             else
 429                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 430             fi
 431         )
 432     fi
 433     ;;
 434 esac
 435
 436
 437 dnl ############################################################################
 438 dnl libmc
 439 dnl ############################################################################
 440
 441 LIBMC_VERSION="0.0.1"
 442 LIBMC_RELEASE="1"
 443 AC_SUBST(LIBMC_VERSION)
 444 AC_SUBST(LIBMC_RELEASE)
 445
 446 AC_ARG_ENABLE([mclib],
 447         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 448         [
 449             if test "x$enableval" = "xno" ; then
 450                 enable_mclib=no
 451             else
 452                 if test "x$enable_shared" = "xno" ; then
 453                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 454                     enable_mclib=no
 455                 else
 456                     enable_mclib=yes
 457                 fi
 458             fi
 459         ],
 460         [enable_mclib=no])
 461
 462 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 463
 464
 465 dnl ############################################################################
 466 dnl MC options
 467 dnl ############################################################################
 468
 469 mc_ASSERT
 470
 471 mc_WITH_INTERNAL_EDIT
 472
 473 dnl Diff viewer support.
 474 AC_ARG_WITH([diff_viewer],
 475     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 476
 477 if test x$with_diff_viewer != xno; then
 478         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 479         use_diff=yes
 480         diff_msg="yes"
 481         AC_MSG_NOTICE([using diff viewer])
 482 else
 483         diff_msg="no"
 484 fi
 485
 486 mc_SUBSHELL
 487 mc_BACKGROUND
 488 mc_EXT2FS_ATTR
 489 mc_VFS_CHECKS
 490
 491 dnl ############################################################################
 492 dnl Directories
 493 dnl ############################################################################
 494
 495 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 496 dnl Let define ${prefix} and ${exec_prefix}
 497 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 498 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 499
 500 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 501     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 502 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 503     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 504 else
 505     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 506 fi
 507 AC_SUBST(EXTHELPERSDIR)
 508
 509
 510 dnl ############################################################################
 511 dnl Documentation
 512 dnl ############################################################################
 513
 514 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 515 AC_SUBST(MAN_DATE)
 516
 517 dnl Determine which help translations we want to install.
 518 ALL_DOC_LINGUAS="es hu it pl ru sr"
 519
 520 DOC_LINGUAS=
 521 if test "x$USE_NLS" = xyes; then
 522     if test -z "$LINGUAS"; then
 523         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 524     else
 525         langs="$LINGUAS"
 526     fi
 527 else
 528     langs=
 529 fi
 530
 531 for h_lang in $ALL_DOC_LINGUAS; do
 532     for lang in $langs; do
 533         if test "$lang" = "$h_lang"; then
 534             DOC_LINGUAS="$DOC_LINGUAS $lang"
 535             break
 536         fi
 537     done
 538 done
 539 AC_SUBST(DOC_LINGUAS)
 540
 541 DX_HTML_FEATURE(ON)
 542 DX_CHM_FEATURE(OFF)
 543 DX_CHI_FEATURE(OFF)
 544 DX_MAN_FEATURE(OFF)
 545 DX_RTF_FEATURE(OFF)
 546 DX_XML_FEATURE(OFF)
 547 DX_PDF_FEATURE(OFF)
 548 DX_PS_FEATURE(OFF)
 549 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 550
 551
 552 dnl ############################################################################
 553 dnl Configure results
 554 dnl ############################################################################
 555
 556 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 557
 558 AC_SUBST(MCLIBS)
 559 AC_SUBST(CFLAGS)
 560 AC_SUBST(CPPFLAGS)
 561 AC_SUBST(LDFLAGS)
 562 AC_SUBST(LIBS)
 563
 564 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 565 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 566 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 567 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 568 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 569 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 570 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 571 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 572 dnl Clarify do we really need GModule
 573 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 574                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 575
 576 AC_ARG_ENABLE([configure-args],
 577     AS_HELP_STRING([--enable-configure-args], [Embed ./configure arguments into binaries]))
 578 if test "x$enable_configure_args" != xno; then
 579     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 580     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 581 fi
 582
 583
 584 AC_CONFIG_FILES(
 585 [
 586 src/man2hlp/man2hlp
 587 ],
 588 [
 589 chmod +x src/man2hlp/man2hlp
 590 ])
 591
 592 AC_CONFIG_FILES([
 593 Makefile
 594
 595 contrib/Makefile
 596
 597 misc/Makefile
 598 misc/mc.charsets
 599 misc/mc.menu
 600 misc/mcedit.menu
 601 misc/skins/Makefile
 602 misc/ext.d/Makefile
 603 misc/ext.d/doc.sh
 604 misc/ext.d/misc.sh
 605 misc/ext.d/text.sh
 606 misc/ext.d/web.sh
 607 misc/macros.d/Makefile
 608 misc/mc.ext.ini
 609
 610 src/Makefile
 611 src/consaver/Makefile
 612 src/editor/Makefile
 613 src/man2hlp/Makefile
 614 src/subshell/Makefile
 615 src/viewer/Makefile
 616 src/diffviewer/Makefile
 617 src/filemanager/Makefile
 618
 619 src/vfs/Makefile
 620
 621 src/vfs/cpio/Makefile
 622
 623 src/vfs/extfs/Makefile
 624 src/vfs/extfs/helpers/Makefile
 625 src/vfs/extfs/helpers/a+
 626 src/vfs/extfs/helpers/apt+
 627 src/vfs/extfs/helpers/audio
 628 src/vfs/extfs/helpers/deb
 629 src/vfs/extfs/helpers/deba
 630 src/vfs/extfs/helpers/debd
 631 src/vfs/extfs/helpers/dpkg+
 632 src/vfs/extfs/helpers/iso9660
 633 src/vfs/extfs/helpers/hp48+
 634 src/vfs/extfs/helpers/lslR
 635 src/vfs/extfs/helpers/mailfs
 636 src/vfs/extfs/helpers/patchfs
 637 src/vfs/extfs/helpers/rpms+
 638 src/vfs/extfs/helpers/s3+
 639 src/vfs/extfs/helpers/uace
 640 src/vfs/extfs/helpers/ualz
 641 src/vfs/extfs/helpers/uar
 642 src/vfs/extfs/helpers/uarc
 643 src/vfs/extfs/helpers/uarj
 644 src/vfs/extfs/helpers/ucab
 645 src/vfs/extfs/helpers/uha
 646 src/vfs/extfs/helpers/ulha
 647 src/vfs/extfs/helpers/ulib
 648 src/vfs/extfs/helpers/unar
 649 src/vfs/extfs/helpers/urar
 650 src/vfs/extfs/helpers/uwim
 651 src/vfs/extfs/helpers/uzip
 652 src/vfs/extfs/helpers/uzoo
 653
 654 src/vfs/shell/Makefile
 655 src/vfs/shell/helpers/Makefile
 656
 657 src/vfs/ftpfs/Makefile
 658
 659 src/vfs/sftpfs/Makefile
 660
 661 src/vfs/local/Makefile
 662
 663 src/vfs/sfs/Makefile
 664
 665 src/vfs/tar/Makefile
 666
 667 src/vfs/undelfs/Makefile
 668
 669 lib/Makefile
 670 lib/event/Makefile
 671 lib/filehighlight/Makefile
 672 lib/mcconfig/Makefile
 673 lib/search/Makefile
 674 lib/skin/Makefile
 675 lib/strutil/Makefile
 676 lib/tty/Makefile
 677
 678 lib/vfs/Makefile
 679
 680 lib/widget/Makefile
 681
 682 misc/syntax/Makefile
 683
 684 doc/Makefile
 685
 686 doc/hints/Makefile
 687 doc/hints/l10n/Makefile
 688
 689 doc/man/Makefile
 690 doc/man/es/Makefile
 691 doc/man/hu/Makefile
 692 doc/man/it/Makefile
 693 doc/man/pl/Makefile
 694 doc/man/ru/Makefile
 695 doc/man/sr/Makefile
 696
 697 doc/hlp/Makefile
 698 doc/hlp/es/Makefile
 699 doc/hlp/hu/Makefile
 700 doc/hlp/it/Makefile
 701 doc/hlp/pl/Makefile
 702 doc/hlp/ru/Makefile
 703 doc/hlp/sr/Makefile
 704
 705 po/Makefile.in
 706 ])
 707
 708 dnl https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable/30932102#30932102
 709 AC_CONFIG_FILES(
 710 [misc/syntax/Syntax], [${SED-sed} -e "s%\${prefix}%$PREFIX%" misc/syntax/Syntax > misc/syntax/Syntax.tmp && \
 711   mv -f misc/syntax/Syntax.tmp misc/syntax/Syntax], [export PREFIX=$prefix]
 712 )
 713
 714 AC_CONFIG_FILES([
 715 tests/Makefile
 716 tests/lib/Makefile
 717 tests/lib/mcconfig/Makefile
 718 tests/lib/search/Makefile
 719 tests/lib/strutil/Makefile
 720 tests/lib/vfs/Makefile
 721 tests/lib/vfs/mc.charsets
 722 tests/lib/widget/Makefile
 723 tests/src/Makefile
 724 tests/src/filemanager/Makefile
 725 tests/src/editor/Makefile
 726 tests/src/editor/test-data.txt
 727 tests/src/vfs/Makefile
 728 tests/src/vfs/extfs/Makefile
 729 tests/src/vfs/extfs/helpers-list/Makefile
 730 tests/src/vfs/extfs/helpers-list/data/config.sh
 731 tests/src/vfs/extfs/helpers-list/misc/Makefile
 732 tests/src/vfs/ftpfs/Makefile
 733 ])
 734
 735 AC_OUTPUT
 736
 737 AC_MSG_NOTICE([
 738
 739 Configuration:
 740
 741   Source code location:           ${srcdir}
 742   Compiler:                       ${CC}
 743   Compiler flags:                 ${CFLAGS}
 744   Assertions:                     ${enable_assert}
 745   Unit tests:                     ${tests_msg}
 746   File system:                    ${vfs_type}
 747                                   ${vfs_flags}
 748   Screen library:                 ${screen_msg}
 749   Mouse support:                  ${mouse_lib}
 750   X11 events support:             ${textmode_x11_support}
 751   With subshell support:          ${subshell}
 752   With background operations:     ${enable_background}
 753   With ext2fs attributes support: ${ext2fs_attr_msg}
 754   Internal editor:                ${edit_msg}
 755   Diff viewer:                    ${diff_msg}
 756   Support for charset:            ${charset_msg}
 757   Search type:                    ${SEARCH_TYPE}
 758 ])
 759
 760 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 761 dnl we enable it back for top-level ./configure
 762 if test -n "$ac_unrecognized_opts"; then
 763   case $enable_option_checking in
 764     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 765     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 766   esac
 767 fi