m4.include/mc-vfs.m4

   1 AC_DEFUN([mc_VFS_ADDNAME],
   2 [
   3     if test x"$vfs_flags" = "x" ; then
   4         vfs_flags="$1"
   5     else
   6         vfs_flags="$vfs_flags, $1"
   7     fi
   8 ])
   9
  10 m4_include([m4.include/vfs/rpc.m4])
  11 m4_include([m4.include/vfs/socket.m4])
  12 m4_include([m4.include/vfs/mc-vfs-extfs.m4])
  13 m4_include([m4.include/vfs/mc-vfs-sfs.m4])
  14 m4_include([m4.include/vfs/mc-vfs-ftp.m4])
  15 m4_include([m4.include/vfs/mc-vfs-sftp.m4])
  16 m4_include([m4.include/vfs/mc-vfs-shell.m4])
  17 m4_include([m4.include/vfs/mc-vfs-undelfs.m4])
  18 m4_include([m4.include/vfs/mc-vfs-tarfs.m4])
  19 m4_include([m4.include/vfs/mc-vfs-cpiofs.m4])
  20
  21 dnl mc_VFS_CHECKS
  22 dnl   Check for various functions needed by libvfs.
  23 dnl   This has various effects:
  24 dnl     Sets MC_VFS_LIBS to libraries required
  25 dnl     Sets vfs_flags to "pretty" list of vfs implementations we include.
  26 dnl     Sets shell variable enable_vfs to yes (default, --with-vfs) or
  27 dnl        "no" (--without-vfs).
  28
  29 dnl Private define
  30 AC_DEFUN([mc_ENABLE_VFS_NET],
  31 [
  32     dnl FIXME: network checks should probably be in their own macro.
  33     AC_REQUIRE_SOCKET
  34     if test x"$have_socket" = xyes; then
  35         AC_CHECK_TYPE([nlink_t], ,
  36                         [AC_DEFINE_UNQUOTED([nlink_t], [unsigned int],
  37                             [Define to 'unsigned int' if <sys/types.h> does not define.])])
  38         AC_CHECK_TYPES([socklen_t],,,
  39             [
  40 #include <sys/types.h>
  41 #include <sys/socket.h>
  42             ])
  43
  44         AC_CHECK_RPC
  45
  46         enable_vfs_net=yes
  47         AC_DEFINE(ENABLE_VFS_NET, [1], [Define to enable network VFSes support])
  48     fi
  49 ])
  50
  51 AC_DEFUN([mc_VFS_CHECKS],
  52 [
  53     vfs_type="normal"
  54
  55     AC_ARG_ENABLE([vfs],
  56         AS_HELP_STRING([--disable-vfs], [Disable VFS]),
  57         [
  58             if test "x$enableval" = "xno"; then
  59                 enable_vfs=no
  60             else
  61                 enable_vfs=yes
  62             fi
  63         ],
  64         [enable_vfs=yes])
  65
  66     if test x"$enable_vfs" = x"yes" ; then
  67         vfs_type="Midnight Commander Virtual Filesystem"
  68         AC_MSG_NOTICE([Enabling VFS code])
  69         AC_DEFINE(ENABLE_VFS, [1], [Define to enable VFS support])
  70     fi
  71
  72     mc_VFS_CPIOFS
  73     mc_VFS_EXTFS
  74     mc_VFS_SHELL
  75     mc_VFS_FTP
  76     mc_VFS_SFS
  77     mc_VFS_SFTP
  78     mc_VFS_TARFS
  79     mc_VFS_UNDELFS
  80
  81     AM_CONDITIONAL(ENABLE_VFS, [test x"$enable_vfs" = x"yes"])
  82
  83     if test x"$enable_vfs_ftp" = x"yes" -o x"$enable_vfs_shell" = x"yes" -o x"$enable_vfs_sftp" = x"yes"; then
  84         mc_ENABLE_VFS_NET
  85     fi
  86
  87     AM_CONDITIONAL([ENABLE_VFS_NET], [test x"$enable_vfs_net" = x"yes"])
  88 ])