m4.include/gnulib/mc-gnulib-common.m4

   1 # gnulib-common.m4
   2 # serial 101
   3 dnl Copyright (C) 2007-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_PREREQ([2.62])
   9
  10
  11 # gl_CONDITIONAL(conditional, condition)
  12 # is like AM_CONDITIONAL(conditional, condition), except that it does not
  13 # produce an error
  14 #   configure: error: conditional "..." was never defined.
  15 #   Usually this means the macro was only invoked conditionally.
  16 # when only invoked conditionally. Instead, in that case, both the _TRUE
  17 # and the _FALSE case are disabled.
  18 AC_DEFUN([gl_CONDITIONAL],
  19 [
  20   pushdef([AC_CONFIG_COMMANDS_PRE], [:])dnl
  21   AM_CONDITIONAL([$1], [$2])
  22   popdef([AC_CONFIG_COMMANDS_PRE])dnl
  23   if test -z "${[$1]_TRUE}" && test -z "${[$1]_FALSE}"; then
  24     [$1]_TRUE='#'
  25     [$1]_FALSE='#'
  26   fi
  27 ])
  28
  29 dnl gl_CONDITIONAL_HEADER([foo.h])
  30 dnl takes a shell variable GL_GENERATE_FOO_H (with value true or false) as input
  31 dnl and produces
  32 dnl   - an AC_SUBSTed variable FOO_H that is either a file name or empty, based
  33 dnl     on whether GL_GENERATE_FOO_H is true or false,
  34 dnl   - an Automake conditional GL_GENERATE_FOO_H that evaluates to the value of
  35 dnl     the shell variable GL_GENERATE_FOO_H.
  36 AC_DEFUN([gl_CONDITIONAL_HEADER],
  37 [
  38   m4_pushdef([gl_header_name], AS_TR_SH(m4_toupper($1)))
  39   m4_pushdef([gl_generate_var], [GL_GENERATE_]AS_TR_SH(m4_toupper($1)))
  40   m4_pushdef([gl_generate_cond], [GL_GENERATE_]AS_TR_SH(m4_toupper($1)))
  41   case "$gl_generate_var" in
  42     false) gl_header_name='' ;;
  43     true)
  44       dnl It is OK to use a .h file in lib/ from within tests/, but not vice
  45       dnl versa.
  46       if test -z "$gl_header_name"; then
  47         gl_header_name="${gl_source_base_prefix}$1"
  48       fi
  49       ;;
  50     *) echo "*** gl_generate_var is not set correctly" 1>&2; exit 1 ;;
  51   esac
  52   AC_SUBST(gl_header_name)
  53   gl_CONDITIONAL(gl_generate_cond, [$gl_generate_var])
  54   m4_popdef([gl_generate_cond])
  55   m4_popdef([gl_generate_var])
  56   m4_popdef([gl_header_name])
  57 ])