configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 dnl 2.64 is required at least for m4_esyscmd_s()
   6 AC_PREREQ(2.64)
   7
   8 AC_INIT([GNU Midnight Commander], m4_esyscmd_s([./version.sh .]),
   9         [https://www.midnight-commander.org/wiki/NewTicket], [mc],
  10         [https://www.midnight-commander.org/])
  11
  12 m4_pattern_forbid(MC_)
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CONFIG_AUX_DIR(config)
  15 AC_CONFIG_SRCDIR(src/main.c)
  16 AC_CONFIG_HEADERS(config.h)
  17
  18 dnl Apply "no-define" to avoid defining the VERSION macro in config.h
  19 AM_INIT_AUTOMAKE([no-define])
  20 dnl PACKAGE macro isn't defined if "no-define" is applied
  21 AC_DEFINE([PACKAGE], ["mc"], [Name of package])
  22
  23 dnl Enable silent rules by default (if yes)
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 mc_VERSION
  27
  28 AM_MAINTAINER_MODE
  29
  30 AC_CANONICAL_HOST
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34
  35 dnl ############################################################################
  36 dnl Check for compiler
  37 dnl ############################################################################
  38
  39 dnl This should be checked before toolchain macros, otherwise they will remember
  40 dnl that ar cannot be found and linking via libtool will fail at a later stage
  41 AC_CHECK_TOOLS([AR], [ar gar])
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_C_O
  45
  46 mc_CHECK_CFLAGS
  47
  48 CFLAGS_OPTS=""
  49 if test "x$CFLAGS" = "x"; then
  50     CFLAGS_OPTS=" -O2 "
  51 fi
  52 if test x$USE_MAINTAINER_MODE = xyes; then
  53     CFLAGS_OPTS="-g3 -O -ggdb"
  54     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  55 fi
  56
  57 AC_ARG_ENABLE([werror],
  58     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  59 if test "x$enable_werror" = xyes; then
  60     AX_APPEND_COMPILE_FLAGS([-Werror], [mc_configured_cflags])
  61 fi
  62
  63 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  64 dnl which causes attribute checks to fail
  65 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  66 _AC_LANG_PREFIX[]FLAGS=
  67 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  68 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  69 unset ax_gcc_func_attribute_save_flags
  70
  71 LT_INIT
  72
  73
  74 dnl ############################################################################
  75 dnl Check for programs
  76 dnl ############################################################################
  77
  78 AC_PROG_SED
  79 PKG_PROG_PKG_CONFIG
  80 AC_PROG_INSTALL
  81 AC_PROG_LN_S
  82 dnl See also the "OS specific stuff" section below.
  83
  84 dnl Check nroff and the options it supports
  85 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  86 dnl Default values
  87 MANDOC=-man
  88 MAN_FLAGS=
  89 if $HAVE_nroff; then
  90     AC_MSG_CHECKING([for manual formatting macros])
  91     AC_CACHE_VAL(mc_cv_mandoc, [
  92     nroff -mandoc < /dev/null > /dev/null 2>&1
  93     if test $? = 0; then
  94         mc_cv_mandoc=-mandoc
  95     else
  96         mc_cv_mandoc=-man
  97     fi
  98     ])
  99     MANDOC=$mc_cv_mandoc
 100     AC_MSG_RESULT([$MANDOC])
 101
 102     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
 103     AC_CACHE_VAL(mc_cv_man_nocolor, [
 104     nroff -c < /dev/null > /dev/null 2>&1
 105     if test $? = 0; then
 106         mc_cv_man_nocolor=-c
 107     else
 108         mc_cv_man_nocolor=
 109     fi
 110     ])
 111     MAN_FLAGS=$mc_cv_man_nocolor
 112     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
 113
 114     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
 115     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 116     mc_cv_nroff_tascii=
 117     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 118     if test $? = 0; then
 119         mc_cv_nroff_tascii=-Tlatin1
 120     else
 121         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 122         if test $? = 0; then
 123             mc_cv_nroff_tascii=-Tascii
 124         fi
 125     fi
 126     ])
 127     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 128     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 129 fi
 130
 131 AC_SUBST(MANDOC)
 132 AC_SUBST(MAN_FLAGS)
 133
 134 dnl Check for -z, -b, -L, and -S options to file
 135 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 136 if $HAVE_FILECMD; then
 137     dnl Don't use the file command if it doesn't accept the -z option
 138     AC_MSG_CHECKING([for -z option to file command])
 139     AC_CACHE_VAL(mc_cv_file_z, [
 140         file -z . > /dev/null 2>&1
 141         if test $? = 0; then
 142             mc_cv_file_z=yes
 143         else
 144             mc_cv_file_z=no
 145         fi
 146     ])
 147     AC_MSG_RESULT([$mc_cv_file_z])
 148
 149     if test x$mc_cv_file_z = xyes; then
 150         AC_DEFINE(USE_FILE_CMD, 1, [Define if the file command accepts the -z option])
 151     else
 152         AC_MSG_WARN([The file command doesn't accept the -z option and will not be used])
 153     fi
 154
 155     if test x$mc_cv_file_z = xyes; then
 156         dnl file is used; check -b, -L and -S options
 157
 158         AC_MSG_CHECKING([for -b option to file command])
 159         AC_CACHE_VAL(mc_cv_file_b, [
 160             file -b . > /dev/null 2>&1
 161             if test $? = 0; then
 162                 mc_cv_file_b=yes
 163             else
 164                 mc_cv_file_b=no
 165             fi
 166         ])
 167         AC_MSG_RESULT([$mc_cv_file_b])
 168
 169         if test x$mc_cv_file_b = xyes; then
 170             AC_DEFINE(FILE_B, "-b ", [Define if the file command accepts the -b option])
 171         fi
 172
 173         AC_MSG_CHECKING([for -L option to file command])
 174         AC_CACHE_VAL(mc_cv_file_L, [
 175             file -L . > /dev/null 2>&1
 176             if test $? = 0; then
 177                 mc_cv_file_L=yes
 178             else
 179                 mc_cv_file_L=no
 180             fi
 181         ])
 182         AC_MSG_RESULT([$mc_cv_file_L])
 183
 184         if test x$mc_cv_file_L = xyes; then
 185             AC_DEFINE(FILE_L, "-L ", [Define if the file command accepts the -L option])
 186         else
 187             AC_DEFINE(FILE_L, "", [Define if the file command accepts the -L option])
 188         fi
 189
 190         dnl The file command accepts the -S option since 5.33
 191         AC_MSG_CHECKING([for -S option to file command])
 192         AC_CACHE_VAL(mc_cv_file_S, [
 193             file -S . > /dev/null 2>&1
 194             if test $? = 0; then
 195                 mc_cv_file_S=yes
 196             else
 197                 mc_cv_file_S=no
 198             fi
 199         ])
 200         AC_MSG_RESULT([$mc_cv_file_S])
 201
 202         if test x$mc_cv_file_S = xyes; then
 203             AC_DEFINE(FILE_S, "-S ", [Define if file command accepts the -S option])
 204         else
 205             AC_DEFINE(FILE_S, "", [Define if file command accepts the -S option])
 206         fi
 207     fi
 208 fi
 209
 210 dnl Only list browsers here that can be run in background (i.e. with `&')
 211 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 212
 213
 214 dnl ############################################################################
 215 dnl Check for other tools
 216 dnl ############################################################################
 217
 218 AC_CHECK_TOOLS([INDENT], [gindent indent])
 219 mc_UNIT_TESTS
 220
 221
 222 dnl ############################################################################
 223 dnl Check for main libraries
 224 dnl ############################################################################
 225
 226 mc_CHECK_GLIB
 227 mc_G_MODULE_SUPPORTED
 228 mc_WITH_SCREEN
 229 mc_CHECK_SEARCH_TYPE
 230 dnl X11 support. Used to read keyboard modifiers when running under X11.
 231 mc_WITH_X
 232
 233
 234 dnl ############################################################################
 235 dnl Check for header files
 236 dnl ############################################################################
 237
 238 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 239         utime.h sys/statfs.h sys/vfs.h \
 240         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 241         sys/socket.h])
 242 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 243 dnl   to work around a buggy version in autoconf <= 2.69.
 244 AC_HEADER_MAJOR
 245
 246 mc_CHECK_HEADER_STDCKDINT
 247
 248
 249 dnl ############################################################################
 250 dnl Check for types
 251 dnl ############################################################################
 252
 253 dnl Check largefile before type sizeof checks
 254 AC_SYS_LARGEFILE
 255
 256 AC_CHECK_SIZEOF(long)
 257 AC_TYPE_UINTMAX_T
 258 AC_CHECK_SIZEOF(uintmax_t)
 259 AC_TYPE_OFF_T
 260 AC_CHECK_SIZEOF(off_t)
 261 AC_TYPE_MODE_T
 262 gl_PROMOTED_TYPE_MODE_T
 263 AC_TYPE_PID_T
 264 AC_TYPE_UID_T
 265
 266 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 267 AC_CHECK_TYPE([dev_t], [unsigned long long int])
 268 AC_CHECK_TYPE([ino_t], [unsigned long long int])
 269
 270 dnl Taken from GNU/Linux, and should be good enough on platforms lacking these types.
 271 AC_CHECK_TYPE([major_t], [unsigned int])
 272 AC_CHECK_TYPE([minor_t], [unsigned int])
 273
 274 AC_STRUCT_ST_BLOCKS
 275 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim, struct stat.st_mtimespec, struct stat.st_mtimensec])
 276 gl_STAT_SIZE
 277
 278 AH_TEMPLATE([sig_atomic_t],
 279             [/* Define to `int' if <signal.h> doesn't define.])
 280 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 281             [Some systems declare sig_atomic_t as volatile, some others -- no.
 282              This define will have value `sig_atomic_t' or
 283              `volatile sig_atomic_t' accordingly.])
 284
 285 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 286 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 287   [
 288     ac_cv_type_sig_atomic_t=yes;
 289     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 290                     signal.h,
 291                     [
 292                         is_sig_atomic_t_volatile=yes;
 293                         AC_MSG_RESULT([yes, volatile])
 294                     ],
 295                     [
 296                         is_sig_atomic_t_volatile=no;
 297                         AC_MSG_RESULT([yes, non volatile])
 298                     ])
 299   ],
 300   [
 301     AC_MSG_RESULT(no)
 302     AC_CHECK_TYPE(sig_atomic_t, int)
 303     is_sig_atomic_t_volatile=no
 304   ])
 305 if test $is_sig_atomic_t_volatile = 'yes'
 306 then
 307     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 308 else
 309     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 310 fi
 311
 312
 313 dnl ############################################################################
 314 dnl Check for functions
 315 dnl ############################################################################
 316
 317 AC_CHECK_FUNCS([\
 318         strverscmp \
 319         strncasecmp \
 320         realpath
 321 ])
 322
 323 dnl getpt is a GNU Extension (glibc 2.1.x)
 324 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 325 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 326
 327 dnl replacing lstat with statlstat on sco makes it more portable between
 328 dnl sco clones
 329 AC_CHECK_FUNCS(statlstat)
 330
 331 mc_GET_FS_INFO
 332
 333
 334 dnl ############################################################################
 335 dnl Internationalization
 336 dnl ############################################################################
 337
 338 AC_CHECK_FUNCS([setlocale])
 339
 340 AM_GNU_GETTEXT([external], [need-ngettext])
 341 AM_GNU_GETTEXT_VERSION([0.18.2])
 342
 343 mc_I18N
 344
 345 dnl ############################################################################
 346 dnl OS specific stuff
 347 dnl ############################################################################
 348
 349 case $host_os in
 350 *os400)
 351     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 352     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/QOpenSys/pkgs/bin/perl])
 353     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 354     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 355     ;;
 356 *)
 357     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 358     AC_PATH_PROG([PERL_FOR_BUILD], [perl], [/usr/bin/perl])
 359     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 360     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 361 esac
 362
 363 case $host_os in
 364 aux*)
 365     # A/UX
 366     LIBS="$LIBS -lposix"
 367     AC_DEFINE(_POSIX_SOURCE)
 368     ;;
 369 esac
 370
 371 dnl If running under AIX, AC_AIX does not tell us that
 372 AC_MSG_CHECKING([for AIX defines])
 373 AC_EGREP_CPP([yes],
 374     [
 375         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 376         yes
 377         #endif
 378     ],
 379     [
 380         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 381         AC_MSG_RESULT(yes)
 382     ],
 383     [
 384         AC_MSG_RESULT(no)
 385     ])
 386
 387 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 388 AC_CHECK_FUNCS([utimensat])
 389
 390 case $host_os in
 391 *os400)
 392     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 393 esac
 394
 395 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 396 case $host_os in
 397 linux*)
 398     AC_CHECK_HEADERS([linux/fs.h])
 399 esac
 400
 401 dnl Check if the OS is supported by the console saver.
 402 cons_saver=""
 403 case $host_os in
 404 linux*)
 405     cons_saver=yes
 406 esac
 407
 408 dnl Check for gpm mouse support (Linux only)
 409 mouse_lib="xterm only"
 410 AC_ARG_WITH([gpm-mouse],
 411     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 412
 413 case $host_os in
 414 linux*)
 415     if test x$with_gpm_mouse != xno; then
 416         AC_CHECK_LIB(gpm, Gpm_Repeat,
 417             [AC_DEFINE(HAVE_LIBGPM, 1,
 418                        [Define to enable gpm mouse support on Linux])
 419             mouse_lib="gpm and xterm"
 420             MCLIBS="$MCLIBS -lgpm"],
 421             if test "x$with_gpm_mouse" = "xyes"; then
 422                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 423             else
 424                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 425             fi
 426         )
 427     fi
 428     ;;
 429 esac
 430
 431
 432 dnl ############################################################################
 433 dnl libmc
 434 dnl ############################################################################
 435
 436 LIBMC_VERSION="0.0.1"
 437 LIBMC_RELEASE="1"
 438 AC_SUBST(LIBMC_VERSION)
 439 AC_SUBST(LIBMC_RELEASE)
 440
 441 AC_ARG_ENABLE([mclib],
 442         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 443         [
 444             if test "x$enableval" = "xno" ; then
 445                 enable_mclib=no
 446             else
 447                 if test "x$enable_shared" = "xno" ; then
 448                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 449                     enable_mclib=no
 450                 else
 451                     enable_mclib=yes
 452                 fi
 453             fi
 454         ],
 455         [enable_mclib=no])
 456
 457 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 458
 459
 460 dnl ############################################################################
 461 dnl MC options
 462 dnl ############################################################################
 463
 464 mc_ASSERT
 465
 466 mc_WITH_INTERNAL_EDIT
 467
 468 dnl Diff viewer support.
 469 AC_ARG_WITH([diff_viewer],
 470     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 471
 472 if test x$with_diff_viewer != xno; then
 473         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 474         use_diff=yes
 475         diff_msg="yes"
 476         AC_MSG_NOTICE([using diff viewer])
 477 else
 478         diff_msg="no"
 479 fi
 480
 481 mc_SUBSHELL
 482 mc_BACKGROUND
 483 mc_EXT2FS_ATTR
 484 mc_VFS_CHECKS
 485
 486 dnl ############################################################################
 487 dnl Directories
 488 dnl ############################################################################
 489
 490 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 491 dnl Let define ${prefix} and ${exec_prefix}
 492 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 493 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 494
 495 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 496     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 497 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 498     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 499 else
 500     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 501 fi
 502 AC_SUBST(EXTHELPERSDIR)
 503
 504
 505 dnl ############################################################################
 506 dnl Documentation
 507 dnl ############################################################################
 508
 509 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 510 AC_SUBST(MAN_DATE)
 511
 512 dnl Determine which help translations we want to install.
 513 ALL_DOC_LINGUAS="es hu it pl ru sr"
 514
 515 DOC_LINGUAS=
 516 if test "x$USE_NLS" = xyes; then
 517     if test -z "$LINGUAS"; then
 518         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 519     else
 520         langs="$LINGUAS"
 521     fi
 522 else
 523     langs=
 524 fi
 525
 526 for h_lang in $ALL_DOC_LINGUAS; do
 527     for lang in $langs; do
 528         if test "$lang" = "$h_lang"; then
 529             DOC_LINGUAS="$DOC_LINGUAS $lang"
 530             break
 531         fi
 532     done
 533 done
 534 AC_SUBST(DOC_LINGUAS)
 535
 536 DX_HTML_FEATURE(ON)
 537 DX_CHM_FEATURE(OFF)
 538 DX_CHI_FEATURE(OFF)
 539 DX_MAN_FEATURE(OFF)
 540 DX_RTF_FEATURE(OFF)
 541 DX_XML_FEATURE(OFF)
 542 DX_PDF_FEATURE(OFF)
 543 DX_PS_FEATURE(OFF)
 544 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 545
 546
 547 dnl ############################################################################
 548 dnl Configure results
 549 dnl ############################################################################
 550
 551 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 552
 553 AC_SUBST(MCLIBS)
 554 AC_SUBST(CFLAGS)
 555 AC_SUBST(CPPFLAGS)
 556 AC_SUBST(LDFLAGS)
 557 AC_SUBST(LIBS)
 558
 559 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 560 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 561 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 562 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 563 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 564 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 565 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 566 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 567 dnl Clarify do we really need GModule
 568 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 569                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 570
 571 AC_ARG_ENABLE([configure-args],
 572     AS_HELP_STRING([--enable-configure-args], [Embed ./configure arguments into binaries]))
 573 if test "x$enable_configure_args" != xno; then
 574     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 575     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 576 fi
 577
 578
 579 AC_CONFIG_FILES(
 580 [
 581 src/man2hlp/man2hlp
 582 ],
 583 [
 584 chmod +x src/man2hlp/man2hlp
 585 ])
 586
 587 AC_CONFIG_FILES([
 588 Makefile
 589
 590 contrib/Makefile
 591
 592 misc/Makefile
 593 misc/mc.charsets
 594 misc/mc.menu
 595 misc/mcedit.menu
 596 misc/skins/Makefile
 597 misc/ext.d/Makefile
 598 misc/ext.d/doc.sh
 599 misc/ext.d/misc.sh
 600 misc/ext.d/text.sh
 601 misc/ext.d/web.sh
 602 misc/macros.d/Makefile
 603 misc/mc.ext.ini
 604
 605 src/Makefile
 606 src/consaver/Makefile
 607 src/editor/Makefile
 608 src/man2hlp/Makefile
 609 src/subshell/Makefile
 610 src/viewer/Makefile
 611 src/diffviewer/Makefile
 612 src/filemanager/Makefile
 613
 614 src/vfs/Makefile
 615
 616 src/vfs/cpio/Makefile
 617
 618 src/vfs/extfs/Makefile
 619 src/vfs/extfs/helpers/Makefile
 620 src/vfs/extfs/helpers/a+
 621 src/vfs/extfs/helpers/apt+
 622 src/vfs/extfs/helpers/audio
 623 src/vfs/extfs/helpers/deb
 624 src/vfs/extfs/helpers/deba
 625 src/vfs/extfs/helpers/debd
 626 src/vfs/extfs/helpers/dpkg+
 627 src/vfs/extfs/helpers/iso9660
 628 src/vfs/extfs/helpers/hp48+
 629 src/vfs/extfs/helpers/lslR
 630 src/vfs/extfs/helpers/mailfs
 631 src/vfs/extfs/helpers/patchfs
 632 src/vfs/extfs/helpers/rpms+
 633 src/vfs/extfs/helpers/s3+
 634 src/vfs/extfs/helpers/uace
 635 src/vfs/extfs/helpers/ualz
 636 src/vfs/extfs/helpers/uar
 637 src/vfs/extfs/helpers/uarc
 638 src/vfs/extfs/helpers/uarj
 639 src/vfs/extfs/helpers/ucab
 640 src/vfs/extfs/helpers/uha
 641 src/vfs/extfs/helpers/ulha
 642 src/vfs/extfs/helpers/ulib
 643 src/vfs/extfs/helpers/unar
 644 src/vfs/extfs/helpers/urar
 645 src/vfs/extfs/helpers/uwim
 646 src/vfs/extfs/helpers/uzip
 647 src/vfs/extfs/helpers/uzoo
 648
 649 src/vfs/shell/Makefile
 650 src/vfs/shell/helpers/Makefile
 651
 652 src/vfs/ftpfs/Makefile
 653
 654 src/vfs/sftpfs/Makefile
 655
 656 src/vfs/local/Makefile
 657
 658 src/vfs/sfs/Makefile
 659
 660 src/vfs/tar/Makefile
 661
 662 src/vfs/undelfs/Makefile
 663
 664 lib/Makefile
 665 lib/event/Makefile
 666 lib/filehighlight/Makefile
 667 lib/mcconfig/Makefile
 668 lib/search/Makefile
 669 lib/skin/Makefile
 670 lib/strutil/Makefile
 671 lib/tty/Makefile
 672
 673 lib/vfs/Makefile
 674
 675 lib/widget/Makefile
 676
 677 misc/syntax/Makefile
 678
 679 doc/Makefile
 680
 681 doc/hints/Makefile
 682 doc/hints/l10n/Makefile
 683
 684 doc/man/Makefile
 685 doc/man/es/Makefile
 686 doc/man/hu/Makefile
 687 doc/man/it/Makefile
 688 doc/man/pl/Makefile
 689 doc/man/ru/Makefile
 690 doc/man/sr/Makefile
 691
 692 doc/hlp/Makefile
 693 doc/hlp/es/Makefile
 694 doc/hlp/hu/Makefile
 695 doc/hlp/it/Makefile
 696 doc/hlp/pl/Makefile
 697 doc/hlp/ru/Makefile
 698 doc/hlp/sr/Makefile
 699
 700 po/Makefile.in
 701 ])
 702
 703 dnl https://stackoverflow.com/questions/30897170/ac-subst-does-not-expand-variable/30932102#30932102
 704 AC_CONFIG_FILES(
 705 [misc/syntax/Syntax], [${SED-sed} -e "s%\${prefix}%$PREFIX%" misc/syntax/Syntax > misc/syntax/Syntax.tmp && \
 706   mv -f misc/syntax/Syntax.tmp misc/syntax/Syntax], [export PREFIX=$prefix]
 707 )
 708
 709 AC_CONFIG_FILES([
 710 tests/Makefile
 711 tests/lib/Makefile
 712 tests/lib/mcconfig/Makefile
 713 tests/lib/search/Makefile
 714 tests/lib/strutil/Makefile
 715 tests/lib/vfs/Makefile
 716 tests/lib/vfs/mc.charsets
 717 tests/lib/widget/Makefile
 718 tests/src/Makefile
 719 tests/src/filemanager/Makefile
 720 tests/src/editor/Makefile
 721 tests/src/editor/test-data.txt
 722 tests/src/vfs/Makefile
 723 tests/src/vfs/extfs/Makefile
 724 tests/src/vfs/extfs/helpers-list/Makefile
 725 tests/src/vfs/extfs/helpers-list/data/config.sh
 726 tests/src/vfs/extfs/helpers-list/misc/Makefile
 727 tests/src/vfs/ftpfs/Makefile
 728 ])
 729
 730 AC_OUTPUT
 731
 732 AC_MSG_NOTICE([
 733
 734 Configuration:
 735
 736   Source code location:           ${srcdir}
 737   Compiler:                       ${CC}
 738   Compiler flags:                 ${CFLAGS}
 739   Assertions:                     ${enable_assert}
 740   Unit tests:                     ${tests_msg}
 741   File system:                    ${vfs_type}
 742                                   ${vfs_flags}
 743   Screen library:                 ${screen_msg}
 744   Mouse support:                  ${mouse_lib}
 745   X11 events support:             ${textmode_x11_support}
 746   With subshell support:          ${subshell}
 747   With background operations:     ${enable_background}
 748   With ext2fs attributes support: ${ext2fs_attr_msg}
 749   Internal editor:                ${edit_msg}
 750   Diff viewer:                    ${diff_msg}
 751   Support for charset:            ${charset_msg}
 752   Search type:                    ${SEARCH_TYPE}
 753 ])
 754
 755 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 756 dnl we enable it back for top-level ./configure
 757 if test -n "$ac_unrecognized_opts"; then
 758   case $enable_option_checking in
 759     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 760     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 761   esac
 762 fi