configure.ac

   1 dnl
   2 dnl Configure.in file for the Midnight Commander
   3 dnl
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([GNU Midnight Commander], [], [mc-devel@gnome.org])
   7 m4_pattern_forbid(MC_)
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CONFIG_AUX_DIR(config)
  10 AC_CONFIG_SRCDIR(src/main.c)
  11 AC_CONFIG_HEADERS(config.h)
  12 mc_VERSION
  13 AM_INIT_AUTOMAKE(mc, ${VERSION} )
  14 dnl Enable silent rules by default (if yes)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23
  24 dnl ############################################################################
  25 dnl Check for compiler
  26 dnl ############################################################################
  27
  28 AC_PROG_CC_STDC
  29 AM_PROG_CC_C_O
  30
  31 mc_CHECK_CFLAGS
  32
  33 CFLAGS_OPTS=""
  34 if test "x$CFLAGS" = "x"; then
  35     CFLAGS_OPTS=" -O2 "
  36 fi
  37 if test x$USE_MAINTAINER_MODE = xyes; then
  38     CFLAGS_OPTS="-g3 -O -ggdb"
  39     AC_DEFINE(USE_MAINTAINER_MODE, 1, [Use maintainer mode])
  40 fi
  41
  42 AC_ARG_ENABLE([werror],
  43     AS_HELP_STRING([--enable-werror], [Handle all compiler warnings as errors]))
  44 if test "x$enable_werror" = xyes; then
  45     mc_CHECK_ONE_CFLAG([-Werror])
  46 fi
  47
  48 dnl Compiler can generate warnings for unrecognized flags added to CFLAGS
  49 dnl which causes attribute checks to fail
  50 ax_gcc_func_attribute_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  51 _AC_LANG_PREFIX[]FLAGS=
  52 AX_GCC_FUNC_ATTRIBUTE([fallthrough])
  53 _AC_LANG_PREFIX[]FLAGS=$ax_gcc_func_attribute_save_flags
  54 unset ax_gcc_func_attribute_save_flags
  55
  56 LT_INIT
  57
  58
  59 dnl ############################################################################
  60 dnl Check for programs
  61 dnl ############################################################################
  62
  63 PKG_PROG_PKG_CONFIG
  64 AC_PROG_INSTALL
  65 AC_PROG_LN_S
  66 dnl See also the "OS specific stuff" section below.
  67
  68 dnl Check nroff and the options it supports
  69 AC_CHECK_PROG(HAVE_nroff, nroff, true, false)
  70 dnl Default values
  71 MANDOC=-man
  72 MAN_FLAGS=
  73 if $HAVE_nroff; then
  74     AC_MSG_CHECKING([for manual formatting macros])
  75     AC_CACHE_VAL(mc_cv_mandoc, [
  76     nroff -mandoc < /dev/null > /dev/null 2>&1
  77     if test $? = 0; then
  78         mc_cv_mandoc=-mandoc
  79     else
  80         mc_cv_mandoc=-man
  81     fi
  82     ])
  83     MANDOC=$mc_cv_mandoc
  84     AC_MSG_RESULT([$MANDOC])
  85
  86     AC_MSG_CHECKING([for option to disable ANSI color in manuals])
  87     AC_CACHE_VAL(mc_cv_man_nocolor, [
  88     nroff -c < /dev/null > /dev/null 2>&1
  89     if test $? = 0; then
  90         mc_cv_man_nocolor=-c
  91     else
  92         mc_cv_man_nocolor=
  93     fi
  94     ])
  95     MAN_FLAGS=$mc_cv_man_nocolor
  96     AC_MSG_RESULT([${MAN_NOCOLOR-none}])
  97
  98     AC_MSG_CHECKING([if nroff accepts -Tlatin1 or -Tascii])
  99     AC_CACHE_VAL(mc_cv_nroff_tascii, [
 100     mc_cv_nroff_tascii=
 101     nroff -Tlatin1 < /dev/null > /dev/null 2>&1 /dev/null
 102     if test $? = 0; then
 103         mc_cv_nroff_tascii=-Tlatin1
 104     else
 105         nroff -Tascii < /dev/null > /dev/null 2>&1 /dev/null
 106         if test $? = 0; then
 107             mc_cv_nroff_tascii=-Tascii
 108         fi
 109     fi
 110     ])
 111     AC_MSG_RESULT([${mc_cv_nroff_tascii-no}])
 112     MAN_FLAGS="$MAN_FLAGS $mc_cv_nroff_tascii"
 113 fi
 114
 115 AC_SUBST(MANDOC)
 116 AC_SUBST(MAN_FLAGS)
 117
 118 dnl Check for -L option to file
 119 AC_CHECK_PROG(HAVE_FILECMD, file, true, false)
 120 if $HAVE_FILECMD; then
 121     AC_MSG_CHECKING([for -L option to file command])
 122     AC_CACHE_VAL(mc_cv_filel, [
 123     file -L . > /dev/null 2>&1
 124     if test $? = 0; then
 125         mc_cv_filel=yes
 126     else
 127         mc_cv_filel=no
 128     fi
 129     ])
 130     if test x$mc_cv_filel = xyes; then
 131         AC_DEFINE(FILE_L, 1, [Define if the file command accepts the -L option])
 132     fi
 133     filel=$mc_cv_filel
 134     AC_MSG_RESULT([$filel])
 135 fi
 136
 137 dnl Only list browsers here that can be run in background (i.e. with `&')
 138 AC_CHECK_PROGS(X11_WWW, [gnome-moz-remote mozilla firefox konqueror opera])
 139
 140
 141 dnl ############################################################################
 142 dnl Check for other tools
 143 dnl ############################################################################
 144
 145 AC_CHECK_TOOL(AR, ar, ar)
 146 mc_UNIT_TESTS
 147
 148
 149 dnl ############################################################################
 150 dnl Check for main libraies
 151 dnl ############################################################################
 152
 153 mc_CHECK_GLIB
 154 mc_G_MODULE_SUPPORTED
 155 mc_WITH_SCREEN
 156 mc_CHECK_SEARCH_TYPE
 157 dnl X11 support. Used to read keyboard modifiers when running under X11.
 158 mc_WITH_X
 159
 160
 161 dnl ############################################################################
 162 dnl Check for header files
 163 dnl ############################################################################
 164
 165 AC_CHECK_HEADERS([string.h memory.h limits.h malloc.h \
 166         utime.h sys/statfs.h sys/vfs.h \
 167         sys/select.h sys/ioctl.h stropts.h arpa/inet.h \
 168         sys/socket.h])
 169 dnl This macro is redefined in m4.include/gnulib/sys_types_h.m4
 170 dnl   to work around a buggy version in autoconf <= 2.69.
 171 AC_HEADER_MAJOR
 172
 173
 174 dnl ############################################################################
 175 dnl Check for types
 176 dnl ############################################################################
 177
 178 dnl Check largefile before type sizeof checks
 179 AC_SYS_LARGEFILE
 180
 181 AC_CHECK_SIZEOF(long)
 182 AC_TYPE_UINTMAX_T
 183 AC_CHECK_SIZEOF(uintmax_t)
 184 AC_TYPE_OFF_T
 185 AC_CHECK_SIZEOF(off_t)
 186 AC_TYPE_MODE_T
 187 gl_PROMOTED_TYPE_MODE_T
 188 AC_TYPE_PID_T
 189 AC_TYPE_UID_T
 190
 191 AC_STRUCT_ST_BLOCKS
 192 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_rdev, struct stat.st_mtim])
 193 gl_STAT_SIZE
 194
 195 AH_TEMPLATE([sig_atomic_t],
 196             [/* Define to `int' if <signal.h> doesn't define.])
 197 AH_TEMPLATE([SIG_ATOMIC_VOLATILE_T],
 198             [Some systems declare sig_atomic_t as volatile, some others -- no.
 199              This define will have value `sig_atomic_t' or
 200              `volatile sig_atomic_t' accordingly.])
 201
 202 AC_MSG_CHECKING(for sig_atomic_t in signal.h)
 203 AC_EGREP_HEADER(sig_atomic_t,signal.h,
 204   [
 205     ac_cv_type_sig_atomic_t=yes;
 206     AC_EGREP_HEADER(volatile.*sig_atomic_t,
 207                     signal.h,
 208                     [
 209                         is_sig_atomic_t_volatile=yes;
 210                         AC_MSG_RESULT([yes, volatile])
 211                     ],
 212                     [
 213                         is_sig_atomic_t_volatile=no;
 214                         AC_MSG_RESULT([yes, non volatile])
 215                     ])
 216   ],
 217   [
 218     AC_MSG_RESULT(no)
 219     AC_CHECK_TYPE(sig_atomic_t, int)
 220     is_sig_atomic_t_volatile=no
 221   ])
 222 if test $is_sig_atomic_t_volatile = 'yes'
 223 then
 224     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, sig_atomic_t)
 225 else
 226     AC_DEFINE(SIG_ATOMIC_VOLATILE_T, [volatile sig_atomic_t])
 227 fi
 228
 229
 230 dnl ############################################################################
 231 dnl Check for functions
 232 dnl ############################################################################
 233
 234 AC_CHECK_FUNCS([\
 235         strverscmp \
 236         strncasecmp \
 237         realpath
 238 ])
 239
 240 dnl getpt is a GNU Extension (glibc 2.1.x)
 241 AC_CHECK_FUNCS(posix_openpt, , [AC_CHECK_FUNCS(getpt)])
 242 AC_CHECK_FUNCS(grantpt, , [AC_CHECK_LIB(pt, grantpt)])
 243
 244 dnl replacing lstat with statlstat on sco makes it more portable between
 245 dnl sco clones
 246 AC_CHECK_FUNCS(statlstat)
 247
 248 dnl Ovverriding mmap support.  This has to be before AC_FUNC_MMAP is used.
 249 dnl We use only part of the functionality of mmap, so on AIX,
 250 dnl it's possible to use mmap, even if it doesn't pass the autoconf test.
 251 AC_ARG_WITH([mmap],
 252         AS_HELP_STRING([--with-mmap], [Use the mmap call @<:@yes if found@:>@]))
 253 if test x$with_mmap != xno; then
 254     if test x$with_mmap = x; then
 255         AC_FUNC_MMAP
 256     else
 257         AC_DEFINE(HAVE_MMAP, 1)
 258     fi
 259 fi
 260
 261 dnl Sequent wants getprocessstats
 262 AC_CHECK_LIB(seq, get_process_stats, [
 263         LIBS="$LIBS -lseq"
 264         AC_DEFINE(HAVE_GET_PROCESS_STATS, 1,
 265                   [Define if you have function `get_process_stats' and
 266 have to use that instead of gettimeofday])])
 267
 268 mc_GET_FS_INFO
 269
 270
 271 dnl ############################################################################
 272 dnl Internationalization
 273 dnl ############################################################################
 274
 275 AC_CHECK_FUNCS([setlocale])
 276
 277 AM_GNU_GETTEXT([external], [need-ngettext])
 278 AM_GNU_GETTEXT_VERSION([0.18.1])
 279
 280 mc_I18N
 281
 282 dnl ############################################################################
 283 dnl OS specific stuff
 284 dnl ############################################################################
 285
 286 case $host_os in
 287 *os400)
 288     AC_PATH_PROG([PERL], [perl], [/QOpenSys/pkgs/bin/perl])
 289     AC_PATH_PROG([PYTHON], [python], [/QOpenSys/pkgs/bin/python2])
 290     AC_PATH_PROG([RUBY], [ruby], [/QOpenSys/pkgs/bin/ruby])
 291     ;;
 292 *)
 293     AC_PATH_PROG([PERL], [perl], [/usr/bin/perl])
 294     AC_PATH_PROG([PYTHON], [python], [/usr/bin/python])
 295     AC_PATH_PROG([RUBY], [ruby], [/usr/bin/ruby])
 296 esac
 297
 298 case $host_os in
 299 aux*)
 300     # A/UX
 301     LIBS="$LIBS -lposix"
 302     AC_DEFINE(_POSIX_SOURCE)
 303     ;;
 304 esac
 305
 306 dnl If running under AIX, AC_AIX does not tell us that
 307 AC_MSG_CHECKING([for AIX defines])
 308 AC_EGREP_CPP([yes],
 309     [
 310         #if defined(AIX) || defined(_AIX) || defined(__aix__) || defined(aix)
 311         yes
 312         #endif
 313     ],
 314     [
 315         AC_DEFINE(IS_AIX, 1, [Define if compiling for AIX])
 316         AC_MSG_RESULT(yes)
 317     ],
 318     [
 319         AC_MSG_RESULT(no)
 320     ])
 321
 322 dnl utimensat is supported since glibc 2.6 and specified in POSIX.1-2008
 323 dnl utimensat() causes different timespec structures to cause failures on IBM i and AIX
 324 case $host_os in
 325 *os400 | aix*)
 326     ;;
 327 *)
 328     AC_CHECK_FUNCS([utimensat])
 329     ;;
 330 esac
 331
 332 case $host_os in
 333 *os400)
 334     AC_DEFINE([PTY_ZEROREAD], [1], [read(1) can return 0 for a non-closed fd])
 335 esac
 336
 337 dnl Check linux/fs.h for FICLONE to support BTRFS's file clone operation
 338 case $host_os in
 339 linux*)
 340     AC_CHECK_HEADERS([linux/fs.h])
 341 esac
 342
 343 dnl Check if the OS is supported by the console saver.
 344 cons_saver=""
 345 case $host_os in
 346 linux*)
 347     cons_saver=yes
 348 esac
 349
 350 dnl Check for gpm mouse support (Linux only)
 351 mouse_lib="xterm only"
 352 AC_ARG_WITH([gpm-mouse],
 353     AS_HELP_STRING([--with-gpm-mouse], [Compile with gpm mouse support (Linux only) @<:@yes if found@:>@]))
 354
 355 case $host_os in
 356 linux*)
 357     if test x$with_gpm_mouse != xno; then
 358         AC_CHECK_LIB(gpm, Gpm_Repeat,
 359             [AC_DEFINE(HAVE_LIBGPM, 1,
 360                        [Define to enable gpm mouse support on Linux])
 361             mouse_lib="gpm and xterm"
 362             MCLIBS="$MCLIBS -lgpm"],
 363             if test "x$with_gpm_mouse" = "xyes"; then
 364                 [AC_MSG_ERROR([libgpm is missing or older than 0.18])]
 365             else
 366                 [AC_MSG_WARN([libgpm is missing or older than 0.18])]
 367             fi
 368         )
 369     fi
 370     ;;
 371 esac
 372
 373
 374 dnl ############################################################################
 375 dnl libmc
 376 dnl ############################################################################
 377
 378 LIBMC_VERSION="0.0.1"
 379 LIBMC_RELEASE="1"
 380 AC_SUBST(LIBMC_VERSION)
 381 AC_SUBST(LIBMC_RELEASE)
 382
 383 AC_ARG_ENABLE([mclib],
 384         [AS_HELP_STRING([--enable-mclib], [Compile shared library libmc.so @<:@no@:>@])],
 385         [
 386             if test "x$enableval" = "xno" ; then
 387                 enable_mclib=no
 388             else
 389                 if test "x$enable_shared" = "xno" ; then
 390                     AC_MSG_WARN([Build of shared library is disabled. Specify --enable-shared first])
 391                     enable_mclib=no
 392                 else
 393                     enable_mclib=yes
 394                 fi
 395             fi
 396         ],
 397         [enable_mclib=no])
 398
 399 AM_CONDITIONAL([ENABLE_MCLIB], [test x$enable_mclib = xyes])
 400
 401
 402 dnl ############################################################################
 403 dnl Where config files should be placed
 404 dnl ############################################################################
 405
 406 AC_ARG_WITH([homedir],
 407     AS_HELP_STRING([--with-homedir],
 408                    [Choose any place of user settings relative to home dir, or XDG for respect XDG standards @<:@XDG@:>@]),
 409     [
 410         dnl Unfortunately, there is no way to tell AC_ARG_WITH that the
 411         dnl argument value is required, so we can't differentiate
 412         dnl between `--with-homedir` and `--with-homedir=yes`, because
 413         dnl `with_homedir` is set to `yes` in both cases.
 414         dnl
 415         dnl We opt to set `with_homedir` to `.mc` if the value is `yes`
 416         dnl in order to avoid the surprise for users using
 417         dnl `--with-homedir` w/o any value and then getting mc to store
 418         dnl settings in the `yes` directory.
 419
 420         if test "x$withval" = "xXDG"; then
 421             with_homedir=XDG
 422         elif test "x$withval" = "xyes"; then
 423             with_homedir=.mc
 424         else
 425             with_homedir=$withval
 426         fi
 427     ],
 428     [with_homedir=XDG])
 429
 430
 431 if test x$with_homedir = xXDG; then
 432     AC_DEFINE(MC_HOMEDIR_XDG, 1, [Define to enable XDG standard support])
 433 else
 434     AC_DEFINE(MC_HOMEDIR_XDG, 0, [Define to disable XDG standard support])
 435     AC_DEFINE_UNQUOTED([MC_USERCONF_DIR], ["$with_homedir"], [Where configs will be placed relative to $HOME])
 436 fi
 437
 438
 439 dnl ############################################################################
 440 dnl MC options
 441 dnl ############################################################################
 442
 443 mc_ASSERT
 444
 445 mc_WITH_INTERNAL_EDIT
 446
 447 dnl Diff viewer support.
 448 AC_ARG_WITH([diff_viewer],
 449     AS_HELP_STRING([--with-diff-viewer], [Compile with diff viewer @<:@yes@:>@]))
 450
 451 if test x$with_diff_viewer != xno; then
 452         AC_DEFINE(USE_DIFF_VIEW, 1, [Define to enable diff viewer])
 453         use_diff=yes
 454         diff_msg="yes"
 455         AC_MSG_NOTICE([using diff viewer])
 456 else
 457         diff_msg="no"
 458 fi
 459
 460 mc_SUBSHELL
 461 mc_BACKGROUND
 462 mc_EXT2FS_ATTR
 463 mc_VFS_CHECKS
 464
 465 dnl ############################################################################
 466 dnl Directories
 467 dnl ############################################################################
 468
 469 dnl ${prefix} and ${exec_prefix} are undefined here if --prefix is not used in command line
 470 dnl Let define ${prefix} and ${exec_prefix}
 471 test "x$prefix" = "xNONE" && prefix="$ac_default_prefix"
 472 test "x$exec_prefix" = "xNONE" && exec_prefix="${prefix}"
 473
 474 if test x${libexecdir} = x'${exec_prefix}/libexec'; then
 475     EXTHELPERSDIR=${prefix}/libexec/${PACKAGE}/ext.d
 476 elif test x${libexecdir} = x'${exec_prefix}/lib'; then
 477     EXTHELPERSDIR=${prefix}/lib/${PACKAGE}/ext.d
 478 else
 479     EXTHELPERSDIR=${libexecdir}/${PACKAGE}/ext.d
 480 fi
 481 AC_SUBST(EXTHELPERSDIR)
 482
 483
 484 dnl ############################################################################
 485 dnl Documentation
 486 dnl ############################################################################
 487
 488 MAN_DATE="$(LC_ALL=C date "+%B %Y")"
 489 AC_SUBST(MAN_DATE)
 490
 491 dnl Determine which help translations we want to install.
 492 ALL_DOC_LINGUAS="es hu it pl ru sr"
 493
 494 DOC_LINGUAS=
 495 if test "x$USE_NLS" = xyes; then
 496     if test -z "$LINGUAS"; then
 497         langs="`grep -v '^#' $srcdir/po/LINGUAS`"
 498     else
 499         langs="$LINGUAS"
 500     fi
 501 else
 502     langs=
 503 fi
 504
 505 for h_lang in $ALL_DOC_LINGUAS; do
 506     for lang in $langs; do
 507         if test "$lang" = "$h_lang"; then
 508             DOC_LINGUAS="$DOC_LINGUAS $lang"
 509             break
 510         fi
 511     done
 512 done
 513 AC_SUBST(DOC_LINGUAS)
 514
 515 DX_HTML_FEATURE(ON)
 516 DX_CHM_FEATURE(OFF)
 517 DX_CHI_FEATURE(OFF)
 518 DX_MAN_FEATURE(OFF)
 519 DX_RTF_FEATURE(OFF)
 520 DX_XML_FEATURE(OFF)
 521 DX_PDF_FEATURE(OFF)
 522 DX_PS_FEATURE(OFF)
 523 DX_INIT_DOXYGEN(mc,doxygen.cfg,devel)
 524
 525
 526 dnl ############################################################################
 527 dnl Configure results
 528 dnl ############################################################################
 529
 530 CFLAGS="$mc_configured_cflags $CFLAGS_OPTS $CFLAGS"
 531
 532 AC_SUBST(MCLIBS)
 533 AC_SUBST(CFLAGS)
 534 AC_SUBST(CPPFLAGS)
 535 AC_SUBST(LDFLAGS)
 536 AC_SUBST(LIBS)
 537
 538 AM_CONDITIONAL(USE_NLS, [test x"$USE_NLS" = xyes])
 539 AM_CONDITIONAL(USE_MAINTAINER_MODE, [test x"$USE_MAINTAINER_MODE" = xyes])
 540 AM_CONDITIONAL(USE_SCREEN_SLANG, [test x"$with_screen" = xslang])
 541 AM_CONDITIONAL(USE_INTERNAL_EDIT, [test x"$use_internal_edit" = xyes ])
 542 AM_CONDITIONAL(USE_ASPELL, [test x"$enable_aspell" = xyes ])
 543 AM_CONDITIONAL(USE_DIFF, [test -n "$use_diff"])
 544 AM_CONDITIONAL(CHARSET, [test -n "$have_charset"])
 545 AM_CONDITIONAL(CONS_SAVER, [test -n "$cons_saver"])
 546 dnl Clarify do we really need GModule
 547 AM_CONDITIONAL([HAVE_GMODULE], [test -n "$g_module_supported" && \
 548                                 test x"$textmode_x11_support" = x"yes" -o x"$enable_aspell" = x"yes"])
 549
 550 AC_ARG_ENABLE([configure-args],
 551     AS_HELP_STRING([--enable-configure-args], [Handle all compiler warnings as errors]))
 552 if test "x$enable_configure_args" != xno; then
 553     AC_DEFINE([ENABLE_CONFIGURE_ARGS], 1, [Define to enable showing configure arguments in help])
 554     AC_DEFINE_UNQUOTED([MC_CONFIGURE_ARGS], ["$ac_configure_args"], [MC configure arguments])
 555 fi
 556
 557
 558 AC_CONFIG_FILES(
 559 [
 560 src/man2hlp/man2hlp
 561 ],
 562 [
 563 chmod +x src/man2hlp/man2hlp
 564 ])
 565
 566 AC_CONFIG_FILES([
 567 Makefile
 568
 569 contrib/Makefile
 570 contrib/dist/Makefile
 571 contrib/dist/gentoo/Makefile
 572 contrib/dist/redhat/Makefile
 573 contrib/dist/redhat/mc.spec
 574 contrib/dist/pkginfo
 575 contrib/dist/prototype
 576
 577 misc/Makefile
 578 misc/mc.charsets
 579 misc/mc.menu
 580 misc/mcedit.menu
 581 misc/skins/Makefile
 582 misc/ext.d/Makefile
 583 misc/ext.d/doc.sh
 584 misc/ext.d/misc.sh
 585 misc/ext.d/text.sh
 586 misc/ext.d/web.sh
 587 misc/macros.d/Makefile
 588 misc/mc.ext
 589
 590 src/Makefile
 591 src/consaver/Makefile
 592 src/editor/Makefile
 593 src/man2hlp/Makefile
 594 src/subshell/Makefile
 595 src/viewer/Makefile
 596 src/diffviewer/Makefile
 597 src/filemanager/Makefile
 598
 599 src/vfs/Makefile
 600
 601 src/vfs/cpio/Makefile
 602
 603 src/vfs/extfs/Makefile
 604 src/vfs/extfs/helpers/Makefile
 605 src/vfs/extfs/helpers/a+
 606 src/vfs/extfs/helpers/apt+
 607 src/vfs/extfs/helpers/audio
 608 src/vfs/extfs/helpers/deb
 609 src/vfs/extfs/helpers/deba
 610 src/vfs/extfs/helpers/debd
 611 src/vfs/extfs/helpers/dpkg+
 612 src/vfs/extfs/helpers/iso9660
 613 src/vfs/extfs/helpers/hp48+
 614 src/vfs/extfs/helpers/lslR
 615 src/vfs/extfs/helpers/mailfs
 616 src/vfs/extfs/helpers/patchfs
 617 src/vfs/extfs/helpers/rpms+
 618 src/vfs/extfs/helpers/s3+
 619 src/vfs/extfs/helpers/uace
 620 src/vfs/extfs/helpers/ualz
 621 src/vfs/extfs/helpers/uar
 622 src/vfs/extfs/helpers/uarc
 623 src/vfs/extfs/helpers/uarj
 624 src/vfs/extfs/helpers/ucab
 625 src/vfs/extfs/helpers/uha
 626 src/vfs/extfs/helpers/ulha
 627 src/vfs/extfs/helpers/ulib
 628 src/vfs/extfs/helpers/unar
 629 src/vfs/extfs/helpers/urar
 630 src/vfs/extfs/helpers/uwim
 631 src/vfs/extfs/helpers/uzip
 632 src/vfs/extfs/helpers/uzoo
 633
 634 src/vfs/fish/Makefile
 635 src/vfs/fish/helpers/Makefile
 636
 637 src/vfs/ftpfs/Makefile
 638
 639 src/vfs/sftpfs/Makefile
 640
 641 src/vfs/local/Makefile
 642
 643 src/vfs/sfs/Makefile
 644
 645 src/vfs/smbfs/Makefile
 646
 647 src/vfs/tar/Makefile
 648
 649 src/vfs/undelfs/Makefile
 650
 651 lib/Makefile
 652 lib/event/Makefile
 653 lib/filehighlight/Makefile
 654 lib/mcconfig/Makefile
 655 lib/search/Makefile
 656 lib/skin/Makefile
 657 lib/strutil/Makefile
 658 lib/tty/Makefile
 659
 660 lib/vfs/Makefile
 661
 662 lib/widget/Makefile
 663
 664 misc/syntax/Makefile
 665 misc/syntax/Syntax
 666
 667 doc/Makefile
 668
 669 doc/hints/Makefile
 670 doc/hints/l10n/Makefile
 671
 672 doc/man/Makefile
 673 doc/man/es/Makefile
 674 doc/man/hu/Makefile
 675 doc/man/it/Makefile
 676 doc/man/pl/Makefile
 677 doc/man/ru/Makefile
 678 doc/man/sr/Makefile
 679
 680 doc/hlp/Makefile
 681 doc/hlp/es/Makefile
 682 doc/hlp/hu/Makefile
 683 doc/hlp/it/Makefile
 684 doc/hlp/pl/Makefile
 685 doc/hlp/ru/Makefile
 686 doc/hlp/sr/Makefile
 687
 688 po/Makefile.in
 689 ])
 690
 691 AC_CONFIG_FILES([
 692 tests/Makefile
 693 tests/lib/Makefile
 694 tests/lib/mcconfig/Makefile
 695 tests/lib/search/Makefile
 696 tests/lib/strutil/Makefile
 697 tests/lib/vfs/Makefile
 698 tests/lib/widget/Makefile
 699 tests/src/Makefile
 700 tests/src/filemanager/Makefile
 701 tests/src/editor/Makefile
 702 tests/src/editor/test-data.txt
 703 tests/src/vfs/Makefile
 704 tests/src/vfs/extfs/Makefile
 705 tests/src/vfs/extfs/helpers-list/Makefile
 706 tests/src/vfs/extfs/helpers-list/data/config.sh
 707 tests/src/vfs/extfs/helpers-list/misc/Makefile
 708 ])
 709
 710 AC_OUTPUT
 711
 712 AC_MSG_NOTICE([
 713
 714 Configuration:
 715
 716   Source code location:           ${srcdir}
 717   Compiler:                       ${CC}
 718   Compiler flags:                 ${CFLAGS}
 719   Assertions:                     ${enable_assert}
 720   Unit tests:                     ${tests_msg}
 721   File system:                    ${vfs_type}
 722                                   ${vfs_flags}
 723   Screen library:                 ${screen_msg}
 724   Mouse support:                  ${mouse_lib}
 725   X11 events support:             ${textmode_x11_support}
 726   With subshell support:          ${subshell}
 727   With background operations:     ${enable_background}
 728   With ext2fs attributes support: ${ext2fs_attr_msg}
 729   Internal editor:                ${edit_msg}
 730   Diff viewer:                    ${diff_msg}
 731   Support for charset:            ${charset_msg}
 732   Search type:                    ${SEARCH_TYPE}
 733 ])
 734
 735 dnl option checking is disable by default due to AC_CONFIG_SUBDIRS
 736 dnl we enable it back for top-level ./configure
 737 if test -n "$ac_unrecognized_opts"; then
 738   case $enable_option_checking in
 739     fatal) AC_MSG_ERROR([unrecognized options: $ac_unrecognized_opts]) ;;
 740     *)     AC_MSG_WARN( [unrecognized options: $ac_unrecognized_opts]) ;;
 741   esac
 742 fi