lib/libc/arch/i386/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.14 2005/09/13 01:44:08 christos Exp $     */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * William Jolitz.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      from: @(#)setjmp.s      5.1 (Berkeley) 4/23/90
  35  */
  36
  37 #include <machine/asm.h>
  38 #if defined(LIBC_SCCS)
  39         RCSID("$NetBSD: setjmp.S,v 1.14 2005/09/13 01:44:08 christos Exp $")
  40 #endif
  41
  42 /*
  43  * C library -- _setjmp, _longjmp
  44  *
  45  *      longjmp(a,v)
  46  * will generate a "return(v)" from the last call to
  47  *      setjmp(a)
  48  * by restoring registers from the stack.
  49  * The previous signal state is restored.
  50  */
  51
  52 ENTRY(__setjmp14)
  53         movl    4(%esp),%ecx
  54         movl    0(%esp),%edx
  55         movl    %edx, 0(%ecx)
  56         movl    %ebx, 4(%ecx)
  57         movl    %esp, 8(%ecx)
  58         movl    %ebp,12(%ecx)
  59         movl    %esi,16(%ecx)
  60         movl    %edi,20(%ecx)
  61
  62         /* Get the signal mask. */
  63         leal    24(%ecx),%edx
  64
  65         PIC_PROLOGUE
  66         pushl   %edx
  67         pushl   $0
  68         pushl   $0
  69 #ifdef PIC
  70         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  71 #else
  72         call    _C_LABEL(__sigprocmask14)
  73 #endif
  74         addl    $12,%esp
  75         PIC_EPILOGUE
  76
  77         xorl    %eax,%eax
  78         ret
  79
  80 ENTRY(__longjmp14)
  81         /* Restore the signal mask. */
  82         movl    4(%esp),%ecx
  83         leal    24(%ecx),%edx
  84
  85         PIC_PROLOGUE
  86         pushl   $0
  87         pushl   %edx
  88 #ifdef __minix
  89         pushl   $2                      /* SIG_SETMASK */
  90 #else
  91         pushl   $3                      /* SIG_SETMASK */
  92 #endif
  93 #ifdef PIC
  94         call    PIC_PLT(_C_LABEL(__sigprocmask14))
  95 #else
  96         call    _C_LABEL(__sigprocmask14)
  97 #endif
  98         addl    $12,%esp
  99         PIC_EPILOGUE
 100
 101         movl    4(%esp),%edx
 102         movl    8(%esp),%eax
 103         movl    0(%edx),%ecx
 104         movl    4(%edx),%ebx
 105         movl    8(%edx),%esp
 106         movl    12(%edx),%ebp
 107         movl    16(%edx),%esi
 108         movl    20(%edx),%edi
 109         testl   %eax,%eax
 110         jnz     1f
 111         incl    %eax
 112 1:      movl    %ecx,0(%esp)
 113         ret
 114
 115 #ifdef __minix
 116 .weak longjmp; sigsetjmp = __longjmp14
 117 .weak setjmp; sigsetjmp = __setjmp14
 118 #endif