common/lib/libc/arch/arm/string/strcpy_thumb.S

   1 /*-
   2  * Copyright (c) 2013 The NetBSD Foundation, Inc.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to The NetBSD Foundation
   6  * by Matt Thomas of 3am Software Foundry.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  18  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  20  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  21  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  22  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  23  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  24  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  25  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  26  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  27  * POSSIBILITY OF SUCH DAMAGE.
  28  */
  29 #include <machine/asm.h>
  30
  31 RCSID("$NetBSD: strcpy_thumb.S,v 1.1 2013/08/20 21:32:50 matt Exp $")
  32
  33 #ifdef _LIBC
  34 #ifdef STRLCPY
  35 WEAK_ALIAS(strlcpy, _strlcpy)
  36 #endif
  37 #include "namespace.h"
  38 #endif
  39
  40 /*
  41  * These are "naive" versions of the str*cpy routines designed to be simple
  42  * and small.
  43  */
  44
  45 #if defined(STRLCPY)
  46 /* LINTSTUB: size_t strlcpy(char *, const char *, size_t) */
  47 ENTRY(strlcpy)
  48         adds    r3, r1, #1              /* save src pointer (+ NUL) */
  49         subs    r2, r2, #1              /* make sure there's room for a NUL */
  50         blt     3f                      /*   no room, do the strlen */
  51         adds    r2, r2, r0              /* get end of dst */
  52         subs    r0, r0, r1              /* bias against r1 so one incr */
  53 1:      cmp     r0, r2                  /* room for another char? */
  54         beq     2f                      /*   no, write NUL and do the strlen */
  55         ldrb    r3, [r1]                /* read a byte */
  56         strb    r3, [r0, r1]            /* write a byte */
  57         adds    r1, r1, #1              /* advance to next byte */
  58         cmp     r3, #0                  /* was it a NUL? */
  59         bne     1b                      /*   no, do next byte */
  60         b       4f                      /*   yes, end of string, so return */
  61 2:      movs    r3, #0                  /* NUL */
  62         strb    r3, [r0]                /* write to end of string */
  63 3:      ldrb    r3, [r1]                /* read a byte */
  64         adds    r1, r1, #1              /* advance to next byte */
  65         cmp     r3, #0                  /* was it a NUL? */
  66         bne     3b                      /*   no, get next byte */
  67 4:      subs    r0, r1, r3              /* return length of src string */
  68         RET
  69 END(strlcpy)
  70 #elif defined(STRNCPY)
  71 /* LINTSTUB: char * strncpy(char *, const char *, size_t) */
  72 ENTRY(strncpy)
  73         mov     ip, r0                  /* we want to preserve r0 */
  74         adds    r2, r2, r0              /* get end of dst buffer */
  75         subs    r1, r1, r0              /* allows to only increment once */
  76 1:      cmp     r0, r2                  /* are at the end of dst already? */
  77         beq     3f                      /*   yes, just return. */
  78         ldrb    r3, [r1, r0]            /* read a byte */
  79         strb    r3, [r0]                /* write a byte */
  80         adds    r0, r0, #1              /* advance a byte */
  81         cmp     r3, #0                  /* was it a NUL? */
  82         bne     1b                      /*   no, try next byte */
  83 2:      cmp     r0, r2                  /* are at the end of dst already? */
  84         beq     3f                      /*   yes, exit loop
  85         strb    r3, [r0]                /* write a NUL */
  86         adds    r0, r0, #1              /* advance a bytes */
  87         b       2b                      /* until dst is filled */
  88 3:      mov     r0, ip                  /* return dst pointer */
  89         RET
  90 END(strncpy)
  91 #else
  92 /* LINTSTUB: char * strcpy(char *, const char *) */
  93 ENTRY(strcpy)
  94         subs    r2, r0, r1              /* we want to preserve r0 */
  95 1:      ldrb    r3, [r1]                /* read a byte */
  96         strb    r3, [r2, r1]            /* write a byte */
  97         adds    r1, r1, #1              /* advance to next byte */
  98         cmp     r3, #0                  /* was it a NUL? */
  99         bne     1b                      /*   no, try next byte */
 100         RET                             /* return dst pointer */
 101 END(strcpy)
 102 #endif