common/lib/libc/arch/m68k/string/memcmp.S

   1 /*      $NetBSD: memcmp.S,v 1.5 2013/09/07 19:06:29 chs Exp $   */
   2
   3 /*-
   4  * Copyright (c) 1990 The Regents of the University of California.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * the Systems Programming Group of the University of Utah Computer
   9  * Science Department.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39 #if 0
  40         RCSID("from: @(#)bcmp.s 5.1 (Berkeley) 5/12/90")
  41 #else
  42         RCSID("$NetBSD: memcmp.S,v 1.5 2013/09/07 19:06:29 chs Exp $")
  43 #endif
  44 #endif /* LIBC_SCCS and not lint */
  45
  46 /* memcmp(s1, s2, n) */
  47
  48 #ifdef __mcoldfire__
  49 #define CMPMB(a,b)      movb b,%d2; cmpb a,%d2
  50 #define CMPMW(a,b)      movw b,%d2; cmpw a,%d2
  51 #define CMPML(a,b)      movl b,%d2; cmpl a,%d2
  52 #else
  53 #define CMPMB(a,b)      cmpmb a,b
  54 #define CMPMW(a,b)      cmpmw a,b
  55 #define CMPML(a,b)      cmpml a,b
  56 #endif
  57
  58 /*
  59  * This is probably not the best we can do, but it is still 2-10 times
  60  * faster than the C version in the portable gen directory.
  61  *
  62  * Things that might help:
  63  *      - longword align when possible (only on the 68020)
  64  *      - use nested DBcc instructions or use one and limit size to 64K
  65  */
  66 ENTRY(memcmp)
  67         movl    4(%sp),%a0              | string 1
  68         movl    8(%sp),%a1              | string 2
  69         movl    12(%sp),%d0             | length
  70 #ifdef __mcoldfire__
  71         movl    %d2,-(%sp)              | save temp
  72 #endif
  73         jeq     .Lbcdone                | if zero, nothing to do
  74         movl    %a0,%d1
  75         btst    #0,%d1                  | string 1 address odd?
  76         jeq     .Lbceven                | no, skip alignment
  77         CMPMB((%a0)+,(%a1)+)            | yes, compare a byte
  78         jne     .Lbcnoteq               | not equal, return non-zero
  79         subql   #1,%d0                  | adjust count
  80         jeq     .Lbcdone                | count 0, reutrn zero
  81 .Lbceven:
  82         movl    %a1,%d1
  83         btst    #0,%d1                  | string 2 address odd?
  84         jne     .Lbcbloop               | yes, no hope for alignment, compare bytes
  85         movl    %d0,%d1                 | no, both even
  86         lsrl    #2,%d1                  | convert count to longword count
  87         jeq     .Lbcbloop               | count 0, skip longword loop
  88 .Lbclloop:
  89         CMPML((%a0)+,(%a1)+)            | compare a longword
  90         jne     .Lbcnoteql              | not equal, return non-zero
  91         subql   #1,%d1                  | adjust count
  92         jne     .Lbclloop               | still more, keep comparing
  93         andl    #3,%d0                  | what remains
  94         jeq     .Lbcdone                | nothing, all done
  95 .Lbcbloop:
  96         CMPMB((%a0)+,(%a1)+)            | compare a byte
  97         jne     .Lbcnoteq               | not equal, return non-zero
  98         subql   #1,%d0                  | adjust count
  99         jne     .Lbcbloop               | still more, keep going
 100         rts
 101 .Lbcnoteql:
 102         subql   #4,%a0
 103         subql   #4,%a1
 104         movl    #4,%d0
 105         jra     .Lbcbloop
 106 .Lbcnoteq:
 107         clrl    %d0
 108         clrl    %d1
 109         movb    -(%a0),%d0
 110         movb    -(%a1),%d1
 111         subl    %d1,%d0
 112 .Lbcdone:
 113 #ifdef __mcoldfire__
 114         movl    (%sp)+,%sp              | restore temp
 115 #endif
 116         rts
 117 END(memcmp)