common/lib/libc/arch/vax/gen/udiv.S

   1 /*-
   2  * Copyright (c) 1991, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Donn Seeley at UUNET Technologies, Inc.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32
  33 #include <machine/asm.h>
  34
  35         /* .asciz "@(#)udiv.s   8.1 (Berkeley) 6/4/93" */
  36 RCSID("$NetBSD: udiv.S,v 1.3 2011/01/25 04:45:28 matt Exp $")
  37
  38 /*
  39  * Unsigned division, PCC flavor.
  40  * udiv() takes an ordinary dividend/divisor pair;
  41  * audiv() takes a pointer to a dividend and an ordinary divisor.
  42  */
  43
  44 #define DIVIDEND        4(%ap)
  45 #define DIVISOR         8(%ap)
  46
  47 ASENTRY(__udiv,0)
  48         movl    DIVISOR,%r2
  49         jlss    Leasy           # big divisor: settle by comparison
  50         movl    DIVIDEND,%r0
  51         jlss    Lhard           # big dividend: extended division
  52         divl2   %r2,%r0         # small divisor and dividend: signed division
  53         ret
  54 Lhard:
  55         clrl    %r1
  56         ediv    %r2,%r0,%r0,%r1
  57         ret
  58 Leasy:
  59         cmpl    DIVIDEND,%r2
  60         jgequ   Lone            # if dividend is as big or bigger, return 1
  61         clrl    %r0             # else return 0
  62         ret
  63 Lone:
  64         movl    $1,%r0
  65         ret
  66 END(__udiv)
  67
  68 ASENTRY(__audiv,0)
  69         movl    DIVIDEND,%r3
  70         movl    DIVISOR,%r2
  71         jlss    La_easy         # big divisor: settle by comparison
  72         movl    (%r3),%r0
  73         jlss    La_hard         # big dividend: extended division
  74         divl2   %r2,%r0         # small divisor and dividend: signed division
  75         movl    %r0,(%r3)               # leave the value of the assignment in %r0
  76         ret
  77 La_hard:
  78         clrl    %r1
  79         ediv    %r2,%r0,%r0,%r1
  80         movl    %r0,(%r3)
  81         ret
  82 La_easy:
  83         cmpl    (%r3),%r2
  84         jgequ   La_one          # if dividend is as big or bigger, return 1
  85         clrl    %r0             # else return 0
  86         clrl    (%r3)
  87         ret
  88 La_one:
  89         movl    $1,%r0
  90         movl    %r0,(%r3)
  91         ret
  92 END(__audiv)