common/lib/libc/arch/arm/string/memset.S

   1 /*      $NetBSD: memset.S,v 1.1 2005/12/20 19:28:49 christos Exp $      */
   2
   3 /*
   4  * Copyright 2003 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Steve C. Woodford for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37 /*
  38  * Copyright (c) 1995 Mark Brinicombe.
  39  * All rights reserved.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by Mark Brinicombe.
  52  * 4. The name of the company nor the name of the author may be used to
  53  *    endorse or promote products derived from this software without specific
  54  *    prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED
  57  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  58  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  59  * IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
  60  * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  61  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  62  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  */
  68
  69 #include <machine/asm.h>
  70
  71 /*
  72  * memset: Sets a block of memory to the specified value
  73  *
  74  * On entry:
  75  *   r0 - dest address
  76  *   r1 - byte to write
  77  *   r2 - number of bytes to write
  78  *
  79  * On exit:
  80  *   r0 - dest address
  81  */
  82 #ifdef _BZERO
  83 /* LINTSTUB: Func: void bzero(void *, size_t) */
  84 ENTRY(bzero)
  85         mov     r3, #0x00
  86 #else
  87 /* LINTSTUB: Func: void *memset(void *, int, size_t) */
  88 ENTRY(memset)
  89         and     r3, r1, #0xff           /* We deal with bytes */
  90         mov     r1, r2
  91 #endif
  92         cmp     r1, #0x04               /* Do we have less than 4 bytes */
  93         mov     ip, r0
  94         blt     .Lmemset_lessthanfour
  95
  96         /* Ok first we will word align the address */
  97         ands    r2, ip, #0x03           /* Get the bottom two bits */
  98         bne     .Lmemset_wordunaligned  /* The address is not word aligned */
  99
 100         /* We are now word aligned */
 101 .Lmemset_wordaligned:
 102 #ifndef _BZERO
 103         orr     r3, r3, r3, lsl #8      /* Extend value to 16-bits */
 104 #endif
 105 #ifdef __XSCALE__
 106         tst     ip, #0x04               /* Quad-align for Xscale */
 107 #else
 108         cmp     r1, #0x10
 109 #endif
 110 #ifndef _BZERO
 111         orr     r3, r3, r3, lsl #16     /* Extend value to 32-bits */
 112 #endif
 113 #ifdef __XSCALE__
 114         subne   r1, r1, #0x04           /* Quad-align if necessary */
 115         strne   r3, [ip], #0x04
 116         cmp     r1, #0x10
 117 #endif
 118         blt     .Lmemset_loop4          /* If less than 16 then use words */
 119         mov     r2, r3                  /* Duplicate data */
 120         cmp     r1, #0x80               /* If < 128 then skip the big loop */
 121         blt     .Lmemset_loop32
 122
 123         /* Do 128 bytes at a time */
 124 .Lmemset_loop128:
 125         subs    r1, r1, #0x80
 126 #ifdef __XSCALE__
 127         strged  r2, [ip], #0x08
 128         strged  r2, [ip], #0x08
 129         strged  r2, [ip], #0x08
 130         strged  r2, [ip], #0x08
 131         strged  r2, [ip], #0x08
 132         strged  r2, [ip], #0x08
 133         strged  r2, [ip], #0x08
 134         strged  r2, [ip], #0x08
 135         strged  r2, [ip], #0x08
 136         strged  r2, [ip], #0x08
 137         strged  r2, [ip], #0x08
 138         strged  r2, [ip], #0x08
 139         strged  r2, [ip], #0x08
 140         strged  r2, [ip], #0x08
 141         strged  r2, [ip], #0x08
 142         strged  r2, [ip], #0x08
 143 #else
 144         stmgeia ip!, {r2-r3}
 145         stmgeia ip!, {r2-r3}
 146         stmgeia ip!, {r2-r3}
 147         stmgeia ip!, {r2-r3}
 148         stmgeia ip!, {r2-r3}
 149         stmgeia ip!, {r2-r3}
 150         stmgeia ip!, {r2-r3}
 151         stmgeia ip!, {r2-r3}
 152         stmgeia ip!, {r2-r3}
 153         stmgeia ip!, {r2-r3}
 154         stmgeia ip!, {r2-r3}
 155         stmgeia ip!, {r2-r3}
 156         stmgeia ip!, {r2-r3}
 157         stmgeia ip!, {r2-r3}
 158         stmgeia ip!, {r2-r3}
 159         stmgeia ip!, {r2-r3}
 160 #endif
 161         bgt     .Lmemset_loop128
 162         RETc(eq)                        /* Zero length so just exit */
 163
 164         add     r1, r1, #0x80           /* Adjust for extra sub */
 165
 166         /* Do 32 bytes at a time */
 167 .Lmemset_loop32:
 168         subs    r1, r1, #0x20
 169 #ifdef __XSCALE__
 170         strged  r2, [ip], #0x08
 171         strged  r2, [ip], #0x08
 172         strged  r2, [ip], #0x08
 173         strged  r2, [ip], #0x08
 174 #else
 175         stmgeia ip!, {r2-r3}
 176         stmgeia ip!, {r2-r3}
 177         stmgeia ip!, {r2-r3}
 178         stmgeia ip!, {r2-r3}
 179 #endif
 180         bgt     .Lmemset_loop32
 181         RETc(eq)                        /* Zero length so just exit */
 182
 183         adds    r1, r1, #0x10           /* Partially adjust for extra sub */
 184
 185         /* Deal with 16 bytes or more */
 186 #ifdef __XSCALE__
 187         strged  r2, [ip], #0x08
 188         strged  r2, [ip], #0x08
 189 #else
 190         stmgeia ip!, {r2-r3}
 191         stmgeia ip!, {r2-r3}
 192 #endif
 193         RETc(eq)                        /* Zero length so just exit */
 194
 195         addlt   r1, r1, #0x10           /* Possibly adjust for extra sub */
 196
 197         /* We have at least 4 bytes so copy as words */
 198 .Lmemset_loop4:
 199         subs    r1, r1, #0x04
 200         strge   r3, [ip], #0x04
 201         bgt     .Lmemset_loop4
 202         RETc(eq)                        /* Zero length so just exit */
 203
 204 #ifdef __XSCALE__
 205         /* Compensate for 64-bit alignment check */
 206         adds    r1, r1, #0x04
 207         RETc(eq)
 208         cmp     r1, #2
 209 #else
 210         cmp     r1, #-2
 211 #endif
 212
 213         strb    r3, [ip], #0x01         /* Set 1 byte */
 214         strgeb  r3, [ip], #0x01         /* Set another byte */
 215         strgtb  r3, [ip]                /* and a third */
 216         RET                             /* Exit */
 217
 218 .Lmemset_wordunaligned:
 219         rsb     r2, r2, #0x004
 220         strb    r3, [ip], #0x01         /* Set 1 byte */
 221         cmp     r2, #0x02
 222         strgeb  r3, [ip], #0x01         /* Set another byte */
 223         sub     r1, r1, r2
 224         strgtb  r3, [ip], #0x01         /* and a third */
 225         cmp     r1, #0x04               /* More than 4 bytes left? */
 226         bge     .Lmemset_wordaligned    /* Yup */
 227
 228 .Lmemset_lessthanfour:
 229         cmp     r1, #0x00
 230         RETc(eq)                                /* Zero length so exit */
 231         strb    r3, [ip], #0x01         /* Set 1 byte */
 232         cmp     r1, #0x02
 233         strgeb  r3, [ip], #0x01         /* Set another byte */
 234         strgtb  r3, [ip]                /* and a third */
 235         RET                             /* Exit */