common/lib/libc/arch/vax/string/memcpy.S

   1 /*      $NetBSD: memcpy.S,v 1.2 2005/12/24 08:33:32 matt Exp $  */
   2 /*-
   3  * Copyright (c) 1990, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. Neither the name of the University nor the names of its contributors
  15  *    may be used to endorse or promote products derived from this software
  16  *    without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  */
  30
  31 #if defined(LIBC_SCCS) && !defined(lint)
  32         .asciz "@(#)memcpy.s    8.1 (Berkeley) 6/4/93"
  33 #endif /* LIBC_SCCS and not lint */
  34
  35 /*
  36  * void *memcpy(dst, src, size)
  37  * returns dst
  38  *
  39  * This optimises the usual case (count < 65536) at the expense
  40  * of some extra memory references and branches when count >= 65536.
  41  */
  42
  43 #include <machine/asm.h>
  44
  45 ENTRY(memcpy, 0)
  46         movzwl  $65535,%r0      /* %r0 = 64K (needed below) */
  47         movq    8(%ap),%r1      /* %r1 = src, %r2 = length */
  48         movl    4(%ap),%r3      /* %r3 = dst */
  49         cmpl    %r1,%r3
  50         bgtru   1f              /* normal forward case */
  51         beql    2f              /* equal, nothing to do */
  52         addl2   %r2,%r1         /* overlaps iff src<dst but src+len>dst */
  53         cmpl    %r1,%r3
  54         bgtru   4f              /* overlapping, must move backwards */
  55         subl2   %r2,%r1
  56
  57 1:      /* move forward */
  58         cmpl    %r2,%r0
  59         bgtru   3f              /* stupid movc3 limitation */
  60         movc3   %r2,(%r1),(%r3) /* move it all */
  61 2:
  62         movl    4(%ap),%r0      /* return original dst */
  63         ret
  64 3:
  65         subl2   %r0,12(%ap)     /* adjust length by 64K */
  66         movc3   %r0,(%r1),(%r3) /* move 64K */
  67         movl    12(%ap),%r2
  68         decw    %r0             /* from 0 to 65535 */
  69         brb     1b              /* retry */
  70
  71 4:      /* move backward */
  72         addl2   %r2,%r3
  73 5:
  74         cmpl    %r2,%r0
  75         bgtru   6f              /* stupid movc3 limitation */
  76         subl2   %r2,%r1
  77         subl2   %r2,%r3
  78         movc3   %r2,(%r1),(%r3) /* move it all */
  79         movl    4(%ap),%r0      /* return original dst */
  80         ret
  81 6:
  82         subl2   %r0,12(%ap)     /* adjust length by 64K */
  83         subl2   %r0,%r1
  84         subl2   %r0,%r3
  85         movc3   %r0,(%r1),(%r3) /* move 64K */
  86         movl    12(%ap),%r2
  87         decw    %r0
  88         subl2   %r0,%r1
  89         subl2   %r0,%r3
  90         brb     5b