lib/libc/arch/sparc/gen/fixunsdfsi.S

   1 /*      $NetBSD: fixunsdfsi.S,v 1.5 2003/08/07 16:42:23 agc Exp $       */
   2
   3 /*
   4  * Copyright (c) 1992, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This software was developed by the Computer Systems Engineering group
   8  * at Lawrence Berkeley Laboratory under DARPA contract BG 91-66 and
   9  * contributed to Berkeley.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * from: Header: fixunsdfsi.s,v 1.3 91/10/08 00:03:15 torek Exp
  36  */
  37
  38 #include <machine/asm.h>
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40 #if 0
  41         .asciz "@(#)fixunsdfsi.s        8.1 (Berkeley) 6/4/93"
  42 #else
  43         RCSID("$NetBSD: fixunsdfsi.S,v 1.5 2003/08/07 16:42:23 agc Exp $")
  44 #endif
  45 #endif /* LIBC_SCCS and not lint */
  46
  47 /*
  48  * Convert double to unsigned integer (for gcc).
  49  *
  50  * I have made the output for NaN agree with the Sun compiler, not
  51  * that it really matters, by using `fbul,a'.
  52  */
  53
  54
  55         .align  8
  56 Lbig:
  57         .word   0x41e00000              ! .double 0r2147483648.0e+00
  58         .word   0                       ! (who me, not trust the assembler?)
  59
  60 ENTRY(__fixunsdfsi)
  61         sub     %sp, 8, %sp
  62         std     %o0, [%sp + 64]         ! get argument into fpu reg
  63         ldd     [%sp + 64], %f0
  64 #ifdef PIC
  65         PICCY_SET(Lbig, %g1, %o0)
  66         ldd     [%g1], %f2
  67 #else
  68         sethi   %hi(Lbig), %g1
  69         ldd     [%g1 + %lo(Lbig)], %f2
  70 #endif
  71         fcmped  %f0, %f2                ! d < 2^31, or NaN, or -Inf?
  72         nop                             ! (fpop2 delay)
  73         fbul,a  1f                      ! if so, use fdtoi to convert to int
  74         fdtoi   %f0, %f0                !        (this includes negatives!)
  75
  76         ! d does not fit in an int, so subtract 2^31, convert,
  77         ! and add 2^31 again (sigh).  Just hope the intermediate
  78         ! fits (if not, the result is undefined anyway).
  79
  80         fsubd   %f0, %f2, %f0           ! d -= 2^31
  81         fdtoi   %f0, %f0                ! convert to int
  82         st      %f0, [%sp + 64]         ! move into return reg
  83         ld      [%sp + 64], %o0
  84         sethi   %hi(0x80000000), %o1
  85         add     %o0, %o1, %o0           ! add 2^31
  86         retl
  87         add     %sp, 8, %sp
  88
  89 1:
  90         st      %f0, [%sp + 64]         ! return result
  91         ld      [%sp + 64], %o0
  92         retl
  93         add     %sp, 8, %sp