libexec/ld.elf_so/arch/arm/rtld_start.S

   1 /*      $NetBSD: rtld_start.S,v 1.10 2009/11/11 14:15:41 skrll Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1998, 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by Matt Thomas and by Charles M. Hannum.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 RCSID("$NetBSD: rtld_start.S,v 1.10 2009/11/11 14:15:41 skrll Exp $")
  35
  36         .text
  37         .align  0
  38         .globl  _rtld_start
  39         .type   _rtld_start,%function
  40 _rtld_start:
  41         sub     sp, sp, #8              /* make room for obj_main & exit proc */
  42         mov     r4, r0                  /* save ps_strings */
  43
  44         ldr     sl, .L2
  45         ldr     r5, .L2+4
  46         ldr     r0, .L2+8
  47 .L1:
  48         add     sl, pc, sl
  49         ldr     r5, [sl, r5]
  50         ldr     r0, [sl, r0]
  51
  52         sub     r1, sl, r5              /* relocbase */
  53         add     r0, r1, r0              /* &_DYNAMIC */
  54         bl      _rtld_relocate_nonplt_self
  55
  56         sub     r1, sl, r5              /* relocbase */
  57         mov     r0, sp                  /* sp */
  58         bl      _rtld                   /* call the shared loader */
  59         mov     r3, r0                  /* save entry point */
  60
  61         ldr     r2, [sp, #0]            /* r2 = cleanup */
  62         ldr     r1, [sp, #4]            /* r1 = obj_main */
  63         add     sp, sp, #8              /* restore stack */
  64         mov     r0, r4                  /* restore ps_strings */
  65 #ifdef _ARM_ARCH_4T
  66         bx      r3                      /* jump to the entry point */
  67 #else
  68         mov     pc, r3                  /* jump to the entry point */
  69 #endif
  70 .L2:
  71         .word   _GLOBAL_OFFSET_TABLE_ - (.L1+8)
  72         .word   _GLOBAL_OFFSET_TABLE_(GOT)
  73         .word   _DYNAMIC(GOT)
  74
  75         .align  0
  76         .globl  _rtld_bind_start
  77         .type   _rtld_bind_start,%function
  78 /*
  79  *      stack[0] = RA
  80  *      ip = &GOT[n+3]
  81  *      lr = &GOT[2]
  82  */
  83 _rtld_bind_start:
  84         stmdb   sp!,{r0-r4,sl,fp}
  85
  86         sub     r1, ip, lr              /* r1 = 4 * (n + 1) */
  87         sub     r1, r1, #4              /* r1 = 4 * n */
  88         add     r1, r1, r1              /* r1 = 8 * n */
  89
  90         ldr     r0, [lr, #-4]           /* get obj ptr from GOT[1] */
  91         mov     r4, ip                  /* save GOT location */
  92
  93         bl      _rtld_bind              /* Call the binder */
  94
  95         str     r0, [r4]                /* save address in GOT */
  96         mov     ip, r0                  /* save new address */
  97
  98         ldmia   sp!,{r0-r4,sl,fp,lr}    /* restore the stack */
  99 #ifdef _ARM_ARCH_4T
 100         bx      ip                      /* jump to the new address */
 101 #else
 102         mov     pc, ip                  /* jump to the new address */
 103 #endif
 104